bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.14.90)
  11 # Uncomment the next line to remove the date from the reported bfd version
  12 #is_release=y
  13
  14 changequote(,)dnl
  15 bfd_version=`echo "${VERSION}" | sed -e 's/\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\).*/\1.00\2.00\3.00\4.00\5/' -e 's/\([^\.]*\)\..*\(..\)\..*\(..\)\..*\(..\)\..*\(..\)$/\1\2\3\4\5/'`
  16 changequote([,])dnl
  17
  18 bfd_version_string="\"${VERSION}\""
  19 if test x${is_release} = x; then
  20   bfd_version_date=`sed -n -e 's/.*DATE //p' < ${srcdir}/version.h`
  21   bfd_version_string="\"${VERSION} ${bfd_version_date}\""
  22 fi
  23 AC_SUBST(bfd_version)
  24 AC_SUBST(bfd_version_string)
  25
  26 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  27 dnl to call AC_CHECK_PROG.
  28 AC_CHECK_TOOL(AR, ar)
  29 AC_CHECK_TOOL(RANLIB, ranlib, :)
  30
  31 dnl Default to a non shared library.  This may be overridden by the
  32 dnl configure option --enable-shared.
  33 AM_DISABLE_SHARED
  34
  35 AM_PROG_LIBTOOL
  36
  37 AC_ARG_ENABLE(64-bit-bfd,
  38 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  39 [case "${enableval}" in
  40   yes)  want64=true  ;;
  41   no)   want64=false ;;
  42   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  43 esac],[want64=false])dnl
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations],
  46 [case "${enableval}" in
  47   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52 AC_ARG_ENABLE(commonbfdlib,
  53 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  54 [case "${enableval}" in
  55   yes) commonbfdlib=true ;;
  56   no)  commonbfdlib=false ;;
  57   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  58 esac])dnl
  59 AC_ARG_WITH(mmap,
  60 [  --with-mmap             try using mmap for BFD input files if available],
  61 [case "${withval}" in
  62   yes)  want_mmap=true ;;
  63   no)   want_mmap=false ;;
  64   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  65 esac],[want_mmap=false])dnl
  66
  67 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  68 AC_ARG_ENABLE(build-warnings,
  69 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  70 [case "${enableval}" in
  71   yes)  ;;
  72   no)   build_warnings="-w";;
  73   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  74         build_warnings="${build_warnings} ${t}";;
  75   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  76         build_warnings="${t} ${build_warnings}";;
  77   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  78 esac
  79 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  80   echo "Setting warning flags = $build_warnings" 6>&1
  81 fi])dnl
  82 WARN_CFLAGS=""
  83 if test "x${build_warnings}" != x && test "x$GCC" = xyes ; then
  84     WARN_CFLAGS="${build_warnings}"
  85 fi
  86 AC_SUBST(WARN_CFLAGS)
  87
  88 AM_CONFIG_HEADER(config.h:config.in)
  89
  90 if test -z "$target" ; then
  91     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  92 fi
  93
  94 AM_MAINTAINER_MODE
  95 AM_INSTALL_LIBBFD
  96 AC_EXEEXT
  97
  98 host64=false
  99 target64=false
 100 bfd_default_target_size=32
 101
 102 # host stuff:
 103
 104 AC_PROG_CC
 105
 106 ALL_LINGUAS="fr tr ja es sv da zh_CN"
 107 CY_GNU_GETTEXT
 108
 109 # Permit host specific settings.
 110 . ${srcdir}/configure.host
 111
 112 AC_SUBST(HDEFINES)
 113 AC_PROG_INSTALL
 114
 115 BFD_HOST_64BIT_LONG=0
 116 BFD_HOST_LONG_LONG=0
 117 BFD_HOST_64_BIT_DEFINED=0
 118 BFD_HOST_64_BIT=
 119 BFD_HOST_U_64_BIT=
 120
 121 AC_MSG_CHECKING([for long long])
 122 AC_CACHE_VAL(bfd_cv_has_long_long,
 123 [AC_TRY_COMPILE(,
 124 [unsigned long long ll = 18446744073709551615ULL;],
 125 bfd_cv_has_long_long=yes, bfd_cv_has_long_long=no)])
 126 AC_MSG_RESULT($bfd_cv_has_long_long)
 127 if test $bfd_cv_has_long_long = yes; then
 128   BFD_HOST_LONG_LONG=1
 129   AC_COMPILE_CHECK_SIZEOF(long long)
 130 fi
 131
 132 AC_COMPILE_CHECK_SIZEOF(long)
 133 if test "x${ac_cv_sizeof_long}" = "x8"; then
 134   host64=true
 135   HOST_64BIT_TYPE="long"
 136 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 137   HOST_64BIT_TYPE="long long"
 138   HOST_U_64BIT_TYPE="unsigned long long"
 139 fi
 140
 141 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 142   BFD_HOST_64BIT_LONG=1
 143 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 144   BFD_HOST_64_BIT_DEFINED=1
 145   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 146   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 147 fi
 148
 149 AC_SUBST(BFD_HOST_64BIT_LONG)
 150 AC_SUBST(BFD_HOST_LONG_LONG)
 151 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 152 AC_SUBST(BFD_HOST_64_BIT)
 153 AC_SUBST(BFD_HOST_U_64_BIT)
 154
 155 BFD_CC_FOR_BUILD
 156
 157 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 158 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 159 AC_HEADER_TIME
 160 AC_HEADER_DIRENT
 161 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 162 AC_CHECK_FUNCS(strtoull)
 163
 164 BFD_BINARY_FOPEN
 165
 166 BFD_NEED_DECLARATION(strstr)
 167 BFD_NEED_DECLARATION(malloc)
 168 BFD_NEED_DECLARATION(realloc)
 169 BFD_NEED_DECLARATION(free)
 170 BFD_NEED_DECLARATION(getenv)
 171
 172 # If we are configured native, pick a core file support file.
 173 COREFILE=
 174 COREFLAG=
 175 TRAD_HEADER=
 176 if test "${target}" = "${host}"; then
 177   case "${host}" in
 178   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 179         COREFILE=''
 180         ;;
 181   alpha*-*-linux-gnu*)
 182         COREFILE=trad-core.lo
 183         TRAD_HEADER='"hosts/alphalinux.h"'
 184         ;;
 185   alpha*-*-netbsd* | alpha*-*-openbsd*)
 186         COREFILE=netbsd-core.lo
 187         ;;
 188   alpha*-*-*)           COREFILE=osf-core.lo ;;
 189   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 190                         COREFILE='' ;;
 191   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 192   arm-*-riscix)         COREFILE=trad-core.lo ;;
 193   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 194   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 195   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 196   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 197                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 198   i370-*-*)
 199         COREFILE=trad-core.lo
 200         TRAD_HEADER='"hosts/i370linux.h"'
 201         ;;
 202
 203 changequote(,)dnl
 204   i[3-7]86-sequent-bsd*)
 205 changequote([,])dnl
 206         COREFILE=trad-core.lo
 207         TRAD_HEADER='"hosts/symmetry.h"'
 208         ;;
 209 changequote(,)dnl
 210   i[3-7]86-sequent-sysv4*) ;;
 211   i[3-7]86-sequent-sysv*)
 212 changequote([,])dnl
 213         COREFILE=trad-core.lo
 214         TRAD_HEADER='"hosts/symmetry.h"'
 215         ;;
 216 changequote(,)dnl
 217   i[3-7]86-*-bsdi)
 218 changequote([,])dnl
 219         COREFILE=
 220         ;;
 221 changequote(,)dnl
 222   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234]* | i[3-7]86-*-freebsd*aout*)
 223 changequote([,])dnl
 224         COREFILE=trad-core.lo
 225         TRAD_HEADER='"hosts/i386bsd.h"'
 226         ;;
 227 changequote(,)dnl
 228   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 229 changequote([,])dnl
 230         COREFILE=''
 231         TRAD_HEADER='"hosts/i386bsd.h"'
 232         ;;
 233 changequote(,)dnl
 234   i[3-7]86-*-netbsd* | i[3-7]86-*-openbsd*)
 235 changequote([,])dnl
 236         COREFILE=netbsd-core.lo
 237         ;;
 238 changequote(,)dnl
 239   i[3-7]86-esix-sysv3*)
 240 changequote([,])dnl
 241         COREFILE=trad-core.lo
 242         TRAD_HEADER='"hosts/esix.h"'
 243         ;;
 244 changequote(,)dnl
 245   i[3-7]86-*-sco3.2v5*)
 246 changequote([,])dnl
 247         COREFILE=sco5-core.lo
 248         ;;
 249 changequote(,)dnl
 250   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 251 changequote([,])dnl
 252         COREFILE=trad-core.lo
 253         TRAD_HEADER='"hosts/i386sco.h"'
 254         ;;
 255 changequote(,)dnl
 256   i[3-7]86-*-mach3*)
 257 changequote([,])dnl
 258         COREFILE=trad-core.lo
 259         TRAD_HEADER='"hosts/i386mach3.h"'
 260         ;;
 261 changequote(,)dnl
 262   i[3-7]86-*-linux-gnu*)
 263 changequote([,])dnl
 264         COREFILE=trad-core.lo
 265         TRAD_HEADER='"hosts/i386linux.h"'
 266         ;;
 267 changequote(,)dnl
 268   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 269   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 270 changequote([,])dnl
 271   i860-*-mach3* | i860-*-osf1*)
 272         COREFILE=trad-core.lo
 273         TRAD_HEADER='"hosts/i860mach3.h"'
 274         ;;
 275   mips-dec-bsd*)
 276         COREFILE=trad-core.lo
 277         TRAD_HEADER='"hosts/mipsbsd.h"'
 278         ;;
 279   mips-dec-mach3*)
 280         COREFILE=trad-core.lo
 281         TRAD_HEADER='"hosts/mipsmach3.h"'
 282         ;;
 283   mips-*-netbsd* | mips*-*-openbsd*)
 284         COREFILE=netbsd-core.lo
 285         ;;
 286   mips-dec-*)
 287         COREFILE=trad-core.lo
 288         TRAD_HEADER='"hosts/decstation.h"'
 289         ;;
 290   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 291   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 292   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 293   mips-*-mach3*)
 294         COREFILE=trad-core.lo
 295         TRAD_HEADER='"hosts/mipsmach3.h"'
 296         ;;
 297   mips-*-sysv4*)        ;;
 298   mips-*-sysv* | mips-*-riscos*)
 299         COREFILE=trad-core.lo
 300         TRAD_HEADER='"hosts/riscos.h"'
 301         ;;
 302   mips-sony-bsd*)
 303         COREFILE=trad-core.lo
 304         TRAD_HEADER='"hosts/news-mips.h"'
 305         ;;
 306   m68*-bull*-sysv*)
 307         COREFILE=trad-core.lo
 308         TRAD_HEADER='"hosts/dpx2.h"'
 309         ;;
 310   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 311   m68*-hp-bsd*)
 312         COREFILE=trad-core.lo
 313         TRAD_HEADER='"hosts/hp300bsd.h"'
 314         ;;
 315   m68*-*-linux-gnu*)
 316         COREFILE=trad-core.lo
 317         TRAD_HEADER='"hosts/m68klinux.h"'
 318         ;;
 319   m68*-motorola-sysv*)
 320         COREFILE=trad-core.lo
 321         TRAD_HEADER='"hosts/delta68.h"'
 322         ;;
 323   m68*-sony-*)
 324         COREFILE=trad-core.lo
 325         TRAD_HEADER='"hosts/news.h"'
 326         ;;
 327   m68*-*-netbsd* | m68*-*-openbsd*)
 328         COREFILE=netbsd-core.lo
 329         ;;
 330   m68*-apple-aux*)
 331         COREFILE=trad-core.lo
 332         TRAD_HEADER='"hosts/m68kaux.h"'
 333         ;;
 334   m88*-*-sysv4*)
 335         ;;
 336   m88*-motorola-sysv*)
 337         COREFILE=ptrace-core.lo
 338         ;;
 339   m88*-*-mach3*)
 340         COREFILE=trad-core.lo
 341         TRAD_HEADER='"hosts/m88kmach3.h"'
 342         ;;
 343   ns32k-pc532-mach)
 344         COREFILE=trad-core.lo
 345         TRAD_HEADER='"hosts/pc532mach.h"'
 346         ;;
 347   ns32k-*-netbsd* | ns32k-*-openbsd*)
 348         COREFILE=netbsd-core.lo
 349         ;;
 350   rs6000-*-lynx*)
 351         COREFILE=lynx-core.lo
 352         ;;
 353   rs6000-*-aix5.* | powerpc-*-aix5.*)
 354         COREFILE=rs6000-core.lo
 355         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 356         ;;
 357 changequote(,)dnl
 358   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 359 changequote([,])dnl
 360         COREFILE=rs6000-core.lo
 361         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 362         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 363         # have c_impl as a member of struct core_dumpx
 364         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 365         AC_TRY_COMPILE([#include <core.h>],
 366           [struct core_dumpx c; c.c_impl = 0;],
 367           [AC_DEFINE(HAVE_ST_C_IMPL, 1,
 368             [Define if struct core_dumpx has member c_impl])
 369           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 370         ;;
 371   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 372   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 373   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 374   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 375   powerpc-*-beos*)      ;;
 376   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 377                         COREFILE='' ;;
 378   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 379   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 380   s390*-*-*)            COREFILE=trad-core.lo ;;
 381   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 382   sparc-*-netbsd* | sparc*-*-openbsd*)
 383         COREFILE=netbsd-core.lo
 384         ;;
 385   tahoe-*-*)
 386         COREFILE=trad-core.lo
 387         TRAD_HEADER='"hosts/tahoe.h"'
 388         ;;
 389   vax-*-netbsd* | vax-*-openbsd*)
 390         COREFILE=netbsd-core.lo
 391         ;;
 392   vax-*-ultrix2*)
 393         COREFILE=trad-core.lo
 394         TRAD_HEADER='"hosts/vaxult2.h"'
 395         ;;
 396   vax-*-ultrix*)
 397         COREFILE=trad-core.lo
 398         TRAD_HEADER='"hosts/vaxult2.h"'
 399         ;;
 400   vax-*-*)
 401         COREFILE=trad-core.lo
 402         TRAD_HEADER='"hosts/vaxbsd.h"'
 403         ;;
 404   x86_64-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 405   esac
 406
 407   case "$COREFILE" in
 408   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 409   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 410   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 411   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 412   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 413   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 414   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 415   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 416   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 417   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 418   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 419   esac
 420
 421   # ELF corefile support has several flavors, but all of
 422   # them use something called <sys/procfs.h>
 423   AC_CHECK_HEADERS(sys/procfs.h)
 424   if test "$ac_cv_header_sys_procfs_h" = yes; then
 425     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 426     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 427     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 428     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 429     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 430     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 431     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 432     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 433     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 434     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 435     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 436     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 437     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 438     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 439     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 440     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 441   fi
 442 fi
 443 AC_SUBST(COREFILE)
 444 AC_SUBST(COREFLAG)
 445 if test -n "$TRAD_HEADER"; then
 446   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 447     [Name of host specific header file to include in trad-core.c.])
 448 fi
 449
 450 # Horrible hacks to build DLLs on Windows.
 451 WIN32LDFLAGS=
 452 WIN32LIBADD=
 453 case "${host}" in
 454 *-*-cygwin*)
 455   if test "$enable_shared" = "yes"; then
 456     WIN32LDFLAGS="-no-undefined"
 457     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 458   fi
 459   ;;
 460 *-*-linux*)
 461   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 462   # libiberty.a.
 463   case "${host}" in
 464   mips*-*-linux*)
 465     # Linux/MIPS uses PIC by default.
 466     if test "$enable_shared" = "yes"; then
 467       WIN32LIBADD="-L../libiberty -liberty"
 468     fi
 469     ;;
 470   *)
 471 changequote(,)dnl
 472     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 473 changequote([,])dnl
 474     if test -n "$x"; then
 475       WIN32LIBADD="-L../libiberty/pic -liberty"
 476     fi
 477   ;;
 478   esac
 479   ;;
 480 esac
 481 AC_SUBST(WIN32LDFLAGS)
 482 AC_SUBST(WIN32LIBADD)
 483
 484 # target stuff:
 485
 486 # Canonicalize the secondary target names.
 487 if test -n "$enable_targets" ; then
 488     for targ in `echo $enable_targets | sed 's/,/ /g'`
 489     do
 490         result=`$ac_config_sub $targ 2>/dev/null`
 491         if test -n "$result" ; then
 492             canon_targets="$canon_targets $result"
 493         else
 494             # Allow targets that config.sub doesn't recognize, like "all".
 495             canon_targets="$canon_targets $targ"
 496         fi
 497     done
 498 fi
 499
 500 all_targets=false
 501 defvec=
 502 selvecs=
 503 assocvecs=
 504 selarchs=
 505 TDEFINES=
 506 for targ in $target $canon_targets
 507 do
 508     if test "x$targ" = "xall"; then
 509         all_targets=true
 510         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 511     else
 512         . $srcdir/config.bfd
 513         if test "x$targ" = "x$target"; then
 514             defvec=$targ_defvec
 515         fi
 516         selvecs="$selvecs $targ_defvec $targ_selvecs"
 517         selarchs="$selarchs $targ_archs"
 518         TDEFINES="$TDEFINES $targ_cflags"
 519     fi
 520 done
 521 AC_SUBST(TDEFINES)
 522
 523 # This processing still needs to be done if we're to decide properly whether
 524 # 64-bit support needs to be compiled in.  Currently, it will be included if
 525 # the default or any other explicitly requested target requires it; it
 526 # will not be included on a 32-bit host if no 64-bit target is requested, and
 527 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 528 # used.
 529
 530 # uniq the default and selected vectors in all the configured targets.
 531 f=""
 532 for i in $selvecs ; do
 533     case " $f " in
 534     *" $i "*) ;;
 535     *) f="$f $i" ;;
 536     esac
 537 done
 538 selvecs="$f"
 539
 540
 541 # uniq the associated vectors in all the configured targets.
 542 f=""
 543 for i in $assocvecs ; do
 544     case " $f " in
 545     *" $i "*) ;;
 546     *) f="$f $i" ;;
 547     esac
 548 done
 549 assocvecs="$f"
 550
 551
 552 # uniq the architectures in all the configured targets.
 553 f=""
 554 for i in $selarchs ; do
 555     case " $f " in
 556     *" $i "*) ;;
 557     *) f="$f $i" ;;
 558     esac
 559 done
 560 selarchs="$f"
 561
 562 # Target backend .o files.
 563 tb=
 564
 565 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 566
 567 for vec in $selvecs
 568 do
 569     target_size=32
 570     case "$vec" in
 571     # This list is alphabetized to make it easy to compare
 572     # with the two vector lists in targets.c.  For the same reason,
 573     # use one entry per line, even though this leads to long lines.
 574     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 575     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 576     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 577     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 578     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 579     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 580     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 581     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 582     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 583     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 584     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 585     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 586     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 587     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 588     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 589     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 590     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 591     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 592     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 593     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 594     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 595     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 596     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 597     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 598     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 599     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 600     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 601     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 602     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 603     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 604     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 605     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 606     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 607     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 608     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 609     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 610     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 611     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 612     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 613     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 614     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 615     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 616     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 617     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 618     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 619     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 620     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 621     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 622     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 623     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 624     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 625     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 626     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 627     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 628     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 629     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 630     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 631     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 632     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 633     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 634     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 635     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 636     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 637     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 638     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 639     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 640     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 641     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 642     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 643     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 644     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 645     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 646     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 647     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 648     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 649     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 650     # FIXME: We include cofflink.lo not because it's needed for
 651     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 652     # which needs it but does not list it.  Should be fixed in right place.
 653     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 654     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 655     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 656     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 657     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 658     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 659     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 660     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 661     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 662     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 663     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 664     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 665     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 666     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 667     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 668     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 669     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 670     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 671     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 672     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 673     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 674     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 675     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 676     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 677     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 678     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 679     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 680     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 681     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 682     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 683     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 684     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 685     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 686     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 687     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 688     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 689     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 690     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 691     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 692     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 693     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 694     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 695     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
 696     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 697     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 698     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 699     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 700     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 701     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 702     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 703     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 704     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 705     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 706     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 707     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 708     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 709     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 710     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 711     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 712     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 713     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 714     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 715     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 716     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 717     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 718     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 719     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 720     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 721     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 722     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 723     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 724     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 725     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 726     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 727     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 728     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 729     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 730     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 731     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 732     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 733     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 734     ieee_vec)                   tb="$tb ieee.lo" ;;
 735     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 736     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 737     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 738     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 739     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 740     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 741     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 742     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 743     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 744     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 745     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 746     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 747     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 748     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 749     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 750     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 751     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 752     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 753     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 754     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 755     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 756     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 757     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 758     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 759     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 760     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 761     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 762     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 763     pef_vec)                    tb="$tb pef.lo" ;;
 764     pef_xlib_vec)               tb="$tb pef.lo" ;;
 765     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 766     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 767     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 768     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 769     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 770     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 771     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 772     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 773     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 774     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 775     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 776     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 777     som_vec)                    tb="$tb som.lo" ;;
 778     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 779     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 780     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 781     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 782     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 783     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 784     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 785     sym_vec)                    tb="$tb xsym.lo" ;;
 786     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 787     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 788     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 789     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 790     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 791     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 792     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 793     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 794     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 795     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 796     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 797     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 798     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 799     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 800     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 801     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 802     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 803     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 804     versados_vec)               tb="$tb versados.lo" ;;
 805     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 806     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 807     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 808     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 809     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 810
 811     # These appear out of order in targets.c
 812     srec_vec)                   tb="$tb srec.lo" ;;
 813     symbolsrec_vec)             tb="$tb srec.lo" ;;
 814     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 815     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 816     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 817
 818     "")                 ;;
 819     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 820     esac
 821
 822     if test ${target_size} = 64; then
 823         target64=true
 824     fi
 825     if test x"${vec}" = x"${defvec}"; then
 826         bfd_default_target_size=${target_size}
 827     fi
 828 done
 829
 830 # Target architecture .o files.
 831 # A couple of CPUs use shorter file names to avoid problems on DOS
 832 # filesystems.
 833 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 834
 835 # Weed out duplicate .o files.
 836 f=""
 837 for i in $tb ; do
 838     case " $f " in
 839     *" $i "*) ;;
 840     *) f="$f $i" ;;
 841     esac
 842 done
 843 tb="$f"
 844
 845 f=""
 846 for i in $ta ; do
 847     case " $f " in
 848     *" $i "*) ;;
 849     *) f="$f $i" ;;
 850     esac
 851 done
 852 ta="$f"
 853
 854 bfd_backends="$tb"
 855 bfd_machines="$ta"
 856
 857 if test x${all_targets} = xtrue ; then
 858   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 859   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 860   selvecs=
 861   havevecs=
 862   selarchs=
 863   test -n "$assocvecs" &&
 864     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 865 else    # all_targets is true
 866   # Only set these if they will be nonempty, for the clever echo.
 867   havevecs=
 868   assocvecs=
 869   test -n "$selvecs" &&
 870     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 871   test -n "$selvecs" &&
 872     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 873   test -n "$selarchs" &&
 874     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 875 fi      # all_targets is true
 876
 877 case ${host64}-${target64}-${want64} in
 878   *true*)
 879     wordsize=64
 880     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 881     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 882     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 883       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 884       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 885     fi
 886     if test -n "$GCC" ; then
 887        bad_64bit_gcc=no;
 888        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 889        # Add more tests for gcc versions with non-working 64-bit support here.
 890        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 891                     bad_64bit_gcc=yes;
 892                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 893                     AC_MSG_RESULT(no))
 894        if test $bad_64bit_gcc = yes ; then
 895          AC_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 896        fi
 897     fi
 898     ;;
 899   false-false-false)
 900     wordsize=32
 901     bfd_libs='$(BFD32_LIBS)'
 902     all_backends='$(BFD32_BACKENDS)'
 903     ;;
 904 esac
 905
 906 AC_SUBST(wordsize)
 907 AC_SUBST(bfd_libs)
 908 AC_SUBST(all_backends)
 909 AC_SUBST(bfd_backends)
 910 AC_SUBST(bfd_machines)
 911 AC_SUBST(bfd_default_target_size)
 912
 913 tdefaults=""
 914 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 915 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 916 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 917 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 918 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 919 AC_SUBST(tdefaults)
 920
 921 dnl AC_CHECK_HEADERS(sys/mman.h)
 922 AC_FUNC_MMAP
 923 AC_CHECK_FUNCS(madvise mprotect)
 924 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 925   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 926 esac
 927
 928 rm -f doc/config.status
 929 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h bfdver.h:version.h po/Makefile.in:po/Make-in,
 930 [sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
 931