media/audio/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/linux/pkg_config.gni")
   6 import("//media/media_options.gni")
   7
   8 # When libpulse is not directly linked, use stubs to allow for dlopening of the
   9 # binary.
  10 if (!link_pulseaudio) {
  11   action("pulse_generate_stubs") {
  12     extra_header = "pulse/pulse_stub_header.fragment"
  13
  14     script = "../../tools/generate_stubs/generate_stubs.py"
  15     sources = [
  16       "pulse/pulse.sigs",
  17     ]
  18     inputs = [
  19       extra_header,
  20     ]
  21     stubs_filename_root = "pulse_stubs"
  22
  23     # TODO(ajwong): these need to be included in the pulse build.
  24     outputs = [
  25       "$target_gen_dir/pulse/$stubs_filename_root.cc",
  26       "$target_gen_dir/pulse/$stubs_filename_root.h",
  27     ]
  28     args = [
  29       "-i",
  30       rebase_path("$target_gen_dir/pulse", root_build_dir),
  31       "-o",
  32       rebase_path("$target_gen_dir/pulse", root_build_dir),
  33       "-t",
  34       "posix_stubs",
  35       "-e",
  36       rebase_path(extra_header, root_build_dir),
  37       "-s",
  38       stubs_filename_root,
  39       "-p",
  40       "media/audio/pulse",
  41     ]
  42
  43     args += rebase_path(sources, root_build_dir)
  44   }
  45 }
  46
  47 source_set("audio") {
  48   visibility = [ "//media/*" ]
  49   sources = [
  50     "agc_audio_stream.h",
  51     "audio_device_name.cc",
  52     "audio_device_name.h",
  53     "audio_device_thread.cc",
  54     "audio_device_thread.h",
  55     "audio_input_controller.cc",
  56     "audio_input_controller.h",
  57     "audio_input_device.cc",
  58     "audio_input_device.h",
  59     "audio_input_ipc.cc",
  60     "audio_input_ipc.h",
  61     "audio_io.h",
  62     "audio_manager.cc",
  63     "audio_manager.h",
  64     "audio_manager_base.cc",
  65     "audio_manager_base.h",
  66     "audio_output_controller.cc",
  67     "audio_output_controller.h",
  68     "audio_output_device.cc",
  69     "audio_output_device.h",
  70     "audio_output_dispatcher.cc",
  71     "audio_output_dispatcher.h",
  72     "audio_output_dispatcher_impl.cc",
  73     "audio_output_dispatcher_impl.h",
  74     "audio_output_ipc.cc",
  75     "audio_output_ipc.h",
  76     "audio_output_proxy.cc",
  77     "audio_output_proxy.h",
  78     "audio_output_resampler.cc",
  79     "audio_output_resampler.h",
  80     "audio_output_stream_sink.cc",
  81     "audio_output_stream_sink.h",
  82     "audio_power_monitor.cc",
  83     "audio_power_monitor.h",
  84     "audio_source_diverter.h",
  85     "clockless_audio_sink.cc",
  86     "clockless_audio_sink.h",
  87     "fake_audio_input_stream.cc",
  88     "fake_audio_input_stream.h",
  89     "fake_audio_log_factory.cc",
  90     "fake_audio_log_factory.h",
  91     "fake_audio_manager.cc",
  92     "fake_audio_manager.h",
  93     "fake_audio_output_stream.cc",
  94     "fake_audio_output_stream.h",
  95     "fake_audio_worker.cc",
  96     "fake_audio_worker.h",
  97     "null_audio_sink.cc",
  98     "null_audio_sink.h",
  99     "sample_rates.cc",
 100     "sample_rates.h",
 101     "scoped_task_runner_observer.cc",
 102     "scoped_task_runner_observer.h",
 103     "simple_sources.cc",
 104     "simple_sources.h",
 105     "sounds/audio_stream_handler.cc",
 106     "sounds/audio_stream_handler.h",
 107     "sounds/sounds_manager.cc",
 108     "sounds/sounds_manager.h",
 109     "sounds/wav_audio_handler.cc",
 110     "sounds/wav_audio_handler.h",
 111     "virtual_audio_input_stream.cc",
 112     "virtual_audio_input_stream.h",
 113     "virtual_audio_output_stream.cc",
 114     "virtual_audio_output_stream.h",
 115   ]
 116   deps = []
 117   libs = []
 118   configs += [
 119     "//media:media_config",
 120     "//media:media_implementation",
 121   ]
 122
 123   if (is_mac) {
 124     sources += [
 125       "mac/audio_auhal_mac.cc",
 126       "mac/audio_auhal_mac.h",
 127       "mac/audio_device_listener_mac.cc",
 128       "mac/audio_device_listener_mac.h",
 129       "mac/audio_input_mac.cc",
 130       "mac/audio_input_mac.h",
 131       "mac/audio_low_latency_input_mac.cc",
 132       "mac/audio_low_latency_input_mac.h",
 133       "mac/audio_manager_mac.cc",
 134       "mac/audio_manager_mac.h",
 135     ]
 136     libs += [
 137       "AudioToolbox.framework",
 138       "AudioUnit.framework",
 139       "CoreAudio.framework",
 140     ]
 141   }
 142
 143   if (is_win) {
 144     sources += [
 145       "win/audio_device_listener_win.cc",
 146       "win/audio_device_listener_win.h",
 147       "win/audio_low_latency_input_win.cc",
 148       "win/audio_low_latency_input_win.h",
 149       "win/audio_low_latency_output_win.cc",
 150       "win/audio_low_latency_output_win.h",
 151       "win/audio_manager_win.cc",
 152       "win/audio_manager_win.h",
 153       "win/avrt_wrapper_win.cc",
 154       "win/avrt_wrapper_win.h",
 155       "win/core_audio_util_win.cc",
 156       "win/core_audio_util_win.h",
 157       "win/device_enumeration_win.cc",
 158       "win/device_enumeration_win.h",
 159       "win/wavein_input_win.cc",
 160       "win/wavein_input_win.h",
 161       "win/waveout_output_win.cc",
 162       "win/waveout_output_win.h",
 163     ]
 164   }
 165
 166   if (is_android) {
 167     sources += [
 168       "android/audio_manager_android.cc",
 169       "android/audio_manager_android.h",
 170       "android/audio_record_input.cc",
 171       "android/audio_record_input.h",
 172       "android/opensles_input.cc",
 173       "android/opensles_input.h",
 174       "android/opensles_output.cc",
 175       "android/opensles_output.h",
 176       "android/opensles_wrapper.cc",
 177     ]
 178     deps += [ "//media/base/android:media_jni_headers" ]
 179   }
 180
 181   if (is_openbsd) {
 182     sources += [
 183       "openbsd/audio_manager_openbsd.cc",
 184       "openbsd/audio_manager_openbsd.h",
 185     ]
 186   }
 187
 188   if (is_linux) {
 189     sources += [ "linux/audio_manager_linux.cc" ]
 190   }
 191
 192   if (use_alsa) {
 193     libs += [ "asound" ]
 194     defines = [ "USE_ALSA" ]
 195     sources += [
 196       "alsa/alsa_input.cc",
 197       "alsa/alsa_input.h",
 198       "alsa/alsa_output.cc",
 199       "alsa/alsa_output.h",
 200       "alsa/alsa_util.cc",
 201       "alsa/alsa_util.h",
 202       "alsa/alsa_wrapper.cc",
 203       "alsa/alsa_wrapper.h",
 204       "alsa/audio_manager_alsa.cc",
 205       "alsa/audio_manager_alsa.h",
 206     ]
 207   }
 208
 209   if (use_cras) {
 210     sources += [
 211       "cras/audio_manager_cras.cc",
 212       "cras/audio_manager_cras.h",
 213       "cras/cras_input.cc",
 214       "cras/cras_input.h",
 215       "cras/cras_unified.cc",
 216       "cras/cras_unified.h",
 217     ]
 218
 219     pkg_config("libcras") {
 220       packages = [ "libcras" ]
 221     }
 222     configs += [ ":libcras" ]
 223   }
 224
 225   if (use_pulseaudio) {
 226     sources += [
 227       "pulse/audio_manager_pulse.cc",
 228       "pulse/audio_manager_pulse.h",
 229       "pulse/pulse_input.cc",
 230       "pulse/pulse_input.h",
 231       "pulse/pulse_output.cc",
 232       "pulse/pulse_output.h",
 233       "pulse/pulse_util.cc",
 234       "pulse/pulse_util.h",
 235     ]
 236
 237     if (link_pulseaudio) {
 238       pkg_config("libpulse") {
 239         packages = [ "libpulse" ]
 240       }
 241       configs += [ ":libpulse" ]
 242     } else {
 243       # TODO(ajwong): Technically, this dl should go in the action.
 244       libs += [ "dl" ]
 245       deps += [ ":pulse_generate_stubs" ]
 246       sources += get_target_outputs(":pulse_generate_stubs")
 247     }
 248   }
 249
 250   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 251 }
 252
 253 source_set("test_support") {
 254   testonly = true
 255   sources = [
 256     "audio_unittest_util.cc",
 257     "audio_unittest_util.h",
 258     "mock_audio_manager.cc",
 259     "mock_audio_manager.h",
 260     "mock_audio_source_callback.cc",
 261     "mock_audio_source_callback.h",
 262     "test_audio_input_controller_factory.cc",
 263     "test_audio_input_controller_factory.h",
 264   ]
 265   deps = [
 266     "//testing/gmock",
 267   ]
 268   configs += [ "//media:media_config" ]
 269 }
 270
 271 source_set("unittests") {
 272   testonly = true
 273   sources = [
 274     "audio_input_controller_unittest.cc",
 275     "audio_input_unittest.cc",
 276     "audio_manager_factory_unittest.cc",
 277     "audio_manager_unittest.cc",
 278     "audio_output_controller_unittest.cc",
 279     "audio_output_device_unittest.cc",
 280     "audio_output_proxy_unittest.cc",
 281     "audio_parameters_unittest.cc",
 282     "audio_power_monitor_unittest.cc",
 283     "fake_audio_worker_unittest.cc",
 284     "simple_sources_unittest.cc",
 285     "virtual_audio_input_stream_unittest.cc",
 286     "virtual_audio_output_stream_unittest.cc",
 287   ]
 288   deps = [
 289     ":test_support",
 290     "//media/base:test_support",
 291     "//testing/gmock",
 292     "//testing/gtest",
 293   ]
 294
 295   configs += [
 296     "//build/config/compiler:no_size_t_to_int_warning",
 297     "//media:media_config",
 298   ]
 299
 300   if (is_android) {
 301     sources += [ "android/audio_android_unittest.cc" ]
 302   } else {
 303     sources += [ "audio_input_volume_unittest.cc" ]
 304   }
 305
 306   if (is_mac) {
 307     sources += [
 308       "mac/audio_auhal_mac_unittest.cc",
 309       "mac/audio_device_listener_mac_unittest.cc",
 310       "mac/audio_low_latency_input_mac_unittest.cc",
 311     ]
 312   }
 313
 314   if (is_chromeos) {
 315     sources += [
 316       "sounds/audio_stream_handler_unittest.cc",
 317       "sounds/sounds_manager_unittest.cc",
 318       "sounds/test_data.cc",
 319       "sounds/test_data.h",
 320       "sounds/wav_audio_handler_unittest.cc",
 321     ]
 322
 323     if (use_cras) {
 324       sources += [
 325         "cras/cras_input_unittest.cc",
 326         "cras/cras_unified_unittest.cc",
 327       ]
 328     }
 329   }
 330
 331   if (is_win) {
 332     sources += [
 333       "win/audio_device_listener_win_unittest.cc",
 334       "win/audio_low_latency_input_win_unittest.cc",
 335       "win/audio_low_latency_output_win_unittest.cc",
 336       "win/audio_output_win_unittest.cc",
 337       "win/core_audio_util_win_unittest.cc",
 338     ]
 339   }
 340
 341   if (use_alsa) {
 342     sources += [
 343       "alsa/alsa_output_unittest.cc",
 344       "audio_low_latency_input_output_unittest.cc",
 345     ]
 346   }
 347 }