content/public/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//content/browser/browser.gni")
   6 import("//build/config/ui.gni")
   7
   8 # See //content/BUILD.gn for how this works.
   9 group("browser") {
  10   if (is_component_build) {
  11     deps = [ "//content" ]
  12   } else {
  13     deps = [ ":browser_sources" ]
  14   }
  15   forward_dependent_configs_from = deps
  16 }
  17
  18 source_set("browser_sources") {
  19   visibility = [ "//content/*" ]
  20
  21   if (is_ios) {
  22     # iOS doesn't get the normal file list and only takes these whitelisted
  23     # files.
  24     sources = [
  25       "browser_main_parts.cc",
  26       "content_browser_client.cc",
  27       "favicon_status.cc",
  28       "navigation_details.cc",
  29       "notification_registrar.cc",
  30       "page_navigator.cc",
  31       "web_ui_controller.cc",
  32     ]
  33   } else {
  34     sources = rebase_path(content_browser_gypi_values.public_browser_sources,
  35                           ".", "//content")
  36   }
  37
  38   if (use_aura) {
  39     sources -= [ "context_factory.h" ]
  40   }
  41
  42   configs += [ "//content:content_implementation" ]
  43
  44   deps = [
  45     "//content/browser",
  46     "//content/public/common:common_sources",
  47     "//net",
  48     "//skia",
  49     "//ui/accessibility",
  50     "//ui/base",
  51     "//ui/events",
  52   ]
  53
  54   allow_circular_includes_from = [
  55     # This target is a pair with content/browser. They always go together and
  56     # include headers from each other.
  57     "//content/browser",
  58   ]
  59
  60   # We expose skia headers in the public API.
  61   forward_dependent_configs_from = [ "//skia" ]
  62 }