makepkg/PKGBUILD

   1 # Maintainer: Alad Wenter <https://github.com/AladW>
   2 pkgname=aurutils-git
   3 pkgver=16.4.r0.g9d8342c5
   4 pkgrel=1
   5 pkgdesc='helper tools for the arch user repository'
   6 url='https://github.com/AladW/aurutils'
   7 arch=('any')
   8 license=('custom:ISC')
   9 source=('git+https://github.com/AladW/aurutils')
  10 changelog=aurutils.changelog
  11 sha256sums=('SKIP')
  12 conflicts=('aurutils')
  13 provides=("aurutils=${pkgver%%.r*}")
  14 depends=('git' 'pacutils' 'curl' 'bash' 'perl' 'perl-json-xs')
  15 makedepends=('git')
  16 optdepends=('bash-completion: bash completion'
  17             'zsh: zsh completion'
  18             'devtools: aur-chroot'
  19             'vifm: default pager'
  20             'ninja: aur-sync ninja support'
  21             'bat: view-delta example script'
  22             'git-delta: view-delta example script'
  23             'python-srcinfo: sync-rebuild example script')
  24
  25 pkgver() {
  26     cd aurutils
  27     git describe --long --tags | sed 's/\([^-]*-g\)/r\1/; s/-/./g'
  28 }
  29
  30 build() {
  31     cd aurutils
  32     make
  33 }
  34
  35 package() {
  36     cd aurutils
  37     make DESTDIR="$pkgdir" install
  38 }