third_party/yasm/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # The yasm build process creates a slew of small C subprograms that
   6 # dynamically generate files at various point in the build process.  This makes
   7 # the build integration moderately complex.
   8 #
   9 # There are three classes of dynamically generated files:
  10 #   1) C source files that should be included in the build (eg., lc3bid.c)
  11 #   2) C source files that are #included by static C sources (eg., license.c)
  12 #   3) Intermediate files that are used as input by other subprograms to
  13 #      further generate files in category #1 or #2.  (eg., version.mac)
  14 #
  15 # This structure is represented with the following targets:
  16 #   1) yasm -- Sources, flags for the main yasm executable. Also has most of
  17 #              of the actions and rules that invoke the subprograms.
  18 #   2) yasm_config -- General build configuration including setting a
  19 #              inputs listing the checked in version of files
  20 #              generated by manually running configure. These manually
  21 #              generated files are used by all binaries.
  22 #   3) yasm_utils -- Object files with memory management and hashing utilities
  23 #              shared between yasm and the genperf subprogram.
  24 #   4) genmacro, genmodule, etc. -- One executable target for each subprogram.
  25 #   5) generate_license, generate_module, etc. -- Actions that invoke programs
  26 #              built in #4 to generate .c files.
  27 #   6) compile_gperf, compile_re2c, etc. -- Actions that invoke programs that
  28 #              turn intermediate files into .c files.
  29
  30 if (current_toolchain == host_toolchain) {
  31   # Various files referenced by multiple targets.
  32   yasm_gen_include_dir = "$target_gen_dir/include"
  33   config_makefile = "source/config/$host_os/Makefile"
  34   version_file = "version.mac"
  35
  36   import("//build/compiled_action.gni")
  37
  38   config("yasm_config") {
  39     include_dirs = [
  40       "source/config/$host_os",
  41       "source/patched-yasm",
  42     ]
  43     defines = [ "HAVE_CONFIG_H" ]
  44     if (is_posix) {
  45       cflags = [ "-std=gnu99" ]
  46     }
  47   }
  48
  49   executable("genmacro") {
  50     sources = [
  51       "source/patched-yasm/tools/genmacro/genmacro.c",
  52     ]
  53     configs -= [ "//build/config/compiler:chromium_code" ]
  54     configs += [
  55       ":yasm_config",
  56       "//build/config/compiler:no_chromium_code",
  57     ]
  58     deps = [
  59       "//build/config/sanitizers:deps",
  60     ]
  61   }
  62
  63   executable("genmodule") {
  64     sources = [
  65       "source/patched-yasm/libyasm/genmodule.c",
  66     ]
  67     configs -= [ "//build/config/compiler:chromium_code" ]
  68     configs += [
  69       ":yasm_config",
  70       "//build/config/compiler:no_chromium_code",
  71     ]
  72     deps = [
  73       "//build/config/sanitizers:deps",
  74     ]
  75   }
  76
  77   executable("genperf") {
  78     sources = [
  79       "source/patched-yasm/tools/genperf/genperf.c",
  80       "source/patched-yasm/tools/genperf/perfect.c",
  81     ]
  82
  83     configs -= [ "//build/config/compiler:chromium_code" ]
  84     configs += [
  85       ":yasm_config",
  86       "//build/config/compiler:no_chromium_code",
  87     ]
  88
  89     deps = [
  90       ":yasm_utils",
  91       "//build/config/sanitizers:deps",
  92     ]
  93   }
  94
  95   # Used by both yasm and genperf binaries.
  96   source_set("yasm_utils") {
  97     sources = [
  98       "source/patched-yasm/libyasm/phash.c",
  99       "source/patched-yasm/libyasm/xmalloc.c",
 100       "source/patched-yasm/libyasm/xstrdup.c",
 101     ]
 102
 103     configs -= [ "//build/config/compiler:chromium_code" ]
 104     configs += [
 105       ":yasm_config",
 106       "//build/config/compiler:no_chromium_code",
 107     ]
 108   }
 109
 110   executable("genstring") {
 111     sources = [
 112       "source/patched-yasm/genstring.c",
 113     ]
 114     configs -= [ "//build/config/compiler:chromium_code" ]
 115     configs += [
 116       ":yasm_config",
 117       "//build/config/compiler:no_chromium_code",
 118     ]
 119     deps = [
 120       "//build/config/sanitizers:deps",
 121     ]
 122   }
 123
 124   executable("genversion") {
 125     sources = [
 126       "source/patched-yasm/modules/preprocs/nasm/genversion.c",
 127     ]
 128     configs -= [ "//build/config/compiler:chromium_code" ]
 129     configs += [
 130       ":yasm_config",
 131       "//build/config/compiler:no_chromium_code",
 132     ]
 133     deps = [
 134       "//build/config/sanitizers:deps",
 135     ]
 136   }
 137
 138   executable("re2c") {
 139     sources = [
 140       "source/patched-yasm/tools/re2c/actions.c",
 141       "source/patched-yasm/tools/re2c/code.c",
 142       "source/patched-yasm/tools/re2c/dfa.c",
 143       "source/patched-yasm/tools/re2c/main.c",
 144       "source/patched-yasm/tools/re2c/mbo_getopt.c",
 145       "source/patched-yasm/tools/re2c/parser.c",
 146       "source/patched-yasm/tools/re2c/scanner.c",
 147       "source/patched-yasm/tools/re2c/substr.c",
 148       "source/patched-yasm/tools/re2c/translate.c",
 149     ]
 150
 151     configs -= [ "//build/config/compiler:chromium_code" ]
 152     configs += [
 153       ":yasm_config",
 154       "//build/config/compiler:no_chromium_code",
 155     ]
 156
 157     # re2c is missing CLOSEVOP from one switch.
 158     if (is_posix) {
 159       cflags = [ "-Wno-switch" ]
 160     }
 161     deps = [
 162       "//build/config/sanitizers:deps",
 163     ]
 164   }
 165
 166   executable("yasm") {
 167     sources = [
 168       "source/patched-yasm/frontends/yasm/yasm-options.c",
 169       "source/patched-yasm/frontends/yasm/yasm.c",
 170       "source/patched-yasm/libyasm/assocdat.c",
 171       "source/patched-yasm/libyasm/bc-align.c",
 172       "source/patched-yasm/libyasm/bc-data.c",
 173       "source/patched-yasm/libyasm/bc-incbin.c",
 174       "source/patched-yasm/libyasm/bc-org.c",
 175       "source/patched-yasm/libyasm/bc-reserve.c",
 176       "source/patched-yasm/libyasm/bitvect.c",
 177       "source/patched-yasm/libyasm/bytecode.c",
 178       "source/patched-yasm/libyasm/errwarn.c",
 179       "source/patched-yasm/libyasm/expr.c",
 180       "source/patched-yasm/libyasm/file.c",
 181       "source/patched-yasm/libyasm/floatnum.c",
 182       "source/patched-yasm/libyasm/hamt.c",
 183       "source/patched-yasm/libyasm/insn.c",
 184       "source/patched-yasm/libyasm/intnum.c",
 185       "source/patched-yasm/libyasm/inttree.c",
 186       "source/patched-yasm/libyasm/linemap.c",
 187       "source/patched-yasm/libyasm/md5.c",
 188       "source/patched-yasm/libyasm/mergesort.c",
 189       "source/patched-yasm/libyasm/section.c",
 190       "source/patched-yasm/libyasm/strcasecmp.c",
 191       "source/patched-yasm/libyasm/strsep.c",
 192       "source/patched-yasm/libyasm/symrec.c",
 193       "source/patched-yasm/libyasm/valparam.c",
 194       "source/patched-yasm/libyasm/value.c",
 195       "source/patched-yasm/modules/arch/lc3b/lc3barch.c",
 196       "source/patched-yasm/modules/arch/lc3b/lc3bbc.c",
 197       "source/patched-yasm/modules/arch/x86/x86arch.c",
 198       "source/patched-yasm/modules/arch/x86/x86bc.c",
 199       "source/patched-yasm/modules/arch/x86/x86expr.c",
 200       "source/patched-yasm/modules/arch/x86/x86id.c",
 201       "source/patched-yasm/modules/dbgfmts/codeview/cv-dbgfmt.c",
 202       "source/patched-yasm/modules/dbgfmts/codeview/cv-symline.c",
 203       "source/patched-yasm/modules/dbgfmts/codeview/cv-type.c",
 204       "source/patched-yasm/modules/dbgfmts/dwarf2/dwarf2-aranges.c",
 205       "source/patched-yasm/modules/dbgfmts/dwarf2/dwarf2-dbgfmt.c",
 206       "source/patched-yasm/modules/dbgfmts/dwarf2/dwarf2-info.c",
 207       "source/patched-yasm/modules/dbgfmts/dwarf2/dwarf2-line.c",
 208       "source/patched-yasm/modules/dbgfmts/null/null-dbgfmt.c",
 209       "source/patched-yasm/modules/dbgfmts/stabs/stabs-dbgfmt.c",
 210       "source/patched-yasm/modules/listfmts/nasm/nasm-listfmt.c",
 211       "source/patched-yasm/modules/objfmts/bin/bin-objfmt.c",
 212       "source/patched-yasm/modules/objfmts/coff/coff-objfmt.c",
 213       "source/patched-yasm/modules/objfmts/coff/win64-except.c",
 214       "source/patched-yasm/modules/objfmts/dbg/dbg-objfmt.c",
 215       "source/patched-yasm/modules/objfmts/elf/elf-objfmt.c",
 216       "source/patched-yasm/modules/objfmts/elf/elf-x86-amd64.c",
 217       "source/patched-yasm/modules/objfmts/elf/elf-x86-x86.c",
 218       "source/patched-yasm/modules/objfmts/elf/elf.c",
 219       "source/patched-yasm/modules/objfmts/macho/macho-objfmt.c",
 220       "source/patched-yasm/modules/objfmts/rdf/rdf-objfmt.c",
 221       "source/patched-yasm/modules/objfmts/xdf/xdf-objfmt.c",
 222       "source/patched-yasm/modules/parsers/gas/gas-parse-intel.c",
 223       "source/patched-yasm/modules/parsers/gas/gas-parse.c",
 224       "source/patched-yasm/modules/parsers/gas/gas-parser.c",
 225       "source/patched-yasm/modules/parsers/nasm/nasm-parse.c",
 226       "source/patched-yasm/modules/parsers/nasm/nasm-parser.c",
 227       "source/patched-yasm/modules/preprocs/cpp/cpp-preproc.c",
 228       "source/patched-yasm/modules/preprocs/nasm/nasm-eval.c",
 229       "source/patched-yasm/modules/preprocs/nasm/nasm-pp.c",
 230       "source/patched-yasm/modules/preprocs/nasm/nasm-preproc.c",
 231       "source/patched-yasm/modules/preprocs/nasm/nasmlib.c",
 232       "source/patched-yasm/modules/preprocs/raw/raw-preproc.c",
 233
 234       # Files generated by compile_gperf
 235       "$target_gen_dir/x86cpu.c",
 236       "$target_gen_dir/x86regtmod.c",
 237
 238       # Files generated by compile_re2c
 239       "$target_gen_dir/gas-token.c",
 240       "$target_gen_dir/nasm-token.c",
 241
 242       # File generated by compile_re2c_lc3b
 243       "$target_gen_dir/lc3bid.c",
 244
 245       # File generated by generate_module
 246       "$target_gen_dir/module.c",
 247     ]
 248
 249     configs -= [ "//build/config/compiler:chromium_code" ]
 250     configs += [
 251       ":yasm_config",
 252       "//build/config/compiler:no_chromium_code",
 253     ]
 254
 255     # Yasm generates a bunch of .c files which its source file #include.
 256     # Add the |target_gen_dir| into the include path so it can find them.
 257     # Ideally, these generated .c files would be placed into a separate
 258     # directory, but the gen_x86_insn.py script does not make this easy.
 259     include_dirs = [ yasm_gen_include_dir ]
 260
 261     if (!is_win) {
 262       cflags = [
 263         "-ansi",
 264         "-pedantic",
 265       ]
 266       if (is_clang) {
 267         cflags += [ "-Wno-incompatible-pointer-types" ]
 268       }
 269     }
 270
 271     # TODO(ajwong): This should take most of the generated output as
 272     # inputs.
 273     deps = [
 274       ":compile_gperf",
 275       ":compile_gperf_for_include",
 276       ":compile_nasm_macros",
 277       ":compile_nasm_version",
 278       ":compile_re2c_lc3b",
 279       ":compile_win64_gas",
 280       ":compile_win64_nasm",
 281       ":compile_re2c",
 282       ":generate_license",
 283       ":generate_module",
 284       ":generate_version",
 285       ":yasm_utils",
 286       "//build/config/sanitizers:deps",
 287     ]
 288   }
 289
 290   compiled_action_foreach("compile_gperf") {
 291     tool = ":genperf"
 292     sources = [
 293       "source/patched-yasm/modules/arch/x86/x86cpu.gperf",
 294       "source/patched-yasm/modules/arch/x86/x86regtmod.gperf",
 295     ]
 296
 297     outputs = [
 298       "$target_gen_dir/{{source_name_part}}.c",
 299     ]
 300     args = [
 301       "{{source}}",
 302       rebase_path(target_gen_dir, root_build_dir) + "/{{source_name_part}}.c",
 303     ]
 304     deps = [
 305       ":generate_x86_insn",
 306     ]
 307   }
 308
 309   # This differs from |compile_gperf| in where it places it output files.
 310   compiled_action_foreach("compile_gperf_for_include") {
 311     tool = ":genperf"
 312     sources = [
 313       # Make sure the generated gperf files in $target_gen_dir are synced with
 314       # the outputs for the related generate_*_insn actions in the
 315       # generate_files target below.
 316       #
 317       # The output for these two are #included by
 318       #   source/patched-yasm/modules/arch/x86/x86id.c
 319       "$yasm_gen_include_dir/x86insn_gas.gperf",
 320       "$yasm_gen_include_dir/x86insn_nasm.gperf",
 321     ]
 322
 323     outputs = [
 324       "$yasm_gen_include_dir/{{source_name_part}}.c",
 325     ]
 326     args = [
 327       "{{source}}",
 328       rebase_path(yasm_gen_include_dir, root_build_dir) +
 329           "/{{source_name_part}}.c",
 330     ]
 331     deps = [
 332       ":generate_x86_insn",
 333     ]
 334   }
 335
 336   template("compile_macro") {
 337     compiled_action(target_name) {
 338       tool = ":genmacro"
 339
 340       # Output #included by source/patched-yasm/frontends/yasm/yasm.c.
 341       inputs = invoker.sources
 342       outputs = invoker.outputs
 343       args = [
 344         rebase_path(outputs[0], root_build_dir),
 345         invoker.macro_varname,
 346         rebase_path(inputs[0], root_build_dir),
 347       ]
 348       if (defined(invoker.deps)) {
 349         deps = invoker.deps
 350       }
 351     }
 352   }
 353
 354   compile_macro("compile_nasm_macros") {
 355     # Output #included by
 356     #   source/patched-yasm/modules/preprocs/nasm/nasm-parser.c
 357     sources = [
 358       "source/patched-yasm/modules/parsers/nasm/nasm-std.mac",
 359     ]
 360     outputs = [
 361       "$yasm_gen_include_dir/nasm-macros.c",
 362     ]
 363     macro_varname = "nasm_standard_mac"
 364   }
 365
 366   compile_macro("compile_nasm_version") {
 367     # Output #included by
 368     #   source/patched-yasm/modules/preprocs/nasm/nasm-preproc.c
 369     sources = [
 370       "$target_gen_dir/$version_file",
 371     ]
 372     outputs = [
 373       "$yasm_gen_include_dir/nasm-version.c",
 374     ]
 375     macro_varname = "nasm_version_mac"
 376     deps = [
 377       ":generate_version",
 378     ]
 379   }
 380
 381   compile_macro("compile_win64_gas") {
 382     # Output #included by source/patched-yasm/frontends/yasm/yasm.c.
 383     sources = [
 384       "source/patched-yasm/modules/objfmts/coff/win64-gas.mac",
 385     ]
 386     outputs = [
 387       "$yasm_gen_include_dir/win64-gas.c",
 388     ]
 389     macro_varname = "win64_gas_stdmac"
 390   }
 391
 392   compile_macro("compile_win64_nasm") {
 393     # Output #included by source/patched-yasm/frontends/yasm/yasm.c.
 394     sources = [
 395       "source/patched-yasm/modules/objfmts/coff/win64-nasm.mac",
 396     ]
 397     outputs = [
 398       "$yasm_gen_include_dir/win64-nasm.c",
 399     ]
 400     macro_varname = "win64_nasm_stdmac"
 401   }
 402
 403   compiled_action_foreach("compile_re2c") {
 404     tool = ":re2c"
 405     sources = [
 406       "source/patched-yasm/modules/parsers/gas/gas-token.re",
 407       "source/patched-yasm/modules/parsers/nasm/nasm-token.re",
 408     ]
 409     outputs = [
 410       "$target_gen_dir/{{source_name_part}}.c",
 411     ]
 412     args = [
 413       "-b",
 414       "-o",
 415       rebase_path(target_gen_dir, root_build_dir) + "/{{source_name_part}}.c",
 416       "{{source}}",
 417     ]
 418   }
 419
 420   # This call doesn't fit into the re2c template above.
 421   compiled_action("compile_re2c_lc3b") {
 422     tool = ":re2c"
 423     inputs = [
 424       "source/patched-yasm/modules/arch/lc3b/lc3bid.re",
 425     ]
 426     outputs = [
 427       "$target_gen_dir/lc3bid.c",
 428     ]
 429     args = [
 430       "-s",
 431       "-o",
 432       rebase_path(outputs[0], root_build_dir),
 433       rebase_path(inputs[0], root_build_dir),
 434     ]
 435   }
 436
 437   compiled_action("generate_license") {
 438     tool = ":genstring"
 439
 440     # Output #included by source/patched-yasm/frontends/yasm/yasm.c.
 441     inputs = [
 442       "source/patched-yasm/COPYING",
 443     ]
 444     outputs = [
 445       "$yasm_gen_include_dir/license.c",
 446     ]
 447     args = [
 448       "license_msg",
 449       rebase_path(outputs[0], root_build_dir),
 450       rebase_path(inputs[0], root_build_dir),
 451     ]
 452   }
 453
 454   compiled_action("generate_module") {
 455     tool = ":genmodule"
 456     inputs = [
 457       "source/patched-yasm/libyasm/module.in",
 458       config_makefile,
 459     ]
 460     outputs = [
 461       "$target_gen_dir/module.c",
 462     ]
 463     args = [
 464       rebase_path(inputs[0], root_build_dir),
 465       rebase_path(config_makefile, root_build_dir),
 466       rebase_path(outputs[0], root_build_dir),
 467     ]
 468   }
 469
 470   compiled_action("generate_version") {
 471     tool = ":genversion"
 472     outputs = [
 473       "$target_gen_dir/$version_file",
 474     ]
 475     args = [ rebase_path(outputs[0], root_build_dir) ]
 476   }
 477
 478   action("generate_x86_insn") {
 479     script = "source/patched-yasm/modules/arch/x86/gen_x86_insn.py"
 480
 481     # Output eventually #included by source/patched-yasm/frontends/yasm/x86id.c
 482     outputs = [
 483       "$yasm_gen_include_dir/x86insns.c",
 484       "$yasm_gen_include_dir/x86insn_gas.gperf",
 485       "$yasm_gen_include_dir/x86insn_nasm.gperf",
 486     ]
 487     args = [ rebase_path(yasm_gen_include_dir, root_build_dir) ]
 488   }
 489 }