src/link/stm32_flash_h743_2m.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_h7x3_2m.ld
   5 **
   6 **  Abstract    : Linker script for STM32H743xI Device with
   7 **                512K AXI-RAM mapped onto AXI bus on D1 domain
   8 **                128K SRAM1 mapped on D2 domain
   9 **                128K SRAM2 mapped on D2 domain
  10 **                 32K SRAM3 mapped on D2 domain
  11 **                 64K SRAM4 mapped on D3 domain
  12 **                 64K ITCM
  13 **                128K DTCM
  14 **
  15 *****************************************************************************
  16 */
  17
  18 /* Entry Point */
  19 ENTRY(Reset_Handler)
  20
  21 /*
  22 0x00000000 to 0x0000FFFF   64K ITCM
  23 0x20000000 to 0x2001FFFF  128K DTCM
  24 0x24000000 to 0x2407FFFF  512K AXI SRAM, D1 domain, main RAM
  25 0x30000000 to 0x3001FFFF  128K SRAM1, D2 domain
  26 0x30020000 to 0x3003FFFF  128K SRAM2, D2 domain
  27 0x30040000 to 0x30047FFF   32K SRAM3, D2 domain, unused
  28 0x38000000 to 0x3800FFFF   64K SRAM4, D3 domain, unused
  29 0x38800000 to 0x38800FFF    4K BACKUP SRAM, Backup domain, unused
  30
  31 0x08000000 to 0x081FFFFF 2048K full flash,
  32 0x08000000 to 0x0801FFFF  128K isr vector, startup code,
  33 0x08020000 to 0x0803FFFF  128K config,                  // FLASH_Sector_1
  34 0x08040000 to 0x081FFFFF 1792K firmware,
  35 */
  36
  37 /* Specify the memory areas */
  38 MEMORY
  39 {
  40     FLASH (rx)        : ORIGIN = 0x08000000, LENGTH = 10K
  41     FLASH_CUSTOM_DEFAULTS (r)  : ORIGIN = 0x08002800, LENGTH = 118K
  42     FLASH_CONFIG (r)  : ORIGIN = 0x08020000, LENGTH = 128K
  43     FLASH1 (rx)       : ORIGIN = 0x08040000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 1664K : 1792K
  44     FLASH_CUSTOM_DEFAULTS_EXTENDED (r): ORIGIN = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 0x081E0000 : 0x08200000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 128K : 0K
  45
  46     ITCM_RAM (rwx)    : ORIGIN = 0x00000000, LENGTH = 64K
  47     DTCM_RAM (rwx)    : ORIGIN = 0x20000000, LENGTH = 128K
  48     RAM (rwx)         : ORIGIN = 0x24000000, LENGTH = 512K
  49
  50     D2_RAM (rwx)      : ORIGIN = 0x30000000, LENGTH = 256K /* SRAM1 + SRAM2 */
  51
  52     MEMORY_B1 (rx)    : ORIGIN = 0x60000000, LENGTH = 0K
  53 }
  54
  55 REGION_ALIAS("STACKRAM", DTCM_RAM)
  56 REGION_ALIAS("FASTRAM", DTCM_RAM)
  57
  58 /* INCLUDE "stm32_flash_f7_split.ld" */
  59 /*
  60 *****************************************************************************
  61 **
  62 **  File        : stm32_flash_f7_split.ld
  63 **
  64 **  Abstract    : Common linker script for STM32 devices.
  65 **
  66 *****************************************************************************
  67 */
  68
  69 /* Entry Point */
  70 ENTRY(Reset_Handler)
  71
  72 /* Highest address of the user mode stack */
  73 _estack = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - 8; /* Reserve 2 x 4bytes for info across reset */
  74
  75 /* Base address where the config is stored. */
  76 __config_start = ORIGIN(FLASH_CONFIG);
  77 __config_end = ORIGIN(FLASH_CONFIG) + LENGTH(FLASH_CONFIG);
  78
  79 /* Generate a link error if heap and stack don't fit into RAM */
  80 _Min_Heap_Size = 0;      /* required amount of heap  */
  81 _Min_Stack_Size = 0x800; /* required amount of stack */
  82
  83 /* Define output sections */
  84 SECTIONS
  85 {
  86   /* The startup code goes first into FLASH */
  87   .isr_vector :
  88   {
  89     . = ALIGN(512);
  90     PROVIDE (isr_vector_table_base = .);
  91     KEEP(*(.isr_vector)) /* Startup code */
  92     . = ALIGN(4);
  93   } >FLASH
  94
  95   /* The program code and other data goes into FLASH */
  96   .text :
  97   {
  98     . = ALIGN(4);
  99     *(.text)           /* .text sections (code) */
 100     *(.text*)          /* .text* sections (code) */
 101     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
 102     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
 103     *(.glue_7)         /* glue arm to thumb code */
 104     *(.glue_7t)        /* glue thumb to arm code */
 105     *(.eh_frame)
 106
 107     KEEP (*(.init))
 108     KEEP (*(.fini))
 109
 110     . = ALIGN(4);
 111     _etext = .;        /* define a global symbols at end of code */
 112   } >FLASH1
 113
 114   /* Critical program code goes into ITCM RAM */
 115   /* Copy specific fast-executing code to ITCM RAM */
 116   tcm_code = LOADADDR(.tcm_code);
 117   .tcm_code :
 118   {
 119     . = ALIGN(4);
 120     tcm_code_start = .;
 121     *(.tcm_code)
 122     *(.tcm_code*)
 123     . = ALIGN(4);
 124     tcm_code_end = .;
 125   } >ITCM_RAM AT >FLASH1
 126
 127   .ARM.extab   :
 128   {
 129     *(.ARM.extab* .gnu.linkonce.armextab.*)
 130   } >FLASH
 131
 132   .ARM :
 133   {
 134     __exidx_start = .;
 135     *(.ARM.exidx*) __exidx_end = .;
 136   } >FLASH
 137
 138   .pg_registry :
 139   {
 140     PROVIDE_HIDDEN (__pg_registry_start = .);
 141     KEEP (*(.pg_registry))
 142     KEEP (*(SORT(.pg_registry.*)))
 143     PROVIDE_HIDDEN (__pg_registry_end = .);
 144   } >FLASH1
 145
 146   .pg_resetdata :
 147   {
 148     PROVIDE_HIDDEN (__pg_resetdata_start = .);
 149     KEEP (*(.pg_resetdata))
 150     PROVIDE_HIDDEN (__pg_resetdata_end = .);
 151   } >FLASH1
 152
 153   /* Storage for the address for the configuration section so we can grab it out of the hex file */
 154   .custom_defaults :
 155   {
 156     . = ALIGN(4);
 157     KEEP (*(.custom_defaults_start_address))
 158     . = ALIGN(4);
 159     KEEP (*(.custom_defaults_end_address))
 160     . = ALIGN(4);
 161     __custom_defaults_internal_start = .;
 162     *(.custom_defaults);
 163   } >FLASH_CUSTOM_DEFAULTS
 164
 165   PROVIDE_HIDDEN (__custom_defaults_start = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? ORIGIN(FLASH_CUSTOM_DEFAULTS_EXTENDED) : __custom_defaults_internal_start);
 166   PROVIDE_HIDDEN (__custom_defaults_end = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? ORIGIN(FLASH_CUSTOM_DEFAULTS_EXTENDED) + LENGTH(FLASH_CUSTOM_DEFAULTS_EXTENDED) : ORIGIN(FLASH_CUSTOM_DEFAULTS) + LENGTH(FLASH_CUSTOM_DEFAULTS));
 167
 168   /* used by the startup to initialize data */
 169   _sidata = LOADADDR(.data);
 170
 171   /* Initialized data sections goes into RAM, load LMA copy after code */
 172   .data :
 173   {
 174     . = ALIGN(4);
 175     _sdata = .;        /* create a global symbol at data start */
 176     *(.data)           /* .data sections */
 177     *(.data*)          /* .data* sections */
 178
 179     . = ALIGN(4);
 180     _edata = .;        /* define a global symbol at data end */
 181   } >RAM AT >FLASH
 182
 183   /* Uninitialized data section */
 184   . = ALIGN(4);
 185   .bss (NOLOAD) :
 186   {
 187     /* This is used by the startup in order to initialize the .bss secion */
 188     _sbss = .;         /* define a global symbol at bss start */
 189     __bss_start__ = _sbss;
 190     *(.bss)
 191     *(SORT_BY_ALIGNMENT(.bss*))
 192     *(COMMON)
 193
 194     . = ALIGN(4);
 195     _ebss = .;         /* define a global symbol at bss end */
 196     __bss_end__ = _ebss;
 197   } >RAM
 198
 199   /* Uninitialized data section */
 200   . = ALIGN(4);
 201   .sram2 (NOLOAD) :
 202   {
 203     /* This is used by the startup in order to initialize the .sram2 secion */
 204     _ssram2 = .;         /* define a global symbol at sram2 start */
 205     __sram2_start__ = _ssram2;
 206     *(.sram2)
 207     *(SORT_BY_ALIGNMENT(.sram2*))
 208
 209     . = ALIGN(4);
 210     _esram2 = .;         /* define a global symbol at sram2 end */
 211     __sram2_end__ = _esram2;
 212   } >RAM
 213
 214   /* used during startup to initialized fastram_data */
 215   _sfastram_idata = LOADADDR(.fastram_data);
 216
 217   /* Initialized FAST_DATA section for unsuspecting developers */
 218   .fastram_data :
 219   {
 220     . = ALIGN(4);
 221     _sfastram_data = .;        /* create a global symbol at data start */
 222     *(.fastram_data)           /* .data sections */
 223     *(.fastram_data*)          /* .data* sections */
 224
 225     . = ALIGN(4);
 226     _efastram_data = .;        /* define a global symbol at data end */
 227   } >FASTRAM AT >FLASH
 228
 229   . = ALIGN(4);
 230   .fastram_bss (NOLOAD) :
 231   {
 232     _sfastram_bss = .;
 233     __fastram_bss_start__ = _sfastram_bss;
 234     *(.fastram_bss)
 235     *(SORT_BY_ALIGNMENT(.fastram_bss*))
 236
 237     . = ALIGN(4);
 238     _efastram_bss = .;
 239     __fastram_bss_end__ = _efastram_bss;
 240   } >FASTRAM
 241
 242   /* used during startup to initialized dmaram_data */
 243   _sdmaram_idata = LOADADDR(.dmaram_data);
 244
 245   . = ALIGN(32);
 246   .dmaram_data :
 247   {
 248     PROVIDE(dmaram_start = .);
 249     _sdmaram = .;
 250     _dmaram_start__ = _sdmaram;
 251     _sdmaram_data = .;        /* create a global symbol at data start */
 252     *(.dmaram_data)           /* .data sections */
 253     *(.dmaram_data*)          /* .data* sections */
 254     . = ALIGN(32);
 255     _edmaram_data = .;        /* define a global symbol at data end */
 256   } >RAM AT >FLASH
 257
 258   . = ALIGN(32);
 259   .dmaram_bss (NOLOAD) :
 260   {
 261     _sdmaram_bss = .;
 262     __dmaram_bss_start__ = _sdmaram_bss;
 263     *(.dmaram_bss)
 264     *(SORT_BY_ALIGNMENT(.dmaram_bss*))
 265     . = ALIGN(32);
 266     _edmaram_bss = .;
 267     __dmaram_bss_end__ = _edmaram_bss;
 268   } >RAM
 269
 270   . = ALIGN(32);
 271   .DMA_RAM (NOLOAD) :
 272   {
 273     KEEP(*(.DMA_RAM))
 274     PROVIDE(dmaram_end = .);
 275     _edmaram = .;
 276     _dmaram_end__ = _edmaram;
 277   } >RAM
 278
 279   .DMA_RW_D2 (NOLOAD) :
 280   {
 281     . = ALIGN(32);
 282     PROVIDE(dmarw_start = .);
 283     _sdmarw = .;
 284     _dmarw_start__ = _sdmarw;
 285     KEEP(*(.DMA_RW))
 286     PROVIDE(dmarw_end = .);
 287     _edmarw = .;
 288     _dmarw_end__ = _edmarw;
 289   } >D2_RAM
 290
 291   .DMA_RW_AXI (NOLOAD) :
 292   {
 293     . = ALIGN(32);
 294     PROVIDE(dmarwaxi_start = .);
 295     _sdmarwaxi = .;
 296     _dmarwaxi_start__ = _sdmarwaxi;
 297     KEEP(*(.DMA_RW_AXI))
 298     PROVIDE(dmarwaxi_end = .);
 299     _edmarwaxi = .;
 300     _dmarwaxi_end__ = _edmarwaxi;
 301   } >RAM
 302
 303   .persistent_data (NOLOAD) :
 304   {
 305     __persistent_data_start__ = .;
 306     *(.persistent_data)
 307     . = ALIGN(4);
 308     __persistent_data_end__ = .;
 309   } >RAM
 310
 311
 312   /* User_heap_stack section, used to check that there is enough RAM left */
 313   _heap_stack_end = ORIGIN(STACKRAM)+LENGTH(STACKRAM) - 8; /* 8 bytes to allow for alignment */
 314   _heap_stack_begin = _heap_stack_end - _Min_Stack_Size  - _Min_Heap_Size;
 315   . = _heap_stack_begin;
 316   ._user_heap_stack :
 317   {
 318     . = ALIGN(4);
 319     PROVIDE ( end = . );
 320     PROVIDE ( _end = . );
 321     . = . + _Min_Heap_Size;
 322     . = . + _Min_Stack_Size;
 323     . = ALIGN(4);
 324   } >STACKRAM = 0xa5
 325
 326   /* MEMORY_bank1 section, code must be located here explicitly            */
 327   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 328   .memory_b1_text :
 329   {
 330     *(.mb1text)        /* .mb1text sections (code) */
 331     *(.mb1text*)       /* .mb1text* sections (code)  */
 332     *(.mb1rodata)      /* read-only data (constants) */
 333     *(.mb1rodata*)
 334   } >MEMORY_B1
 335
 336   /* Remove information from the standard libraries */
 337   /DISCARD/ :
 338   {
 339     libc.a ( * )
 340     libm.a ( * )
 341     libgcc.a ( * )
 342   }
 343
 344   .ARM.attributes 0 : { *(.ARM.attributes) }
 345 }