build/config/BUILDCONFIG.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # =============================================================================
   6 # PLATFORM SELECTION
   7 # =============================================================================
   8 #
   9 # There are two main things to set: "os" and "cpu". The "toolchain" is the name
  10 # of the GN thing that encodes combinations of these things.
  11 #
  12 # Users typically only set the variables "target_os" and "target_cpu" in "gn
  13 # args", the rest are set up by our build and internal to GN.
  14 #
  15 # There are three different types of each of these things: The "host"
  16 # represents the computer doing the compile and never changes. The "target"
  17 # represents the main thing we're trying to build. The "current" represents
  18 # which configuration is currently being defined, which can be either the
  19 # host, the target, or something completely different (like nacl). GN will
  20 # run the same build file multiple times for the different required
  21 # configuration in the same build.
  22 #
  23 # This gives the following variables:
  24 #  - host_os, host_cpu, host_toolchain
  25 #  - target_os, target_cpu, default_toolchain
  26 #  - current_os, current_cpu, current_toolchain.
  27 #
  28 # Note the default_toolchain isn't symmetrical (you would expect
  29 # target_toolchain). This is because the "default" toolchain is a GN built-in
  30 # concept, and "target" is something our build sets up that's symmetrical with
  31 # its GYP counterpart. Potentially the built-in default_toolchain variable
  32 # could be renamed in the future.
  33 #
  34 # When writing build files, to do something only for the host:
  35 #   if (current_toolchain == host_toolchain) { ...
  36
  37 if (target_os == "") {
  38   target_os = host_os
  39 }
  40
  41 if (target_cpu == "") {
  42   if (target_os == "android") {
  43     # If we're building for Android, we should assume that we want to
  44     # build for ARM by default, not the host_cpu (which is likely x64).
  45     # This allows us to not have to specify both target_os and target_cpu
  46     # on the command line.
  47     target_cpu = "arm"
  48   } else {
  49     target_cpu = host_cpu
  50   }
  51 }
  52
  53 if (current_cpu == "") {
  54   current_cpu = target_cpu
  55 }
  56 if (current_os == "") {
  57   current_os = target_os
  58 }
  59
  60 # =============================================================================
  61 # BUILD FLAGS
  62 # =============================================================================
  63 #
  64 # This block lists input arguments to the build, along with their default
  65 # values.
  66 #
  67 # If a value is specified on the command line, it will overwrite the defaults
  68 # given in a declare_args block, otherwise the default will be used.
  69 #
  70 # YOU SHOULD ALMOST NEVER NEED TO ADD FLAGS TO THIS FILE. GN allows any file in
  71 # the build to declare build flags. If you need a flag for a single component,
  72 # you can just declare it in the corresponding BUILD.gn file. If you need a
  73 # flag in multiple components, there are a few options:
  74 #
  75 # - If your feature is a single target, say //components/foo, and the targets
  76 #   depending on foo need to have some define set if foo is enabled: (1) Write
  77 #   a declare_args block in foo's BUILD.gn file listing your enable_foo build
  78 #   flag. (2) Write a config in that file listing the define, and list that
  79 #   config in foo's public_configs. This will propagate that define to all the
  80 #   targets depending on foo. (3) When foo is not enabled, just make it expand
  81 #   to an empty group (or whatever's appropriate for the "off" state of your
  82 #   feature.
  83 #
  84 # - If a semi-random set of targets need to know about a define: (1) In the
  85 #   lowest level of the build that knows about this feature, add a declare_args
  86 #   block in the build file for your enable flag. (2) Write a config that adds
  87 #   a define conditionally based on that build flags. (3) Manually add that
  88 #   config to the "configs" applying to the targets that need the define.
  89 #
  90 # - If a semi-random set of targets need to know about the build flag (to do
  91 #   file inclusion or exclusion, more than just defines): (1) Write a .gni file
  92 #   in the lowest-level directory that knows about the feature. (2) Put the
  93 #   declare_args block with your build flag in that .gni file. (3) Import that
  94 #   .gni file from the BUILD.gn files that need the flag.
  95 #
  96 # Other advice:
  97 #
  98 # - Use boolean values when possible. If you need a default value that expands
  99 #   to some complex thing in the default case (like the location of the
 100 #   compiler which would be computed by a script), use a default value of -1 or
 101 #   the empty string. Outside of the declare_args block, conditionally expand
 102 #   the default value as necessary.
 103 #
 104 # - Use a name like "use_foo" or "is_foo" (whatever is more appropriate for
 105 #   your feature) rather than just "foo".
 106 #
 107 # - Write good comments directly above the declaration with no blank line.
 108 #   These comments will appear as documentation in "gn args --list".
 109 #
 110 # - Don't call exec_script inside declare_args. This will execute the script
 111 #   even if the value is overridden, which is wasteful. See first bullet.
 112
 113 declare_args() {
 114   # Component build.
 115   is_component_build = false
 116
 117   # Debug build.
 118   is_debug = true
 119
 120   # Whether we're a traditional desktop unix.
 121   is_desktop_linux = current_os == "linux" && current_os != "chromeos"
 122
 123   # Set to true when compiling with the Clang compiler. Typically this is used
 124   # to configure warnings.
 125   is_clang = current_os == "mac" || current_os == "ios" ||
 126              current_os == "linux" || current_os == "chromeos"
 127
 128   if (current_os == "chromeos") {
 129     # Allows the target toolchain to be injected as arguments. This is needed
 130     # to support the CrOS build system which supports per-build-configuration
 131     # toolchains.
 132     cros_use_custom_toolchain = false
 133   }
 134
 135   # DON'T ADD MORE FLAGS HERE. Read the comment above.
 136 }
 137
 138 # This flag indicates if the build is using the new optimization and symbol
 139 # level configs, or the old ones.
 140 #
 141 # This is part of a multi-repo landing. When all required deps (WebKit and
 142 # ffmpeg) have been updated to handle this flag, we can change the optimization
 143 # and symbol level configs and set this flag to true. Then delete the users of
 144 # the flag, wait for all deps rolls, then remove the flag.
 145 #
 146 # In the old scheme, this file sets the appropriate optimization or symbol
 147 # level config on targets depending on what the current build setup is. This
 148 # requires that targets know what the default is, and if they want to change it,
 149 # they have to figure out which one to remove depending on the state of the
 150 # current build. It also means that symbol_level and the sanitizer flags need
 151 # to be global.
 152 #
 153 # In the new scheme, this file sets a "default_symbols" and
 154 # "default_optimization" configs, which then expands to the right thing
 155 # depending on the current build. This means less information has to be global,
 156 # and there's only one config to remove that's the same in all cases for
 157 # targets that want to override it. It also means that the associated flags can
 158 # be non-global.
 159 using_new_global_compiler_configs = true
 160
 161 # To assist in a multi-sided landing of updating the default optimization
 162 # config. When false, this file sets up the default optimization config to be
 163 # either "no_optimize" (debug) or "optimize" (release). When true it will
 164 # always set the config "default_optimization".
 165 #
 166 # TODO(brettw) remove this when all repos are updated.
 167 using_new_optimization_config = true
 168
 169 # To assist in a multi-sided landing of updating the default optimization
 170 # config. When false, this file sets up the default optimization config to be
 171 # either "no_optimize" (debug) or "optimize" (release). When true it will
 172 # always set the config "default_optimization".
 173 #
 174 # TODO(brettw) remove this when all repos are updated.
 175 using_new_optimization_config = true
 176
 177 # =============================================================================
 178 # OS DEFINITIONS
 179 # =============================================================================
 180 #
 181 # We set these various is_FOO booleans for convenience in writing OS-based
 182 # conditions.
 183 #
 184 # - is_android, is_chromeos, is_ios, and is_win should be obvious.
 185 # - is_mac is set only for desktop Mac. It is not set on iOS.
 186 # - is_posix is true for mac and any Unix-like system (basically everything
 187 #   except Windows).
 188 # - is_linux is true for desktop Linux and ChromeOS, but not Android (which is
 189 #   generally too different despite being based on the Linux kernel).
 190 #
 191 # Do not add more is_* variants here for random lesser-used Unix systems like
 192 # aix or one of the BSDs. If you need to check these, just check the
 193 # current_os value directly.
 194
 195 if (current_os == "win" || current_os == "winrt_81" ||
 196     current_os == "winrt_81_phone" || current_os == "winrt_10") {
 197   is_android = false
 198   is_chromeos = false
 199   is_ios = false
 200   is_linux = false
 201   is_mac = false
 202   is_nacl = false
 203   is_posix = false
 204   is_win = true
 205 } else if (current_os == "mac") {
 206   is_android = false
 207   is_chromeos = false
 208   is_ios = false
 209   is_linux = false
 210   is_mac = true
 211   is_nacl = false
 212   is_posix = true
 213   is_win = false
 214 } else if (current_os == "android") {
 215   is_android = true
 216   is_chromeos = false
 217   is_ios = false
 218   is_linux = false
 219   is_mac = false
 220   is_nacl = false
 221   is_posix = true
 222   is_win = false
 223 } else if (current_os == "chromeos") {
 224   is_android = false
 225   is_chromeos = true
 226   is_ios = false
 227   is_linux = true
 228   is_mac = false
 229   is_nacl = false
 230   is_posix = true
 231   is_win = false
 232 } else if (current_os == "nacl") {
 233   # current_os == "nacl" will be passed by the nacl toolchain definition.
 234   # It is not set by default or on the command line. We treat is as a
 235   # Posix variant.
 236   is_android = false
 237   is_chromeos = false
 238   is_ios = false
 239   is_linux = false
 240   is_mac = false
 241   is_nacl = true
 242   is_posix = true
 243   is_win = false
 244 } else if (current_os == "ios") {
 245   is_android = false
 246   is_chromeos = false
 247   is_ios = true
 248   is_linux = false
 249   is_mac = false
 250   is_nacl = false
 251   is_posix = true
 252   is_win = false
 253 } else if (current_os == "linux") {
 254   is_android = false
 255   is_chromeos = false
 256   is_ios = false
 257   is_linux = true
 258   is_mac = false
 259   is_nacl = false
 260   is_posix = true
 261   is_win = false
 262 }
 263
 264 # =============================================================================
 265 # SOURCES FILTERS
 266 # =============================================================================
 267 #
 268 # These patterns filter out platform-specific files when assigning to the
 269 # sources variable. The magic variable |sources_assignment_filter| is applied
 270 # to each assignment or appending to the sources variable and matches are
 271 # automatcally removed.
 272 #
 273 # Note that the patterns are NOT regular expressions. Only "*" and "\b" (path
 274 # boundary = end of string or slash) are supported, and the entire string
 275 # muct match the pattern (so you need "*.cc" to match all .cc files, for
 276 # example).
 277
 278 # DO NOT ADD MORE PATTERNS TO THIS LIST, see set_sources_assignment_filter call
 279 # below.
 280 sources_assignment_filter = []
 281 if (!is_posix) {
 282   sources_assignment_filter += [
 283     "*_posix.h",
 284     "*_posix.cc",
 285     "*_posix_unittest.h",
 286     "*_posix_unittest.cc",
 287     "*\bposix/*",
 288   ]
 289 }
 290 if (!is_win) {
 291   sources_assignment_filter += [
 292     "*_win.cc",
 293     "*_win.h",
 294     "*_win_unittest.cc",
 295     "*\bwin/*",
 296     "*.def",
 297     "*.rc",
 298   ]
 299 }
 300 if (!is_mac) {
 301   sources_assignment_filter += [
 302     "*_mac.h",
 303     "*_mac.cc",
 304     "*_mac.mm",
 305     "*_mac_unittest.h",
 306     "*_mac_unittest.cc",
 307     "*_mac_unittest.mm",
 308     "*\bmac/*",
 309     "*_cocoa.h",
 310     "*_cocoa.cc",
 311     "*_cocoa.mm",
 312     "*_cocoa_unittest.h",
 313     "*_cocoa_unittest.cc",
 314     "*_cocoa_unittest.mm",
 315     "*\bcocoa/*",
 316   ]
 317 }
 318 if (!is_ios) {
 319   sources_assignment_filter += [
 320     "*_ios.h",
 321     "*_ios.cc",
 322     "*_ios.mm",
 323     "*_ios_unittest.h",
 324     "*_ios_unittest.cc",
 325     "*_ios_unittest.mm",
 326     "*\bios/*",
 327   ]
 328 }
 329 if (!is_mac && !is_ios) {
 330   sources_assignment_filter += [ "*.mm" ]
 331 }
 332 if (!is_linux) {
 333   sources_assignment_filter += [
 334     "*_linux.h",
 335     "*_linux.cc",
 336     "*_linux_unittest.h",
 337     "*_linux_unittest.cc",
 338     "*\blinux/*",
 339   ]
 340 }
 341 if (!is_android) {
 342   sources_assignment_filter += [
 343     "*_android.h",
 344     "*_android.cc",
 345     "*_android_unittest.h",
 346     "*_android_unittest.cc",
 347     "*\bandroid/*",
 348   ]
 349 }
 350 if (!is_chromeos) {
 351   sources_assignment_filter += [
 352     "*_chromeos.h",
 353     "*_chromeos.cc",
 354     "*_chromeos_unittest.h",
 355     "*_chromeos_unittest.cc",
 356     "*\bchromeos/*",
 357   ]
 358 }
 359
 360 # DO NOT ADD MORE PATTERNS TO THIS LIST, see set_sources_assignment_filter call
 361 # below.
 362
 363 # Actually save this list.
 364 #
 365 # These patterns are executed for every file in the source tree of every run.
 366 # Therefore, adding more patterns slows down the build for everybody. We should
 367 # only add automatic patterns for configurations affecting hundreds of files
 368 # across many projects in the tree.
 369 #
 370 # Therefore, we only add rules to this list corresponding to platforms on the
 371 # Chromium waterfall.  This is not for non-officially-supported platforms
 372 # (FreeBSD, etc.) toolkits, (X11, GTK, etc.), or features. For these cases,
 373 # write a conditional in the target to remove the file(s) from the list when
 374 # your platform/toolkit/feature doesn't apply.
 375 set_sources_assignment_filter(sources_assignment_filter)
 376
 377 # =============================================================================
 378 # TARGET DEFAULTS
 379 # =============================================================================
 380 #
 381 # Set up the default configuration for every build target of the given type.
 382 # The values configured here will be automatically set on the scope of the
 383 # corresponding target. Target definitions can add or remove to the settings
 384 # here as needed.
 385
 386 # Holds all configs used for making native executables and libraries, to avoid
 387 # duplication in each target below.
 388 _native_compiler_configs = [
 389   "//build/config:feature_flags",
 390   "//build/config/compiler:compiler",
 391   "//build/config/compiler:compiler_arm_fpu",
 392   "//build/config/compiler:chromium_code",
 393   "//build/config/compiler:default_include_dirs",
 394   "//build/config/compiler:default_optimization",
 395   "//build/config/compiler:default_symbols",
 396   "//build/config/compiler:no_rtti",
 397   "//build/config/compiler:runtime_library",
 398 ]
 399 if (is_win) {
 400   _native_compiler_configs += [
 401     "//build/config/win:lean_and_mean",
 402     "//build/config/win:nominmax",
 403     "//build/config/win:sdk",
 404     "//build/config/win:unicode",
 405     "//build/config/win:winver",
 406   ]
 407 }
 408 if (current_os == "winrt_81" || current_os == "winrt_81_phone" ||
 409     current_os == "winrt_10") {
 410   _native_compiler_configs += [ "//build/config/win:target_winrt" ]
 411 }
 412 if (is_posix) {
 413   _native_compiler_configs += [
 414     "//build/config/gcc:no_exceptions",
 415     "//build/config/gcc:symbol_visibility_hidden",
 416   ]
 417 }
 418
 419 if (is_linux) {
 420   _native_compiler_configs += [ "//build/config/linux:sdk" ]
 421 } else if (is_mac) {
 422   _native_compiler_configs += [ "//build/config/mac:sdk" ]
 423 } else if (is_ios) {
 424 } else if (is_android) {
 425   _native_compiler_configs += [ "//build/config/android:sdk" ]
 426 }
 427
 428 if (is_clang && !is_nacl) {
 429   _native_compiler_configs += [
 430     "//build/config/clang:find_bad_constructs",
 431     "//build/config/clang:extra_warnings",
 432   ]
 433 }
 434
 435 # Debug/release-related defines.
 436 if (is_debug) {
 437   _native_compiler_configs += [ "//build/config:debug" ]
 438 } else {
 439   _native_compiler_configs += [ "//build/config:release" ]
 440 }
 441
 442 # Windows linker setup for EXEs and DLLs.
 443 if (is_win) {
 444   _windows_linker_configs = [
 445     "//build/config/win:default_incremental_linking",
 446     "//build/config/win:sdk_link",
 447     "//build/config/win:common_linker_setup",
 448
 449     # Default to console-mode apps. Most of our targets are tests and such
 450     # that shouldn't use the windows subsystem.
 451     "//build/config/win:console",
 452   ]
 453 }
 454
 455 # Executable defaults.
 456 _executable_configs =
 457     _native_compiler_configs + [ "//build/config:default_libs" ]
 458 if (is_win) {
 459   _executable_configs += _windows_linker_configs
 460 } else if (is_mac) {
 461   _executable_configs += [
 462     "//build/config/mac:mac_dynamic_flags",
 463     "//build/config/mac:mac_executable_flags",
 464   ]
 465 } else if (is_linux || is_android) {
 466   _executable_configs += [ "//build/config/gcc:executable_ldconfig" ]
 467   if (is_android) {
 468     _executable_configs += [ "//build/config/android:executable_config" ]
 469   }
 470 }
 471 set_defaults("executable") {
 472   configs = _executable_configs
 473 }
 474
 475 # Static library defaults.
 476 set_defaults("static_library") {
 477   configs = _native_compiler_configs
 478 }
 479
 480 # Shared library defaults (also for components in component mode).
 481 _shared_library_configs =
 482     _native_compiler_configs + [ "//build/config:default_libs" ]
 483 if (is_win) {
 484   _shared_library_configs += _windows_linker_configs
 485 } else if (is_mac) {
 486   _shared_library_configs += [ "//build/config/mac:mac_dynamic_flags" ]
 487 } else if (is_android) {
 488   # Strip native JNI exports from shared libraries by default. Binaries that
 489   # want this can remove this config.
 490   _shared_library_configs +=
 491       [ "//build/config/android:hide_native_jni_exports" ]
 492 }
 493 set_defaults("shared_library") {
 494   configs = _shared_library_configs
 495 }
 496 if (is_component_build) {
 497   set_defaults("component") {
 498     configs = _shared_library_configs
 499   }
 500 }
 501
 502 # Source set defaults (also for components in non-component mode).
 503 set_defaults("source_set") {
 504   configs = _native_compiler_configs
 505 }
 506 if (!is_component_build) {
 507   set_defaults("component") {
 508     configs = _native_compiler_configs
 509   }
 510 }
 511
 512 # Test defaults.
 513 set_defaults("test") {
 514   if (is_android) {
 515     configs = _shared_library_configs
 516   } else {
 517     configs = _executable_configs
 518   }
 519 }
 520
 521 # ==============================================================================
 522 # TOOLCHAIN SETUP
 523 # ==============================================================================
 524 #
 525 # Here we set the default toolchain, as well as the variable host_toolchain
 526 # which will identify the toolchain corresponding to the local system when
 527 # doing cross-compiles. When not cross-compiling, this will be the same as the
 528 # default toolchain.
 529
 530 if (is_win) {
 531   # On windows we use the same toolchain for host and target by default.
 532   if (is_clang) {
 533     host_toolchain = "//build/toolchain/win:clang_$current_cpu"
 534   } else {
 535     host_toolchain = "//build/toolchain/win:$current_cpu"
 536   }
 537
 538   if (current_os == "win") {
 539     set_default_toolchain("$host_toolchain")
 540   } else if (current_cpu == "x64") {  # WinRT x64
 541     set_default_toolchain("//build/toolchain/win:winrt_x64")
 542   } else if (current_cpu == "x86") {  # WinRT x86
 543     set_default_toolchain("//build/toolchain/win:winrt_x86")
 544   }
 545 } else if (is_android) {
 546   if (host_os == "linux") {
 547     # Use clang for the x86/64 Linux host builds.
 548     if (host_cpu == "x86" || host_cpu == "x64") {
 549       host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
 550     } else {
 551       host_toolchain = "//build/toolchain/linux:$host_cpu"
 552     }
 553   } else if (host_os == "mac") {
 554     host_toolchain = "//build/toolchain/mac:clang_$host_cpu"
 555   } else {
 556     assert(false, "Unknown host for android cross compile")
 557   }
 558   if (is_clang) {
 559     set_default_toolchain("//build/toolchain/android:clang_$current_cpu")
 560   } else {
 561     set_default_toolchain("//build/toolchain/android:$current_cpu")
 562   }
 563 } else if (is_linux) {
 564   if (is_clang) {
 565     host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
 566     set_default_toolchain("//build/toolchain/linux:clang_$current_cpu")
 567   } else {
 568     host_toolchain = "//build/toolchain/linux:$host_cpu"
 569     set_default_toolchain("//build/toolchain/linux:$current_cpu")
 570   }
 571   if (is_chromeos && cros_use_custom_toolchain) {
 572     set_default_toolchain("//build/toolchain/cros:target")
 573   }
 574 } else if (is_mac) {
 575   host_toolchain = "//build/toolchain/mac:clang_x64"
 576   set_default_toolchain(host_toolchain)
 577 } else if (is_ios) {
 578   host_toolchain = "//build/toolchain/mac:clang_x64"
 579   set_default_toolchain("//build/toolchain/mac:ios_clang_arm")
 580 } else if (is_nacl) {
 581   # TODO(GYP): This will need to change when we get NaCl working
 582   # on multiple platforms, but this whole block of code (how we define
 583   # host_toolchain) needs to be reworked regardless to key off of host_os
 584   # and host_cpu rather than the is_* variables.
 585   host_toolchain = "//build/toolchain/linux:clang_x64"
 586 }
 587
 588 # ==============================================================================
 589 # COMPONENT SETUP
 590 # ==============================================================================
 591
 592 if (is_component_build) {
 593   _component_mode = "shared_library"
 594 } else {
 595   _component_mode = "source_set"
 596 }
 597 template("component") {
 598   target(_component_mode, target_name) {
 599     forward_variables_from(invoker, "*")
 600
 601     # All shared libraries must have the sanitizer deps to properly link in
 602     # asan mode (this target will be empty in other cases).
 603     if (!defined(deps)) {
 604       deps = []
 605     }
 606     deps += [ "//build/config/sanitizers:deps" ]
 607   }
 608 }