third_party/libpng/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 config("libpng_config") {
   6   include_dirs = [ "." ]
   7
   8   defines = [
   9     "CHROME_PNG_WRITE_SUPPORT",
  10     "PNG_USER_CONFIG",
  11   ]
  12
  13   if (is_android) {
  14     #'toolsets': ['target', 'host'],
  15     defines += [ "CHROME_PNG_READ_PACK_SUPPORT" ]  # Required by freetype.
  16   }
  17
  18   if (is_win) {
  19     if (component_mode == "shared_library") {
  20       defines += [
  21         "PNG_USE_DLL",
  22         "PNG_NO_MODULEDEF",
  23       ]
  24     }
  25   }
  26 }
  27
  28 source_set("libpng_sources") {
  29   sources = [
  30     "png.c",
  31     "png.h",
  32     "pngconf.h",
  33     "pngerror.c",
  34     "pnggccrd.c",
  35     "pngget.c",
  36     "pngmem.c",
  37     "pngpread.c",
  38     "pngread.c",
  39     "pngrio.c",
  40     "pngrtran.c",
  41     "pngrutil.c",
  42     "pngset.c",
  43     "pngtrans.c",
  44     "pngusr.h",
  45     "pngvcrd.c",
  46     "pngwio.c",
  47     "pngwrite.c",
  48     "pngwtran.c",
  49     "pngwutil.c",
  50   ]
  51
  52   configs -= [ "//build/config/compiler:chromium_code" ]
  53   configs += [ "//build/config/compiler:no_chromium_code" ]
  54
  55   if (is_win && is_component_build) {
  56     defines = [ "PNG_BUILD_DLL" ]
  57   }
  58
  59   public_configs = [ ":libpng_config" ]
  60
  61   public_deps = [
  62     "//third_party/zlib",
  63   ]
  64 }
  65
  66 if (is_win) {
  67   component("libpng") {
  68     public_deps = [
  69       ":libpng_sources",
  70     ]
  71   }
  72 } else {
  73   group("libpng") {
  74     public_deps = [
  75       ":libpng_sources",
  76     ]
  77   }
  78 }