gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2022 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT
  22 AC_CONFIG_MACRO_DIRS([../config])
  23 AC_CONFIG_SRCDIR([main.c])
  24 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  25 AM_MAINTAINER_MODE
  26
  27 AC_PROG_CC
  28 AC_PROG_CXX
  29
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_INSTALL_STRIP
  33
  34 AC_CONFIG_AUX_DIR(..)
  35
  36 # Set build, build_cpu, build_vendor and build_os.
  37 AC_CANONICAL_BUILD
  38
  39 # Set host, host_cpu, host_vendor, and host_os.
  40 AC_CANONICAL_HOST
  41
  42 # Set target, target_cpu, target_vendor, and target_os.
  43 AC_CANONICAL_TARGET
  44
  45 ACX_NONCANONICAL_TARGET
  46
  47 AC_ARG_PROGRAM
  48
  49 # We require a C++11 compiler.  Check if one is available, and if
  50 # necessary, set CXX_DIALECT to some -std=xxx switch.
  51 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  52
  53 # Dependency checking.
  54 ZW_CREATE_DEPDIR
  55 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  56
  57 dnl List of object files and targets accumulated by configure.
  58
  59 CONFIG_OBS=
  60 CONFIG_DEPS=
  61 CONFIG_SRCS=
  62 ENABLE_CFLAGS=
  63
  64 CONFIG_ALL=
  65 CONFIG_CLEAN=
  66 CONFIG_INSTALL=
  67 CONFIG_UNINSTALL=
  68
  69 dnl Set up for gettext.
  70 ZW_GNU_GETTEXT_SISTER_DIR
  71
  72 localedir='${datadir}/locale'
  73 AC_SUBST(localedir)
  74
  75 if test x"$USE_NLS" = xyes; then
  76    CONFIG_ALL="$CONFIG_ALL all-po"
  77    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  78    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  79    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  80 fi
  81
  82 PACKAGE=gdb
  83 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  84 AC_SUBST(PACKAGE)
  85
  86 # We never need to detect it in this sub-configure.
  87 # But preserve it for config.status --recheck.
  88 AC_ARG_VAR(MAKEINFO,
  89   [Parent configure detects if it is of sufficient version.])
  90 AC_ARG_VAR(MAKEINFOFLAGS,
  91   [Parameters for MAKEINFO.])
  92
  93 MAKEINFO_EXTRA_FLAGS=""
  94 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  95   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  96   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  97     gdb_cv_have_makeinfo_click=yes
  98   else
  99     gdb_cv_have_makeinfo_click=no
 100   fi])
 101 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 102   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 103 fi
 104 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 105
 106 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 107     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 108     [${libdir}/debug])
 109
 110 # We can't pass paths as command line arguments.
 111 # Mingw32 tries to be clever and will convert the paths for us.
 112 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 113 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 114 # This breaks GDB's relocatable path conversions since paths passed in
 115 # config.h would not get so translated, the path prefixes no longer match.
 116 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 117
 118 # GDB's datadir relocation
 119
 120 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 121     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 122     [${datadir}/gdb])
 123
 124 AC_ARG_WITH(relocated-sources,
 125 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 126 [reloc_srcdir="${withval}"
 127  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 128               [Relocated directory for source files. ])
 129 ])
 130
 131 AC_MSG_CHECKING([for default auto-load directory])
 132 AC_ARG_WITH(auto-load-dir,
 133 AS_HELP_STRING([--with-auto-load-dir=PATH],
 134   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 135   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 136 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 137 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 138               [Directories from which to load auto-loaded scripts.])
 139 AC_MSG_RESULT([$with_auto_load_dir])
 140
 141 AC_MSG_CHECKING([for default auto-load safe-path])
 142 AC_ARG_WITH(auto-load-safe-path,
 143 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 144   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 145 AS_HELP_STRING([--without-auto-load-safe-path],
 146                [do not restrict auto-loaded files locations]),
 147     [if test "$with_auto_load_safe_path" = "no"; then
 148      with_auto_load_safe_path="/"
 149      fi],
 150 [with_auto_load_safe_path="$with_auto_load_dir"])
 151 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 152 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 153               [Directories safe to hold auto-loaded files.])
 154 AC_MSG_RESULT([$with_auto_load_safe_path])
 155
 156 AC_CONFIG_SUBDIRS(testsuite)
 157
 158 # Check whether to support alternative target configurations
 159 AC_ARG_ENABLE(targets,
 160 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 161 [case "${enableval}" in
 162   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
 163             ;;
 164   no)       enable_targets= ;;
 165   *)        enable_targets=$enableval ;;
 166 esac])
 167
 168 BFD_64_BIT
 169
 170 # Provide defaults for some variables set by the per-host and per-target
 171 # configuration.
 172 gdb_host_obs=posix-hdep.o
 173
 174 if test "${target}" = "${host}"; then
 175   gdb_native=yes
 176 else
 177   gdb_native=no
 178 fi
 179
 180 . $srcdir/configure.host
 181
 182 # Accumulate some settings from configure.tgt over all enabled targets
 183
 184 TARGET_OBS=
 185 all_targets=
 186 HAVE_NATIVE_GCORE_TARGET=
 187
 188 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 189 do
 190   if test "$targ_alias" = "all"; then
 191     all_targets=true
 192   else
 193     # Canonicalize the secondary target names.
 194     result=`$ac_config_sub $targ_alias 2>/dev/null`
 195     if test -n "$result"; then
 196         targ=$result
 197     else
 198         targ=$targ_alias
 199     fi
 200
 201     . ${srcdir}/configure.tgt
 202
 203     AS_IF([test -z "${gdb_target_obs}"],
 204       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 205
 206     # Target-specific object files
 207     for i in ${gdb_target_obs}; do
 208         case " $TARGET_OBS " in
 209         *" ${i} "*) ;;
 210         *)
 211           TARGET_OBS="$TARGET_OBS ${i}"
 212           ;;
 213         esac
 214     done
 215
 216     # Check whether this target needs 64-bit CORE_ADDR
 217     if test x${enable_64_bit_bfd} = xno; then
 218       . ${srcdir}/../bfd/config.bfd
 219     fi
 220
 221     # Check whether this target is native and supports gcore.
 222     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 223        && $gdb_have_gcore; then
 224       HAVE_NATIVE_GCORE_TARGET=1
 225     fi
 226   fi
 227 done
 228
 229 if test x${all_targets} = xtrue; then
 230   if test x${enable_64_bit_bfd} = xyes; then
 231     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 232   else
 233     TARGET_OBS='$(ALL_TARGET_OBS)'
 234   fi
 235 fi
 236
 237 AC_SUBST(TARGET_OBS)
 238 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 239
 240 # For other settings, only the main target counts.
 241 gdb_sim=
 242 gdb_osabi=
 243 targ=$target; . ${srcdir}/configure.tgt
 244
 245 # Fetch the default architecture and default target vector from BFD.
 246 targ=$target; . $srcdir/../bfd/config.bfd
 247
 248 # We only want the first architecture, so strip off the others if
 249 # there is more than one.
 250 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 251
 252 if test "x$targ_archs" != x; then
 253   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 254     [Define to BFD's default architecture. ])
 255 fi
 256 if test "x$targ_defvec" != x; then
 257   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 258     [Define to BFD's default target vector. ])
 259 fi
 260
 261 # Enable MI.
 262 AC_ARG_ENABLE(gdbmi,
 263 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 264   [case $enableval in
 265     yes | no)
 266       ;;
 267     *)
 268       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 269   esac],
 270   [enable_gdbmi=yes])
 271 if test x"$enable_gdbmi" = xyes; then
 272   if test -d "$srcdir/mi"; then
 273     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 274     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 275     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 276     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 277   fi
 278 fi
 279
 280 # Enable TUI.
 281 AC_ARG_ENABLE(tui,
 282 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 283   [case $enableval in
 284     yes | no | auto)
 285       ;;
 286     *)
 287       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 288   esac],enable_tui=auto)
 289
 290 # Enable gdbtk.
 291 AC_ARG_ENABLE(gdbtk,
 292 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 293   [case $enableval in
 294     yes | no)
 295       ;;
 296     *)
 297       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 298   esac],
 299   [if test -d "$srcdir/gdbtk"; then
 300     enable_gdbtk=yes
 301   else
 302     enable_gdbtk=no
 303   fi])
 304 # We unconditionally disable gdbtk tests on selected platforms.
 305 case $host_os in
 306   go32* | windows*)
 307     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 308     enable_gdbtk=no ;;
 309 esac
 310
 311 # Handle optional debuginfod support
 312 AC_DEBUGINFOD
 313
 314 # Libunwind support for ia64.
 315 AC_ARG_WITH(libunwind-ia64,
 316 AS_HELP_STRING([--with-libunwind-ia64],
 317                [use libunwind frame unwinding for ia64 targets]),,
 318             [with_libunwind_ia64=auto])
 319
 320 # Backward compatibility option.
 321 if test "${with_libunwind+set}" = set; then
 322   if test x"$with_libunwind_ia64" != xauto; then
 323     AC_MSG_ERROR(
 324       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 325   fi
 326   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 327   with_libunwind_ia64="$with_libunwind"
 328 fi
 329
 330 case "$with_libunwind_ia64" in
 331   yes | no)
 332     ;;
 333   auto)
 334     AC_CHECK_HEADERS(libunwind-ia64.h)
 335     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 336     ;;
 337   *)
 338     AC_MSG_ERROR(
 339       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 340     ;;
 341 esac
 342
 343 if test x"$with_libunwind_ia64" = xyes; then
 344   AC_CHECK_HEADERS(libunwind-ia64.h)
 345   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 346     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 347   fi
 348   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 349   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 350   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 351 fi
 352
 353 opt_curses=no
 354 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 355
 356 prefer_curses=no
 357 if test "$opt_curses" = "yes"; then
 358   prefer_curses=yes
 359 fi
 360
 361 # Profiling support.
 362 AC_ARG_ENABLE(profiling,
 363 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 364   [case $enableval in
 365     yes | no)
 366       ;;
 367     *)
 368       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 369   esac],
 370  [enable_profiling=no])
 371
 372 AC_CHECK_FUNCS(monstartup _mcleanup)
 373 AC_CACHE_CHECK(
 374   [for _etext],
 375   [ac_cv_var__etext],
 376   [AC_LINK_IFELSE(
 377      [AC_LANG_PROGRAM(
 378         [#include <stdlib.h>
 379          extern char _etext;],
 380         [free (&_etext);]
 381       )],
 382      [ac_cv_var__etext=yes],
 383      [ac_cv_var__etext=no]
 384    )]
 385 )
 386 if test "$ac_cv_var__etext" = yes; then
 387   AC_DEFINE(HAVE__ETEXT, 1,
 388             [Define to 1 if your system has the _etext variable. ])
 389 fi
 390 AC_CACHE_CHECK(
 391   [for etext],
 392   [ac_cv_var_etext],
 393   [AC_LINK_IFELSE(
 394      [AC_LANG_PROGRAM(
 395         [#include <stdlib.h>
 396          extern char etext;],
 397         [free (&etext);]
 398       )],
 399      [ac_cv_var_etext=yes],
 400      [ac_cv_var_etext=no]
 401    )]
 402 )
 403 if test "$ac_cv_var_etext" = yes; then
 404   AC_DEFINE(HAVE_ETEXT, 1,
 405             [Define to 1 if your system has the etext variable. ])
 406 fi
 407 if test "$enable_profiling" = yes ; then
 408   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 409     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 410   fi
 411   PROFILE_CFLAGS=-pg
 412   OLD_CFLAGS="$CFLAGS"
 413   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 414
 415   AC_CACHE_CHECK(
 416     [whether $CC supports -pg],
 417     [ac_cv_cc_supports_pg],
 418     [AC_COMPILE_IFELSE(
 419        [AC_LANG_PROGRAM([], [int x;])],
 420        [ac_cv_cc_supports_pg=yes],
 421        [ac_cv_cc_supports_pg=no]
 422      )]
 423   )
 424
 425   if test "$ac_cv_cc_supports_pg" = no; then
 426     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 427   fi
 428
 429   CFLAGS="$OLD_CFLAGS"
 430 fi
 431
 432 CODESIGN_CERT=
 433 AC_ARG_ENABLE([codesign],
 434   AS_HELP_STRING([--enable-codesign=CERT],
 435                  [sign gdb with 'codesign -s CERT']),
 436   [CODESIGN_CERT=$enableval])
 437 AC_SUBST([CODESIGN_CERT])
 438
 439 ACX_PKGVERSION([GDB])
 440 ACX_BUGURL([https://www.gnu.org/software/gdb/bugs/])
 441 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 442 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 443
 444 # --------------------- #
 445 # Checks for programs.  #
 446 # --------------------- #
 447
 448 AC_PROG_AWK
 449 AC_PROG_INSTALL
 450 AC_PROG_LN_S
 451 AC_PROG_RANLIB
 452 AC_PROG_YACC
 453
 454 AC_CHECK_TOOL(AR, ar)
 455 AC_CHECK_TOOL(DLLTOOL, dlltool)
 456 AC_CHECK_TOOL(WINDRES, windres)
 457
 458 case $host_os in
 459   gnu*)
 460     # Needed for GNU Hurd hosts.
 461     AC_CHECK_TOOL(MIG, mig)
 462     if test x"$MIG" = x; then
 463       AC_MSG_ERROR([MIG not found but required for $host hosts])
 464     fi
 465     ;;
 466 esac
 467
 468 # ---------------------- #
 469 # Checks for libraries.  #
 470 # ---------------------- #
 471
 472 # We might need to link with -lm; most simulators need it.
 473 AC_CHECK_LIB(m, main)
 474
 475 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 476 AC_SEARCH_LIBS(gethostbyname, nsl)
 477
 478 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 479 AC_SEARCH_LIBS(socketpair, socket)
 480
 481 # Link in zlib if we can.  This allows us to read compressed debug sections.
 482 AM_ZLIB
 483
 484 AM_ICONV
 485
 486 # GDB may fork/exec the iconv program to get the list of supported character
 487 # sets.  Allow the user to specify where to find it.
 488 # There are several factors affecting the choice of option name:
 489 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 490 #   the build-time location of libiconv files.
 491 # - The program we need to find is iconv, which comes with glibc.  The user
 492 #   doesn't necessarily have libiconv installed.  Therefore naming this
 493 #   --with-libiconv-foo feels wrong.
 494 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 495 #   defined to work on directories not files (though it really doesn't know
 496 #   the difference).
 497 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 498 #   with --with-libiconv-prefix.
 499 # Putting these together is why the option name is --with-iconv-bin.
 500
 501 AC_ARG_WITH(iconv-bin,
 502 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 503 [iconv_bin="${withval}"
 504  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 505                     [Path of directory of iconv program.])
 506  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 507 ])
 508
 509 # For the TUI, we need enhanced curses functionality.
 510 if test x"$enable_tui" != xno; then
 511   prefer_curses=yes
 512 fi
 513
 514 curses_found=no
 515 if test x"$prefer_curses" = xyes; then
 516   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 517   # curses library because the latter might not provide all the
 518   # functionality we need.  However, this leads to problems on systems
 519   # where the linker searches /usr/local/lib, but the compiler doesn't
 520   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 521   # default installation of ncurses on alpha*-dec-osf* will lead to such
 522   # a situation.
 523   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 524
 525   if test "$ac_cv_search_waddstr" != no; then
 526     curses_found=yes
 527   fi
 528 fi
 529
 530 # Check whether we should enable the TUI, but only do so if we really
 531 # can.
 532 if test x"$enable_tui" != xno; then
 533   if test -d "$srcdir/tui"; then
 534     if test "$curses_found" != no; then
 535       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 536       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 537       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 538       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 539     else
 540       if test x"$enable_tui" = xyes; then
 541         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 542       else
 543         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 544       fi
 545     fi
 546   fi
 547 fi
 548
 549 # Since GDB uses Readline, we need termcap functionality.  In many
 550 # cases this will be provided by the curses library, but some systems
 551 # have a separate termcap library, or no curses library at all.
 552
 553 case $host_os in
 554   cygwin*)
 555     if test -d "$srcdir/libtermcap"; then
 556       LIBS="../libtermcap/libtermcap.a $LIBS"
 557       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 558     fi ;;
 559   go32* | *djgpp*)
 560     ac_cv_search_tgetent="none required"
 561     ;;
 562 esac
 563
 564 # These are the libraries checked by Readline.
 565 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 566
 567 if test "$ac_cv_search_tgetent" = no; then
 568   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 569 fi
 570
 571 AC_ARG_WITH([system-readline],
 572   [AS_HELP_STRING([--with-system-readline],
 573                   [use installed readline library])])
 574
 575 if test "$with_system_readline" = yes; then
 576   AC_CHECK_HEADERS(readline/readline.h, [readline_h=yes], [readline_h=no])
 577   if test "$readline_h" = "no"; then
 578     AC_MSG_ERROR([readline development packages are probably missing])
 579   fi
 580   AC_CACHE_CHECK(
 581     [whether system readline is new enough],
 582     [gdb_cv_readline_ok],
 583     [AC_COMPILE_IFELSE(
 584        [AC_LANG_PROGRAM(
 585           [#include <stdio.h>
 586            #include <readline/readline.h>],
 587           [#if RL_VERSION_MAJOR < 7
 588            # error "readline version 7 required"
 589            #endif]
 590         )],
 591        [gdb_cv_readline_ok=yes],
 592        [gdb_cv_readline_ok=no]
 593      )]
 594   )
 595   if test "$gdb_cv_readline_ok" != yes; then
 596     AC_MSG_ERROR([system readline is not new enough])
 597   fi
 598
 599   READLINE=-lreadline
 600   READLINE_DEPS=
 601   READLINE_CFLAGS=
 602   READLINE_TEXI_INCFLAG=
 603 else
 604   READLINE='$(READLINE_DIR)/libreadline.a'
 605   READLINE_DEPS='$(READLINE)'
 606   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 607   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 608 fi
 609 AC_SUBST(READLINE)
 610 AC_SUBST(READLINE_DEPS)
 611 AC_SUBST(READLINE_CFLAGS)
 612 AC_SUBST(READLINE_TEXI_INCFLAG)
 613
 614 # Generate jit-reader.h
 615
 616 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 617 TARGET_PTR=
 618
 619 AC_CHECK_SIZEOF(unsigned long long)
 620 AC_CHECK_SIZEOF(unsigned long)
 621 AC_CHECK_SIZEOF(unsigned __int128)
 622
 623 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 624   TARGET_PTR="unsigned long"
 625 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 626   TARGET_PTR="unsigned long long"
 627 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 628   TARGET_PTR="unsigned __int128"
 629 else
 630   TARGET_PTR="unsigned long"
 631 fi
 632
 633 AC_SUBST(TARGET_PTR)
 634 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 635
 636 AC_SEARCH_LIBS(dlopen, dl)
 637
 638 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 639                 [directory to load the JIT readers from],
 640                 [${libdir}/gdb])
 641
 642 AC_ARG_WITH(expat,
 643   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 644   [], [with_expat=auto])
 645 AC_MSG_CHECKING([whether to use expat])
 646 AC_MSG_RESULT([$with_expat])
 647
 648 if test "${with_expat}" = no; then
 649   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 650   HAVE_LIBEXPAT=no
 651 else
 652   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 653                         [XML_Parser p = XML_ParserCreate (0);])
 654   if test "$HAVE_LIBEXPAT" != yes; then
 655     if test "$with_expat" = yes; then
 656       AC_MSG_ERROR([expat is missing or unusable])
 657     else
 658       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 659     fi
 660   else
 661     save_LIBS=$LIBS
 662     LIBS="$LIBS $LIBEXPAT"
 663     AC_CHECK_FUNCS(XML_StopParser)
 664     LIBS=$save_LIBS
 665   fi
 666 fi
 667
 668 # Verify that we have a usable GMP library.
 669 AC_LIB_HAVE_LINKFLAGS([gmp], [], [#include <gmp.h>],
 670                       [mpz_t n;
 671                        mpz_init (n);])
 672 if test "$HAVE_LIBGMP" != yes; then
 673   AC_MSG_ERROR([GMP is missing or unusable])
 674 fi
 675
 676 AC_ARG_WITH(mpfr,
 677   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 678   [], [with_mpfr=auto])
 679 AC_MSG_CHECKING([whether to use MPFR])
 680 AC_MSG_RESULT([$with_mpfr])
 681
 682 if test "${with_mpfr}" = no; then
 683   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 684   HAVE_LIBMPFR=no
 685 else
 686   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 687                         [mpfr_exp_t exp; mpfr_t x;
 688                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 689   if test "$HAVE_LIBMPFR" != yes; then
 690     if test "$with_mpfr" = yes; then
 691       AC_MSG_ERROR([MPFR is missing or unusable])
 692     else
 693       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 694     fi
 695   fi
 696 fi
 697
 698 # --------------------- #
 699 # Check for libpython.  #
 700 # --------------------- #
 701
 702 dnl Utility to simplify finding libpython.
 703 dnl $1 = the shell variable to assign the result to
 704 dnl      If libpython is found we store $version here.
 705 dnl $2 = additional flags to add to CPPFLAGS
 706 dnl $3 = additional flags to add to LIBS
 707
 708 AC_DEFUN([AC_TRY_LIBPYTHON],
 709 [
 710   define([have_libpython_var],$1)
 711   new_CPPFLAGS=$2
 712   new_LIBS=$3
 713   AC_MSG_CHECKING([for python])
 714   save_CPPFLAGS=$CPPFLAGS
 715   save_LIBS=$LIBS
 716   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 717   LIBS="$new_LIBS $LIBS"
 718   found_usable_python=no
 719   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 720                                  [[
 721                                     #if PY_MAJOR_VERSION != 3
 722                                     # error "We only support Python 3"
 723                                     #endif
 724                                     Py_Initialize ();
 725                                  ]])],
 726                  [have_libpython_var=yes
 727                   found_usable_python=yes
 728                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 729                   PYTHON_LIBS=$new_LIBS])
 730   CPPFLAGS=$save_CPPFLAGS
 731   LIBS=$save_LIBS
 732   AC_MSG_RESULT([${found_usable_python}])
 733 ])
 734
 735 dnl There are several different values for --with-python:
 736 dnl
 737 dnl no -   Don't include python support.
 738 dnl yes -  Include python support, error if it's missing.
 739 dnl        If we find python in $PATH, use it to fetch configure options,
 740 dnl        otherwise assume the compiler can find it with no help from us.
 741 dnl auto - Same as "yes", but if python is missing from the system,
 742 dnl        fall back to "no".
 743 dnl /path/to/python/exec-prefix -
 744 dnl        Use the python located in this directory.
 745 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 746 dnl        the compilation parameters.  Otherwise use
 747 dnl        -I/path/to/python/exec-prefix/include,
 748 dnl        -L/path/to/python/exec-prefix/lib.
 749 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 750 dnl        but is deprecated.
 751 dnl /path/to/python/executable -
 752 dnl        Run python-config.py with this version of python to fetch the
 753 dnl        compilation parameters.
 754 dnl        NOTE: This needn't be the real python executable.
 755 dnl        In a cross-compilation scenario (build != host), this could be
 756 dnl        a shell script that provides what python-config.py provides for
 757 dnl        --ldflags, --includes, --exec-prefix.
 758 dnl python-executable -
 759 dnl        Find python-executable in $PATH, and then handle the same as
 760 dnl        /path/to/python/executable.
 761 dnl
 762 dnl If a python program is specified, it is used to run python-config.py and
 763 dnl is passed --ldflags, --includes, --exec-prefix.
 764
 765 AC_ARG_WITH(python,
 766   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 767   [], [with_python=auto])
 768 AC_MSG_CHECKING([whether to use python])
 769 AC_MSG_RESULT([$with_python])
 770
 771 if test "${with_python}" = no; then
 772   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 773   have_libpython=no
 774 else
 775   case "${with_python}" in
 776   [[\\/]]* | ?:[[\\/]]*)
 777     if test -d "${with_python}"; then
 778       # Assume the python binary is ${with_python}/bin/python.
 779       python_prog="${with_python}/bin/python"
 780       python_prefix=
 781       # If python does not exit ${with_python}/bin, then try in
 782       # ${with_python}.  On Windows/MinGW, this is where the Python
 783       # executable is.
 784       if test ! -x "${python_prog}"; then
 785         python_prog="${with_python}/python"
 786         python_prefix=
 787       fi
 788       if test ! -x "${python_prog}"; then
 789         # Fall back to gdb 7.0/7.1 behaviour.
 790         python_prog=missing
 791         python_prefix=${with_python}
 792       fi
 793     elif test -x "${with_python}"; then
 794       # While we can't run python compiled for $host (unless host == build),
 795       # the user could write a script that provides the needed information,
 796       # so we support that.
 797       python_prog=${with_python}
 798       python_prefix=
 799     else
 800       AC_MSG_ERROR(invalid value for --with-python)
 801     fi
 802     ;;
 803   */*)
 804     # Disallow --with-python=foo/bar.
 805     AC_MSG_ERROR(invalid value for --with-python)
 806     ;;
 807   *)
 808     # The user has either specified auto, yes, or the name of the python
 809     # program assumed to be in $PATH.
 810     python_prefix=
 811     case "${with_python}" in
 812     yes | auto)
 813       if test "${build}" = "${host}"; then
 814         AC_PATH_PROG(python_prog_path, python, missing)
 815         if test "${python_prog_path}" = missing; then
 816           python_prog=missing
 817         else
 818           python_prog=${python_prog_path}
 819         fi
 820       else
 821         # Not much we can do except assume the cross-compiler will find the
 822         # right files.
 823         python_prog=missing
 824       fi
 825       ;;
 826     *)
 827       # While we can't run python compiled for $host (unless host == build),
 828       # the user could write a script that provides the needed information,
 829       # so we support that.
 830       python_prog="${with_python}"
 831       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 832       if test "${python_prog_path}" = missing; then
 833         AC_MSG_ERROR(unable to find python program ${python_prog})
 834       fi
 835       ;;
 836     esac
 837   esac
 838
 839   if test "${python_prog}" != missing; then
 840     # We have a python program to use, but it may be too old.
 841     # Don't flag an error for --with-python=auto (the default).
 842     have_python_config=yes
 843     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 844     if test $? != 0; then
 845       have_python_config=failed
 846       if test "${with_python}" != auto; then
 847         AC_MSG_ERROR(failure running python-config --includes)
 848       fi
 849     fi
 850     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 851     if test $? != 0; then
 852       have_python_config=failed
 853       if test "${with_python}" != auto; then
 854         AC_MSG_ERROR(failure running python-config --ldflags)
 855       fi
 856     fi
 857     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 858     if test $? != 0; then
 859       have_python_config=failed
 860       if test "${with_python}" != auto; then
 861         AC_MSG_ERROR(failure running python-config --exec-prefix)
 862       fi
 863     fi
 864   else
 865     # We do not have a python executable we can use to determine where
 866     # to find the Python headers and libs.  We cannot guess the include
 867     # path from the python_prefix either, because that include path
 868     # depends on the Python version.  So, there is nothing much we can
 869     # do except assume that the compiler will be able to find those files.
 870     python_includes=
 871     python_libs=
 872     have_python_config=no
 873   fi
 874
 875   # If we have python-config, only try the configuration it provides.
 876   # Otherwise fallback on the old way of trying different versions of
 877   # python in turn.
 878
 879   have_libpython=no
 880   if test "${have_python_config}" = yes; then
 881     AC_TRY_LIBPYTHON(have_libpython,
 882                      ${python_includes}, ${python_libs})
 883   fi
 884
 885   if test "${have_libpython}" = no; then
 886     case "${with_python}" in
 887     yes)
 888       AC_MSG_ERROR([python is missing or unusable])
 889       ;;
 890     auto)
 891       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 892       ;;
 893     *)
 894       AC_MSG_ERROR([no usable python found at ${with_python}])
 895       ;;
 896     esac
 897   else
 898     if test -n "${python_prefix}"; then
 899       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 900                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 901       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 902     fi
 903   fi
 904 fi
 905
 906 dnl Use --with-python-libdir to control where GDB looks for the Python
 907 dnl libraries.
 908 dnl
 909 dnl If this is not given then the default will be based on the value
 910 dnl passed to --with-python, which is in the python_prefix variable.
 911 dnl If the --with-python option wasn't given then the default value in
 912 dnl python_prefix is based on running the 'gdb/python/python-config
 913 dnl --exec-prefix' script.
 914 AC_ARG_WITH(python-libdir,
 915   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 916   [],[
 917     # If no python libdir is specified then select one based on
 918     # python's prefix path.
 919     if test -n "${python_prefix}"; then
 920       with_python_libdir=${python_prefix}/lib
 921     fi
 922   ])
 923
 924 if test "${have_libpython}" != no; then
 925   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 926   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 927   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 928   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 929   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 930   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 931
 932   if test -n "${with_python_libdir}"; then
 933     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 934                        [Directory containing Python's standard libraries from --with-python-libdir.])
 935     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 936   fi
 937
 938   # Flags needed to compile Python code (taken from python-config --cflags).
 939   # We cannot call python-config directly because it will output whatever was
 940   # used when compiling the Python interpreter itself, including flags which
 941   # would make the python-related objects be compiled differently from the
 942   # rest of GDB (e.g., -O2 and -fPIC).
 943   if test "${GCC}" = yes; then
 944     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 945     # Python headers recommend -DNDEBUG, but it's unclear if that just
 946     # refers to building Python itself.  In release mode, though, it
 947     # doesn't hurt for the Python code in gdb to follow.
 948     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 949   fi
 950
 951   if test "x${tentative_python_cflags}" != x; then
 952     AC_MSG_CHECKING(compiler flags for python code)
 953     for flag in ${tentative_python_cflags}; do
 954       # Check that the compiler accepts it
 955       saved_CFLAGS="$CFLAGS"
 956       CFLAGS="$CFLAGS $flag"
 957       AC_COMPILE_IFELSE(
 958         [AC_LANG_PROGRAM([], [])],
 959         [PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag"],
 960         []
 961       )
 962       CFLAGS="$saved_CFLAGS"
 963     done
 964     AC_MSG_RESULT(${PYTHON_CFLAGS})
 965   fi
 966
 967   # On x64 Windows, Python's include headers, and pyconfig.h in
 968   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 969   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 970   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 971   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 972   # The issue was reported to the Python community, but still isn't
 973   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 974
 975   case "$gdb_host" in
 976     mingw64)
 977            if test "${GCC}" = yes; then
 978              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 979            fi
 980            ;;
 981   esac
 982 else
 983   # Even if Python support is not compiled in, we need to have this file
 984   # included so that the "python" command, et.al., still exists.
 985   CONFIG_OBS="$CONFIG_OBS python/python.o"
 986   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 987 fi
 988
 989 # Work around Python http://bugs.python.org/issue10112.  See also
 990 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 991 # no effect.  Note that the only test after this that uses Python is
 992 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 993 # run without -export-dynamic too.
 994 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 995
 996 AC_SUBST(PYTHON_CFLAGS)
 997 AC_SUBST(PYTHON_CPPFLAGS)
 998 AC_SUBST(PYTHON_LIBS)
 999 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1000
1001 # -------------------- #
1002 # Check for libguile.  #
1003 # -------------------- #
1004
1005 dnl Utility to simplify finding libguile.
1006 dnl $1 = pkg-config-program
1007 dnl $2 = space-separate list of guile versions to try
1008 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1009 dnl $4 = the shell variable to assign the result to
1010 dnl      If libguile is found we store "yes" here.
1011
1012 AC_DEFUN([AC_TRY_LIBGUILE],
1013 [
1014   pkg_config=$1
1015   guile_version_list=$2
1016   flag_errors=$3
1017   define([have_libguile_var],$4)
1018   found_usable_guile=checking
1019   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1020   for guile_version in ${guile_version_list}; do
1021     ${pkg_config} --exists ${guile_version} 2>/dev/null
1022     if test $? != 0; then
1023       continue
1024     fi
1025     dnl pkg-config says the package exists, so if we get an error now,
1026     dnl that's bad.
1027     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1028     if test $? != 0; then
1029       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1030     fi
1031     new_LIBS=`${pkg_config} --libs ${guile_version}`
1032     if test $? != 0; then
1033       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1034     fi
1035     dnl If we get this far, great.
1036     found_usable_guile=${guile_version}
1037     break
1038   done
1039   if test "${found_usable_guile}" = "checking"; then
1040     if test "${flag_errors}" = "yes"; then
1041       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1042     else
1043       found_usable_guile=no
1044     fi
1045   fi
1046   dnl One final sanity check.
1047   dnl The user could have said --with-guile=python-2.7.
1048   if test "${found_usable_guile}" != no; then
1049     save_CPPFLAGS=$CPPFLAGS
1050     save_LIBS=$LIBS
1051     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1052     LIBS="$LIBS $new_LIBS"
1053     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1054                                    [[scm_init_guile ();]])],
1055                    [have_libguile_var=yes
1056                     GUILE_CPPFLAGS=$new_CPPFLAGS
1057                     GUILE_LIBS=$new_LIBS],
1058                    [found_usable_guile=no])
1059     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1060     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1061       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1062                 [Define if Guile supports manual finalization.])
1063     )
1064     CPPFLAGS=$save_CPPFLAGS
1065     LIBS=$save_LIBS
1066     if test "${found_usable_guile}" = no; then
1067       if test "${flag_errors}" = yes; then
1068         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1069       fi
1070     fi
1071   fi
1072   AC_MSG_RESULT([${found_usable_guile}])
1073 ])
1074
1075 dnl There are several different values for --with-guile:
1076 dnl
1077 dnl no -   Don't include guile support.
1078 dnl yes -  Include guile support, error if it's missing.
1079 dnl        The pkg-config program must be in $PATH.
1080 dnl auto - Same as "yes", but if guile is missing from the system,
1081 dnl        fall back to "no".
1082 dnl guile-version [guile-version-choice-2 ...] -
1083 dnl        A space-separated list of guile package versions to try.
1084 dnl        These are passed to pkg-config as-is.
1085 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1086 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1087 dnl /path/to/pkg-config -
1088 dnl        Use this pkg-config program.
1089 dnl        NOTE: This needn't be the "real" pkg-config program.
1090 dnl        It could be a shell script.  It is invoked as:
1091 dnl        pkg-config --exists $version
1092 dnl        pkg-config --cflags $version
1093 dnl        pkg-config --libs $version
1094 dnl        pkg-config --variable guild $version
1095 dnl        The script will be called with $version having each value in
1096 dnl        $try_guile_versions until --exists indicates success.
1097
1098 AC_ARG_WITH(guile,
1099   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1100   [], [with_guile=auto])
1101 AC_MSG_CHECKING([whether to use guile])
1102 AC_MSG_RESULT([$with_guile])
1103
1104 dnl We check guile with pkg-config.
1105 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1106
1107 try_guile_versions="guile-3.0 guile-2.2 guile-2.0"
1108 have_libguile=no
1109 case "${with_guile}" in
1110 no)
1111   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1112   ;;
1113 auto)
1114   if test "${pkg_config_prog_path}" = "missing"; then
1115     AC_MSG_WARN([pkg-config not found, guile support disabled])
1116   else
1117     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1118   fi
1119   ;;
1120 yes)
1121   if test "${pkg_config_prog_path}" = "missing"; then
1122     AC_MSG_ERROR([pkg-config not found])
1123   fi
1124   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1125   ;;
1126 [[\\/]]* | ?:[[\\/]]*)
1127   if test -x "${with_guile}"; then
1128     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1129   else
1130     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1131   fi
1132   ;;
1133 "" | */*)
1134   # Disallow --with=guile="" and --with-guile=foo/bar.
1135   AC_MSG_ERROR([invalid value for --with-guile])
1136   ;;
1137 *)
1138   # A space separate list of guile versions to try, in order.
1139   if test "${pkg_config_prog_path}" = "missing"; then
1140     AC_MSG_ERROR([pkg-config not found])
1141   fi
1142   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1143   ;;
1144 esac
1145
1146 if test "${have_libguile}" != no; then
1147   dnl Get the name of the 'guild' program.
1148   case "${with_guile}" in
1149   [[\\/]]* | ?:[[\\/]]*)
1150     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1151     ;;
1152   *)
1153     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1154     ;;
1155   esac
1156
1157   dnl Make sure guild can handle this host.
1158   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1159   dnl If not, disable guile support.
1160   if test "$ac_cv_guild_ok" = no; then
1161     have_libguile=no
1162     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1163   fi
1164 fi
1165
1166 if test "${have_libguile}" != no; then
1167   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1168   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1169   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1170   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1171   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1172   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1173
1174   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1175   save_LIBS="$LIBS"
1176   save_CPPFLAGS="$CPPFLAGS"
1177   LIBS="$GUILE_LIBS"
1178   CPPFLAGS="$GUILE_CPPFLAGS"
1179   AC_CHECK_FUNCS([scm_new_smob])
1180   LIBS="$save_LIBS"
1181   CPPFLAGS="$save_CPPFLAGS"
1182 else
1183   # Even if Guile support is not compiled in, we need to have these files
1184   # included.
1185   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1186   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1187 fi
1188 AC_SUBST(GUILE_CPPFLAGS)
1189 AC_SUBST(GUILE_LIBS)
1190 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1191
1192 # ---------------------------- #
1193 # Check for source highlight.  #
1194 # ---------------------------- #
1195
1196 SRCHIGH_LIBS=
1197 SRCHIGH_CFLAGS=
1198
1199 AC_ARG_ENABLE(source-highlight,
1200   AS_HELP_STRING([--enable-source-highlight],
1201     [enable source-highlight for source listings]),
1202   [case "${enableval}" in
1203   yes)  enable_source_highlight=yes ;;
1204   no)   enable_source_highlight=no  ;;
1205   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1206 esac],
1207 [enable_source_highlight=auto])
1208
1209 if test "${enable_source_highlight}" != "no"; then
1210   AC_MSG_CHECKING([for the source-highlight library])
1211   if test "${pkg_config_prog_path}" = "missing"; then
1212     AC_MSG_RESULT([no - pkg-config not found])
1213     if test "${enable_source_highlight}" = "yes"; then
1214       AC_MSG_ERROR([pkg-config was not found in your system])
1215     fi
1216   else
1217     if ${pkg_config_prog_path} --exists source-highlight; then
1218       case "$LDFLAGS" in
1219         *static-libstdc*)
1220           AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1221 either use --disable-source-highlight or dnl
1222 --without-static-standard-libraries])
1223           ;;
1224       esac
1225
1226       srchigh_pkg_cflags=`${pkg_config_prog_path} --cflags source-highlight`
1227       srchigh_pkg_libs=`${pkg_config_prog_path} --libs source-highlight`
1228
1229       # Now that we have found a source-highlight library, check if we can use
1230       # it.  In particular, we're trying to detect the situation that the
1231       # library is using the new libstdc++ library abi ( see
1232       # https://gcc.gnu.org/onlinedocs/libstdc++/manual/using_dual_abi.html )
1233       # while the compiler being used to compile gdb is using the old abi.
1234       # Such a situation will result in an undefined reference to
1235       # srchilite::SourceHighlight::SourceHighlight(std::string const&).
1236       # This situation can occur for instance when using a source highlight
1237       # library compiled with g++ 7.5.0 while building gdb with g++ 4.8.5.
1238       AC_LANG_PUSH(C++)
1239       save_CXXFLAGS="$CXXFLAGS"
1240       save_LIBS="$LIBS"
1241       CXXFLAGS="$CXXFLAGS $srchigh_pkg_cflags"
1242       LIBS="$LIBS $srchigh_pkg_libs"
1243       AC_LINK_IFELSE(
1244         [AC_LANG_PROGRAM(
1245           [#include <srchilite/sourcehighlight.h>],
1246           [std::string outlang = "esc.outlang";
1247            new srchilite::SourceHighlight (outlang);]
1248         )],
1249         [have_usable_source_highlight=yes],
1250         [have_usable_source_highlight=no]
1251       )
1252       CXXFLAGS="$save_CXXFLAGS"
1253       LIBS="$save_LIBS"
1254       AC_LANG_POP(C++)
1255
1256       if test "${have_usable_source_highlight}" = "yes"; then
1257         AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1258                   [Define to 1 if the source-highlight library is available])
1259         AC_MSG_RESULT([yes])
1260         SRCHIGH_CFLAGS="$srchigh_pkg_cflags"
1261         SRCHIGH_LIBS="$srchigh_pkg_libs"
1262       else
1263         AC_MSG_RESULT([no])
1264         if test "${enable_source_highlight}" = "yes"; then
1265           AC_MSG_ERROR([source-highlight in your system could not be used])
1266         fi
1267       fi
1268     else
1269       AC_MSG_RESULT([no])
1270       if test "${enable_source_highlight}" = "yes"; then
1271         AC_MSG_ERROR([source-highlight was not found in your system])
1272       fi
1273     fi
1274   fi
1275 fi
1276 AC_SUBST(SRCHIGH_LIBS)
1277 AC_SUBST(SRCHIGH_CFLAGS)
1278
1279 # ------------------------- #
1280 # Checks for header files.  #
1281 # ------------------------- #
1282
1283 AC_HEADER_STDC
1284 # elf_hp.h is for HP/UX 64-bit shared library support.
1285 AC_CHECK_HEADERS([nlist.h machine/reg.h \
1286                   thread_db.h \
1287                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1288                   sys/procctl.h sys/resource.h sys/ptrace.h ptrace.h \
1289                   sys/reg.h sys/debugreg.h \
1290                   termios.h elf_hp.h])
1291 AC_CHECK_HEADERS(sys/user.h, [], [],
1292 [#if HAVE_SYS_PARAM_H
1293 # include <sys/param.h>
1294 #endif
1295 ])
1296
1297 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1298 AC_CHECK_HEADERS(term.h, [], [],
1299 [#if HAVE_CURSES_H
1300 # include <curses.h>
1301 #endif
1302 ])
1303
1304 AC_CHECK_HEADERS([sys/socket.h])
1305 AC_CHECK_HEADERS([ws2tcpip.h])
1306 AC_CHECK_HEADERS([execinfo.h])
1307
1308 # ------------------------- #
1309 # Checks for declarations.  #
1310 # ------------------------- #
1311
1312 libiberty_INIT
1313
1314 AC_CHECK_DECLS([snprintf])
1315 AM_LC_MESSAGES
1316
1317 # ------------------ #
1318 # Checks for types.  #
1319 # ------------------ #
1320
1321 AC_CHECK_TYPES(socklen_t, [], [],
1322 [#include <sys/types.h>
1323 #if HAVE_SYS_SOCKET_H
1324 # include <sys/socket.h>
1325 #elif HAVE_WS2TCPIP_H
1326 # include <ws2tcpip.h>
1327 #endif
1328 ])
1329
1330 # ------------------------------------- #
1331 # Checks for compiler characteristics.  #
1332 # ------------------------------------- #
1333
1334 AC_C_CONST
1335 AC_C_INLINE
1336 AC_C_BIGENDIAN
1337
1338 # ------------------------------ #
1339 # Checks for library functions.  #
1340 # ------------------------------ #
1341
1342 AC_CHECK_FUNCS([getuid getgid \
1343                 pipe pread pread64 pwrite resize_term \
1344                 getpgid setsid \
1345                 sigaction sigsetmask socketpair \
1346                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1347                 setrlimit getrlimit posix_madvise waitpid \
1348                 use_default_colors])
1349 AM_LANGINFO_CODESET
1350 GDB_AC_COMMON
1351
1352 # Check the return and argument types of ptrace.
1353 GDB_AC_PTRACE
1354
1355 dnl AC_FUNC_SETPGRP does not work when cross compiling
1356 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1357 if test "$cross_compiling" = no; then
1358   AC_FUNC_SETPGRP
1359 else
1360   AC_CACHE_CHECK(
1361     [whether setpgrp takes no argument],
1362     [ac_cv_func_setpgrp_void],
1363     [AC_COMPILE_IFELSE(
1364        [AC_LANG_PROGRAM(
1365           [#include <unistd.h>],
1366           [if (setpgrp(1,1) == -1)
1367              exit (0);
1368            else
1369              exit (1);]
1370         )],
1371        [ac_cv_func_setpgrp_void=no],
1372        [ac_cv_func_setpgrp_void=yes]
1373      )]
1374   )
1375 if test "$ac_cv_func_setpgrp_void" = yes; then
1376   AC_DEFINE(SETPGRP_VOID, 1)
1377 fi
1378 fi
1379
1380 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1381 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1382 [#include <sys/param.h>
1383 #include <sys/proc.h>
1384 ])
1385
1386 # See if <sys/lwp.h> defines `struct lwp`.
1387 AC_CACHE_CHECK(
1388   [for struct lwp],
1389   [gdb_cv_struct_lwp],
1390   [AC_COMPILE_IFELSE(
1391      [AC_LANG_PROGRAM(
1392         [#include <sys/param.h>
1393          #define _KMEMUSER
1394          #include <sys/lwp.h>],
1395         [struct lwp l;]
1396       )],
1397      [gdb_cv_struct_lwp=yes],
1398      [gdb_cv_struct_lwp=no]
1399    )]
1400 )
1401 if test "$gdb_cv_struct_lwp" = yes; then
1402   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1403             [Define to 1 if your system has struct lwp.])
1404 fi
1405
1406 # See if <machine/reg.h> degines `struct reg'.
1407 AC_CACHE_CHECK(
1408   [for struct reg in machine/reg.h],
1409   [gdb_cv_struct_reg],
1410   [AC_COMPILE_IFELSE(
1411      [AC_LANG_PROGRAM(
1412         [#include <sys/types.h>
1413          #include <machine/reg.h>],
1414         [struct reg r;]
1415       )],
1416      [gdb_cv_struct_reg=yes],
1417      [gdb_cv_struct_reg=no]
1418    )]
1419 )
1420 if test "$gdb_cv_struct_reg" = yes; then
1421   AC_DEFINE(HAVE_STRUCT_REG, 1,
1422             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1423 fi
1424
1425 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1426 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1427 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1428                  [#include <sys/types.h>
1429 #include <machine/reg.h>])
1430
1431 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1432 AC_MSG_CHECKING(for PTRACE_GETREGS)
1433 AC_CACHE_VAL(
1434   [gdb_cv_have_ptrace_getregs],
1435   [AC_COMPILE_IFELSE(
1436     [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
1437     [gdb_cv_have_ptrace_getregs=yes],
1438     [gdb_cv_have_ptrace_getregs=no]
1439    )]
1440 )
1441 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1442 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1443   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1444   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1445 fi
1446
1447 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1448 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1449 AC_CACHE_VAL(
1450   [gdb_cv_have_ptrace_getfpxregs],
1451   [AC_COMPILE_IFELSE(
1452      [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
1453      [gdb_cv_have_ptrace_getfpxregs=yes],
1454      [gdb_cv_have_ptrace_getfpxregs=no]
1455    )]
1456 )
1457 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1458 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1459   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1460   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1461 fi
1462
1463 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1464 AC_MSG_CHECKING(for PT_GETDBREGS)
1465 AC_CACHE_VAL(
1466   [gdb_cv_have_pt_getdbregs],
1467   [AC_COMPILE_IFELSE(
1468      [AC_LANG_PROGRAM(
1469         [#include <sys/types.h>
1470          #include <sys/ptrace.h>],
1471         [PT_GETDBREGS;]
1472       )],
1473      [gdb_cv_have_pt_getdbregs=yes],
1474      [gdb_cv_have_pt_getdbregs=no]
1475    )]
1476 )
1477 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1478 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1479   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1480   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1481 fi
1482
1483 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1484 # Older FreeBSD versions don't have the pl_tdname member of
1485 # `struct ptrace_lwpinfo'.
1486 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1487                  [#include <sys/ptrace.h>])
1488
1489 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1490 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1491 # FreeBSD 10.3.
1492 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1493                  [#include <sys/ptrace.h>])
1494
1495 # Check if the compiler supports the `long long' type.
1496
1497 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1498                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1499 [[extern long long foo;]],
1500 [[switch (foo & 2) { case 0: return 1; }]])],
1501                                   gdb_cv_c_long_long=yes,
1502                                   gdb_cv_c_long_long=no)])
1503 if test "$gdb_cv_c_long_long" != yes; then
1504   # libdecnumber requires long long.
1505   AC_MSG_ERROR([Compiler must support long long for GDB.])
1506 fi
1507
1508 # Check if the compiler and runtime support printing decfloats.
1509
1510 AC_CACHE_CHECK([for decfloat support in printf],
1511                gdb_cv_printf_has_decfloat,
1512                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1513 [[char buf[64];
1514   _Decimal32 d32 = 1.2345df;
1515   _Decimal64 d64 = 1.2345dd;
1516   _Decimal128 d128 = 1.2345dl;
1517   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1518   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1519                               gdb_cv_printf_has_decfloat=yes,
1520                               gdb_cv_printf_has_decfloat=no,
1521                               gdb_cv_printf_has_decfloat=no)])
1522 if test "$gdb_cv_printf_has_decfloat" = yes; then
1523   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1524             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1525 fi
1526
1527 # Check if the compiler supports the `long double' type.  We can't use
1528 # AC_C_LONG_DOUBLE because that one does additional checks on the
1529 # constants defined in <float.h> that fail on some systems,
1530 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1531
1532 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1533                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1534                                   gdb_cv_c_long_double=yes,
1535                                   gdb_cv_c_long_double=no)])
1536 if test "$gdb_cv_c_long_double" = yes; then
1537   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1538            [Define to 1 if the compiler supports long double.])
1539 fi
1540
1541 # Check if the compiler and runtime support printing long doubles.
1542
1543 AC_CACHE_CHECK([for long double support in printf],
1544                gdb_cv_printf_has_long_double,
1545                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1546 [[char buf[16];
1547   long double f = 3.141592653;
1548   sprintf (buf, "%Lg", f);
1549   return (strncmp ("3.14159", buf, 7));]])],
1550                               gdb_cv_printf_has_long_double=yes,
1551                               gdb_cv_printf_has_long_double=no,
1552                               gdb_cv_printf_has_long_double=no)])
1553 if test "$gdb_cv_printf_has_long_double" = yes; then
1554   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1555             [Define to 1 if the "%Lg" format works to print long doubles.])
1556 fi
1557
1558 # Check if the compiler and runtime support scanning long doubles.
1559
1560 AC_CACHE_CHECK([for long double support in scanf],
1561                gdb_cv_scanf_has_long_double,
1562                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1563 [[#include <stdio.h>]],
1564 [[char *buf = "3.141592653";
1565   long double f = 0;
1566   sscanf (buf, "%Lg", &f);
1567   return !(f > 3.14159 && f < 3.14160);]])],
1568                               gdb_cv_scanf_has_long_double=yes,
1569                               gdb_cv_scanf_has_long_double=no,
1570                               gdb_cv_scanf_has_long_double=no)])
1571 if test "$gdb_cv_scanf_has_long_double" = yes; then
1572   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1573             [Define to 1 if the "%Lg" format works to scan long doubles.])
1574 fi
1575
1576 case ${host_os} in
1577 aix*)
1578   AC_CACHE_CHECK(
1579     [for -bbigtoc option], [gdb_cv_bigtoc],
1580     [SAVE_LDFLAGS=$LDFLAGS
1581
1582      case $GCC in
1583        yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1584        *) gdb_cv_bigtoc=-bbigtoc ;;
1585      esac
1586
1587      LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1588      AC_LINK_IFELSE(
1589        [AC_LANG_PROGRAM([], [int i;])],
1590        [],
1591        [gdb_cv_bigtoc=]
1592      )
1593      LDFLAGS="${SAVE_LDFLAGS}"]
1594   )
1595   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1596   ;;
1597 esac
1598
1599 AC_MSG_CHECKING(for the dynamic export flag)
1600 dynamic_list=false
1601 if test "${gdb_native}" = yes; then
1602    # The dynamically loaded libthread_db needs access to symbols in the gdb
1603    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1604    # may not be supported there.
1605    old_LDFLAGS="$LDFLAGS"
1606    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1607    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1608    LDFLAGS="$LDFLAGS $RDYNAMIC"
1609    if test "${have_libpython}" = no; then
1610      AC_LINK_IFELSE(
1611        [AC_LANG_PROGRAM([], [])],
1612        [dynamic_list=true],
1613        []
1614      )
1615    else
1616      # Workaround http://bugs.python.org/issue4434 where static
1617      # libpythonX.Y.a would get its symbols required for
1618      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1619      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1620
1621      # Note the workaround for Python
1622      # http://bugs.python.org/issue10112 earlier has removed
1623      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1624      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1625      # always pass.
1626      old_CFLAGS="$CFLAGS"
1627      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1628      old_LIBS="$LIBS"
1629      LIBS="$LIBS $PYTHON_LIBS"
1630      old_CPPFLAGS="$CPPFLAGS"
1631      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1632      AC_RUN_IFELSE(
1633        [AC_LANG_PROGRAM(
1634          [#include "Python.h"],
1635          [int err;
1636           Py_Initialize ();
1637           err = PyRun_SimpleString ("import ctypes\n");
1638           Py_Finalize ();
1639           return err == 0 ? 0 : 1;])],
1640        [dynamic_list=true], [], [true])
1641      LIBS="$old_LIBS"
1642      CFLAGS="$old_CFLAGS"
1643      CPPFLAGS="$old_CPPFLAGS"
1644    fi
1645    LDFLAGS="$old_LDFLAGS"
1646 fi
1647 if $dynamic_list; then
1648   found="-Wl,--dynamic-list"
1649   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1650 else
1651   found="-rdynamic"
1652   RDYNAMIC="-rdynamic"
1653 fi
1654 AC_SUBST(RDYNAMIC)
1655 AC_MSG_RESULT($found)
1656
1657 AC_CACHE_CHECK(
1658   [whether execinfo.h backtrace is available],
1659   gdb_cv_execinfo_backtrace,
1660   [AC_LINK_IFELSE(
1661      [AC_LANG_PROGRAM(
1662         [
1663          #include <execinfo.h>
1664         ],
1665         [
1666          int f;
1667          void *b[[2]];
1668          f = backtrace (b, 2);
1669          backtrace_symbols_fd (b, f, 2);
1670         ])],
1671    [gdb_cv_execinfo_backtrace=yes],
1672    [gdb_cv_execinfo_backtrace=no])])
1673 if test "$gdb_cv_execinfo_backtrace" = yes; then
1674   AC_DEFINE(HAVE_EXECINFO_BACKTRACE, 1,
1675             [Define to 1 if execinfo.h backtrace functions are available.])
1676 fi
1677
1678 dnl For certain native configurations, we need to check whether thread
1679 dnl support can be built in or not.
1680 dnl
1681 dnl Note that we only want this if we are both native (host == target),
1682 dnl and not doing a canadian cross build (build == host).
1683
1684 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1685    case ${host_os} in
1686    aix*)
1687       AC_MSG_CHECKING(for AiX thread debugging library)
1688       AC_CACHE_VAL(
1689         [gdb_cv_have_aix_thread_debug],
1690         [AC_COMPILE_IFELSE(
1691            [AC_LANG_PROGRAM(
1692               [#include <sys/pthdebug.h>],
1693               [#ifndef PTHDB_VERSION_3
1694                #error
1695                #endif]
1696             )],
1697            [gdb_cv_have_aix_thread_debug=yes],
1698            [gdb_cv_have_aix_thread_debug=no]
1699          )]
1700       )
1701       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1702       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1703          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1704          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1705          LIBS="$LIBS -lpthdebug"
1706
1707          # Older versions of AIX do not provide the declaration for
1708          # the getthrds function (it appears that it was introduced
1709          # with AIX 6.x).
1710          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1711       fi
1712       ;;
1713    esac
1714    AC_SUBST(CONFIG_LDFLAGS)
1715 fi
1716
1717 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1718 dnl other error codes.
1719 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1720   AC_CACHE_CHECK(
1721     [whether <thread_db.h> has TD_NOTALLOC],
1722     [gdb_cv_thread_db_h_has_td_notalloc],
1723     [AC_COMPILE_IFELSE(
1724        [AC_LANG_PROGRAM(
1725           [#include <thread_db.h>],
1726           [int i = TD_NOTALLOC;]
1727         )],
1728        [gdb_cv_thread_db_h_has_td_notalloc=yes],
1729        [gdb_cv_thread_db_h_has_td_notalloc=no]
1730      )]
1731   )
1732
1733   AC_CACHE_CHECK(
1734     [whether <thread_db.h> has TD_VERSION],
1735     [gdb_cv_thread_db_h_has_td_version],
1736     [AC_COMPILE_IFELSE(
1737        [AC_LANG_PROGRAM(
1738           [#include <thread_db.h>],
1739           [int i = TD_VERSION;]
1740         )],
1741        [gdb_cv_thread_db_h_has_td_version=yes],
1742        [gdb_cv_thread_db_h_has_td_version=no]
1743      )]
1744   )
1745
1746   AC_CACHE_CHECK(
1747     [whether <thread_db.h> has TD_NOTLS],
1748     [gdb_cv_thread_db_h_has_td_notls],
1749     [AC_COMPILE_IFELSE(
1750        [AC_LANG_PROGRAM(
1751           [#include <thread_db.h>],
1752           [int i = TD_NOTLS;]
1753         )],
1754        [gdb_cv_thread_db_h_has_td_notls=yes],
1755        [gdb_cv_thread_db_h_has_td_notls=no]
1756      )]
1757   )
1758 fi
1759 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1760   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1761             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1762 fi
1763 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1764   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1765             [Define if <thread_db.h> has the TD_VERSION error code.])
1766 fi
1767 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1768   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1769             [Define if <thread_db.h> has the TD_NOTLS error code.])
1770 fi
1771
1772 dnl Set the host's .gdbinit filename.
1773 case $host_os in
1774   go32* | *djgpp*)
1775     gdbinit=gdb.ini
1776     ;;
1777   *)
1778     gdbinit=.gdbinit
1779     ;;
1780 esac
1781 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1782
1783 dnl Set the host's .gdbearlyinit filename
1784 AC_DEFINE_UNQUOTED(GDBEARLYINIT,".gdbearlyinit",[The .gdbearlyinit filename.])
1785
1786 dnl Handle optional features that can be enabled.
1787
1788 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1789 # except that the argument to --with-sysroot is optional.
1790 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1791 if test "x$with_sysroot" = xyes; then
1792   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1793 fi
1794 AC_ARG_WITH(sysroot,
1795   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1796                  [search for usr/lib et al within DIR]),
1797   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1798 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1799               [search for usr/lib et al within DIR])
1800 AC_SUBST(TARGET_SYSTEM_ROOT)
1801 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1802
1803 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1804     [automatically load a system-wide gdbinit file],
1805     [])
1806 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1807     [automatically load system-wide gdbinit files from this directory],
1808     [])
1809
1810 AM_GDB_COMPILER_TYPE
1811 AM_GDB_WARNINGS
1812 AM_GDB_UBSAN
1813
1814 # In the Cygwin environment, we need some additional flags.
1815 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1816 [AC_EGREP_CPP(^lose$, [
1817 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1818 lose
1819 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1820
1821
1822 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1823 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1824 case ${host} in
1825   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1826   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1827   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1828   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1829 esac
1830 AC_SUBST(SER_HARDWIRE)
1831
1832 # libreadline needs libuser32.a in a cygwin environment
1833 WIN32LIBS=
1834 if test x"$gdb_cv_os_cygwin" = xyes; then
1835     WIN32LIBS="-luser32"
1836     case "${target}" in
1837         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1838         ;;
1839     esac
1840 fi
1841
1842 # The ser-tcp.c module requires sockets.
1843 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1844 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1845
1846 # Add ELF support to GDB, but only if BFD includes ELF support.
1847 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1848                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1849 if test "$gdb_cv_var_elf" = yes; then
1850   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o \
1851                 gcore-elf.o elf-none-tdep.o"
1852   AC_DEFINE(HAVE_ELF, 1,
1853             [Define if ELF support should be included.])
1854   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1855   if test "$plugins" = "yes"; then
1856     AC_SEARCH_LIBS(dlopen, dl)
1857   fi
1858 fi
1859
1860 # Add macho support to GDB, but only if BFD includes it.
1861 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1862                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1863 if test "$gdb_cv_var_macho" = yes; then
1864   CONFIG_OBS="$CONFIG_OBS machoread.o"
1865 fi
1866
1867 # Add any host-specific objects to GDB.
1868 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1869
1870 # If building on ELF, look for lzma support for embedded compressed debug info.
1871 if test "$gdb_cv_var_elf" = yes; then
1872   AC_ARG_WITH(lzma,
1873     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1874     [], [with_lzma=auto])
1875   AC_MSG_CHECKING([whether to use lzma])
1876   AC_MSG_RESULT([$with_lzma])
1877
1878   if test "${with_lzma}" != no; then
1879     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1880                           [lzma_index_iter iter;
1881                            lzma_index_iter_init (&iter, 0);
1882                            lzma_mf_is_supported (LZMA_MF_HC3);])
1883     if test "$HAVE_LIBLZMA" != yes; then
1884       if test "$with_lzma" = yes; then
1885         AC_MSG_ERROR([missing liblzma for --with-lzma])
1886       fi
1887     fi
1888   fi
1889 fi
1890
1891 LIBGUI="../libgui/src/libgui.a"
1892 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1893 AC_SUBST(LIBGUI)
1894 AC_SUBST(GUI_CFLAGS_X)
1895
1896 WIN32LDAPP=
1897 AC_SUBST(WIN32LIBS)
1898 AC_SUBST(WIN32LDAPP)
1899
1900 case "${host}" in
1901 *-*-cygwin* | *-*-mingw* )
1902     configdir="win"
1903     ;;
1904 *)
1905     configdir="unix"
1906     ;;
1907 esac
1908
1909 GDBTKLIBS=
1910 if test "${enable_gdbtk}" = "yes"; then
1911
1912     # Gdbtk must have an absolute path to srcdir in order to run
1913     # properly when not installed.
1914     here=`pwd`
1915     cd ${srcdir}
1916     GDBTK_SRC_DIR=`pwd`
1917     cd $here
1918
1919     SC_PATH_TCLCONFIG
1920
1921     # If $no_tk is nonempty, then we can't do Tk, and there is no
1922     # point to doing Tcl.
1923     SC_PATH_TKCONFIG
1924
1925     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1926         SC_LOAD_TCLCONFIG
1927
1928         # Check for in-tree tcl
1929         here=`pwd`
1930         cd ${srcdir}/..
1931         topdir=`pwd`
1932         cd ${here}
1933
1934         intree="no"
1935         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1936           intree="yes"
1937         fi
1938
1939         # Find Tcl private headers
1940         if test x"${intree}" = xno; then
1941           CY_AC_TCL_PRIVATE_HEADERS
1942           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1943           TCL_LIBRARY="${TCL_LIB_SPEC}"
1944           TCL_DEPS=""
1945         else
1946           # If building tcl in the same src tree, private headers
1947           # are not needed, but we need to be sure to use the right
1948           # headers library
1949           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1950           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1951           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1952         fi
1953         AC_SUBST(TCL_INCLUDE)
1954         AC_SUBST(TCL_LIBRARY)
1955         AC_SUBST(TCL_DEPS)
1956
1957         SC_LOAD_TKCONFIG
1958
1959         # Check for in-tree Tk
1960         intree="no"
1961         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1962           intree="yes"
1963         fi
1964
1965         # Find Tk private headers
1966         if test x"${intree}" = xno; then
1967           CY_AC_TK_PRIVATE_HEADERS
1968           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1969           TK_LIBRARY=${TK_LIB_SPEC}
1970           TK_DEPS=""
1971         else
1972           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1973           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1974           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1975         fi
1976         AC_SUBST(TK_INCLUDE)
1977         AC_SUBST(TK_LIBRARY)
1978         AC_SUBST(TK_DEPS)
1979         AC_SUBST(TK_XINCLUDES)
1980
1981         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1982
1983         # Include some libraries that Tcl and Tk want.
1984         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1985         # Yes, the ordering seems wrong here.  But it isn't.
1986         # TK_LIBS is the list of libraries that need to be linked
1987         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1988         # were in LIBS then any link tests after this point would
1989         # try to include things like `$(LIBGUI)', which wouldn't work.
1990         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1991
1992         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1993         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1994         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1995         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1996         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1997         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1998         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1999
2000         if test x"$gdb_cv_os_cygwin" = xyes; then
2001           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2002           WIN32LDAPP="-Wl,--subsystem,console"
2003           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2004         fi
2005
2006         AC_CONFIG_SUBDIRS(gdbtk)
2007     fi
2008 fi
2009
2010 AC_SUBST(X_CFLAGS)
2011 AC_SUBST(X_LDFLAGS)
2012 AC_SUBST(X_LIBS)
2013 AC_SUBST(GDBTKLIBS)
2014 AC_SUBST(GDBTK_CFLAGS)
2015 AC_SUBST(GDBTK_SRC_DIR)
2016
2017 AC_PATH_X
2018
2019 # Unlike the sim directory, whether a simulator is linked is controlled by
2020 # presence of a gdb_sim definition in the target configure.tgt entry.
2021 # This code just checks for a few cases where we'd like to ignore those
2022 # definitions, even when they're present in the '.mt' file.  These cases
2023 # are when --disable-sim is specified, or if the simulator directory is
2024 # not part of the source tree.
2025 #
2026 AC_ARG_ENABLE(sim,
2027 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2028 [echo "enable_sim = $enable_sim";
2029  echo "enableval = ${enableval}";
2030  case "${enableval}" in
2031   yes) ignore_sim=false ;;
2032   no)  ignore_sim=true ;;
2033   *)   ignore_sim=false ;;
2034  esac],
2035 [ignore_sim=false])
2036
2037 if test ! -d "${srcdir}/../sim"; then
2038   ignore_sim=true
2039 fi
2040
2041 SIM=
2042 SIM_OBS=
2043 if test "${ignore_sim}" = "false"; then
2044   if test x"${gdb_sim}" != x ; then
2045     SIM="${gdb_sim}"
2046     SIM_OBS="remote-sim.o"
2047
2048     # Some tdep code should only be compiled in when the ppc sim is
2049     # built.  PR sim/13418.
2050     case $target in
2051       powerpc*-*-*)
2052         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2053         ;;
2054     esac
2055   fi
2056 fi
2057 AC_SUBST(SIM)
2058 AC_SUBST(SIM_OBS)
2059
2060 AC_SUBST(ENABLE_CFLAGS)
2061 AC_SUBST(PROFILE_CFLAGS)
2062
2063 AC_SUBST(CONFIG_OBS)
2064 AC_SUBST(CONFIG_DEPS)
2065 AC_SUBST(CONFIG_SRCS)
2066 AC_SUBST(CONFIG_ALL)
2067 AC_SUBST(CONFIG_CLEAN)
2068 AC_SUBST(CONFIG_INSTALL)
2069 AC_SUBST(CONFIG_UNINSTALL)
2070
2071 # List of host floatformats.
2072 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2073 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2074 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2075
2076 # target_subdir is used by the testsuite to find the target libraries.
2077 target_subdir=
2078 if test "${host}" != "${target}"; then
2079     target_subdir="${target_alias}/"
2080 fi
2081 AC_SUBST(target_subdir)
2082
2083 # Import nat definitions.
2084 nat_makefile_frag=/dev/null
2085 if test "${gdb_native}" = "yes"; then
2086   . ${srcdir}/configure.nat
2087   nativefile=$NAT_FILE
2088 fi
2089
2090 AC_SUBST(NAT_FILE)
2091 AC_SUBST(NATDEPFILES)
2092 AC_SUBST(NAT_CDEPS)
2093 AC_SUBST(LOADLIBES)
2094 AC_SUBST(MH_CFLAGS)
2095 AC_SUBST(XM_CLIBS)
2096 AC_SUBST(NAT_GENERATED_FILES)
2097 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2098 AC_SUBST_FILE(nat_makefile_frag)
2099
2100 if test x"${gdb_osabi}" != x ; then
2101     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2102                        [Define to the default OS ABI for this configuration.])
2103 fi
2104
2105 # Setup possible use of libbacktrace.
2106 AC_ARG_ENABLE([libbacktrace],
2107 [AS_HELP_STRING([--enable-libbacktrace],
2108                 [use libbacktrace to write a backtrace after a fatal signal.])],
2109 [case "${enableval}" in
2110   yes)  enable_libbacktrace=yes ;;
2111   no)   enable_libbacktrace=no  ;;
2112   *)    AC_MSG_ERROR(bad value ${enableval} for --enable-libbacktrace option) ;;
2113 esac],
2114 enable_libbacktrace=yes)
2115
2116 if test "${enable_libbacktrace}" == "yes"; then
2117   LIBBACKTRACE_INC="-I$srcdir/../libbacktrace/ -I../libbacktrace/"
2118   LIBBACKTRACE_LIB=../libbacktrace/.libs/libbacktrace.a
2119   AC_DEFINE(HAVE_LIBBACKTRACE, 1, [Define if libbacktrace is being used.])
2120 else
2121   LIBBACKTRACE_INC=
2122   LIBBACKTRACE_LIB=
2123 fi
2124
2125 AC_SUBST(LIBBACKTRACE_INC)
2126 AC_SUBST(LIBBACKTRACE_LIB)
2127
2128 # Check for babeltrace and babeltrace-ctf
2129 AC_ARG_WITH(babeltrace,
2130   AS_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2131   [], [with_babeltrace=auto])
2132 AC_MSG_CHECKING([whether to use babeltrace])
2133 AC_MSG_RESULT([$with_babeltrace])
2134
2135 if test "x$with_babeltrace" = "xno"; then
2136   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2137 else
2138   # Append -Werror to CFLAGS so that configure can catch the warning
2139   # "assignment from incompatible pointer type", which is related to
2140   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2141   # in GDB, while babeltrace 1.0.3 is broken.
2142   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2143   # safe to save and restore CFLAGS here.
2144   saved_CFLAGS=$CFLAGS
2145   CFLAGS="$CFLAGS -Werror"
2146   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2147                         [#include <babeltrace/babeltrace.h>
2148                          #include <babeltrace/ctf/events.h>
2149                          #include <babeltrace/ctf/iterator.h>],
2150                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2151                         struct bt_ctf_event *event = NULL;
2152                         const struct bt_definition *scope;
2153
2154                         pos->type = BT_SEEK_BEGIN;
2155                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2156                         scope = bt_ctf_get_top_level_scope (event,
2157                                                            BT_STREAM_EVENT_HEADER);
2158                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2159                         ])
2160   CFLAGS=$saved_CFLAGS
2161
2162   if test "$HAVE_LIBBABELTRACE" != yes; then
2163      if test "$with_babeltrace" = yes; then
2164        AC_MSG_ERROR([babeltrace is missing or unusable])
2165      else
2166        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2167      fi
2168   fi
2169 fi
2170
2171 # Check for xxhash
2172 AC_ARG_WITH(xxhash,
2173   AS_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2174   [], [with_xxhash=auto])
2175
2176 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
2177 if test x${enable_static} = xno; then
2178   LIBCTF="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
2179   CTF_DEPS="../libctf/.libs/libctf.so"
2180 else
2181   LIBCTF="../libctf/.libs/libctf.a"
2182   CTF_DEPS="$LIBCTF"
2183 fi
2184 if test "${enable_libctf}" = yes; then
2185   AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
2186 else
2187   LIBCTF=
2188   CTF_DEPS=
2189 fi
2190 AC_SUBST(LIBCTF)
2191 AC_SUBST(CTF_DEPS)
2192
2193 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2194 # empty version.
2195
2196 if test "x$with_xxhash" != "xno"; then
2197   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2198                         [#include <xxhash.h>],
2199                         [XXH32("foo", 3, 0);
2200                         ])
2201   if test "$HAVE_LIBXXHASH" != yes; then
2202     if test "$with_xxhash" = yes; then
2203       AC_MSG_ERROR([xxhash is missing or unusable])
2204     fi
2205   fi
2206   if test "x$with_xxhash" = "xauto"; then
2207     with_xxhash="$HAVE_LIBXXHASH"
2208   fi
2209 fi
2210
2211 AC_MSG_CHECKING([whether to use xxhash])
2212 AC_MSG_RESULT([$with_xxhash])
2213
2214 NM_H=
2215 rm -f nm.h
2216 if test "${nativefile}" != ""; then
2217     case "${nativefile}" in
2218       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2219       * ) GDB_NM_FILE="${nativefile}"
2220     esac
2221     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2222                     [GDB_NM_FILE=$GDB_NM_FILE])
2223     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2224     NM_H=nm.h
2225 fi
2226 AC_SUBST(GDB_NM_FILE)
2227 AC_SUBST(NM_H)
2228
2229 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2230 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2231 if test "x$USE_MAINTAINER_MODE" = xyes; then
2232   if test "${XSLTPROC}" = missing; then
2233     AC_MSG_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2234   fi
2235 fi
2236 AC_SUBST(XSLTPROC)
2237
2238 dnl Check for exe extension set on certain hosts (e.g. Win32)
2239 AC_EXEEXT
2240
2241 dnl  Detect the character set used by this host.
2242 dnl  At the moment, we just assume it's UTF-8.
2243 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2244           [Define to be a string naming the default host character set.])
2245
2246 GDB_AC_SELFTEST([
2247   CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)"
2248   CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)"
2249 ])
2250
2251 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2252 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2253 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2254 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2255
2256 AC_OUTPUT