configure.in

   1 ###
   2 ### Welcome to Beagle's configure.in.  We hope you enjoy your stay.
   3 ###
   4
   5 AC_INIT(beagled/BeagleDaemon.cs)
   6 AC_CANONICAL_SYSTEM
   7 AM_INIT_AUTOMAKE(beagle, 0.2.13)
   8
   9 ########################################################################
  10
  11 ###
  12 ### Some dependencies
  13 ###
  14
  15 MONO_REQUIRED=1.1.13.5
  16 GTK_SHARP_REQUIRED=2.4.0
  17 GMIME_SHARP_REQUIRED=2.2.0
  18 EVOLUTION_SHARP_REQUIRED=0.10.2
  19 GSF_SHARP_REQUIRED=0.6
  20 GTK_REQUIRED=2.6.0
  21
  22 LIBBEAGLE_GOBJECT_REQUIRED=2.6
  23 LIBBEAGLE_LIBXML_REQUIRED=2.6.19
  24
  25 PYTHON_REQUIRED=2.3
  26 PYGTK_REQUIRED=2.6
  27
  28 ########################################################################
  29
  30 AM_MAINTAINER_MODE
  31 AM_CONFIG_HEADER(config.h)
  32
  33 AC_PROG_INSTALL
  34 AM_PROG_LIBTOOL
  35 AC_PROG_CXX
  36
  37 VERSION=${VERSION}
  38 AC_SUBST(VERSION)
  39
  40 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  41 if test "x$PKG_CONFIG" = "xno"; then
  42         AC_MSG_ERROR([You need to install pkg-config])
  43 fi
  44
  45 AC_PATH_PROG(BASH, bash)
  46 AC_SUBST(BASH)
  47
  48 # mozilla extension uses zip to create the jar/xpi files
  49 AC_PATH_PROG(ZIP, zip)
  50
  51 AC_PATH_PROG(MONO, mono)
  52 AC_PATH_PROG(MCS, mcs)
  53
  54 AC_MSG_CHECKING([for mono.pc])
  55 if test -z `$PKG_CONFIG --variable=prefix mono`; then
  56   AC_MSG_ERROR([missing the mono.pc file, usually found in the mono-devel package])
  57 else
  58   AC_MSG_RESULT([found])
  59 fi
  60
  61 # check that we have the require version of mono
  62 PKG_CHECK_MODULES(MONO, mono >= $MONO_REQUIRED)
  63
  64 BEAGLE_DEFINES=""
  65
  66 # SharpZipLib broke API in 1.1.11.  Route around the damage.
  67 if `$PKG_CONFIG --atleast-version=1.1.11 mono`; then
  68   SHARPZIPLIB_LIBS="-r:`$PKG_CONFIG --variable=prefix mono`/lib/mono/compat-1.0/ICSharpCode.SharpZipLib.dll"
  69 else
  70   SHARPZIPLIB_LIBS="-r:ICSharpCode.SharpZipLib"
  71 fi
  72 AC_SUBST(SHARPZIPLIB_LIBS)
  73
  74 # check for various mono DLLs that we need.
  75 needed_dlls="Mono.Data.SqliteClient Mono.Posix System.Runtime.Remoting System.Web System.Web.Services"
  76 for i in $needed_dlls; do
  77   AC_MSG_CHECKING([for $i.dll])
  78   if test ! -e `$PKG_CONFIG --variable=prefix mono`/lib/mono/1.0/$i.dll; then
  79     AC_MSG_ERROR([missing required mono DLL: $i.dll])
  80   else
  81     AC_MSG_RESULT([found])
  82   fi
  83 done
  84
  85 # check for OS
  86 case "$target" in
  87   *-*-linux*)
  88     os=linux
  89         os_has_inotify=yes
  90     ;;
  91   *-*-freebsd*)
  92     os=freebsd
  93         os_has_inotify=no
  94     ;;
  95   *)
  96     AC_MSG_ERROR([Unrecognised target OS: $target])
  97     ;;
  98 esac
  99 AM_CONDITIONAL(OS_LINUX, test "x$os" = "xlinux")
 100 AM_CONDITIONAL(OS_FREEBSD, test "x$os" = "xfreebsd")
 101
 102 # xdgmime really wants to have HAVE_MMAP defined
 103 AC_FUNC_MMAP()
 104
 105 # check for desktop-launch
 106
 107 AC_PATH_PROG(DESKTOP_LAUNCH, desktop-launch, no)
 108 AM_CONDITIONAL(ENABLE_DESKTOP_LAUNCH, test "x$DESKTOP_LAUNCH" != "xno")
 109
 110 # Google QueryDriver
 111 # Disable GoogleDriver by default, enable if you want know what you are doing
 112 dnl -----------------------------------------------
 113 AC_ARG_ENABLE([googledriver],
 114         AC_HELP_STRING([--enable-googledriver], [Enable Google backend]),
 115         enable_googledriver=$enableval,
 116         enable_googledriver=no)
 117
 118 if test "x$enable_googledriver" = "xyes"; then
 119         # check for wsdl
 120         AC_PATH_PROG(WSDL, wsdl)
 121 fi
 122
 123 AM_CONDITIONAL(ENABLE_GOOGLEDRIVER, test "x$enable_googledriver" = "xyes")
 124
 125 #
 126 # I18N
 127 #
 128
 129 AC_PROG_INTLTOOL([0.23])
 130 GETTEXT_PACKAGE=beagle
 131 AC_SUBST(GETTEXT_PACKAGE)
 132 ALL_LINGUAS="ar bg ca cs da de el en_CA en_GB es fi fr gl he hi hu it ja ka ko lt lv mk nb nl pa pl pt_BR ru sr sr@Latn sv th tr uk vi zh_CN zh_HK zh_TW"
 133 AM_GLIB_GNU_GETTEXT
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Name of the package for translations])
 135
 136 # Many distros don't have a dependency on sqlite for their
 137 # mono-data-sqlite packages, and the mono build process itself
 138 # doesn't require it.  But we do, so check for it here.
 139 SQLITE_MAJ_VER="0"
 140 AC_ARG_ENABLE([sqlite2],
 141               AC_HELP_STRING([--enable-sqlite2], [Force the use of sqlite2, even if 3 is available.]),
 142               enable_sqlite2=$enableval,
 143               enable_sqlite2=auto)
 144 if test "x$enable_sqlite2" = "xyes"; then
 145         PKG_CHECK_MODULES(SQLITE, sqlite, SQLITE_MAJ_VER="2", do_nothing="1")
 146         if test "x$SQLITE_MAJ_VER" = "x0"; then
 147         AC_MSG_ERROR([You need to install sqlite 2])
 148         fi
 149 fi
 150
 151 AC_ARG_ENABLE([sqlite3],
 152               AC_HELP_STRING([--enable-sqlite3], [Force the use of sqlite3, even if 3 is available.]),
 153               enable_sqlite3=$enableval,
 154               enable_sqlite3=auto)
 155 if test "x$enable_sqlite3" = "xyes"; then
 156         PKG_CHECK_MODULES(SQLITE, sqlite3, SQLITE_MAJ_VER="3", do_nothing="1")
 157         if test "x$SQLITE_MAJ_VER" = "x0"; then
 158         AC_MSG_ERROR([You need to install sqlite 3])
 159         fi
 160 fi
 161 if test "x$SQLITE_MAJ_VER" = "x0"; then
 162         PKG_CHECK_MODULES(SQLITE, sqlite, SQLITE_MAJ_VER="2", do_nothing="1")
 163         # Note we really need 3.3.1, but the pkgconfig file from upstream only
 164         # reports 3.3 for all releases in the 3.3 line.
 165         PKG_CHECK_MODULES(SQLITE3, sqlite3 >= 3.3, SQLITE_MAJ_VER="3", do_nothing="1")
 166
 167         if test "x$SQLITE_MAJ_VER" = "x0"; then
 168                 # Note we really need 3.3.1, but the pkgconfig file from upstream only
 169                 # reports 3.3 for all releases in the 3.3 line.  Make sure we error out
 170                 # with the correct 3.3.1 version requirement, though.
 171                 AC_MSG_ERROR([You need to install sqlite 2.x or >= 3.3.1])
 172         fi
 173 fi
 174
 175 AC_SUBST(SQLITE_MAJ_VER)
 176
 177 AC_ARG_ENABLE([xss],
 178               AC_HELP_STRING([--disable-xss], [Disable monitoring xscreensaver to speed up indexing when user is idle]),
 179               enable_xss=$enableval,
 180               enable_xss=yes)
 181
 182 AC_PATH_XTRA
 183
 184 # Needed by glue/screensaver-glue.c
 185 # The OLD_CFLAGS/CFLAGS hack is needed to build on Ubuntu Breezy Badger
 186 OLD_CFLAGS="$CFLAGS"
 187 OLD_LDFLAGS="$LDFLAGS"
 188 OLD_LIBS="$LIBS"
 189 CFLAGS="$CFLAGS $X_CFLAGS"
 190 LDFLAGS="$LDFLAGS $X_LIBS"
 191 AC_CHECK_HEADER(X11/extensions/scrnsaver.h, enable_scrnsaver=yes, enable_scrnsaver=no)
 192 AC_CHECK_LIB(Xss,XScreenSaverQueryExtension, enable_libxss=yes, enable_libxss=no)
 193 have_xss=no
 194 if test "x$enable_xss$enable_scrnsaver$enable_libxss" = "xyesyesyes"; then
 195         XSS_LIBS="-lXss"
 196         have_xss=yes
 197         AC_DEFINE(HAVE_LIBXSS,1,[Define to 1 if libXss is installed])
 198 fi
 199 AM_CONDITIONAL(ENABLE_LIBXSS, test "x$have_xss" = "xyes")
 200 CFLAGS="$OLD_CFLAGS"
 201 LDFLAGS="$OLD_LDFLAGS"
 202 LIBS="$OLD_LIBS"
 203
 204 dnl ----------------------------------------------
 205 AC_ARG_ENABLE([thunderbird],
 206         AC_HELP_STRING([--disable-thunderbird], [Disable Thunderbird Mail Backend]),
 207         enable_tbird=$enableval,
 208         enable_tbird=yes)
 209 AM_CONDITIONAL(ENABLE_THUNDERBIRD, test "x$enable_tbird" = "xyes")
 210
 211 dnl -------------------------------------------------------
 212
 213 AC_ARG_ENABLE([gui],
 214         AC_HELP_STRING([--disable-gui], [Disable beagle-search]),
 215         enable_gui=$enableval,
 216         enable_gui=yes)
 217
 218 AM_CONDITIONAL(ENABLE_GUI, test "x$enable_gui" = "xyes")
 219
 220 if test "x$enable_gui" = "xyes"; then
 221
 222         # We pinvoke into gnome-vfs directly from Util/GnomeFu.cs, and
 223         # we get the GNOME prefix from libgnome-2.0
 224         PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 libgnome-2.0)
 225
 226         dnl -------------------------------------------------------
 227         dnl Various version requirements
 228
 229         PKG_CHECK_MODULES(BEAGLE_UI,
 230 [
 231         gtk-sharp-2.0 >= $GTK_SHARP_REQUIRED
 232         gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED
 233         glade-sharp-2.0 >= $GTK_SHARP_REQUIRED
 234         gnome-sharp-2.0 >= $GTK_SHARP_REQUIRED
 235         gnome-vfs-sharp-2.0 >= $GTK_SHARP_REQUIRED
 236         gmime-sharp >= $GMIME_SHARP_REQUIRED
 237 ])
 238         AC_SUBST(BEAGLE_UI_LIBS)
 239
 240         PKG_CHECK_MODULES(UIGLUE, gtk+-2.0 >= $GTK_REQUIRED librsvg-2.0)
 241         AC_SUBST(UIGLUE_CFLAGS)
 242         AC_SUBST(UIGLUE_LIBS)
 243
 244         dnl Gdk and Atk are needed for trayicon glue
 245
 246         GDK20_MINIMUM_VERSION=2.2.3
 247         ATK_MINIMUM_VERSION=1.2.4
 248
 249         PKG_CHECK_MODULES(LIBTRAYICON,
 250 [
 251         gdk-2.0 >= $GDK20_MINIMUM_VERSION
 252         atk >= $ATK_MINIMUM_VERSION
 253 ])
 254         AC_SUBST(LIBTRAYICON_CFLAGS)
 255         AC_SUBST(LIBTRAYICON_LIBS)
 256
 257 fi
 258
 259 dnl ----------------------------------------------
 260
 261 dnl "Open With" Menu (Requires GTK 2.8)
 262         PKG_CHECK_MODULES(OPEN_WITH,
 263 [
 264         gtk-sharp-2.0 >= 2.8
 265 ],OPEN_WITH=yes,OPEN_WITH=no)
 266 AM_CONDITIONAL(ENABLE_OPEN_WITH, test "x$OPEN_WITH" != "xno")
 267 dnl ----------------------------------------------
 268
 269 dnl evolution support
 270
 271 AC_ARG_ENABLE([evolution],
 272         AC_HELP_STRING([--disable-evolution], [Disable evolution support (default auto)]),
 273         enable_evo=$enableval,
 274         enable_evo_sharp=auto)
 275
 276
 277 EVO_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix evolution-sharp`
 278
 279 EVO_LIBDIR=`$PKG_CONFIG --variable=evolibdir evolution-sharp`
 280 AC_SUBST(EVO_LIBDIR)
 281
 282 PKG_CHECK_MODULES(EVO,
 283                   evolution-sharp >= $EVOLUTION_SHARP_REQUIRED  \
 284                   gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED        \
 285                   gmime-sharp >= $GMIME_SHARP_REQUIRED,
 286                   have_evo_dependencies=yes, have_evo_dependencies=no)
 287 AC_SUBST(EVO_LIBS)
 288
 289 if test "x$have_evo_dependencies" = "xno"; then
 290
 291         dnl error out if user has explicitly requested evolution support
 292         if test "x$enable_evo" = "xyes"; then
 293                 AC_MSG_ERROR([Could not find Evolution dependencies])
 294         fi
 295
 296         enable_evo="no (missing dependencies)"
 297
 298 else
 299
 300         if test "x$enable_evo" != "xno"; then
 301                 enable_evo="yes"
 302         else
 303                 enable_evo="no (disabled)"
 304         fi
 305
 306 fi
 307
 308 AM_CONDITIONAL(ENABLE_EVOLUTION, test "x$enable_evo" = "xyes")
 309
 310 dnl ----------------------------------------------
 311
 312 dnl Should we use our own copy of the sqlite bindings or the version
 313 dnl that got installed along with mono?
 314
 315 use_local_sqlite="yes" # hard-wired for now
 316 AM_CONDITIONAL(USE_LOCAL_SQLITE, test "x$use_local_sqlite" = "xyes")
 317
 318 dnl ----------------------------------------------
 319
 320 dnl inotify
 321
 322 AC_ARG_ENABLE([inotify],
 323          AC_HELP_STRING([--disable-inotify], [Disable inotify filesystem monitoring support (default auto)]),
 324          enable_inotify=$enableval,
 325          enable_inotify=auto)
 326
 327 if test "x$os_has_inotify" = "xno"; then
 328
 329         dnl error out if user has explicitly requested inotify
 330         if test "x$enable_inotify" = "xyes"; then
 331                 AC_MSG_ERROR([inotify is unavailable on your system architecture])
 332         fi
 333
 334         enable_inotify="no (unavailable)"
 335
 336 else
 337
 338         if test "x$enable_inotify" != "xno"; then
 339                 enable_inotify="yes"
 340         else
 341                 enable_inotify="no (disabled)"
 342         fi
 343
 344 fi
 345
 346 AM_CONDITIONAL(ENABLE_INOTIFY, test "x$enable_inotify" = "xyes")
 347
 348 dnl ----------------------------------------------
 349
 350 dnl gsf-sharp
 351
 352 PKG_CHECK_MODULES(GSF_SHARP, gsf-sharp >= 0.5, enable_gsf_sharp=yes, enable_gsf_sharp=no)
 353 AM_CONDITIONAL(ENABLE_GSF_SHARP, test "x$enable_gsf_sharp" = "xyes")
 354 if test "x$enable_gsf_sharp" = "xyes"; then
 355         BEAGLE_DEFINES="$BEAGLE_DEFINES -define:ENABLE_GSF_SHARP"
 356 fi
 357
 358 dnl ----------------------------------------------
 359
 360 dnl wv1
 361
 362 enable_wv1=no
 363 if test "x$enable_gsf_sharp" = "xyes"; then
 364         PKG_CHECK_MODULES(WV1, wv-1.0, enable_wv1=yes, enable_wv1=no)
 365         AC_SUBST(WV1_LIBS)
 366 fi
 367
 368 AM_CONDITIONAL(ENABLE_WV1, test "x$enable_wv1" = "xyes")
 369 if test "x$enable_wv1" = "xyes"; then
 370         BEAGLE_DEFINES="$BEAGLE_DEFINES -define:ENABLE_WV1"
 371 fi
 372
 373 dnl ----------------------------------------------
 374
 375 dnl libexif: Needed to index jpeg metadata
 376
 377 LIBEXIF_API_CHANGE=0.6.0
 378 LIBEXIF_REQUIRED_MIN=0.5.7
 379 LIBEXIF_REQUIRED_MAX=0.7.0
 380
 381 PKG_CHECK_MODULES(LIBEXIF, libexif >= $LIBEXIF_REQUIRED_MIN libexif < $LIBEXIF_REQUIRED_MAX)
 382 PKG_CHECK_MODULES(LIBEXIF_API_CHECK, libexif >= $LIBEXIF_API_CHANGE, have_old_libexif=no, have_old_libexif=yes)
 383
 384 if test "x$have_old_libexif" = "xyes"; then
 385         EXIF_SOVERSION=9
 386 else
 387         PKG_CHECK_MODULES(LIBEXIF_VERSION_CHECK, libexif >= 0.6.12, EXIF_SOVERSION=12, EXIF_SOVERSION=10)
 388 fi
 389 AC_SUBST(EXIF_SOVERSION)
 390
 391 PKG_CHECK_MODULES(BEAGLED,
 392 [
 393         shared-mime-info
 394         gmime-sharp >= $GMIME_SHARP_REQUIRED
 395         glib-sharp-2.0 >= $GTK_SHARP_REQUIRED
 396 ])
 397         BEAGLED_LIBS="$BEAGLED_LIBS $GSF_SHARP_LIBS"
 398 AC_SUBST(BEAGLED_LIBS)
 399
 400 GSF_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gsf-sharp`
 401 GMIME_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gmime-sharp`
 402
 403 dnl ----------------------------------------------
 404
 405 dnl libbeagle
 406
 407 GTK_DOC_CHECK(1.0)
 408
 409 AC_ARG_ENABLE([libbeagle],
 410         AC_HELP_STRING([--disable-libbeagle], [Disable libbeagle (C API)]),
 411         enable_libbeagle=$enableval,
 412         enable_libbeagle=auto)
 413
 414 dnl library versioning
 415 dnl Increase when changing the API
 416 LIBBEAGLE_CURRENT=0
 417
 418 dnl Update when changing implementation of current API,
 419 dnl reset to 0 when changing CURRENT.  This is the revision of
 420 dnl current API version
 421 LIBBEAGLE_REVISION=0
 422
 423 dnl Increase of API change is ABI compatible, otherwise reset to 0
 424 LIBBEAGLE_AGE=0
 425
 426 LIBBEAGLE_VERSION_INFO="$LIBBEAGLE_CURRENT:$LIBBEAGLE_REVISION:$LIBBEAGLE_AGE"
 427 AC_SUBST(LIBBEAGLE_VERSION_INFO)
 428
 429 PKG_CHECK_MODULES(LIBBEAGLE, [
 430         gobject-2.0 >= $LIBBEAGLE_GOBJECT_REQUIRED
 431         libxml-2.0  >= $LIBBEAGLE_LIBXML_REQUIRED
 432 ], have_libbeagle_deps=yes, have_libbeagle_deps=no)
 433
 434 AC_SUBST(LIBBEAGLE_CFLAGS)
 435 AC_SUBST(LIBBEAGLE_LIBS)
 436
 437 if test "x$have_libbeagle_deps" = "xno"; then
 438
 439         if test "x$enable_libbeagle" = "xyes"; then
 440                 AC_MSG_ERROR([Missing libbeagle dependencies])
 441         fi
 442
 443         enable_libbeagle="no (missing dependencies)"
 444 else
 445         if test "x$enable_libbeagle" != "xno"; then
 446                 enable_libbeagle="yes"
 447         else
 448                 enable_libbeagle="no (disabled)"
 449         fi
 450 fi
 451
 452 AM_CONDITIONAL(ENABLE_LIBBEAGLE, test "x$enable_libbeagle" = "xyes")
 453
 454 dnl ----------------------------------------------
 455 AC_ARG_ENABLE([bludgeon],
 456         AC_HELP_STRING([--disable-bludgeon], [Disable bludgeon testing tool]),
 457         enable_bludgeon=$enableval,
 458         enable_bludgeon=yes)
 459 AM_CONDITIONAL(ENABLE_BLUDGEON, test "x$enable_bludgeon" = "xyes")
 460
 461
 462 dnl ----------------------------------------------
 463 dnl Epiphany Extension
 464 dnl Much of this is cut&pasted from epiphany-extensions/configure.ac
 465
 466 AC_ARG_ENABLE([epiphany-extension],
 467         AC_HELP_STRING([--enable-epiphany-extension], [Enable Epiphany Extension (default auto)]),
 468         enable_epiphany_extension=$enableval,
 469         enable_epiphany_extension=auto)
 470
 471 if $PKG_CONFIG --exists epiphany-2.16; then
 472         EPIPHANY_MAJOR=2.16
 473         EPIPHANY_REQUIRED=2.16.0
 474 elif $PKG_CONFIG --exists epiphany-2.14; then
 475         EPIPHANY_MAJOR=2.14
 476         EPIPHANY_REQUIRED=2.14.0
 477 elif $PKG_CONFIG --exists epiphany-1.8; then
 478         EPIPHANY_MAJOR=1.8
 479         EPIPHANY_REQUIRED=1.7.0
 480 elif $PKG_CONFIG --exists epiphany-1.6; then
 481         EPIPHANY_MAJOR=1.6
 482         EPIPHANY_REQUIRED=1.6.0
 483 else
 484         enable_epiphany_extension="no (Epiphany not installed)"
 485 fi
 486
 487 if test "x$enable_epiphany_extension" = "xyes"; then
 488
 489 LIBXML_REQUIRED=2.6.0
 490 LIBGLIB_REQUIRED=2.4.0
 491 LIBGTK_REQUIRED=2.4.0
 492
 493 AC_SUBST(EPIPHANY_REQUIRED)
 494 AC_SUBST(LIBXML_REQUIRED)
 495 AC_SUBST(LIBGLIB_REQUIRED)
 496 AC_SUBST(LIBGTK_REQUIRED)
 497
 498 PKG_CHECK_MODULES(EPIPHANY_DEPENDENCY,
 499                   libxml-2.0 >= $LIBXML_REQUIRED \
 500                   libglade-2.0 \
 501                   glib-2.0 >= $LIBGLIB_REQUIRED \
 502                   gmodule-2.0 \
 503                   gtk+-2.0 >= $LIBGTK_REQUIRED \
 504                   epiphany-$EPIPHANY_MAJOR >= $EPIPHANY_REQUIRED,
 505                   have_epiphany_dependencies=yes,
 506                   have_epiphany_dependencies=no)
 507 AC_SUBST(EPIPHANY_DEPENDENCY_CFLAGS)
 508 AC_SUBST(EPIPHANY_DEPENDENCY_LIBS)
 509
 510 EPIPHANY_EXTENSIONS_DIR="`$PKG_CONFIG --variable=extensionsdir epiphany-$EPIPHANY_MAJOR`"
 511 AC_SUBST([EPIPHANY_EXTENSIONS_DIR])
 512 EPIPHANY_PREFIX="`$PKG_CONFIG --variable=prefix epiphany-$EPIPHANY_MAJOR`"
 513 AC_SUBST(EPIPHANY_PREFIX)
 514
 515 if test "x$have_epiphany_dependencies" = "xno"; then
 516         enable_epiphany_extension="no (missing dependencies)"
 517 elif test "x$enable_epiphany_extension" != "xyes"; then
 518         enable_epiphany_extension="disabled"
 519 fi
 520
 521 fi
 522
 523 AM_CONDITIONAL(ENABLE_EPIPHANY_EXTENSION, test "x$enable_epiphany_extension" = "xyes")
 524
 525 AC_ARG_ENABLE([epiphany-extension-install],
 526         AS_HELP_STRING([--enable-epiphany-extension-install],[Install Epiphany Extension]),
 527         [install_epiphany_extension=$enableval],
 528         [install_epiphany_extension=yes])
 529
 530 AM_CONDITIONAL([INSTALL_EPIPHANY_EXTENSION], [test "x$install_epiphany_extension" = "xyes"])
 531
 532 dnl ----------------------------------------------
 533
 534 dnl Galago
 535
 536 PKG_CHECK_MODULES(GALAGO, galago-sharp >= 0.5 , enable_galago=yes, enable_galago=no)
 537 AM_CONDITIONAL(ENABLE_GALAGO, test "x$enable_galago" = "xyes")
 538 AC_SUBST(GALAGO_LIBS)
 539
 540
 541 dnl ----------------------------------------------
 542
 543 GTK_BINARY_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 544 AC_SUBST(GTK_BINARY_VERSION)
 545
 546 dnl For the systeminfo glue
 547
 548 SYSTEMINFO_GLUE_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 $XSS_LIBS $X_EXTRA_LIBS"
 549 AC_SUBST(SYSTEMINFO_GLUE_X_LIBS)
 550
 551 dnl ----------------------------------------------
 552
 553 dnl KDE launcher/icon support
 554
 555 kde_prefix_print="unknown; will guess at runtime"
 556 AC_PATH_PROG(KDE_CONFIG, [kde-config], [no])
 557 if test ! "x$KDE_CONFIG" = "xno"; then
 558         KDE_PREFIX=`$KDE_CONFIG --prefix`
 559         kde_prefix_print="$KDE_PREFIX"
 560 fi
 561 AC_SUBST(KDE_PREFIX)
 562
 563 dnl ----------------------------------------------
 564
 565 dnl Prefixes for helper scripts
 566 GAC_PREFIX="$EVO_SHARP_PREFIX:$GSF_SHARP_PREFIX:$GMIME_SHARP_PREFIX"
 567 dnl Remove duplicate prefixes
 568 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|:|\n|g' | sort | uniq | tr '\n' ':'`"
 569 dnl Remove stray :s
 570 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|::\+|:|g' -e 's|^:\+||' -e 's|:\+$||'`"
 571 AC_SUBST(GAC_PREFIX)
 572
 573 GNOME_PREFIX="`$PKG_CONFIG --variable=prefix libgnome-2.0`"
 574 AC_SUBST(GNOME_PREFIX)
 575
 576 dnl ----------------------------------------------
 577
 578 dnl Check if the system has libchm, used by the CHMFilter
 579
 580 # Check for libchm for CHM filter
 581 AC_CHECK_LIB(chm,chm_open,has_libchm=yes,has_libchm=no)
 582 AM_CONDITIONAL(HAS_LIBCHM, test "x$has_libchm" = "xyes")
 583 if test "x$has_libchm" = "xyes"; then
 584         BEAGLE_DEFINES="$BEAGLE_DEFINES -define:HAVE_LIBCHM"
 585 fi
 586
 587 dnl ----------------------------------------------
 588
 589 dnl Conditional for debugging XML messages.
 590
 591 AC_ARG_ENABLE([xml-dump],
 592         AC_HELP_STRING([--enable-xml-dump], [Enables printing of the XML messages sent between components (default no)]),
 593         enable_xml_dump=$enableval,
 594         enable_xml_dump=no)
 595
 596 if test "x$enable_xml_dump" = "xyes"; then
 597         AC_DEFINE_UNQUOTED(ENABLE_XML_DUMP, 1, [Dump XML messages for debugging])
 598         BEAGLE_DEFINES="$BEAGLE_DEFINES -define:ENABLE_XML_DUMP"
 599 fi
 600
 601 AC_SUBST(BEAGLE_DEFINES)
 602
 603 dnl ----------------------------------------------
 604
 605 dnl Python 2.3
 606
 607 AC_ARG_ENABLE(python,
 608         AC_HELP_STRING([--disable-python], [Disable python support (default auto)]),
 609         enable_python=$enableval,
 610         enable_python=auto)
 611
 612 have_python=no
 613 if test "x$enable_libbeagle" = "xyes" -a "x$enable_python" != "xno"; then
 614         have_python_version=no
 615         have_python_headers=no
 616         have_pygtk_deps=no
 617         have_pygtk_codegen=no
 618
 619         AM_PATH_PYTHON()
 620
 621         if test -z "$PYTHON"; then
 622                 AC_MSG_WARN([Python not found])
 623         else
 624                 AM_PYTHON_CHECK_VERSION($PYTHON, $PYTHON_REQUIRED,
 625                         have_python_version=yes,
 626                         have_python_version=no)
 627         fi
 628
 629         if test "x$have_python_version" != "xyes"; then
 630                 AC_MSG_WARN([Python version $PYTHON_REQUIRED not found])
 631         else
 632                 AM_CHECK_PYTHON_HEADERS(have_python_headers=yes, have_python_headers=no)
 633         fi
 634
 635         if test "x$have_python_headers" != "xyes"; then
 636                 AC_MSG_WARN([could not find Python headers])
 637         else
 638                 PKG_CHECK_MODULES(PYBEAGLE,
 639                         pygtk-2.0 >= $PYGTK_REQUIRED
 640                         pygobject-2.0 >= $PYGTK_REQUIRED,
 641                         have_pygtk_deps=yes,
 642                         have_pygtk_deps=no)
 643         fi
 644
 645         if test "x$have_pygtk_deps" != "xyes"; then
 646                 AC_MSG_WARN([could not find pygtk])
 647         else
 648                 AC_PATH_PROG(PYGTK_CODEGEN, pygtk-codegen-2.0, no)
 649         fi
 650
 651         if test -z "$PYGTK_CODEGEN"; then
 652                 AC_MSG_WARN([could not find pygtk-codegen in path])
 653         else
 654                 AC_MSG_CHECKING(for pygtk defs)
 655                 PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
 656                 AC_MSG_RESULT($PYGTK_DEFSDIR)
 657
 658                 have_python=yes
 659         fi
 660 fi
 661
 662 if test "x$enable_python" = "xyes"; then
 663         if test "x$enable_libbeagle" != "xyes"; then
 664                 AC_MSG_ERROR([Python bindings are requested, but libbeagle isn't to be built])
 665         elif test "x$have_python" = "xno"; then
 666                 AC_MSG_ERROR([Python bindings are requested, but cannot be built])
 667         fi
 668 fi
 669
 670 AM_CONDITIONAL(ENABLE_PYTHON, test "x$have_python" = "xyes")
 671 AC_SUBST(PYBEAGLE_LIBS)
 672 AC_SUBST(PYBEAGLE_CFLAGS)
 673 AC_SUBST(PYGTK_DEFSDIR)
 674
 675 dnl ----------------------------------------------
 676
 677 AC_OUTPUT([
 678 Makefile
 679 Util/Makefile
 680 Util/Util.dll.config
 681 images/Makefile
 682 glue/Makefile
 683 BeagleClient/Makefile
 684 beagled/Makefile
 685 Filters/Makefile
 686 tools/Makefile
 687 tools/beagle-settings.desktop.in
 688 search/Makefile
 689 search/beagle-search.desktop.in
 690 ImLogViewer/Makefile
 691 ContactViewer/Makefile
 692 libbeagle/Makefile
 693 libbeagle/libbeagle-0.0.pc
 694 libbeagle/beagle/Makefile
 695 libbeagle/examples/Makefile
 696 libbeagle/docs/Makefile
 697 libbeagle/docs/reference/Makefile
 698 epiphany-extension/Makefile
 699 mozilla-extension/Makefile
 700 bludgeon/Makefile
 701 wrappers/Makefile
 702 wrappers/python/Makefile
 703 beagle-0.0.pc
 704 beagle-daemon.pc
 705 beagle-ui-0.0.pc
 706 beagle.spec
 707 po/Makefile.in
 708 ])
 709
 710 echo "
 711         Beagle Version:           ${VERSION}
 712         Target OS:                ${os}
 713         inotify?                  ${enable_inotify}
 714
 715         Prefix:                   ${prefix}
 716         GNOME Prefix:             ${GNOME_PREFIX}
 717         KDE Prefix:               ${kde_prefix_print}
 718
 719         Evolution support?        ${enable_evo}
 720         gsf-sharp?                ${enable_gsf_sharp}
 721         wv1?                      ${enable_wv1}
 722         galago-sharp?             ${enable_galago}
 723         libchm?                   ${has_libchm}
 724         google backend?           ${enable_googledriver} (Unsupported)
 725         Thunderbird backend?      ${enable_tbird}
 726
 727         Mozilla Extension?        yes
 728         Epiphany Extension?       ${enable_epiphany_extension}
 729
 730         Local SqliteClient?       ${use_local_sqlite}
 731         Sqlite version:           ${SQLITE_MAJ_VER}.x
 732
 733         Enable libbeagle          ${enable_libbeagle}
 734         Enable python bindings    ${have_python}
 735         Monitor screensaver       ${have_xss}
 736
 737         Enable beagle-search GUI  ${enable_gui}
 738         Enable \"Open With\" menu   ${OPEN_WITH}
 739 "
 740 echo
 741
 742 if test "x$enable_epiphany_extension" = "xyes"; then
 743    echo "NOTE: The Beagle Epiphany Extension Is Totally Insecure!"
 744    echo "      Use it at your own risk!"
 745    echo
 746 fi