build/toolchain/gcc_toolchain.gni

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/sanitizers/sanitizers.gni")
   6 import("//build/toolchain/toolchain.gni")
   7
   8 # This value will be inherited in the toolchain below.
   9 concurrent_links = exec_script("get_concurrent_links.py", [], "value")
  10
  11 # This template defines a toolchain for something that works like gcc
  12 # (including clang).
  13 #
  14 # It requires the following variables specifying the executables to run:
  15 #  - cc
  16 #  - cxx
  17 #  - ar
  18 #  - ld
  19 # and the following which is used in the toolchain_args
  20 #  - toolchain_cpu  (What "current_cpu" should be set to when invoking a
  21 #                    build using this toolchain.)
  22 #  - toolchain_os  (What "current_os" should be set to when invoking a
  23 #                   build using this toolchain.)
  24 #
  25 # Optional parameters that control the tools:
  26 #
  27 #  - libs_section_prefix
  28 #  - libs_section_postfix
  29 #      The contents of these strings, if specified, will be placed around
  30 #      the libs section of the linker line. It allows one to inject libraries
  31 #      at the beginning and end for all targets in a toolchain.
  32 #  - solink_libs_section_prefix
  33 #  - solink_libs_section_postfix
  34 #      Same as libs_section_{pre,post}fix except used for solink instead of link.
  35 #  - link_outputs
  36 #      The content of this array, if specified, will be added to the list of
  37 #      outputs from the link command. This can be useful in conjunction with
  38 #      the post_link parameter.
  39 #  - post_link
  40 #      The content of this string, if specified, will be run as a separate
  41 #      command following the the link command.
  42 #  - deps
  43 #      Just forwarded to the toolchain definition.
  44 #  - executable_extension
  45 #      If this string is specified it will be used for the file extension
  46 #      for an executable, rather than using no extension; targets will
  47 #      still be able to override the extension using the output_extension
  48 #      variable.
  49 #  - rebuild_define
  50 #      The contents of this string, if specified, will be passed as a #define
  51 #      to the toolchain. It can be used to force recompiles whenever a
  52 #      toolchain is updated.
  53 #  - shlib_extension
  54 #      If this string is specified it will be used for the file extension
  55 #      for a shared library, rather than default value specified in
  56 #      toolchain.gni
  57 #  - strip
  58 #      Location of the strip executable. When specified, strip will be run on
  59 #      all shared libraries and executables as they are built. The pre-stripped
  60 #      artifacts will be put in lib.stripped/ and exe.stripped/.
  61 #
  62 # Optional build argument contols.
  63 #
  64 #  - clear_sanitizers
  65 #      When set to true, is_asan, is_msan, etc.will all be set to false. Often
  66 #      secondary toolchains do not want to run with sanitizers.
  67 #  - is_clang
  68 #      Whether to use clang instead of gcc.
  69 #  - is_component_build
  70 #      Whether to forcibly enable or disable component builds for this
  71 #      toolchain; if not specified, the toolchain will inherit the
  72 #      default setting.
  73 template("gcc_toolchain") {
  74   toolchain(target_name) {
  75     assert(defined(invoker.cc), "gcc_toolchain() must specify a \"cc\" value")
  76     assert(defined(invoker.cxx), "gcc_toolchain() must specify a \"cxx\" value")
  77     assert(defined(invoker.ar), "gcc_toolchain() must specify a \"ar\" value")
  78     assert(defined(invoker.ld), "gcc_toolchain() must specify a \"ld\" value")
  79     assert(defined(invoker.toolchain_cpu),
  80            "gcc_toolchain() must specify a \"toolchain_cpu\"")
  81     assert(defined(invoker.toolchain_os),
  82            "gcc_toolchain() must specify a \"toolchain_os\"")
  83
  84     # This define changes when the toolchain changes, forcing a rebuild.
  85     # Nothing should ever use this define.
  86     if (defined(invoker.rebuild_define)) {
  87       rebuild_string = "-D" + invoker.rebuild_define + " "
  88     } else {
  89       rebuild_string = ""
  90     }
  91
  92     # We can't do string interpolation ($ in strings) on things with dots in
  93     # them. To allow us to use $cc below, for example, we create copies of
  94     # these values in our scope.
  95     cc = invoker.cc
  96     cxx = invoker.cxx
  97     ar = invoker.ar
  98     ld = invoker.ld
  99     if (defined(invoker.readelf)) {
 100       readelf = invoker.readelf
 101     } else {
 102       readelf = "readelf"
 103     }
 104     if (defined(invoker.nm)) {
 105       nm = invoker.nm
 106     } else {
 107       nm = "nm"
 108     }
 109
 110     if (defined(invoker.shlib_extension)) {
 111       default_shlib_extension = invoker.shlib_extension
 112     } else {
 113       default_shlib_extension = shlib_extension
 114     }
 115
 116     if (defined(invoker.executable_extension)) {
 117       default_executable_extension = invoker.executable_extension
 118     } else {
 119       default_executable_extension = ""
 120     }
 121
 122     # Bring these into our scope for string interpolation with default values.
 123     if (defined(invoker.libs_section_prefix)) {
 124       libs_section_prefix = invoker.libs_section_prefix
 125     } else {
 126       libs_section_prefix = ""
 127     }
 128
 129     if (defined(invoker.libs_section_postfix)) {
 130       libs_section_postfix = invoker.libs_section_postfix
 131     } else {
 132       libs_section_postfix = ""
 133     }
 134
 135     if (defined(invoker.solink_libs_section_prefix)) {
 136       solink_libs_section_prefix = invoker.solink_libs_section_prefix
 137     } else {
 138       solink_libs_section_prefix = ""
 139     }
 140
 141     if (defined(invoker.solink_libs_section_postfix)) {
 142       solink_libs_section_postfix = invoker.solink_libs_section_postfix
 143     } else {
 144       solink_libs_section_postfix = ""
 145     }
 146
 147     # These library switches can apply to all tools below.
 148     lib_switch = "-l"
 149     lib_dir_switch = "-L"
 150
 151     tool("cc") {
 152       depfile = "{{output}}.d"
 153       command = "$cc -MMD -MF $depfile ${rebuild_string}{{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
 154       depsformat = "gcc"
 155       description = "CC {{output}}"
 156       outputs = [
 157         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
 158       ]
 159     }
 160
 161     tool("cxx") {
 162       depfile = "{{output}}.d"
 163       command = "$cxx -MMD -MF $depfile ${rebuild_string}{{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
 164       depsformat = "gcc"
 165       description = "CXX {{output}}"
 166       outputs = [
 167         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
 168       ]
 169     }
 170
 171     tool("asm") {
 172       # For GCC we can just use the C compiler to compile assembly.
 173       depfile = "{{output}}.d"
 174       command = "$cc -MMD -MF $depfile ${rebuild_string}{{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
 175       depsformat = "gcc"
 176       description = "ASM {{output}}"
 177       outputs = [
 178         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
 179       ]
 180     }
 181
 182     tool("alink") {
 183       rspfile = "{{output}}.rsp"
 184       arflags = ""
 185       if (is_cfi && invoker.toolchain_os != "nacl") {
 186         gold_plugin_path = rebase_path(
 187                 "//third_party/llvm-build/Release+Asserts/lib/LLVMgold.so",
 188                 root_build_dir)
 189         arflags = "--plugin $gold_plugin_path"
 190       }
 191       command = "rm -f {{output}} && $ar rcs $arflags {{output}} @$rspfile"
 192       description = "AR {{output}}"
 193       rspfile_content = "{{inputs}}"
 194       outputs = [
 195         "{{target_out_dir}}/{{target_output_name}}{{output_extension}}",
 196       ]
 197       default_output_extension = ".a"
 198       output_prefix = "lib"
 199     }
 200
 201     tool("solink") {
 202       soname = "{{target_output_name}}{{output_extension}}"  # e.g. "libfoo.so".
 203       sofile = "{{root_out_dir}}/$soname"  # Possibly including toolchain dir.
 204       if (shlib_subdir != ".") {
 205         sofile = "{{root_out_dir}}/$shlib_subdir/$soname"
 206       }
 207       rspfile = sofile + ".rsp"
 208
 209       unstripped_sofile = sofile
 210       if (defined(invoker.strip)) {
 211         unstripped_sofile = "{{root_out_dir}}/lib.unstripped/$soname"
 212       }
 213
 214       # These variables are not built into GN but are helpers that implement
 215       # (1) linking to produce a .so, (2) extracting the symbols from that file
 216       # to a temporary file, (3) if the temporary file has differences from the
 217       # existing .TOC file, overwrite it, otherwise, don't change it.
 218       tocfile = sofile + ".TOC"
 219       temporary_tocname = sofile + ".tmp"
 220
 221       link_command = "$ld -shared {{ldflags}} -o $unstripped_sofile -Wl,-soname=$soname @$rspfile"
 222       assert(defined(readelf), "to solink you must have a readelf")
 223       assert(defined(nm), "to solink you must have an nm")
 224       toc_command = "{ $readelf -d $unstripped_sofile | grep SONAME ; $nm -gD -f p $unstripped_sofile | cut -f1-2 -d' '; } > $temporary_tocname"
 225       replace_command = "if ! cmp -s $temporary_tocname $tocfile; then mv $temporary_tocname $tocfile; fi"
 226
 227       command = "$link_command && $toc_command && $replace_command"
 228       if (defined(invoker.strip)) {
 229         strip_command =
 230             "${invoker.strip} --strip-unneeded -o $sofile $unstripped_sofile"
 231         command += " && " + strip_command
 232       }
 233       rspfile_content = "-Wl,--whole-archive {{inputs}} {{solibs}} -Wl,--no-whole-archive $solink_libs_section_prefix {{libs}} $solink_libs_section_postfix"
 234
 235       description = "SOLINK $sofile"
 236
 237       # Use this for {{output_extension}} expansions unless a target manually
 238       # overrides it (in which case {{output_extension}} will be what the target
 239       # specifies).
 240       default_output_extension = default_shlib_extension
 241
 242       output_prefix = "lib"
 243
 244       # Since the above commands only updates the .TOC file when it changes, ask
 245       # Ninja to check if the timestamp actually changed to know if downstream
 246       # dependencies should be recompiled.
 247       restat = true
 248
 249       # Tell GN about the output files. It will link to the sofile but use the
 250       # tocfile for dependency management.
 251       outputs = [
 252         sofile,
 253         tocfile,
 254       ]
 255       if (sofile != unstripped_sofile) {
 256         outputs += [ unstripped_sofile ]
 257       }
 258       link_output = sofile
 259       depend_output = tocfile
 260     }
 261
 262     tool("link") {
 263       exename = "{{target_output_name}}{{output_extension}}"
 264       outfile = "{{root_out_dir}}/$exename"
 265       rspfile = "$outfile.rsp"
 266       unstripped_outfile = outfile
 267
 268       # Use this for {{output_extension}} expansions unless a target manually
 269       # overrides it (in which case {{output_extension}} will be what the target
 270       # specifies).
 271       default_output_extension = default_executable_extension
 272
 273       if (defined(invoker.strip)) {
 274         unstripped_outfile = "{{root_out_dir}}/exe.unstripped/$exename"
 275       }
 276
 277       command = "$ld {{ldflags}} -o $unstripped_outfile -Wl,--start-group @$rspfile {{solibs}} -Wl,--end-group $libs_section_prefix {{libs}} $libs_section_postfix"
 278       if (defined(invoker.strip)) {
 279         strip_command =
 280             "${invoker.strip} --strip-unneeded -o $outfile $unstripped_outfile"
 281         command += " && " + strip_command
 282       }
 283       if (defined(invoker.postlink)) {
 284         command += " && " + invoker.postlink
 285       }
 286       description = "LINK $outfile"
 287       rspfile_content = "{{inputs}}"
 288       outputs = [
 289         outfile,
 290       ]
 291       if (outfile != unstripped_outfile) {
 292         outputs += [ unstripped_outfile ]
 293       }
 294       if (defined(invoker.link_outputs)) {
 295         outputs += invoker.link_outputs
 296       }
 297     }
 298
 299     tool("stamp") {
 300       command = "touch {{output}}"
 301       description = "STAMP {{output}}"
 302     }
 303
 304     tool("copy") {
 305       command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
 306       description = "COPY {{source}} {{output}}"
 307     }
 308
 309     # When invoking this toolchain not as the default one, these args will be
 310     # passed to the build. They are ignored when this is the default toolchain.
 311     toolchain_args() {
 312       current_cpu = invoker.toolchain_cpu
 313       current_os = invoker.toolchain_os
 314
 315       # These values need to be passed through unchanged.
 316       target_os = target_os
 317       target_cpu = target_cpu
 318
 319       forward_variables_from(invoker,
 320                              [
 321                                "is_clang",
 322                                "is_component_build",
 323                              ])
 324
 325       if (defined(invoker.clear_sanitizers) && invoker.clear_sanitizers) {
 326         is_asan = false
 327         is_cfi = false
 328         is_lsan = false
 329         is_msan = false
 330         is_syzyasan = false
 331         is_tsan = false
 332       }
 333     }
 334
 335     forward_variables_from(invoker, [ "deps" ])
 336   }
 337 }