configure.in

   1 ###
   2 ### Welcome to Beagle's configure.in.  We hope you enjoy your stay.
   3 ###
   4
   5 AC_INIT(beagled/BeagleDaemon.cs)
   6 AC_CANONICAL_SYSTEM
   7 AM_INIT_AUTOMAKE(beagle, 0.2.12)
   8
   9 ########################################################################
  10
  11 ###
  12 ### Some dependencies
  13 ###
  14
  15 MONO_REQUIRED=1.1.13.5
  16 GTK_SHARP_REQUIRED=2.4.0
  17 GMIME_SHARP_REQUIRED=2.2.0
  18 EVOLUTION_SHARP_REQUIRED=0.10.2
  19 GSF_SHARP_REQUIRED=0.6
  20 GTK_REQUIRED=2.6.0
  21
  22 LIBBEAGLE_GOBJECT_REQUIRED=2.6
  23 LIBBEAGLE_LIBXML_REQUIRED=2.6.19
  24
  25 PYTHON_REQUIRED=2.3
  26 PYGTK_REQUIRED=2.6
  27
  28 ########################################################################
  29
  30 AM_MAINTAINER_MODE
  31 AM_CONFIG_HEADER(config.h)
  32
  33 AC_PROG_INSTALL
  34 AM_PROG_LIBTOOL
  35 AC_PROG_CXX
  36
  37 VERSION=${VERSION}
  38 AC_SUBST(VERSION)
  39
  40 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  41 if test "x$PKG_CONFIG" = "xno"; then
  42         AC_MSG_ERROR([You need to install pkg-config])
  43 fi
  44
  45 AC_PATH_PROG(BASH, bash)
  46 AC_SUBST(BASH)
  47
  48 # mozilla extension uses zip to create the jar/xpi files
  49 AC_PATH_PROG(ZIP, zip)
  50
  51 AC_PATH_PROG(MONO, mono)
  52 AC_PATH_PROG(MCS, mcs)
  53
  54 AC_MSG_CHECKING([for mono.pc])
  55 if test -z `$PKG_CONFIG --variable=prefix mono`; then
  56   AC_MSG_ERROR([missing the mono.pc file, usually found in the mono-devel package])
  57 else
  58   AC_MSG_RESULT([found])
  59 fi
  60
  61 # check that we have the require version of mono
  62 PKG_CHECK_MODULES(MONO, mono >= $MONO_REQUIRED)
  63
  64 BEAGLE_DEFINES=""
  65
  66 # SharpZipLib broke API in 1.1.11.  Route around the damage.
  67 if `$PKG_CONFIG --atleast-version=1.1.11 mono`; then
  68   SHARPZIPLIB_LIBS="-r:`$PKG_CONFIG --variable=prefix mono`/lib/mono/compat-1.0/ICSharpCode.SharpZipLib.dll"
  69 else
  70   SHARPZIPLIB_LIBS="-r:ICSharpCode.SharpZipLib"
  71 fi
  72 AC_SUBST(SHARPZIPLIB_LIBS)
  73
  74 # check for various mono DLLs that we need.
  75 needed_dlls="Mono.Data.SqliteClient Mono.Posix System.Runtime.Remoting System.Web System.Web.Services"
  76 for i in $needed_dlls; do
  77   AC_MSG_CHECKING([for $i.dll])
  78   if test ! -e `$PKG_CONFIG --variable=prefix mono`/lib/mono/1.0/$i.dll; then
  79     AC_MSG_ERROR([missing required mono DLL: $i.dll])
  80   else
  81     AC_MSG_RESULT([found])
  82   fi
  83 done
  84
  85 # check for OS
  86 case "$target" in
  87   *-*-linux*)
  88     os=linux
  89         os_has_inotify=yes
  90     ;;
  91   *-*-freebsd*)
  92     os=freebsd
  93         os_has_inotify=no
  94     ;;
  95   *)
  96     AC_MSG_ERROR([Unrecognised target OS: $target])
  97     ;;
  98 esac
  99 AM_CONDITIONAL(OS_LINUX, test "x$os" = "xlinux")
 100 AM_CONDITIONAL(OS_FREEBSD, test "x$os" = "xfreebsd")
 101
 102 # xdgmime really wants to have HAVE_MMAP defined
 103 AC_FUNC_MMAP()
 104
 105 # check for desktop-launch
 106
 107 AC_PATH_PROG(DESKTOP_LAUNCH, desktop-launch, no)
 108 AM_CONDITIONAL(ENABLE_DESKTOP_LAUNCH, test "x$DESKTOP_LAUNCH" != "xno")
 109
 110 # Google QueryDriver
 111 # Disable GoogleDriver by default, enable if you want know what you are doing
 112 dnl -----------------------------------------------
 113 AC_ARG_ENABLE([googledriver],
 114         AC_HELP_STRING([--enable-googledriver], [Enable Google backend]),
 115         enable_googledriver=$enableval,
 116         enable_googledriver=no)
 117
 118 if test "x$enable_googledriver" = "xyes"; then
 119         # check for wsdl
 120         AC_PATH_PROG(WSDL, wsdl)
 121 fi
 122
 123 AM_CONDITIONAL(ENABLE_GOOGLEDRIVER, test "x$enable_googledriver" = "xyes")
 124
 125 #
 126 # I18N
 127 #
 128
 129 AC_PROG_INTLTOOL([0.23])
 130 GETTEXT_PACKAGE=beagle
 131 AC_SUBST(GETTEXT_PACKAGE)
 132 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es fi fr gl he hi hu it ja ka ko lt lv mk nb nl pa pl pt_BR ru sr sr@Latn sv th tr uk vi zh_CN zh_HK zh_TW"
 133 AM_GLIB_GNU_GETTEXT
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Name of the package for translations])
 135
 136 # Many distros don't have a dependency on sqlite for their
 137 # mono-data-sqlite packages, and the mono build process itself
 138 # doesn't require it.  But we do, so check for it here.
 139 SQLITE_MAJ_VER="0"
 140 AC_ARG_ENABLE([sqlite2],
 141               AC_HELP_STRING([--enable-sqlite2], [Force the use of sqlite2, even if 3 is available.]),
 142               enable_sqlite2=$enableval,
 143               enable_sqlite2=auto)
 144 if test "x$enable_sqlite2" = "xyes"; then
 145         PKG_CHECK_MODULES(SQLITE, sqlite, SQLITE_MAJ_VER="2", do_nothing="1")
 146         if test "x$SQLITE_MAJ_VER" = "x0"; then
 147         AC_MSG_ERROR([You need to install sqlite 2])
 148         fi
 149 fi
 150
 151 AC_ARG_ENABLE([sqlite3],
 152               AC_HELP_STRING([--enable-sqlite3], [Force the use of sqlite3, even if 3 is available.]),
 153               enable_sqlite3=$enableval,
 154               enable_sqlite3=auto)
 155 if test "x$enable_sqlite3" = "xyes"; then
 156         PKG_CHECK_MODULES(SQLITE, sqlite3, SQLITE_MAJ_VER="3", do_nothing="1")
 157         if test "x$SQLITE_MAJ_VER" = "x0"; then
 158         AC_MSG_ERROR([You need to install sqlite 3])
 159         fi
 160 fi
 161 if test "x$SQLITE_MAJ_VER" = "x0"; then
 162         PKG_CHECK_MODULES(SQLITE, sqlite, SQLITE_MAJ_VER="2", do_nothing="1")
 163         # Note we really need 3.3.1, but the pkgconfig file from upstream only
 164         # reports 3.3 for all releases in the 3.3 line.
 165         PKG_CHECK_MODULES(SQLITE3, sqlite3 >= 3.3, SQLITE_MAJ_VER="3", do_nothing="1")
 166
 167         if test "x$SQLITE_MAJ_VER" = "x0"; then
 168                 # Note we really need 3.3.1, but the pkgconfig file from upstream only
 169                 # reports 3.3 for all releases in the 3.3 line.  Make sure we error out
 170                 # with the correct 3.3.1 version requirement, though.
 171                 AC_MSG_ERROR([You need to install sqlite 2.x or >= 3.3.1])
 172         fi
 173 fi
 174
 175 AC_SUBST(SQLITE_MAJ_VER)
 176
 177 AC_ARG_ENABLE([xss],
 178               AC_HELP_STRING([--disable-xss], [Disable monitoring xscreensaver to speed up indexing when user is idle]),
 179               enable_xss=$enableval,
 180               enable_xss=yes)
 181
 182 AC_PATH_XTRA
 183
 184 # Needed by glue/screensaver-glue.c
 185 # The OLD_CFLAGS/CFLAGS hack is needed to build on Ubuntu Breezy Badger
 186 OLD_CFLAGS="$CFLAGS"
 187 OLD_LDFLAGS="$LDFLAGS"
 188 OLD_LIBS="$LIBS"
 189 CFLAGS="$CFLAGS $X_CFLAGS"
 190 LDFLAGS="$LDFLAGS $X_LIBS"
 191 AC_CHECK_HEADER(X11/extensions/scrnsaver.h, enable_scrnsaver=yes, enable_scrnsaver=no)
 192 AC_CHECK_LIB(Xss,XScreenSaverQueryExtension, enable_libxss=yes, enable_libxss=no)
 193 have_xss=no
 194 if test "x$enable_xss$enable_scrnsaver$enable_libxss" = "xyesyesyes"; then
 195         XSS_LIBS="-lXss"
 196         have_xss=yes
 197         AC_DEFINE(HAVE_LIBXSS,1,[Define to 1 if libXss is installed])
 198 fi
 199 AM_CONDITIONAL(ENABLE_LIBXSS, test "x$have_xss" = "xyes")
 200 CFLAGS="$OLD_CFLAGS"
 201 LDFLAGS="$OLD_LDFLAGS"
 202 LIBS="$OLD_LIBS"
 203
 204 dnl ----------------------------------------------
 205 AC_ARG_ENABLE([thunderbird],
 206         AC_HELP_STRING([--disable-thunderbird], [Disable Thunderbird Mail Backend]),
 207         enable_tbird=$enableval,
 208         enable_tbird=yes)
 209 AM_CONDITIONAL(ENABLE_THUNDERBIRD, test "x$enable_tbird" = "xyes")
 210
 211 dnl -------------------------------------------------------
 212
 213 AC_ARG_ENABLE([gui],
 214         AC_HELP_STRING([--disable-gui], [Disable beagle-search]),
 215         enable_gui=$enableval,
 216         enable_gui=yes)
 217
 218 AM_CONDITIONAL(ENABLE_GUI, test "x$enable_gui" = "xyes")
 219
 220 if test "x$enable_gui" = "xyes"; then
 221
 222         # We pinvoke into gnome-vfs directly from Util/GnomeFu.cs, and
 223         # we get the GNOME prefix from libgnome-2.0
 224         PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 libgnome-2.0)
 225
 226         dnl -------------------------------------------------------
 227         dnl Various version requirements
 228
 229         PKG_CHECK_MODULES(BEAGLE_UI,
 230 [
 231         gtk-sharp-2.0 >= $GTK_SHARP_REQUIRED
 232         gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED
 233         glade-sharp-2.0 >= $GTK_SHARP_REQUIRED
 234         gnome-sharp-2.0 >= $GTK_SHARP_REQUIRED
 235         gnome-vfs-sharp-2.0 >= $GTK_SHARP_REQUIRED
 236         gmime-sharp >= $GMIME_SHARP_REQUIRED
 237 ])
 238         AC_SUBST(BEAGLE_UI_LIBS)
 239
 240         PKG_CHECK_MODULES(UIGLUE, gtk+-2.0 >= $GTK_REQUIRED librsvg-2.0)
 241         AC_SUBST(UIGLUE_CFLAGS)
 242         AC_SUBST(UIGLUE_LIBS)
 243
 244         dnl Gdk and Atk are needed for trayicon glue
 245
 246         GDK20_MINIMUM_VERSION=2.2.3
 247         ATK_MINIMUM_VERSION=1.2.4
 248
 249         PKG_CHECK_MODULES(LIBTRAYICON,
 250 [
 251         gdk-2.0 >= $GDK20_MINIMUM_VERSION
 252         atk >= $ATK_MINIMUM_VERSION
 253 ])
 254         AC_SUBST(LIBTRAYICON_CFLAGS)
 255         AC_SUBST(LIBTRAYICON_LIBS)
 256
 257 fi
 258
 259 dnl ----------------------------------------------
 260
 261 dnl "Open With" Menu (Requires GTK 2.8)
 262         PKG_CHECK_MODULES(OPEN_WITH,
 263 [
 264         gtk-sharp-2.0 >= 2.8
 265 ],OPEN_WITH=yes,OPEN_WITH=no)
 266 AM_CONDITIONAL(ENABLE_OPEN_WITH, test "x$OPEN_WITH" != "xno")
 267 dnl ----------------------------------------------
 268
 269 dnl evolution support
 270
 271 AC_ARG_ENABLE([evolution],
 272         AC_HELP_STRING([--disable-evolution], [Disable evolution support (default auto)]),
 273         enable_evo=$enableval,
 274         enable_evo_sharp=auto)
 275
 276
 277 EVO_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix evolution-sharp`
 278
 279 EVO_LIBDIR=`$PKG_CONFIG --variable=evolibdir evolution-sharp`
 280 AC_SUBST(EVO_LIBDIR)
 281
 282 PKG_CHECK_MODULES(EVO,
 283                   evolution-sharp >= $EVOLUTION_SHARP_REQUIRED  \
 284                   gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED        \
 285                   gmime-sharp >= $GMIME_SHARP_REQUIRED,
 286                   have_evo_dependencies=yes, have_evo_dependencies=no)
 287 AC_SUBST(EVO_LIBS)
 288
 289 if test "x$have_evo_dependencies" = "xno"; then
 290
 291         dnl error out if user has explicitly requested evolution support
 292         if test "x$enable_evo" = "xyes"; then
 293                 AC_MSG_ERROR([Could not find Evolution dependencies])
 294         fi
 295
 296         enable_evo="no (missing dependencies)"
 297
 298 else
 299
 300         if test "x$enable_evo" != "xno"; then
 301                 enable_evo="yes"
 302         else
 303                 enable_evo="no (disabled)"
 304         fi
 305
 306 fi
 307
 308 AM_CONDITIONAL(ENABLE_EVOLUTION, test "x$enable_evo" = "xyes")
 309
 310 dnl ----------------------------------------------
 311
 312 dnl Should we use our own copy of the sqlite bindings or the version
 313 dnl that got installed along with mono?
 314
 315 use_local_sqlite="yes" # hard-wired for now
 316 AM_CONDITIONAL(USE_LOCAL_SQLITE, test "x$use_local_sqlite" = "xyes")
 317
 318 dnl ----------------------------------------------
 319
 320 dnl inotify
 321
 322 AC_ARG_ENABLE([inotify],
 323          AC_HELP_STRING([--disable-inotify], [Disable inotify filesystem monitoring support (default auto)]),
 324          enable_inotify=$enableval,
 325          enable_inotify=auto)
 326
 327 if test "x$os_has_inotify" = "xno"; then
 328
 329         dnl error out if user has explicitly requested inotify
 330         if test "x$enable_inotify" = "xyes"; then
 331                 AC_MSG_ERROR([inotify is unavailable on your system architecture])
 332         fi
 333
 334         enable_inotify="no (unavailable)"
 335
 336 else
 337
 338         if test "x$enable_inotify" != "xno"; then
 339                 enable_inotify="yes"
 340         else
 341                 enable_inotify="no (disabled)"
 342         fi
 343
 344 fi
 345
 346 AM_CONDITIONAL(ENABLE_INOTIFY, test "x$enable_inotify" = "xyes")
 347
 348 dnl ----------------------------------------------
 349
 350 dnl beagled
 351
 352 PKG_CHECK_MODULES(GSF_SHARP, gsf-sharp >= 0.5, enable_gsf_sharp=yes, enable_gsf_sharp=no)
 353 AM_CONDITIONAL(ENABLE_GSF_SHARP, test "x$enable_gsf_sharp" = "xyes")
 354 if test "x$enable_gsf_sharp" = "xyes"; then
 355         BEAGLE_DEFINES = "$BEAGLE_DEFINES -define:ENABLE_GSF_SHARP"
 356 fi
 357
 358 dnl ----------------------------------------------
 359
 360 dnl libexif: Needed to index jpeg metadata
 361
 362 LIBEXIF_API_CHANGE=0.6.0
 363 LIBEXIF_REQUIRED_MIN=0.5.7
 364 LIBEXIF_REQUIRED_MAX=0.7.0
 365
 366 PKG_CHECK_MODULES(LIBEXIF, libexif >= $LIBEXIF_REQUIRED_MIN libexif < $LIBEXIF_REQUIRED_MAX)
 367 PKG_CHECK_MODULES(LIBEXIF_API_CHECK, libexif >= $LIBEXIF_API_CHANGE, have_old_libexif=no, have_old_libexif=yes)
 368
 369 if test "x$have_old_libexif" = "xyes"; then
 370         EXIF_SOVERSION=9
 371 else
 372         PKG_CHECK_MODULES(LIBEXIF_VERSION_CHECK, libexif >= 0.6.12, EXIF_SOVERSION=12, EXIF_SOVERSION=10)
 373 fi
 374 AC_SUBST(EXIF_SOVERSION)
 375
 376 PKG_CHECK_MODULES(BEAGLED,
 377 [
 378         shared-mime-info
 379         gmime-sharp >= $GMIME_SHARP_REQUIRED
 380         glib-sharp-2.0 >= $GTK_SHARP_REQUIRED
 381 ])
 382         BEAGLED_LIBS="$BEAGLED_LIBS $GSF_SHARP_LIBS"
 383 AC_SUBST(BEAGLED_LIBS)
 384
 385 GSF_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gsf-sharp`
 386 GMIME_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gmime-sharp`
 387
 388 dnl ----------------------------------------------
 389
 390 dnl libbeagle
 391
 392 GTK_DOC_CHECK(1.0)
 393
 394 AC_ARG_ENABLE([libbeagle],
 395         AC_HELP_STRING([--disable-libbeagle], [Disable libbeagle (C API)]),
 396         enable_libbeagle=$enableval,
 397         enable_libbeagle=auto)
 398
 399 dnl library versioning
 400 dnl Increase when changing the API
 401 LIBBEAGLE_CURRENT=0
 402
 403 dnl Update when changing implementation of current API,
 404 dnl reset to 0 when changing CURRENT.  This is the revision of
 405 dnl current API version
 406 LIBBEAGLE_REVISION=0
 407
 408 dnl Increase of API change is ABI compatible, otherwise reset to 0
 409 LIBBEAGLE_AGE=0
 410
 411 LIBBEAGLE_VERSION_INFO="$LIBBEAGLE_CURRENT:$LIBBEAGLE_REVISION:$LIBBEAGLE_AGE"
 412 AC_SUBST(LIBBEAGLE_VERSION_INFO)
 413
 414 PKG_CHECK_MODULES(LIBBEAGLE, [
 415         gobject-2.0 >= $LIBBEAGLE_GOBJECT_REQUIRED
 416         libxml-2.0  >= $LIBBEAGLE_LIBXML_REQUIRED
 417 ], have_libbeagle_deps=yes, have_libbeagle_deps=no)
 418
 419 AC_SUBST(LIBBEAGLE_CFLAGS)
 420 AC_SUBST(LIBBEAGLE_LIBS)
 421
 422 if test "x$have_libbeagle_deps" = "xno"; then
 423
 424         if test "x$enable_libbeagle" = "xyes"; then
 425                 AC_MSG_ERROR([Missing libbeagle dependencies])
 426         fi
 427
 428         enable_libbeagle="no (missing dependencies)"
 429 else
 430         if test "x$enable_libbeagle" != "xno"; then
 431                 enable_libbeagle="yes"
 432         else
 433                 enable_libbeagle="no (disabled)"
 434         fi
 435 fi
 436
 437 AM_CONDITIONAL(ENABLE_LIBBEAGLE, test "x$enable_libbeagle" = "xyes")
 438
 439 dnl ----------------------------------------------
 440 AC_ARG_ENABLE([bludgeon],
 441         AC_HELP_STRING([--disable-bludgeon], [Disable bludgeon testing tool]),
 442         enable_bludgeon=$enableval,
 443         enable_bludgeon=yes)
 444 AM_CONDITIONAL(ENABLE_BLUDGEON, test "x$enable_bludgeon" = "xyes")
 445
 446
 447 dnl ----------------------------------------------
 448 dnl Epiphany Extension
 449 dnl Much of this is cut&pasted from epiphany-extensions/configure.ac
 450
 451 AC_ARG_ENABLE([epiphany-extension],
 452         AC_HELP_STRING([--enable-epiphany-extension], [Enable Epiphany Extension (default auto)]),
 453         enable_epiphany_extension=$enableval,
 454         enable_epiphany_extension=auto)
 455
 456 if $PKG_CONFIG --exists epiphany-2.16; then
 457         EPIPHANY_MAJOR=2.16
 458         EPIPHANY_REQUIRED=2.16.0
 459 elif $PKG_CONFIG --exists epiphany-2.14; then
 460         EPIPHANY_MAJOR=2.14
 461         EPIPHANY_REQUIRED=2.14.0
 462 elif $PKG_CONFIG --exists epiphany-1.8; then
 463         EPIPHANY_MAJOR=1.8
 464         EPIPHANY_REQUIRED=1.7.0
 465 elif $PKG_CONFIG --exists epiphany-1.6; then
 466         EPIPHANY_MAJOR=1.6
 467         EPIPHANY_REQUIRED=1.6.0
 468 else
 469         enable_epiphany_extension="no (Epiphany not installed)"
 470 fi
 471
 472 if test "x$enable_epiphany_extension" = "xyes"; then
 473
 474 LIBXML_REQUIRED=2.6.0
 475 LIBGLIB_REQUIRED=2.4.0
 476 LIBGTK_REQUIRED=2.4.0
 477
 478 AC_SUBST(EPIPHANY_REQUIRED)
 479 AC_SUBST(LIBXML_REQUIRED)
 480 AC_SUBST(LIBGLIB_REQUIRED)
 481 AC_SUBST(LIBGTK_REQUIRED)
 482
 483 PKG_CHECK_MODULES(EPIPHANY_DEPENDENCY,
 484                   libxml-2.0 >= $LIBXML_REQUIRED \
 485                   libglade-2.0 \
 486                   glib-2.0 >= $LIBGLIB_REQUIRED \
 487                   gmodule-2.0 \
 488                   gtk+-2.0 >= $LIBGTK_REQUIRED \
 489                   epiphany-$EPIPHANY_MAJOR >= $EPIPHANY_REQUIRED,
 490                   have_epiphany_dependencies=yes,
 491                   have_epiphany_dependencies=no)
 492 AC_SUBST(EPIPHANY_DEPENDENCY_CFLAGS)
 493 AC_SUBST(EPIPHANY_DEPENDENCY_LIBS)
 494
 495 EPIPHANY_EXTENSIONS_DIR="`$PKG_CONFIG --variable=extensionsdir epiphany-$EPIPHANY_MAJOR`"
 496 AC_SUBST([EPIPHANY_EXTENSIONS_DIR])
 497 EPIPHANY_PREFIX="`$PKG_CONFIG --variable=prefix epiphany-$EPIPHANY_MAJOR`"
 498 AC_SUBST(EPIPHANY_PREFIX)
 499
 500 if test "x$have_epiphany_dependencies" = "xno"; then
 501         enable_epiphany_extension="no (missing dependencies)"
 502 elif test "x$enable_epiphany_extension" != "xyes"; then
 503         enable_epiphany_extension="disabled"
 504 fi
 505
 506 fi
 507
 508 AM_CONDITIONAL(ENABLE_EPIPHANY_EXTENSION, test "x$enable_epiphany_extension" = "xyes")
 509
 510 AC_ARG_ENABLE([epiphany-extension-install],
 511         AS_HELP_STRING([--enable-epiphany-extension-install],[Install Epiphany Extension]),
 512         [install_epiphany_extension=$enableval],
 513         [install_epiphany_extension=yes])
 514
 515 AM_CONDITIONAL([INSTALL_EPIPHANY_EXTENSION], [test "x$install_epiphany_extension" = "xyes"])
 516
 517 dnl ----------------------------------------------
 518
 519 dnl Galago
 520
 521 PKG_CHECK_MODULES(GALAGO, galago-sharp >= 0.5 , enable_galago=yes, enable_galago=no)
 522 AM_CONDITIONAL(ENABLE_GALAGO, test "x$enable_galago" = "xyes")
 523 AC_SUBST(GALAGO_LIBS)
 524
 525
 526 dnl ----------------------------------------------
 527
 528 GTK_BINARY_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 529 AC_SUBST(GTK_BINARY_VERSION)
 530
 531 dnl For the systeminfo glue
 532
 533 SYSTEMINFO_GLUE_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 $XSS_LIBS $X_EXTRA_LIBS"
 534 AC_SUBST(SYSTEMINFO_GLUE_X_LIBS)
 535
 536 dnl ----------------------------------------------
 537
 538 dnl For the wv1 glue
 539
 540 PKG_CHECK_MODULES(WV1, wv-1.0, enable_wv1=yes, enable_wv1=no)
 541 AM_CONDITIONAL(ENABLE_WV1, test "x$enable_wv1" = "xyes")
 542 if test "x$enable_wv1" = "xyes"; then
 543         BEAGLE_DEFINES = "$BEAGLE_DEFINES -define:ENABLE_WV1"
 544 fi
 545 AC_SUBST(WV1_LIBS)
 546
 547 dnl ----------------------------------------------
 548
 549 dnl KDE launcher/icon support
 550
 551 kde_prefix_print="unknown; will guess at runtime"
 552 AC_PATH_PROG(KDE_CONFIG, [kde-config], [no])
 553 if test ! "x$KDE_CONFIG" = "xno"; then
 554         KDE_PREFIX=`$KDE_CONFIG --prefix`
 555         kde_prefix_print="$KDE_PREFIX"
 556 fi
 557 AC_SUBST(KDE_PREFIX)
 558
 559 dnl ----------------------------------------------
 560
 561 dnl Prefixes for helper scripts
 562 GAC_PREFIX="$EVO_SHARP_PREFIX:$GSF_SHARP_PREFIX:$GMIME_SHARP_PREFIX"
 563 dnl Remove duplicate prefixes
 564 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|:|\n|g' | sort | uniq | tr '\n' ':'`"
 565 dnl Remove stray :s
 566 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|::\+|:|g' -e 's|^:\+||' -e 's|:\+$||'`"
 567 AC_SUBST(GAC_PREFIX)
 568
 569 GNOME_PREFIX="`$PKG_CONFIG --variable=prefix libgnome-2.0`"
 570 AC_SUBST(GNOME_PREFIX)
 571
 572 dnl ----------------------------------------------
 573
 574 dnl Check if the system has libchm, used by the CHMFilter
 575
 576 # Check for libchm for CHM filter
 577 AC_CHECK_LIB(chm,chm_open,has_libchm=yes,has_libchm=no)
 578 AM_CONDITIONAL(HAS_LIBCHM, test "x$has_libchm" = "xyes")
 579 if test "x$has_libchm" = "xyes"; then
 580         BEAGLE_DEFINES = "$BEAGLE_DEFINES -define:HAVE_LIBCHM"
 581 fi
 582
 583 dnl ----------------------------------------------
 584
 585 dnl Conditional for debugging XML messages.
 586
 587 AC_ARG_ENABLE([xml-dump],
 588         AC_HELP_STRING([--enable-xml-dump], [Enables printing of the XML messages sent between components (default no)]),
 589         enable_xml_dump=$enableval,
 590         enable_xml_dump=no)
 591
 592 if test "x$enable_xml_dump" = "xyes"; then
 593         AC_DEFINE_UNQUOTED(ENABLE_XML_DUMP, 1, [Dump XML messages for debugging])
 594         BEAGLE_DEFINES="$BEAGLE_DEFINES -define:ENABLE_XML_DUMP"
 595 fi
 596
 597 AC_SUBST(BEAGLE_DEFINES)
 598
 599 dnl ----------------------------------------------
 600
 601 dnl Python 2.3
 602
 603 AC_ARG_ENABLE(python,
 604         AC_HELP_STRING([--disable-python], [Disable python support (default auto)]),
 605         enable_python=$enableval,
 606         enable_python=auto)
 607
 608 have_python=no
 609 if test "x$enable_libbeagle" = "xyes" -a "x$enable_python" != "xno"; then
 610         have_python_version=no
 611         have_python_headers=no
 612         have_pygtk_deps=no
 613         have_pygtk_codegen=no
 614
 615         AM_PATH_PYTHON()
 616
 617         if test -z "$PYTHON"; then
 618                 AC_MSG_WARN([Python not found])
 619         else
 620                 AM_PYTHON_CHECK_VERSION($PYTHON, $PYTHON_REQUIRED,
 621                         have_python_version=yes,
 622                         have_python_version=no)
 623         fi
 624
 625         if test "x$have_python_version" != "xyes"; then
 626                 AC_MSG_WARN([Python version $PYTHON_REQUIRED not found])
 627         else
 628                 AM_CHECK_PYTHON_HEADERS(have_python_headers=yes, have_python_headers=no)
 629         fi
 630
 631         if test "x$have_python_headers" != "xyes"; then
 632                 AC_MSG_WARN([could not find Python headers])
 633         else
 634                 PKG_CHECK_MODULES(PYBEAGLE,
 635                         pygtk-2.0 >= $PYGTK_REQUIRED
 636                         pygobject-2.0 >= $PYGTK_REQUIRED,
 637                         have_pygtk_deps=yes,
 638                         have_pygtk_deps=no)
 639         fi
 640
 641         if test "x$have_pygtk_deps" != "xyes"; then
 642                 AC_MSG_WARN([could not find pygtk])
 643         else
 644                 AC_PATH_PROG(PYGTK_CODEGEN, pygtk-codegen-2.0, no)
 645         fi
 646
 647         if test -z "$PYGTK_CODEGEN"; then
 648                 AC_MSG_WARN([could not find pygtk-codegen in path])
 649         else
 650                 AC_MSG_CHECKING(for pygtk defs)
 651                 PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
 652                 AC_MSG_RESULT($PYGTK_DEFSDIR)
 653
 654                 have_python=yes
 655         fi
 656 fi
 657
 658 if test "x$enable_python" = "xyes"; then
 659         if test "x$enable_libbeagle" != "xyes"; then
 660                 AC_MSG_ERROR([Python bindings are requested, but libbeagle isn't to be built])
 661         elif test "x$have_python" = "xno"; then
 662                 AC_MSG_ERROR([Python bindings are requested, but cannot be built])
 663         fi
 664 fi
 665
 666 AM_CONDITIONAL(ENABLE_PYTHON, test "x$have_python" = "xyes")
 667 AC_SUBST(PYBEAGLE_LIBS)
 668 AC_SUBST(PYBEAGLE_CFLAGS)
 669 AC_SUBST(PYGTK_DEFSDIR)
 670
 671 dnl ----------------------------------------------
 672
 673 AC_OUTPUT([
 674 Makefile
 675 Util/Makefile
 676 Util/Util.dll.config
 677 images/Makefile
 678 glue/Makefile
 679 BeagleClient/Makefile
 680 beagled/Makefile
 681 Filters/Makefile
 682 tools/Makefile
 683 tools/beagle-settings.desktop.in
 684 search/Makefile
 685 search/beagle-search.desktop.in
 686 ImLogViewer/Makefile
 687 ContactViewer/Makefile
 688 libbeagle/Makefile
 689 libbeagle/libbeagle-0.0.pc
 690 libbeagle/beagle/Makefile
 691 libbeagle/examples/Makefile
 692 libbeagle/docs/Makefile
 693 libbeagle/docs/reference/Makefile
 694 epiphany-extension/Makefile
 695 mozilla-extension/Makefile
 696 bludgeon/Makefile
 697 wrappers/Makefile
 698 wrappers/python/Makefile
 699 beagle-0.0.pc
 700 beagle-daemon.pc
 701 beagle-ui-0.0.pc
 702 beagle.spec
 703 po/Makefile.in
 704 ])
 705
 706 echo "
 707         Beagle Version:           ${VERSION}
 708         Target OS:                ${os}
 709         inotify?                  ${enable_inotify}
 710
 711         Prefix:                   ${prefix}
 712         GNOME Prefix:             ${GNOME_PREFIX}
 713         KDE Prefix:               ${kde_prefix_print}
 714
 715         Evolution support?        ${enable_evo}
 716         gsf-sharp?                ${enable_gsf_sharp}
 717         wv1?                      ${enable_wv1}
 718         galago-sharp?             ${enable_galago}
 719         libchm?                   ${has_libchm}
 720         google backend?           ${enable_googledriver} (Unsupported)
 721         Thunderbird backend?      ${enable_tbird}
 722
 723         Mozilla Extension?        yes
 724         Epiphany Extension?       ${enable_epiphany_extension}
 725
 726         Local SqliteClient?       ${use_local_sqlite}
 727         Sqlite version:           ${SQLITE_MAJ_VER}.x
 728
 729         Enable libbeagle          ${enable_libbeagle}
 730         Enable python bindings    ${have_python}
 731         Monitor screensaver       ${have_xss}
 732
 733         Enable beagle-search GUI  ${enable_gui}
 734         Enable \"Open With\" menu   ${OPEN_WITH}
 735 "
 736 echo
 737
 738 if test "x$enable_epiphany_extension" = "xyes"; then
 739    echo "NOTE: The Beagle Epiphany Extension Is Totally Insecure!"
 740    echo "      Use it at your own risk!"
 741    echo
 742 fi