gin/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/module_args/v8.gni")
   6 import("//testing/test.gni")
   7
   8 component("gin") {
   9   sources = [
  10     "arguments.cc",
  11     "arguments.h",
  12     "array_buffer.cc",
  13     "array_buffer.h",
  14     "context_holder.cc",
  15     "converter.cc",
  16     "converter.h",
  17     "debug_impl.cc",
  18     "debug_impl.h",
  19     "dictionary.cc",
  20     "dictionary.h",
  21     "function_template.cc",
  22     "function_template.h",
  23     "gin_export.h",
  24     "handle.h",
  25     "interceptor.cc",
  26     "interceptor.h",
  27     "isolate_holder.cc",
  28     "modules/console.cc",
  29     "modules/console.h",
  30     "modules/file_module_provider.cc",
  31     "modules/file_module_provider.h",
  32     "modules/module_registry.cc",
  33     "modules/module_registry.h",
  34     "modules/module_registry_observer.h",
  35     "modules/module_runner_delegate.cc",
  36     "modules/module_runner_delegate.h",
  37     "modules/timer.cc",
  38     "modules/timer.h",
  39     "object_template_builder.cc",
  40     "object_template_builder.h",
  41     "per_context_data.cc",
  42     "per_context_data.h",
  43     "per_isolate_data.cc",
  44     "per_isolate_data.h",
  45     "public/context_holder.h",
  46     "public/debug.h",
  47     "public/gin_embedders.h",
  48     "public/isolate_holder.h",
  49     "public/v8_platform.h",
  50     "public/wrapper_info.h",
  51     "run_microtasks_observer.cc",
  52     "run_microtasks_observer.h",
  53     "runner.cc",
  54     "runner.h",
  55     "shell_runner.cc",
  56     "shell_runner.h",
  57     "try_catch.cc",
  58     "try_catch.h",
  59     "v8_initializer.cc",
  60     "v8_initializer.h",
  61     "v8_platform.cc",
  62     "wrappable.cc",
  63     "wrappable.h",
  64     "wrapper_info.cc",
  65   ]
  66
  67   defines = [ "GIN_IMPLEMENTATION" ]
  68
  69   public_deps = [
  70     "//base",
  71     "//v8",
  72   ]
  73   deps = [
  74     "//base/third_party/dynamic_annotations",
  75   ]
  76   if (v8_use_external_startup_data && is_win) {
  77     deps += [
  78       ":gin_v8_snapshot_fingerprint",
  79       "//crypto:crypto",
  80     ]
  81     sources += [ "$target_gen_dir/v8_snapshot_fingerprint.cc" ]
  82     defines += [ "V8_VERIFY_EXTERNAL_STARTUP_DATA" ]
  83   }
  84 }
  85
  86 if (v8_use_external_startup_data) {
  87   action("gin_v8_snapshot_fingerprint") {
  88     script = "//gin/fingerprint/fingerprint_v8_snapshot.py"
  89
  90     snapshot_file = "$root_build_dir/snapshot_blob.bin"
  91     natives_file = "$root_build_dir/natives_blob.bin"
  92     output_file = "$target_gen_dir/v8_snapshot_fingerprint.cc"
  93
  94     args = [
  95       "--snapshot_file",
  96       rebase_path(snapshot_file, root_build_dir),
  97       "--natives_file",
  98       rebase_path(natives_file, root_build_dir),
  99       "--output_file",
 100       rebase_path(output_file, root_build_dir),
 101     ]
 102     inputs = [
 103       snapshot_file,
 104       natives_file,
 105     ]
 106     outputs = [
 107       output_file,
 108     ]
 109   }
 110 }
 111
 112 executable("gin_shell") {
 113   sources = [
 114     "shell/gin_main.cc",
 115   ]
 116
 117   deps = [
 118     ":gin",
 119     "//base",
 120     "//base:i18n",
 121     "//v8",
 122   ]
 123 }
 124
 125 source_set("gin_test") {
 126   testonly = true
 127   sources = [
 128     "test/file.cc",
 129     "test/file.h",
 130     "test/file_runner.cc",
 131     "test/file_runner.h",
 132     "test/gc.cc",
 133     "test/gc.h",
 134     "test/gtest.cc",
 135     "test/gtest.h",
 136     "test/v8_test.cc",
 137     "test/v8_test.h",
 138   ]
 139
 140   public_deps = [
 141     ":gin",
 142     "//testing/gtest",
 143   ]
 144   deps = [
 145     "//v8",
 146   ]
 147 }
 148
 149 test("gin_unittests") {
 150   sources = [
 151     "converter_unittest.cc",
 152     "interceptor_unittest.cc",
 153     "modules/module_registry_unittest.cc",
 154     "modules/timer_unittest.cc",
 155     "per_context_data_unittest.cc",
 156     "shell/gin_shell_unittest.cc",
 157     "shell_runner_unittest.cc",
 158     "test/run_all_unittests.cc",
 159     "test/run_js_tests.cc",
 160     "wrappable_unittest.cc",
 161   ]
 162
 163   deps = [
 164     ":gin_test",
 165     "//base/test:test_support",
 166     "//v8",
 167   ]
 168 }