base/files/file_util_mac.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "base/files/file_util.h"
   6
   7 #import <Foundation/Foundation.h>
   8 #include <copyfile.h>
   9
  10 #include "base/basictypes.h"
  11 #include "base/files/file_path.h"
  12 #include "base/mac/foundation_util.h"
  13 #include "base/strings/string_util.h"
  14 #include "base/threading/thread_restrictions.h"
  15
  16 namespace base {
  17
  18 bool CopyFile(const FilePath& from_path, const FilePath& to_path) {
  19   ThreadRestrictions::AssertIOAllowed();
  20   if (from_path.ReferencesParent() || to_path.ReferencesParent())
  21     return false;
  22   return (copyfile(from_path.value().c_str(),
  23                    to_path.value().c_str(), NULL, COPYFILE_DATA) == 0);
  24 }
  25
  26 bool GetTempDir(base::FilePath* path) {
  27   NSString* tmp = NSTemporaryDirectory();
  28   if (tmp == nil)
  29     return false;
  30   *path = base::mac::NSStringToFilePath(tmp);
  31   return true;
  32 }
  33
  34 FilePath GetHomeDir() {
  35   NSString* tmp = NSHomeDirectory();
  36   if (tmp != nil) {
  37     FilePath mac_home_dir = base::mac::NSStringToFilePath(tmp);
  38     if (!mac_home_dir.empty())
  39       return mac_home_dir;
  40   }
  41
  42   // Fall back on temp dir if no home directory is defined.
  43   FilePath rv;
  44   if (GetTempDir(&rv))
  45     return rv;
  46
  47   // Last resort.
  48   return FilePath("/tmp");
  49 }
  50
  51 }  // namespace base