opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_USE_SYSTEM_EXTENSIONS
  23
  24 dnl These must be called before LT_INIT, because it may want
  25 dnl to call AC_CHECK_PROG.
  26 AC_CHECK_TOOL(AR, ar)
  27 AC_CHECK_TOOL(RANLIB, ranlib, :)
  28
  29 dnl Default to a non shared library.  This may be overridden by the
  30 dnl configure option --enable-shared.
  31 AC_DISABLE_SHARED
  32
  33 LT_INIT
  34
  35 AC_ARG_ENABLE(targets,
  36 [  --enable-targets        alternative target configurations],
  37 [case "${enableval}" in
  38   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  39             ;;
  40   no)       enable_targets= ;;
  41   *)        enable_targets=$enableval ;;
  42 esac])dnl
  43
  44 AM_BINUTILS_WARNINGS
  45
  46 AC_CONFIG_HEADERS(config.h:config.in)
  47
  48 if test -z "$target" ; then
  49     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  50 fi
  51
  52 AM_MAINTAINER_MODE
  53 AM_INSTALL_LIBBFD
  54 AC_EXEEXT
  55
  56 # host-specific stuff:
  57
  58 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN"
  59 ZW_GNU_GETTEXT_SISTER_DIR
  60 AM_PO_SUBDIRS
  61
  62 . ${srcdir}/../bfd/configure.host
  63
  64 BFD_CC_FOR_BUILD
  65
  66 AC_SUBST(HDEFINES)
  67 AC_PROG_INSTALL
  68
  69 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  70
  71 AC_CHECK_DECLS([basename, stpcpy])
  72
  73 cgen_maint=no
  74 cgendir='$(srcdir)/../cgen'
  75
  76 AC_ARG_ENABLE(cgen-maint,
  77 [  --enable-cgen-maint[=dir]    build cgen generated files],
  78 [case "${enableval}" in
  79   yes)  cgen_maint=yes ;;
  80   no)   cgen_maint=no ;;
  81   *)
  82         # argument is cgen install directory (not implemented yet).
  83         # Having a `share' directory might be more appropriate for the .scm,
  84         # .cpu, etc. files.
  85         cgen_maint=yes
  86         cgendir=${cgen_maint}/lib/cgen
  87         ;;
  88 esac])dnl
  89 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
  90 AC_SUBST(cgendir)
  91
  92 using_cgen=no
  93
  94 # Check if linker supports --as-needed and --no-as-needed options
  95 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
  96         [bfd_cv_ld_as_needed=no
  97         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
  98                 bfd_cv_ld_as_needed=yes
  99         fi
 100         ])
 101
 102 LT_LIB_M
 103
 104 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 105 SHARED_LDFLAGS=
 106 SHARED_LIBADD=
 107 SHARED_DEPENDENCIES=
 108 if test "$enable_shared" = "yes"; then
 109 # When building a shared libopcodes, link against the pic version of libiberty
 110 # so that apps that use libopcodes won't need libiberty just to satisfy any
 111 # libopcodes references.
 112 # We can't do that if a pic libiberty is unavailable since including non-pic
 113 # code would insert text relocations into libopcodes.
 114 # Note that linking against libbfd as we do here, which is itself linked
 115 # against libiberty, may not satisfy all the libopcodes libiberty references
 116 # since libbfd may not pull in the entirety of libiberty.
 117 changequote(,)dnl
 118   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 119 changequote([,])dnl
 120   if test -n "$x"; then
 121     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 122   fi
 123
 124   case "${host}" in
 125     *-*-cygwin*)
 126       SHARED_LDFLAGS="-no-undefined"
 127       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 128       ;;
 129    *-*-darwin*)
 130      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}"
 131      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 132      ;;
 133     *)
 134       case "$host_vendor" in
 135         hp)
 136           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}"
 137           ;;
 138         *)
 139           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}"
 140           ;;
 141       esac
 142       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 143       ;;
 144   esac
 145
 146   if test -n "$SHARED_LIBADD"; then
 147     if test -n "$LIBM"; then
 148       if test x"$bfd_cv_ld_as_needed" = xyes; then
 149         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 150         # to stop libtool reordering these options.
 151         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 152       else
 153         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 154       fi
 155     fi
 156   fi
 157 fi
 158 AC_SUBST(SHARED_LDFLAGS)
 159 AC_SUBST(SHARED_LIBADD)
 160 AC_SUBST(SHARED_DEPENDENCIES)
 161
 162 # target-specific stuff:
 163
 164 # Canonicalize the secondary target names.
 165 if test -n "$enable_targets" ; then
 166     for targ in `echo $enable_targets | sed 's/,/ /g'`
 167     do
 168         result=`$ac_config_sub $targ 2>/dev/null`
 169         if test -n "$result" ; then
 170             canon_targets="$canon_targets $result"
 171         else
 172             # Allow targets that config.sub doesn't recognize, like "all".
 173             canon_targets="$canon_targets $targ"
 174         fi
 175     done
 176 fi
 177
 178 all_targets=false
 179 selarchs=
 180 for targ in $target $canon_targets
 181 do
 182     if test "x$targ" = "xall" ; then
 183         all_targets=true
 184     else
 185         . $srcdir/../bfd/config.bfd
 186         selarchs="$selarchs $targ_archs"
 187     fi
 188 done
 189
 190 # Utility var, documents generic cgen support files.
 191
 192 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 193
 194 # We don't do any links based on the target system, just makefile config.
 195
 196 if test x${all_targets} = xfalse ; then
 197
 198     # Target architecture .o files.
 199     ta=
 200
 201     for arch in $selarchs
 202     do
 203         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 204         archdefs="$archdefs -DARCH_$ad"
 205         case "$arch" in
 206         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 207         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 208         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 209         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 210         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 211         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 212         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 213         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 214         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 215         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 216         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 217         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 218         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 219         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 220         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 221         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 222         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 223         bfd_i386_arch)          ta="$ta i386-dis.lo i386-opc.lo" ;;
 224         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 225         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 226         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 227         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 228         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 229         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 230         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 231         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 232         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 233         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 234         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 235         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 236         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 237         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 238         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 239         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 240         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 241         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 242         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 243         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 244         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 245         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 246         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 247         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 248         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 249         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 250         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 251         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 252         bfd_pyramid_arch)       ;;
 253         bfd_romp_arch)          ;;
 254         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 255         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 256         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 257         bfd_sh_arch)
 258           # We can't decide what we want just from the CPU family.
 259           # We want SH5 support unless a specific version of sh is
 260           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 261           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 262           for t in $target $canon_targets; do
 263             case $t in
 264               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 265               sh-*-linux* | shl-*-linux*)
 266                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 267                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 268                                 break;;
 269             esac;
 270           done
 271                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 272         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 273         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 274         bfd_tahoe_arch)         ;;
 275         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 276         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 277         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 278         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 279         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 280         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 281         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 282         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 283         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 284         bfd_we32k_arch)         ;;
 285         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 286         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 287         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 288         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 289         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 290
 291         "")                     ;;
 292         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 293         esac
 294     done
 295
 296     if test $using_cgen = yes ; then
 297         ta="$ta $cgen_files"
 298     fi
 299
 300     # Weed out duplicate .o files.
 301     f=""
 302     for i in $ta ; do
 303         case " $f " in
 304         *" $i "*) ;;
 305         *) f="$f $i" ;;
 306         esac
 307     done
 308     ta="$f"
 309
 310     # And duplicate -D flags.
 311     f=""
 312     for i in $archdefs ; do
 313         case " $f " in
 314         *" $i "*) ;;
 315         *) f="$f $i" ;;
 316         esac
 317     done
 318     archdefs="$f"
 319
 320     BFD_MACHINES="$ta"
 321
 322 else    # all_targets is true
 323     archdefs=-DARCH_all
 324     BFD_MACHINES='$(ALL_MACHINES)'
 325 fi
 326
 327 AC_SUBST(archdefs)
 328 AC_SUBST(BFD_MACHINES)
 329
 330 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 331 AC_OUTPUT