content/browser/theme_helper_mac.mm

   1 // Copyright 2013 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "content/browser/theme_helper_mac.h"
   6
   7 #import <Cocoa/Cocoa.h>
   8
   9 #include "base/command_line.h"
  10 #include "base/mac/sdk_forward_declarations.h"
  11 #include "content/common/view_messages.h"
  12 #include "content/public/browser/browser_thread.h"
  13 #include "content/public/browser/notification_service.h"
  14 #include "content/public/browser/notification_types.h"
  15 #include "content/public/browser/render_process_host.h"
  16 #include "content/public/common/content_switches.h"
  17
  18 @interface ScrollbarPrefsObserver : NSObject
  19
  20 + (void)registerAsObserver;
  21 + (void)appearancePrefsChanged:(NSNotification*)notification;
  22 + (void)behaviorPrefsChanged:(NSNotification*)notification;
  23 + (void)notifyPrefsChangedWithRedraw:(BOOL)redraw;
  24
  25 @end
  26
  27 @implementation ScrollbarPrefsObserver
  28
  29 + (void)registerAsObserver {
  30   [[NSDistributedNotificationCenter defaultCenter]
  31       addObserver:self
  32          selector:@selector(appearancePrefsChanged:)
  33              name:@"AppleAquaScrollBarVariantChanged"
  34            object:nil
  35 suspensionBehavior:NSNotificationSuspensionBehaviorDeliverImmediately];
  36
  37   [[NSDistributedNotificationCenter defaultCenter]
  38       addObserver:self
  39          selector:@selector(behaviorPrefsChanged:)
  40              name:@"AppleNoRedisplayAppearancePreferenceChanged"
  41            object:nil
  42 suspensionBehavior:NSNotificationSuspensionBehaviorCoalesce];
  43
  44   // In single-process mode, renderers will catch these notifications
  45   // themselves and listening for them here may trigger the DCHECK in Observe().
  46   if ([NSScroller respondsToSelector:@selector(preferredScrollerStyle)] &&
  47       !base::CommandLine::ForCurrentProcess()->HasSwitch(
  48           switches::kSingleProcess)) {
  49     [[NSNotificationCenter defaultCenter]
  50         addObserver:self
  51            selector:@selector(behaviorPrefsChanged:)
  52                name:NSPreferredScrollerStyleDidChangeNotification
  53              object:nil];
  54   }
  55 }
  56
  57 + (void)appearancePrefsChanged:(NSNotification*)notification {
  58   [self notifyPrefsChangedWithRedraw:YES];
  59 }
  60
  61 + (void)behaviorPrefsChanged:(NSNotification*)notification {
  62   [self notifyPrefsChangedWithRedraw:NO];
  63 }
  64
  65 + (void)notifyPrefsChangedWithRedraw:(BOOL)redraw {
  66   DCHECK_CURRENTLY_ON(content::BrowserThread::UI);
  67   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
  68   [defaults synchronize];
  69
  70   content::ThemeHelperMac::SendThemeChangeToAllRenderers(
  71       [defaults floatForKey:@"NSScrollerButtonDelay"],
  72       [defaults floatForKey:@"NSScrollerButtonPeriod"],
  73       [defaults boolForKey:@"AppleScrollerPagingBehavior"],
  74       content::ThemeHelperMac::GetPreferredScrollerStyle(),
  75       redraw);
  76 }
  77
  78 @end
  79
  80 namespace content {
  81
  82 // static
  83 ThemeHelperMac* ThemeHelperMac::GetInstance() {
  84   return Singleton<ThemeHelperMac,
  85       LeakySingletonTraits<ThemeHelperMac> >::get();
  86 }
  87
  88 // static
  89 blink::ScrollerStyle ThemeHelperMac::GetPreferredScrollerStyle() {
  90   if (![NSScroller respondsToSelector:@selector(preferredScrollerStyle)])
  91     return blink::ScrollerStyleLegacy;
  92   return static_cast<blink::ScrollerStyle>([NSScroller preferredScrollerStyle]);
  93 }
  94
  95 // static
  96 void ThemeHelperMac::SendThemeChangeToAllRenderers(
  97     float initial_button_delay,
  98     float autoscroll_button_delay,
  99     bool jump_on_track_click,
 100     blink::ScrollerStyle preferred_scroller_style,
 101     bool redraw) {
 102   for (RenderProcessHost::iterator it(RenderProcessHost::AllHostsIterator());
 103        !it.IsAtEnd();
 104        it.Advance()) {
 105     it.GetCurrentValue()->Send(new ViewMsg_UpdateScrollbarTheme(
 106         initial_button_delay,
 107         autoscroll_button_delay,
 108         jump_on_track_click,
 109         preferred_scroller_style,
 110         redraw));
 111   }
 112 }
 113
 114 ThemeHelperMac::ThemeHelperMac() {
 115   [ScrollbarPrefsObserver registerAsObserver];
 116   registrar_.Add(this,
 117                  NOTIFICATION_RENDERER_PROCESS_CREATED,
 118                  NotificationService::AllSources());
 119 }
 120
 121 ThemeHelperMac::~ThemeHelperMac() {
 122 }
 123
 124 void ThemeHelperMac::Observe(int type,
 125                              const NotificationSource& source,
 126                              const NotificationDetails& details) {
 127   DCHECK_EQ(NOTIFICATION_RENDERER_PROCESS_CREATED, type);
 128
 129   DCHECK_CURRENTLY_ON(BrowserThread::UI);
 130   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
 131   [defaults synchronize];
 132
 133   RenderProcessHost* rph = Source<RenderProcessHost>(source).ptr();
 134   rph->Send(new ViewMsg_UpdateScrollbarTheme(
 135       [defaults floatForKey:@"NSScrollerButtonDelay"],
 136       [defaults floatForKey:@"NSScrollerButtonPeriod"],
 137       [defaults boolForKey:@"AppleScrollerPagingBehavior"],
 138       GetPreferredScrollerStyle(),
 139       false));
 140 }
 141
 142 }  // namespace content