gold/testsuite/script_test_2.t

   1 /* script_test_2.t -- linker script test 2 for gold
   2
   3    Copyright 2008 Free Software Foundation, Inc.
   4    Written by Ian Lance Taylor <iant@google.com>.
   5
   6    This file is part of gold.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  21    MA 02110-1301, USA.  */
  22
  23 test_addr_alias = test_addr;
  24
  25 SECTIONS
  26 {
  27   /* With luck this will work everywhere.  */
  28   . = 0x10000000;
  29
  30   /* With luck this will be enough to get the program working.  */
  31   .text : { *(.text) }
  32   . += 0x100000;
  33   . = ALIGN(0x100);
  34   .data : { *(.data) }
  35   .bss : { *(.bss) }
  36
  37   /* Now the real test.  */
  38   . = 0x20000001;
  39   start_test_area = .;
  40   .gold_test ALIGN(16) : SUBALIGN(32) {
  41     start_test_area_1 = .;
  42
  43     /* No sections should wind up here, because of the EXCLUDE_FILE.  */
  44     *( EXCLUDE_FILE(script_test*) .gold_test)
  45
  46     /* This should match only script_test_2b.o.  */
  47     script_test_2b.o(.gold_test)
  48
  49     /* This should match the remaining sections.  */
  50     *(.gold_test)
  51
  52     . = . + 4;
  53     start_data = .;
  54     BYTE(1)
  55     SHORT(2)
  56     LONG(4)
  57     QUAD(8)
  58     end_data = .;
  59
  60     start_fill = .;
  61     FILL(0x12345678);
  62     . = . + 7;
  63     BYTE(0)
  64     end_fill = .;
  65   }
  66   end_test_area = .;
  67   test_addr = ADDR(.gold_test);
  68 }