mpd-skiphidden/PKGBUILD

   1 # Maintainer: Damir Perisa <damir.perisa@bluewin.ch>
   2 # Contributor: Ben <ben@benmazer.net>
   3 # Contributor: eWoud <ewoud.nuyts@gmail.com>
   4
   5 pkgname=mpd-skiphidden
   6 _pkgname=mpd
   7 conflicts=('mpd')
   8 provides=('mpd')
   9 pkgver=0.15.5
  10 pkgrel=1
  11 pkgdesc="Music daemon that plays MP3, FLAC, and Ogg Vorbis files (skips hidden files)"
  12 arch=('i686' 'x86_64')
  13 license=('GPL')
  14 url="http://musicpd.org"
  15 depends=('libao' 'ffmpeg' 'libmodplug' 'audiofile' 'libshout' 'libmad' 'curl'
  16          'sqlite3' 'libsamplerate' 'libmms' 'libmikmod' 'wavpack' 'libmpcdec')
  17 makedepends=('pkgconfig')
  18 install=mpd.install
  19 source=(http://downloads.sourceforge.net/project/musicpd/mpd/${pkgver}/mpd-${pkgver}.tar.bz2
  20         'mpd'
  21         'hide-dot-files.diff')
  22 md5sums=('078bd45c8266ac577e4a96fa38d1e534'
  23          'b1fd15de359db08e4b9ae4b199640f0e'
  24          'b40b4f186440bb1373d4621e957e00d8')
  25
  26 build() {
  27   cd ${srcdir}/${_pkgname}-${pkgver}
  28   patch -p0 -i ${srcdir}/hide-dot-files.diff || exit 1
  29   ./configure --prefix=/usr \
  30     --sysconfdir=/etc \
  31     --disable-jack \
  32     --enable-ao \
  33     --enable-mikmod \
  34     --with-zeroconf=no
  35   make || return 1
  36   make DESTDIR=${pkgdir} install
  37
  38   # set ours dirs in mpd.conf file
  39   sed -i 's|^music_directory.*$|#music_directory "path_to_your_music_collection"|1' doc/mpdconf.example
  40   sed -i 's|playlist_directory.*$|playlist_directory "/var/lib/mpd/playlists"|1' doc/mpdconf.example
  41   sed -i 's|db_file.*$|db_file "/var/lib/mpd/mpd.db"|1' doc/mpdconf.example
  42   sed -i 's|log_file.*$|log_file "/var/log/mpd/mpd.log"|1' doc/mpdconf.example
  43   sed -i 's|error_file.*$|error_file "/var/log/mpd/mpd.error"|1' doc/mpdconf.example
  44   sed -i 's|#pid_file.*$|pid_file "/var/run/mpd/mpd.pid"|1' doc/mpdconf.example
  45   sed -i 's|#state_file.*$|state_file "/var/lib/mpd/mpdstate"|1' doc/mpdconf.example
  46   sed -i 's|#user.*$|user "mpd"|1' doc/mpdconf.example
  47
  48   install -Dm644 doc/mpdconf.example ${pkgdir}/etc/mpd.conf.example || return 1
  49
  50   install -D ${srcdir}/mpd ${pkgdir}/etc/rc.d/mpd || return 1
  51   install -d ${pkgdir}/var/lib/mpd/playlists ${pkgdir}/var/log/mpd ${pkgdir}/var/run/mpd
  52 }