chrome/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/locales.gni")
   8 import("//build/config/ui.gni")
   9 import("//chrome/chrome_repack_locales.gni")
  10 import("//chrome/version.gni")
  11
  12 if (is_android) {
  13   import("//build/config/android/rules.gni")
  14 }
  15
  16 if (!is_android) {
  17   # TODO(GYP) for Windows need to the the reorder-imports step which probably
  18   # means adding another target and renaming this to chrome_initial like in GYP.
  19   executable("chrome") {
  20     # Because the sources list varies so significantly per-platform, generally
  21     # each platform lists its own files rather than relying on filtering or
  22     # removing unused files.
  23     sources = [
  24       "app/chrome_exe_resource.h",
  25     ]
  26     defines = []
  27     deps = []
  28     data_deps = []
  29
  30     # TODO(GYP) mac_bundle_resources, xcode_settings
  31
  32     # TODO(GYP) order_profiling, order_text_section
  33
  34     if (is_win) {
  35       sources += [
  36         "//content/public/common/content_switches.cc",
  37         "//content/public/common/content_switches.h",
  38         "app/chrome_crash_reporter_client.cc",
  39         "app/chrome_crash_reporter_client.h",
  40         "app/chrome_exe.rc",
  41         "app/chrome_exe_load_config_win.cc",
  42         "app/chrome_exe_main_win.cc",
  43         "app/chrome_watcher_client_win.cc",
  44         "app/chrome_watcher_client_win.h",
  45         "app/chrome_watcher_command_line_win.cc",
  46         "app/chrome_watcher_command_line_win.h",
  47         "app/client_util.cc",
  48         "app/client_util.h",
  49         "app/kasko_client.cc",
  50         "app/kasko_client.h",
  51         "app/signature_validator_win.cc",
  52         "app/signature_validator_win.h",
  53         "common/crash_keys.cc",
  54         "common/crash_keys.h",
  55       ]
  56
  57       if (is_component_build) {
  58         # This is necessary to make content_switches compile without DLL
  59         # linkage errors in a component build.
  60         defines += [ "COMPILE_CONTENT_STATICALLY" ]
  61       }
  62
  63       deps += [
  64         ":chrome_exe_version",
  65         ":image_pre_reader",
  66         ":main_dll",
  67
  68         # 'chrome_nacl_win64" TODO(GYP)
  69         # '../win8/delegate_execute/delegate_execute.gyp:*', TODO(GYP)
  70         # '../win8/metro_driver/metro_driver.gyp:metro_driver', TODO(GYP)
  71         "//base",
  72         "//breakpad:breakpad_handler",
  73         "//breakpad:breakpad_sender",
  74         "//chrome/browser:chrome_process_finder",
  75         "//chrome/chrome_watcher",
  76         "//chrome/chrome_watcher:client",
  77         "//chrome/installer/util",
  78         "//chrome_elf",
  79         "//components/browser_watcher:browser_watcher_client",
  80         "//components/crash/app",
  81         "//content:startup_helper_win",
  82         "//crypto",
  83         "//sandbox",
  84         "//ui/gfx",
  85       ]
  86       libs = [
  87         "wintrust.lib",
  88         "crypt32.lib",
  89       ]
  90       configs -= [ "//build/config/win:console" ]
  91       configs += [ "//build/config/win:windowed" ]
  92     } else if (use_aura) {
  93       # Non-Windows aura entrypoint.
  94       sources += [ "app/chrome_exe_main_aura.cc" ]
  95     }
  96
  97     if (is_linux) {
  98       sources += [
  99         "app/chrome_dll_resource.h",
 100         "app/chrome_main.cc",
 101         "app/chrome_main_delegate.cc",
 102         "app/chrome_main_delegate.h",
 103       ]
 104
 105       deps += [
 106         # On Linux, link the dependencies (libraries) that make up actual
 107         # Chromium functionality directly into the executable.
 108         ":browser_dependencies",
 109         ":child_dependencies",
 110         ":manpage",
 111         "//base/allocator",
 112
 113         # Needed to use the master_preferences functions
 114         "//chrome/installer/util",
 115         "//content/public/app:both",
 116       ]
 117
 118       # Needed for chrome_main.cc initialization of libraries.
 119       configs += [ "//build/config/linux:pangocairo" ]
 120
 121       # GYP has this in a 'profiling==0 and linux_disable_pie==0' condition.
 122       # but GN doesn't have either of these flags.
 123       ldflags = [ "-pie" ]
 124
 125       if (use_x11) {
 126         configs += [
 127           "//build/config/linux:x11",
 128           "//build/config/linux:xext",
 129         ]
 130       }
 131     }
 132
 133     if (is_mac) {
 134       sources += [ "app/chrome_exe_main_mac.cc" ]
 135       # TODO(GYP) lots more stuff in the is_mac block.
 136     } else {  # Non-Mac.
 137       deps += [
 138         ":packed_extra_resources",
 139         ":packed_resources",
 140         "//components/startup_metric_utils",
 141
 142         # Precompiled plugins that need to get copied to the output directory.
 143         # On Mac, internal plugins go inside the framework, so these
 144         # dependencies are on chrome.dll.
 145         "//third_party/adobe/flash:flapper_binaries",
 146         "//third_party/widevine/cdm:widevinecdmadapter",
 147       ]
 148     }
 149
 150     if (is_linux && enable_plugins) {
 151       deps += [ "//pdf" ]
 152     }
 153
 154     if (is_multi_dll_chrome) {
 155       defines += [ "CHROME_MULTIPLE_DLL" ]
 156       data_deps += [ ":chrome_child" ]
 157     }
 158   }
 159 }  # !is_android
 160
 161 shared_library("main_dll") {
 162   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 163   defines = []
 164
 165   deps = [
 166     ":browser_dependencies",
 167     "//base/allocator",
 168   ]
 169   if (is_win) {
 170     output_name = "chrome"
 171
 172     sources = [
 173       "//base/win/dllmain.cc",
 174       "app/chrome_command_ids.h",
 175       "app/chrome_dll.rc",
 176       "app/chrome_dll_resource.h",
 177       "app/chrome_main.cc",
 178       "app/chrome_main_delegate.cc",
 179       "app/chrome_main_delegate.h",
 180       "app/close_handle_hook_win.cc",
 181       "app/close_handle_hook_win.h",
 182       "app/delay_load_hook_win.cc",
 183       "app/delay_load_hook_win.h",
 184     ]
 185
 186     deps += [
 187       ":chrome_dll_version",
 188       "//base/trace_event/etw_manifest:chrome_events_win",
 189       "//chrome/app/theme:chrome_unscaled_resources",
 190       "//chrome_elf",
 191       "//content/app/resources",
 192       "//crypto",
 193       "//net:net_resources",
 194       "//third_party/wtl",
 195       "//ui/views",
 196     ]
 197     if (enable_configuration_policy) {
 198       deps += [ "//components/policy" ]
 199     }
 200     if (current_cpu == "x86") {
 201       # Add a dependency to custom import library for user32 delay imports only
 202       # in x86 builds.
 203       #deps += [ 'chrome_user32_delay_imports' ]  TODO(GYP)
 204     }
 205
 206     # This is a large module that can't do incremental linking in some cases.
 207     configs -= [ "//build/config/win:default_incremental_linking" ]
 208     configs += [ "//build/config/win:default_large_module_incremental_linking" ]
 209
 210     # TODO(GYP) Lots of VCLinkerTool stuff on Windows.
 211
 212     # TODO(GYP) chrome_pgo_phase on Windows.
 213   }
 214
 215   if (use_aura) {
 216     deps += [ "//ui/compositor" ]
 217   }
 218
 219   if (is_multi_dll_chrome) {
 220     defines += [ "CHROME_MULTIPLE_DLL_BROWSER" ]
 221     deps += [ "//content/public/app:browser" ]
 222   } else {
 223     deps += [
 224       ":child_dependencies",
 225       "//content/public/app:both",
 226     ]
 227   }
 228
 229   if (cld_version == 0 || cld_version == 2) {
 230     deps += [ "//third_party/cld_2" ]
 231   }
 232
 233   if (is_mac) {
 234     #['OS=="mac" and component!="shared_library"', {  TODO(GYP)
 235     #  'includes': [ 'chrome_dll_bundle.gypi' ],
 236     #}],
 237     # TODO(GYP) Lots of other stuff in the OS=="mac" block.
 238   }
 239
 240   if (enable_plugins && !is_multi_dll_chrome) {
 241     deps += [ "//pdf" ]
 242   }
 243 }
 244
 245 if (is_multi_dll_chrome) {
 246   shared_library("chrome_child") {
 247     sources = [
 248       "app/chrome_main.cc",
 249       "app/chrome_main_delegate.cc",
 250       "app/chrome_main_delegate.h",
 251       "app/close_handle_hook_win.cc",
 252       "app/close_handle_hook_win.h",
 253     ]
 254
 255     configs += [ "//build/config/compiler:wexit_time_destructors" ]
 256     defines = [ "CHROME_MULTIPLE_DLL_CHILD" ]
 257
 258     deps = [
 259       ":child_dependencies",
 260       ":chrome_dll_version",
 261       "//chrome/browser/policy:path_parser",
 262       "//content/public/app:child",
 263     ]
 264
 265     if (is_win) {
 266       deps += [ "//chrome_elf" ]
 267       # TODO(GYP): PGO on Windows.
 268       # ['chrome_pgo_phase==1', {
 269       #   'msvs_settings': {
 270       #     'VCLinkerTool': {
 271       #       'LinkTimeCodeGeneration': '2',
 272       #     },
 273       #   },
 274       # }],
 275       # ['chrome_pgo_phase==2', {
 276       #   'msvs_settings': {
 277       #     'VCLinkerTool': {
 278       #       'LinkTimeCodeGeneration': '3',
 279       #     },
 280       #   },
 281       # }],
 282     }
 283     if (enable_plugins) {
 284       deps += [ "//pdf" ]
 285     }
 286   }
 287 }
 288
 289 # GYP version: chromium_browser_dependencies variable in chrome.gyp
 290 group("browser_dependencies") {
 291   deps = [
 292     "//chrome/browser",
 293     "//chrome/common",
 294     "//sync",
 295   ]
 296   if (!is_ios) {
 297     deps += [ "//ppapi/host" ]
 298   }
 299
 300   if (enable_basic_printing || enable_print_preview) {
 301     deps += [ "//printing" ]
 302     if (enable_print_preview) {
 303       deps += [ "//chrome/service" ]
 304     }
 305   }
 306 }
 307
 308 # GYP version: chromium_child_dependencies variable in chrome.gyp
 309 group("child_dependencies") {
 310   deps = [
 311     "//chrome/common",
 312     "//sync",
 313   ]
 314   if (!is_ios) {
 315     deps += [
 316       "//chrome/browser/devtools",
 317       "//chrome/child",
 318       "//chrome/plugin",
 319       "//chrome/renderer",
 320       "//chrome/utility",
 321       "//content/public/child",
 322       "//third_party/WebKit/public:blink_devtools_frontend_resources",
 323     ]
 324   }
 325   if (cld_version == 0 || cld_version == 2) {
 326     deps += [ "//third_party/cld_2:cld2_platform_impl" ]
 327   }
 328
 329   if (enable_nacl) {
 330     deps += [ "//components/nacl/renderer/plugin:nacl_trusted_plugin" ]
 331   }
 332   if (enable_remoting) {
 333     deps += [ "//remoting/client/plugin" ]
 334   }
 335 }
 336
 337 if (is_win) {
 338   # TODO(brettw) this duplicates "//chrome/common:version" which applies to
 339   # Linux.
 340   process_version("version_header") {
 341     # TODO(brettW) this should have more reduced visibility, but chrome/browser
 342     # currently depends on this.
 343     #visibility = [ ":*" ]
 344
 345     # This one just uses the custom template and no separate sources.
 346     sources = []
 347     template_file = "version.h.in"
 348
 349     # TODO(brettw) this should move to $target_gen_dir/version.h and
 350     # source files including it should reference it via "chrome/version.h"
 351     output = "$root_gen_dir/version.h"
 352   }
 353
 354   process_version("chrome_exe_version") {
 355     sources = [
 356       "app/chrome_exe.ver",
 357     ]
 358     output = "$target_gen_dir/chrome_exe_version.rc"
 359   }
 360
 361   process_version("chrome_dll_version") {
 362     sources = [
 363       "app/chrome_dll.ver",
 364     ]
 365     output = "$target_gen_dir/chrome_dll_version.rc"
 366   }
 367
 368   process_version("nacl64_exe_version") {
 369     sources = [
 370       "app/nacl64_exe.ver",
 371     ]
 372     output = "$target_gen_dir/nacl64_exe_version.rc"
 373   }
 374
 375   process_version("other_version") {
 376     sources = [
 377       "app/other.ver",
 378     ]
 379     output = "$target_gen_dir/other_version.rc"
 380   }
 381
 382   source_set("image_pre_reader") {
 383     sources = [
 384       "app/image_pre_reader_win.cc",
 385       "app/image_pre_reader_win.h",
 386     ]
 387     deps = [
 388       "//base",
 389     ]
 390   }
 391 }
 392
 393 # GYP version: chrome/chrome_resources.gyp:chrome_resources
 394 group("resources") {
 395   deps = [
 396     # Note: GYP lists some dependencies in addition to these actions. However,
 397     # these are just dependencies for the actions themselves, which our actions
 398     # list individually when needed.
 399     "//chrome/browser:resources",
 400     "//chrome/common:resources",
 401     "//chrome/renderer:resources",
 402   ]
 403
 404   if (enable_extensions) {
 405     deps += [ "//chrome/common:extensions_api_resources" ]
 406   }
 407 }
 408
 409 # GYP version: chrome/chrome_resources.gyp:chrome_extra_resources
 410 group("extra_resources") {
 411   deps = [
 412     "//chrome/browser/resources:invalidations_resources",
 413     "//chrome/browser/resources:memory_internals_resources",
 414     "//chrome/browser/resources:net_internals_resources",
 415     "//chrome/browser/resources:password_manager_internals_resources",
 416     "//chrome/browser/resources:signin_internals_resources",
 417     "//chrome/browser/resources:sync_internals_resources",
 418     "//chrome/browser/resources:translate_internals_resources",
 419   ]
 420   if (!is_ios) {
 421     deps += [
 422       "//chrome/browser/resources:component_extension_resources",
 423       "//chrome/browser/resources:options_resources",
 424       "//chrome/browser/resources:settings_resources",
 425     ]
 426   }
 427
 428   if (enable_chromevox_next) {
 429     deps += [
 430       #'browser/resources/chromeos/chromevox2/chromevox.gyp:chromevox2',  TODO(GYP)
 431     ]
 432   } else {
 433     deps += [
 434       #'browser/resources/chromeos/chromevox/chromevox.gyp:chromevox',  TODO(GYP)
 435     ]
 436   }
 437
 438   if (enable_extensions) {
 439     deps += [
 440       "//chrome/browser/resources:quota_internals_resources",
 441       "//chrome/browser/resources:sync_file_system_internals_resources",
 442     ]
 443   }
 444 }
 445
 446 if (is_chrome_branded) {
 447   copy("default_apps") {
 448     visibility = [ ":packed_resources" ]
 449     sources = [
 450       "browser/resources/default_apps/docs.crx",
 451       "browser/resources/default_apps/drive.crx",
 452       "browser/resources/default_apps/external_extensions.json",
 453       "browser/resources/default_apps/gmail.crx",
 454       "browser/resources/default_apps/search.crx",
 455       "browser/resources/default_apps/youtube.crx",
 456     ]
 457     outputs = [
 458       "$root_out_dir/default_apps/{{source_file_part}}",
 459     ]
 460   }
 461 }
 462
 463 group("packed_resources") {
 464   deps = [
 465     ":repack_locales_pack",
 466     ":repack_pseudo_locales_pack",
 467     ":repack_chrome_100_percent",
 468   ]
 469
 470   if (is_chrome_branded) {
 471     deps += [ ":default_apps" ]
 472   }
 473
 474   if (enable_hidpi) {
 475     deps += [ ":repack_chrome_200_percent" ]
 476   }
 477 }
 478
 479 repack("packed_extra_resources") {
 480   visibility = [ "./*" ]
 481   sources = [
 482     "$root_gen_dir/chrome/browser_resources.pak",
 483     "$root_gen_dir/chrome/chrome_unscaled_resources.pak",
 484     "$root_gen_dir/chrome/common_resources.pak",
 485     "$root_gen_dir/chrome/invalidations_resources.pak",
 486     "$root_gen_dir/chrome/memory_internals_resources.pak",
 487     "$root_gen_dir/chrome/net_internals_resources.pak",
 488     "$root_gen_dir/chrome/password_manager_internals_resources.pak",
 489     "$root_gen_dir/chrome/signin_internals_resources.pak",
 490     "$root_gen_dir/chrome/sync_internals_resources.pak",
 491     "$root_gen_dir/chrome/translate_internals_resources.pak",
 492     "$root_gen_dir/components/components_resources.pak",
 493     "$root_gen_dir/net/net_resources.pak",
 494     "$root_gen_dir/ui/resources/webui_resources.pak",
 495   ]
 496   deps = [
 497     "//chrome/browser:resources",
 498     "//chrome/app/theme:chrome_unscaled_resources",
 499     "//chrome/common:resources",
 500     "//chrome/browser/resources:invalidations_resources",
 501     "//chrome/browser/resources:memory_internals_resources",
 502     "//chrome/browser/resources:net_internals_resources",
 503     "//chrome/browser/resources:password_manager_internals_resources",
 504     "//chrome/browser/resources:signin_internals_resources",
 505     "//chrome/browser/resources:sync_internals_resources",
 506     "//chrome/browser/resources:translate_internals_resources",
 507     "//components/resources",
 508     "//net:net_resources",
 509     "//ui/resources",
 510   ]
 511
 512   if (!is_ios && !is_android) {
 513     # New paks should be added here by default.
 514     sources += [
 515       "$root_gen_dir/blink/devtools_resources.pak",
 516       "$root_gen_dir/chrome/component_extension_resources.pak",
 517       "$root_gen_dir/chrome/options_resources.pak",
 518       "$root_gen_dir/chrome/quota_internals_resources.pak",
 519       "$root_gen_dir/chrome/settings_resources.pak",
 520       "$root_gen_dir/chrome/sync_file_system_internals_resources.pak",
 521       "$root_gen_dir/chrome/webrtc_device_provider_resources.pak",
 522     ]
 523     deps += [
 524       "//chrome/browser/devtools:webrtc_device_provider_resources",
 525       "//chrome/browser/resources:component_extension_resources",
 526       "//chrome/browser/resources:options_resources",
 527       "//chrome/browser/resources:settings_resources",
 528       "//chrome/browser/resources:quota_internals_resources",
 529       "//chrome/browser/resources:sync_file_system_internals_resources",
 530       "//content/browser/devtools:devtools_resources",
 531     ]
 532   }
 533   if (!is_ios) {
 534     sources += [
 535       "$root_gen_dir/blink/public/resources/blink_resources.pak",
 536       "$root_gen_dir/content/browser/tracing/tracing_resources.pak",
 537       "$root_gen_dir/content/content_resources.pak",
 538     ]
 539     deps += [
 540       "//content:resources",
 541       "//content/browser/tracing:resources",
 542       "//third_party/WebKit/public:resources",
 543     ]
 544   }
 545   if (is_chromeos) {
 546     sources += [ "$root_gen_dir/ui/file_manager/file_manager_resources.pak" ]
 547     sources += [ "$root_gen_dir/ui/oobe/oobe_resources.pak" ]
 548     deps += [ "//ui/file_manager:resources" ]
 549     deps += [ "//ui/oobe:resources" ]
 550   }
 551   if (enable_extensions) {
 552     sources += [
 553       "$root_gen_dir/chrome/extensions_api_resources.pak",
 554       "$root_gen_dir/extensions/extensions_renderer_resources.pak",
 555       "$root_gen_dir/extensions/extensions_resources.pak",
 556     ]
 557     deps += [
 558       "//chrome/common:extensions_api_resources",
 559       "//extensions:extensions_resources",
 560     ]
 561   }
 562
 563   # GYP outputs the file in the gen/repack directory. On non-Mac/iOS platforms
 564   # it them copies it. This skipes the copy step and writes it to the final
 565   # location.
 566   if (is_mac || is_ios) {
 567     output = "$root_gen_dir/repack/resources.pak"
 568   } else {
 569     output = "$root_out_dir/resources.pak"
 570   }
 571 }
 572
 573 # GYP version: chrome/chrome_resources.gyp:browser_tests_pak
 574 repack("browser_tests_pak") {
 575   sources = [
 576     "$root_gen_dir/chrome/options_test_resources.pak",
 577   ]
 578   output = "$root_out_dir/browser_tests.pak"
 579   deps = [
 580     "//chrome/browser/resources:options_test_resources",
 581   ]
 582 }
 583
 584 # Collects per-locale grit files from many sources into global per-locale files.
 585 chrome_repack_locales("repack_locales_pack") {
 586   visibility = [ ":*" ]
 587
 588   input_locales = locales
 589
 590   if (is_mac) {
 591     output_locales = locales_as_mac_outputs
 592   } else {
 593     output_locales = locales
 594   }
 595 }
 596
 597 chrome_repack_locales("repack_pseudo_locales_pack") {
 598   visibility = [ ":*" ]
 599
 600   input_locales = [ "fake-bidi" ]
 601
 602   if (is_mac) {
 603     output_locales = [ "fake_bidi" ]  # Mac uses underscores.
 604   } else {
 605     output_locales = [ "fake-bidi" ]
 606   }
 607 }
 608
 609 # Generates a rule to repack a set of resources, substituting a given string
 610 # in for the percentage (e.g. "100", "200"). It generates the repacked files in
 611 # the "gen" directory, and then introduces a copy rule to copy it to the root
 612 # build directory.
 613 #
 614 # It's not clear why this two-step dance is necessary as opposed to just
 615 # generating the file in the destination. However, this is what the GYP build
 616 # does, and for maintenance purposes, this keeps the same files in the same
 617 # place between the two builds when possible.
 618 #
 619 # Argument:
 620 #   percent [required]
 621 #      String to substitute for the percentage.
 622 template("chrome_repack_percent") {
 623   percent = invoker.percent
 624
 625   repack_name = "${target_name}_repack"
 626   repack_output_file = "$root_gen_dir/repack/chrome_${percent}_percent.pak"
 627
 628   copy_name = target_name
 629
 630   repack(repack_name) {
 631     visibility = [ ":$copy_name" ]
 632
 633     # All sources should also have deps for completeness.
 634     sources = [
 635       "$root_gen_dir/chrome/renderer_resources_${percent}_percent.pak",
 636       "$root_gen_dir/chrome/theme_resources_${percent}_percent.pak",
 637       "$root_gen_dir/components/components_resources_${percent}_percent.pak",
 638       "$root_gen_dir/ui/resources/ui_resources_${percent}_percent.pak",
 639     ]
 640
 641     deps = [
 642       "//chrome/app/theme:theme_resources",
 643       "//chrome/renderer:resources",
 644       "//components/resources",
 645       "//components/strings",
 646       "//net:net_resources",
 647       "//ui/resources",
 648     ]
 649
 650     if (!is_ios) {
 651       sources += [
 652         "$root_gen_dir/blink/public/resources/blink_image_resources_${percent}_percent.pak",
 653         "$root_gen_dir/content/app/resources/content_resources_${percent}_percent.pak",
 654       ]
 655       deps += [
 656         "//content/app/resources",
 657         "//third_party/WebKit/public:image_resources",
 658       ]
 659     }
 660     if (use_ash) {
 661       sources +=
 662           [ "$root_gen_dir/ash/resources/ash_resources_${percent}_percent.pak" ]
 663       deps += [ "//ash/resources" ]
 664     }
 665     if (is_chromeos) {
 666       sources += [ "$root_gen_dir/ui/chromeos/resources/ui_chromeos_resources_${percent}_percent.pak" ]
 667       deps += [ "//ui/chromeos/resources" ]
 668     }
 669     if (enable_extensions) {
 670       sources += [ "$root_gen_dir/extensions/extensions_browser_resources_${percent}_percent.pak" ]
 671       deps += [ "//extensions:extensions_browser_resources" ]
 672     }
 673
 674     output = repack_output_file
 675   }
 676
 677   copy(copy_name) {
 678     visibility = [ ":*" ]
 679     deps = [
 680       ":$repack_name",
 681     ]
 682     sources = [
 683       repack_output_file,
 684     ]
 685     outputs = [
 686       "$root_build_dir/chrome_${percent}_percent.pak",
 687     ]
 688   }
 689 }
 690
 691 chrome_repack_percent("repack_chrome_100_percent") {
 692   percent = "100"
 693 }
 694
 695 if (enable_hidpi) {
 696   chrome_repack_percent("repack_chrome_200_percent") {
 697     percent = "200"
 698   }
 699 }
 700
 701 # GYP version: chrome/chrome_resources.gyp:chrome_strings
 702 group("strings") {
 703   deps = [
 704     "//chrome/app:chromium_strings",
 705     "//chrome/app:generated_resources",
 706     "//chrome/app:google_chrome_strings",
 707     "//chrome/app/resources:locale_settings",
 708   ]
 709 }
 710
 711 if (is_android) {
 712   # GYP: //chrome/chrome.gyp:content_setting_java
 713   java_cpp_enum("content_setting_javagen") {
 714     sources = [
 715       "../components/content_settings/core/common/content_settings.h",
 716     ]
 717     outputs = [
 718       "org/chromium/chrome/browser/ContentSetting.java",
 719     ]
 720   }
 721
 722   # GYP: //chrome/chrome.gyp:content_settings_type_java
 723   java_cpp_enum("content_settings_type_javagen") {
 724     sources = [
 725       "../components/content_settings/core/common/content_settings_types.h",
 726     ]
 727     outputs = [
 728       "org/chromium/chrome/browser/ContentSettingsType.java",
 729     ]
 730   }
 731
 732   # GYP: //chrome/chrome.gyp:page_info_connection_type_java
 733   java_cpp_enum("page_info_connection_type_javagen") {
 734     sources = [
 735       "browser/ui/android/website_settings_popup_android.h",
 736     ]
 737     outputs = [
 738       "org/chromium/chrome/browser/PageInfoConnectionType.java",
 739     ]
 740   }
 741
 742   # GYP: //chrome/chrome_android.gypi:chrome_android_core
 743   static_library("chrome_android_core") {
 744     sources = [
 745       "app/android/chrome_android_initializer.cc",
 746       "app/android/chrome_android_initializer.h",
 747       "app/android/chrome_jni_onload.cc",
 748       "app/android/chrome_jni_onload.h",
 749       "app/android/chrome_main_delegate_android.cc",
 750       "app/android/chrome_main_delegate_android.h",
 751       "app/chrome_main_delegate.cc",
 752       "app/chrome_main_delegate.h",
 753     ]
 754
 755     include_dirs = [ android_ndk_include_dir ]
 756
 757     libs = [
 758       "android",
 759       "jnigraphics",
 760     ]
 761
 762     deps = [
 763       "//chrome/browser",
 764       "//chrome/browser/ui",
 765       "//chrome/child",
 766       "//chrome/plugin",
 767       "//chrome/renderer",
 768       "//chrome/utility",
 769       "//components/enhanced_bookmarks",
 770       "//content/public/app:both",
 771     ]
 772   }
 773 }
 774
 775 if (is_linux) {
 776   action("manpage") {
 777     if (is_chrome_branded) {
 778       name = "Google Chrome"
 779       filename = "google-chrome"
 780       confdir = "google-chrome"
 781     } else {
 782       name = "Chromium"
 783       filename = "chromium-browser"
 784       confdir = "chromium"
 785     }
 786
 787     script = "//chrome/tools/build/linux/sed.py"
 788     infile = "app/resources/manpage.1.in"
 789     inputs = [
 790       infile,
 791     ]
 792
 793     outfile = "$root_out_dir/chrome.1"
 794     outputs = [
 795       outfile,
 796     ]
 797
 798     args = [
 799       rebase_path(infile, root_build_dir),
 800       rebase_path(outfile, root_build_dir),
 801       "-e s/@@NAME@@/$name/",
 802       "-e s/@@FILENAME@@/$filename/",
 803       "-e s/@@CONFDIR@@/$confdir/",
 804     ]
 805   }
 806 }