device/usb/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(!is_android && !is_ios)
   6
   7 source_ids = "//third_party/usb_ids/usb.ids"
   8 generated_ids = "$target_gen_dir/usb_ids_gen.cc"
   9
  10 source_set("usb") {
  11   sources = [
  12     "usb_context.cc",
  13     "usb_context.h",
  14     "usb_descriptors.cc",
  15     "usb_descriptors.h",
  16     "usb_device_impl.cc",
  17     "usb_device_impl.h",
  18     "usb_device.h",
  19     "usb_device_filter.cc",
  20     "usb_device_filter.h",
  21     "usb_device_handle_impl.cc",
  22     "usb_device_handle_impl.h",
  23     "usb_device_handle.h",
  24     "usb_error.cc",
  25     "usb_error.h",
  26     "usb_ids.cc",
  27     "usb_ids.h",
  28     "usb_service.cc",
  29     "usb_service.h",
  30     "usb_service_impl.cc",
  31     "usb_service_impl.h",
  32     generated_ids,
  33   ]
  34
  35   deps = [
  36     ":usb_device_ids",
  37     "//base",
  38     "//base/third_party/dynamic_annotations",
  39     "//net",
  40     "//third_party/libusb",
  41   ]
  42
  43   if (is_linux) {
  44     deps += [ "//device/udev_linux" ]
  45   }
  46 }
  47
  48 action("usb_device_ids") {
  49   script = "//device/usb/tools/usb_ids.py"
  50   inputs = [
  51     source_ids,
  52   ]
  53   outputs = [
  54     generated_ids,
  55   ]
  56   args = [
  57     "-i",
  58     rebase_path(source_ids, root_build_dir),
  59     "-o",
  60     rebase_path(generated_ids, root_build_dir),
  61   ]
  62
  63   # Only the device_usb target can depend on us.
  64   visibility = [ ":usb" ]
  65 }