ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  15 AC_ARG_ENABLE(targets,
  16 [  --enable-targets        alternative target configurations],
  17 [case "${enableval}" in
  18   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  19             ;;
  20   no)       enable_targets= ;;
  21   *)        enable_targets=$enableval ;;
  22 esac])dnl
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30
  31 AC_ARG_WITH(sysroot,
  32 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  33 [
  34  case ${with_sysroot} in
  35  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  36  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  37  esac
  38
  39  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  40  use_sysroot=yes
  41
  42  if test "x$prefix" = xNONE; then
  43   test_prefix=/usr/local
  44  else
  45   test_prefix=$prefix
  46  fi
  47  if test "x$exec_prefix" = xNONE; then
  48   test_exec_prefix=$test_prefix
  49  else
  50   test_exec_prefix=$exec_prefix
  51  fi
  52  case ${TARGET_SYSTEM_ROOT} in
  53  "${test_prefix}"|"${test_prefix}/"*|\
  54  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  55  '${prefix}'|'${prefix}/'*|\
  56  '${exec_prefix}'|'${exec_prefix}/'*)
  57    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  58    TARGET_SYSTEM_ROOT_DEFINE="$t"
  59    ;;
  60  esac
  61 ], [
  62  use_sysroot=no
  63  TARGET_SYSTEM_ROOT=
  64  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  65 ])
  66 AC_SUBST(use_sysroot)
  67 AC_SUBST(TARGET_SYSTEM_ROOT)
  68 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  69
  70 AM_BINUTILS_WARNINGS
  71
  72 AM_CONFIG_HEADER(config.h:config.in)
  73
  74 if test -z "$target" ; then
  75     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  76 fi
  77 if test -z "$host" ; then
  78     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  79 fi
  80
  81 # host-specific stuff:
  82
  83 AC_PROG_CC
  84 AC_GNU_SOURCE
  85 AC_PROG_INSTALL
  86
  87 AM_PROG_LIBTOOL
  88
  89 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi"
  90 ZW_GNU_GETTEXT_SISTER_DIR
  91 AM_PO_SUBDIRS
  92
  93 AC_EXEEXT
  94
  95 AC_PROG_YACC
  96 AM_PROG_LEX
  97
  98 AM_MAINTAINER_MODE
  99 AM_CONDITIONAL(GENINSRC_NEVER, false)
 100
 101 . ${srcdir}/configure.host
 102
 103 AC_SUBST(HDEFINES)
 104 AC_SUBST(HOSTING_CRT0)
 105 AC_SUBST(HOSTING_LIBS)
 106 AC_SUBST(NATIVE_LIB_DIRS)
 107
 108 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 109 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 110 AC_HEADER_DIRENT
 111
 112 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 113 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 114 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 115 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 116 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 117 if test $ld_cv_decl_getopt_unistd_h = yes; then
 118   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 119             [Is the prototype for getopt in <unistd.h> in the expected format?])
 120 fi
 121
 122 BFD_BINARY_FOPEN
 123
 124 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 125
 126 # When converting linker scripts into strings for use in emulation
 127 # files, use astring.sed if the compiler supports ANSI string
 128 # concatenation, or ostring.sed otherwise.  This is to support the
 129 # broken Microsoft MSVC compiler, which limits the length of string
 130 # constants, while still supporting pre-ANSI compilers which do not
 131 # support string concatenation.
 132 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 133 AC_CACHE_VAL(ld_cv_string_concatenation,
 134 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 135   [ld_cv_string_concatenation=yes],
 136   [ld_cv_string_concatenation=no])])
 137 AC_MSG_RESULT($ld_cv_string_concatenation)
 138 if test "$ld_cv_string_concatenation" = "yes"; then
 139   STRINGIFY=astring.sed
 140 else
 141   STRINGIFY=ostring.sed
 142 fi
 143 AC_SUBST(STRINGIFY)
 144
 145 # target-specific stuff:
 146
 147 all_targets=
 148 EMUL=
 149 all_emuls=
 150 all_emul_extras=
 151 all_libpath=
 152
 153 dnl We need to get an arbitrary number of tdir definitions into
 154 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 155 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 156 dnl file.
 157 rm -f tdirs
 158
 159 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 160 do
 161   if test "$targ_alias" = "all"; then
 162     all_targets=true
 163   else
 164     # Canonicalize the secondary target names.
 165     result=`$ac_config_sub $targ_alias 2>/dev/null`
 166     if test -n "$result"; then
 167         targ=$result
 168     else
 169         targ=$targ_alias
 170     fi
 171
 172     . ${srcdir}/configure.tgt
 173
 174     if test "$targ" = "$target"; then
 175       EMUL=$targ_emul
 176     fi
 177
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181
 182     if test x${want64} = xtrue; then
 183       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 184       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 185     fi
 186
 187     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 188         case " $all_emuls " in
 189         *" e${i}.o "*) ;;
 190         *)
 191           all_emuls="$all_emuls e${i}.o"
 192           eval result=\$tdir_$i
 193           test -z "$result" && result=$targ_alias
 194           echo tdir_$i=$result >> tdirs
 195           ;;
 196         esac
 197     done
 198
 199     for i in $targ_emul $targ_extra_libpath; do
 200         case " $all_libpath " in
 201         *" ${i} "*) ;;
 202         *)
 203           if test -z "$all_libpath"; then
 204             all_libpath=${i}
 205           else
 206             all_libpath="$all_libpath ${i}"
 207           fi
 208           ;;
 209         esac
 210     done
 211
 212     for i in $targ_extra_ofiles; do
 213         case " $all_emul_extras " in
 214         *" ${i} "*) ;;
 215         *)
 216           all_emul_extras="$all_emul_extras ${i}"
 217           ;;
 218         esac
 219     done
 220   fi
 221 done
 222
 223 AC_SUBST(EMUL)
 224
 225 TDIRS=tdirs
 226 AC_SUBST_FILE(TDIRS)
 227
 228 if test x${all_targets} = xtrue; then
 229   if test x${want64} = xfalse; then
 230     AC_CHECK_SIZEOF(long)
 231     if test "x${ac_cv_sizeof_long}" = "x8"; then
 232       want64=true
 233     fi
 234   fi
 235   if test x${want64} = xtrue; then
 236     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 237   else
 238     EMULATION_OFILES='$(ALL_EMULATIONS)'
 239   fi
 240   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 241 else
 242   EMULATION_OFILES=$all_emuls
 243   EMUL_EXTRA_OFILES=$all_emul_extras
 244 fi
 245 AC_SUBST(EMULATION_OFILES)
 246 AC_SUBST(EMUL_EXTRA_OFILES)
 247 AC_SUBST(LIB_PATH)
 248
 249 EMULATION_LIBPATH=$all_libpath
 250 AC_SUBST(EMULATION_LIBPATH)
 251
 252 if test x${enable_static} = xno; then
 253   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 254 else
 255   TESTBFDLIB="../bfd/.libs/libbfd.a"
 256 fi
 257 AC_SUBST(TESTBFDLIB)
 258
 259 target_vendor=${target_vendor=$host_vendor}
 260 case "$target_vendor" in
 261   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 262   *)  EXTRA_SHLIB_EXTENSION= ;;
 263 esac
 264
 265 case "$target_os" in
 266   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 267 esac
 268
 269 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 270   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 271    [Additional extension a shared object might have.])
 272 fi
 273
 274 dnl Required by html and install-html
 275 AC_SUBST(datarootdir)
 276 AC_SUBST(docdir)
 277 AC_SUBST(htmldir)
 278
 279 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)