configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991-2024 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.69])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 # The explicit URL can be removed when autoconf > 2.69 is released.
  27 AC_INIT([GNU coreutils],
  28         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  29         [bug-coreutils@gnu.org],
  30         [coreutils],
  31         [https://www.gnu.org/software/coreutils/])
  32
  33 AC_CONFIG_SRCDIR([src/ls.c])
  34
  35 AC_CONFIG_AUX_DIR([build-aux])
  36 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  37
  38 AM_INIT_AUTOMAKE([1.11.2 dist-xz color-tests parallel-tests subdir-objects])
  39 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  40
  41 dnl POSIXCHECK is worthwhile for maintainers, but adds several seconds
  42 dnl (more than 10% execution time) to ./configure, with no benefit for
  43 dnl most users.  Using it to look for bugs requires:
  44 dnl   GNULIB_POSIXCHECK=1 autoreconf -f
  45 dnl   ./configure
  46 dnl   make
  47 dnl   make -C src clean
  48 dnl   make CFLAGS=-DGNULIB_POSIXCHECK=1
  49 dnl FIXME: Once we figure out how to avoid false positives, we should
  50 dnl have 'make my-distcheck' in dist-check.mk exercise this.
  51 m4_syscmd([test "${GNULIB_POSIXCHECK+set}" = set])
  52 m4_if(m4_sysval, [0], [], [dnl
  53 gl_ASSERT_NO_GNULIB_POSIXCHECK])
  54
  55 AC_PROG_CC
  56 AM_PROG_CC_C_O
  57 AC_PROG_CPP
  58 AC_PROG_RANLIB
  59 AC_PROG_EGREP
  60 AC_PROG_LN_S
  61 gl_EARLY
  62 gl_SET_CRYPTO_CHECK_DEFAULT([auto-gpl-compat])
  63 gl_INIT
  64 coreutils_MACROS
  65
  66 # These are safe, since 'sort', coreutils's only multithreaded app,
  67 # does not use the relevant modules.
  68 AC_DEFINE([GNULIB_EXCLUDE_SINGLE_THREAD], [1],
  69   [Define to 1 if apps call 'exclude' functions from a single thread.])
  70 AC_DEFINE([GNULIB_REGEX_SINGLE_THREAD], [1],
  71   [Define to 1 if apps call 'regex' functions from a single thread.])
  72 # Although 'sort' is multithreaded and can use these functions,
  73 # it uses them only from the main thread.
  74 AC_DEFINE([GNULIB_MBRTOWC_SINGLE_THREAD], [1],
  75   [Define to 1 if apps call mbrtowc, mbrtoc32, and 'regex' functions
  76    from a single thread.])
  77 # This is safe, since all apps set locale early.
  78 AC_DEFINE([GNULIB_WCHAR_SINGLE_LOCALE], [1],
  79   [Define to 1 if apps don't set the locale after calling
  80    locale-sensitive functions like mbrtowc and wcwidth.])
  81
  82 AC_DEFINE([GNULIB_MBRTOC32_REGULAR], [1],
  83   [Do not worry about rare encodings like CP864, EBCDIC, Johab, and Shift JIS
  84    that glibc does not support.])
  85
  86 # The test suite needs to know if we have a working perl.
  87 AM_CONDITIONAL([HAVE_PERL], [test "$gl_cv_prog_perl" != no])
  88
  89 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
  90 # ------------------------------------------------
  91 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
  92 # Otherwise, run RUN-IF-NOT-FOUND.
  93 AC_DEFUN([gl_GCC_VERSION_IFELSE],
  94   [AC_PREPROC_IFELSE(
  95     [AC_LANG_PROGRAM(
  96       [[
  97 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
  98 /* ok */
  99 #else
 100 # error "your version of gcc is older than $1.$2"
 101 #endif
 102       ]]),
 103     ], [$3], [$4])
 104   ]
 105 )
 106
 107 AC_ARG_ENABLE([single-binary],
 108   [AS_HELP_STRING([--enable-single-binary=[shebangs|symlinks]],
 109      [Compile all the tools in a single binary, reducing the overall size.
 110       When compiled this way, shebangs (default when enabled) or symlinks are
 111       installed for each tool that points to the single binary.])],
 112   [gl_single_binary=no ;
 113    case $enableval in
 114      yes) gl_single_binary=shebangs ;;
 115      no|shebangs|symlinks) gl_single_binary=$enableval ;;
 116      *)      AC_MSG_ERROR([bad value $enableval for single-binary option.
 117                            Options are: symlinks, shebangs, no.]) ;;
 118    esac],
 119   [gl_single_binary=no]
 120 )
 121 AC_ARG_ENABLE([single-binary-exceptions],
 122   [AS_HELP_STRING([--enable-single-binary-exceptions=PROG_LIST],
 123      [When used with --enable-single-binary, exclude the PROG_LIST from
 124       it, so these programs are compiled as separated files
 125       (comma-separated, default none))])],
 126   [gl_single_binary_exceptions=$enableval],
 127   [gl_single_binary_exceptions=]
 128 )
 129 if test "$gl_single_binary" = 'symlinks'; then
 130   if ! test "`echo ls | sed \"$program_transform_name\"`" = 'ls'; then
 131     AC_MSG_ERROR([program name transformations are not currently supported
 132                   with --enable-single-binary=symlinks.])
 133   fi
 134 fi
 135 AM_CONDITIONAL([SINGLE_BINARY], [test "$gl_single_binary" != no])
 136
 137 AC_ARG_ENABLE([bold-man-page-references],
 138   [AS_HELP_STRING([--disable-bold-man-page-references],
 139      [When generating man pages, do not apply bold style around any
 140       references like name(1) etc.])],
 141   [gl_bold_manpages=yes ;
 142    case $enableval in
 143      no|yes) gl_bold_manpages=$enableval ;;
 144      *)      AC_MSG_ERROR([bad value $enableval for bold-man-page-references.
 145                            Options are: yes, no.]) ;;
 146    esac],
 147   [gl_bold_manpages=yes]
 148 )
 149 AM_CONDITIONAL([BOLD_MAN_REFS], [test "$gl_bold_manpages" != no])
 150
 151 AC_ARG_ENABLE([gcc-warnings],
 152   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 153     [control generation of GCC warnings.  The TYPE 'no' disables
 154      warnings (default for non-developer builds); 'yes' generates
 155      cheap warnings if available (default for developer builds);
 156      'expensive' in addition generates expensive-to-compute warnings
 157      if available.])],
 158   [case $enableval in
 159      no|yes|expensive) ;;
 160      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 161    esac
 162    gl_gcc_warnings=$enableval],
 163   [
 164    # GCC provides fine-grained control over diagnostics which
 165    # is used in gnulib for example to suppress warnings from
 166    # certain sections of code.  So if this is available and
 167    # we're running from a git repo, then auto enable the warnings.
 168    gl_gcc_warnings=no
 169    gl_GCC_VERSION_IFELSE([4], [6],
 170                          [test -d "$srcdir"/.git \
 171                           && ! test -f "$srcdir"/.tarball-version \
 172                           && gl_gcc_warnings=yes])]
 173 )
 174
 175 # clang is unduly picky about some things, even by default.
 176 if test "$gl_cv_compiler_clang" = yes; then
 177   gl_WARN_ADD([-Wno-format-extra-args])
 178   gl_WARN_ADD([-Wno-implicit-const-int-float-conversion])
 179   gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 180 fi
 181
 182 if test $gl_gcc_warnings != no; then
 183   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 184   AC_SUBST([WERROR_CFLAGS])
 185
 186   ew=
 187   AS_IF([test $gl_gcc_warnings != expensive],
 188     [# -fanalyzer and related options slow GCC considerably.
 189      ew="$ew -fanalyzer -Wno-analyzer-malloc-leak"])
 190
 191   # This, $nw, is the list of warnings we disable.
 192   nw=$ew
 193   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
 194   nw="$nw -Waggregate-return"       # anachronistic
 195   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 196   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 197   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 198   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 199   nw="$nw -Wcast-qual"              # Too many warnings for now
 200   nw="$nw -Wconversion"             # Too many warnings for now
 201   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 202   nw="$nw -Wsign-conversion"        # Too many warnings for now
 203   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 204   nw="$nw -Wunreachable-code"       # Too many warnings for now
 205   nw="$nw -Wpadded"                 # Our structs are not padded
 206   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 207   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
 208   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 209   nw="$nw -Wswitch-enum"            # Too many warnings for now
 210   nw="$nw -Wswitch-default"         # Too many warnings for now
 211   nw="$nw -Wstack-protector"        # not worth working around
 212   nw="$nw -Wformat-overflow=2"      # False alarms due to GCC bug 110333
 213   nw="$nw -Wformat-truncation=2"    # False alarm in ls.c, probably related
 214   # things I might fix soon:
 215   nw="$nw -Wfloat-equal"            # sort.c, seq.c
 216   nw="$nw -Wmissing-format-attribute" # copy.c
 217   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
 218   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
 219   nw="$nw -Wvector-operation-performance" # warns about randperm.c
 220
 221   # Suppress noreturn warnings with single binaries; otherwise
 222   # GCC complains about the renamed 'main' not being declared noreturn
 223   # because 'main_exit' calls 'exit' when linting.
 224   if test "$gl_single_binary" != no; then
 225     nw="$nw -Wsuggest-attribute=noreturn"
 226   fi
 227
 228   # Using -Wstrict-overflow is a pain, but the alternative is worse.
 229   # For an example, see the code that provoked this report:
 230   # https://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
 231   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
 232
 233   gl_MANYWARN_ALL_GCC([ws])
 234   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 235   for w in $ws; do
 236     gl_WARN_ADD([$w])
 237   done
 238   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 239   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 240   gl_WARN_ADD([-Wno-format-nonliteral])
 241
 242   gl_WARN_ADD([-fdiagnostics-show-option])
 243   gl_WARN_ADD([-funit-at-a-time])
 244
 245   AC_SUBST([WARN_CFLAGS])
 246
 247   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 248   AH_VERBATIM([FORTIFY_SOURCE],
 249   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 250       without upsetting glibc 2.15+. */
 251    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 252    # define _FORTIFY_SOURCE 2
 253    #endif
 254   ])
 255   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 256
 257   # We use a slightly smaller set of warning options for lib/.
 258   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 259   nw=$ew
 260   nw="$nw -Wduplicated-branches"    # Too many false alarms
 261   nw="$nw -Wformat-truncation=2"
 262   nw="$nw -Wstrict-overflow"
 263   nw="$nw -Wuninitialized"
 264   nw="$nw -Wunused-macros"
 265   nw="$nw -Wmissing-prototypes"
 266   nw="$nw -Wold-style-definition"
 267   # FIXME: it may be easy to remove this, since it affects only one file:
 268   # the snprintf call at ftoastr.c:132.
 269   nw="$nw -Wdouble-promotion"
 270
 271   # FIXME: remove this line when gcc improves
 272   # FP in careadlinkat.c w/gcc 10.0.1 20200205
 273   gl_WARN_ADD([-Wno-return-local-addr])
 274
 275   # FIXME: remove this line when gcc improves
 276   # https://gcc.gnu.org/bugzilla/show_bug.cgi?id=88443
 277   gl_WARN_ADD([-Wno-stringop-overflow])
 278
 279   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 280   AC_SUBST([GNULIB_WARN_CFLAGS])
 281
 282   # For gnulib-tests, the set is slightly smaller still.
 283   nw=
 284   nw="$nw -Wstrict-prototypes"
 285   # It's not worth being this picky about test programs.
 286   nw="$nw -Wsuggest-attribute=const"
 287   nw="$nw -Wsuggest-attribute=format"
 288   nw="$nw -Wsuggest-attribute=pure"
 289   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 290                          [$GNULIB_WARN_CFLAGS], [$nw])
 291   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 292 fi
 293
 294 AC_FUNC_FORK
 295
 296 optional_bin_progs=
 297 AC_CHECK_FUNCS([chroot],
 298         gl_ADD_PROG([optional_bin_progs], [chroot]))
 299 AC_CHECK_FUNCS([gethostid],
 300         gl_ADD_PROG([optional_bin_progs], [hostid]))
 301 AC_CHECK_FUNCS([sigsuspend],
 302         gl_ADD_PROG([optional_bin_progs], [timeout]))
 303
 304 gl_WINSIZE_IN_PTEM
 305
 306 AC_MSG_CHECKING([whether localtime caches TZ])
 307 AC_CACHE_VAL([utils_cv_localtime_cache],
 308 [if test x$ac_cv_func_tzset = xyes; then
 309 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 310 #if STDC_HEADERS
 311 # include <stdlib.h>
 312 #endif
 313 extern char **environ;
 314 void unset_TZ (void)
 315 {
 316   char **from, **to;
 317   for (to = from = environ; (*to = *from); from++)
 318     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 319       to++;
 320 }
 321 int
 322 main ()
 323 {
 324   time_t now = time ((time_t *) 0);
 325   int hour_GMT0, hour_unset;
 326   if (putenv ("TZ=GMT0") != 0)
 327     return 1;
 328   hour_GMT0 = localtime (&now)->tm_hour;
 329   unset_TZ ();
 330   hour_unset = localtime (&now)->tm_hour;
 331   if (putenv ("TZ=PST8") != 0)
 332     return 1;
 333   if (localtime (&now)->tm_hour == hour_GMT0)
 334     return 1;
 335   unset_TZ ();
 336   if (localtime (&now)->tm_hour != hour_unset)
 337     return 1;
 338   return 0;
 339 }]])],
 340 [utils_cv_localtime_cache=no],
 341 [utils_cv_localtime_cache=yes],
 342 [# If we have tzset, assume the worst when cross-compiling.
 343 utils_cv_localtime_cache=yes])
 344 else
 345         # If we lack tzset, report that localtime does not cache TZ,
 346         # since we can't invalidate the cache if we don't have tzset.
 347         utils_cv_localtime_cache=no
 348 fi])dnl
 349 AC_MSG_RESULT([$utils_cv_localtime_cache])
 350 if test $utils_cv_localtime_cache = yes; then
 351   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 352 fi
 353
 354 # Find the library for dynamic loading of shared libraries.
 355 AC_SEARCH_LIBS([dlopen], [dl])
 356 AS_CASE([$ac_cv_search_dlopen],
 357   [no | 'none required'],
 358     [LIB_DL=],
 359   [*],
 360     [LIB_DL="$ac_cv_search_dlopen"])
 361 AC_SUBST([LIB_DL])
 362
 363 # Should 'sort' link libcrypto dynamically?
 364 AS_CASE([$LIB_CRYPTO],
 365   [-lcrypto],
 366     [# Check for dlopen and libcrypto dynamic linking in one program,
 367      # as there's little point to checking them separately.
 368      AC_CACHE_CHECK([for dlopen and whether libcrypto is linked dynamically],
 369        [utils_cv_dlopen_libcrypto],
 370        [utils_cv_dlopen_libcrypto=no
 371         saved_LIBS=$LIBS
 372         LIBS="$LIBS $LIB_DL $LIB_CRYPTO"
 373         AC_LINK_IFELSE(
 374           [AC_LANG_PROGRAM(
 375              [[#include <dlfcn.h>
 376                #include <openssl/sha.h>
 377                /* Use SHA512 rather than MD5 here to avoid deprecation warnings.
 378                   So need to check HAVE_OPENSSL_MD5.. with DLOPEN_LIBCRYPTO. */
 379              ]],
 380              [[return !(dlopen ("libcrypto.so", RTLD_LAZY | RTLD_GLOBAL)
 381                         && SHA512 (0, 0, 0));]])],
 382           [# readelf works with cross-builds; ldd works on more platforms.
 383            LIBCRYPTO_SONAME="`(readelf -d conftest$EXEEXT || ldd conftest$EXEEXT
 384                               ) 2>/dev/null |
 385                               sed -n 's/.*\(libcrypto\.so\.[[.0-9]]*\).*/\1/p'`"
 386            AS_CASE([$LIBCRYPTO_SONAME],
 387              [*libcrypto*],
 388                [utils_cv_dlopen_libcrypto=yes])])
 389         LIBS=$saved_LIBS])
 390      AS_CASE([$utils_cv_dlopen_libcrypto],
 391        [yes],
 392          [AC_DEFINE([DLOPEN_LIBCRYPTO], [1],
 393                     [Define to 1 if dlopen exists and libcrypto is
 394                      linked dynamically.])
 395           AC_DEFINE_UNQUOTED([LIBCRYPTO_SONAME], ["$LIBCRYPTO_SONAME"],
 396                              [versioned libcrypto])
 397          ])])
 398
 399 # macOS >= 10.12
 400 AC_CHECK_FUNCS([fclonefileat])
 401
 402 # Assume that if getattrat exists, it's compatible with Solaris 11.
 403 AC_CHECK_FUNCS([getattrat])
 404 if test $ac_cv_func_getattrat = yes; then
 405   LIB_NVPAIR=-lnvpair
 406   AC_SUBST([LIB_NVPAIR])
 407 fi
 408
 409 # glibc >= 2.28 and linux kernel >= 4.11
 410 AC_CHECK_FUNCS([statx])
 411
 412 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 413 AC_CHECK_FUNCS([initgroups])
 414 if test $ac_cv_func_initgroups = no; then
 415   AC_CHECK_LIB([os], [initgroups])
 416 fi
 417
 418 AC_CHECK_FUNCS([syslog])
 419 if test $ac_cv_func_syslog = no; then
 420   # syslog is not in the default libraries.  See if it's in some other.
 421   for lib in bsd socket inet; do
 422     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 423       LIBS="$LIBS -l$lib"; break])
 424   done
 425 fi
 426
 427 AC_CACHE_CHECK([for 3-argument setpriority function],
 428   [utils_cv_func_setpriority],
 429   [AC_LINK_IFELSE(
 430     [AC_LANG_PROGRAM(
 431        [[#include <sys/time.h>
 432          #include <sys/resource.h>
 433        ]],
 434        [[setpriority (0, 0, 0);]])],
 435     [utils_cv_func_setpriority=yes],
 436     [utils_cv_func_setpriority=no])])
 437 if test $utils_cv_func_setpriority = no; then
 438   AC_CHECK_FUNCS([nice])
 439 fi
 440 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 441 *yes*)
 442   gl_ADD_PROG([optional_bin_progs], [nice])
 443 esac
 444
 445 if test "$cross_compiling" = yes || test -c /dev/stdin <.; then
 446   AC_DEFINE([DEV_FD_MIGHT_BE_CHR], [1],
 447     [Define to 1 if /dev/std{in,out,err} and /dev/fd/N, if they exist, might be
 448      character-special devices whose minor device number is the file
 449      descriptor number, such as on Solaris.  Leave undefined if they are
 450      definitely the actual files.  This determination should be done after any
 451      symbolic links are followed.])
 452 fi
 453
 454 AC_DEFUN([coreutils_DUMMY_1],
 455 [
 456   AC_REQUIRE([gl_READUTMP])
 457   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 458     gl_ADD_PROG([optional_bin_progs], [who])
 459     gl_ADD_PROG([optional_bin_progs], [users])
 460     gl_ADD_PROG([optional_bin_progs], [pinky])
 461   fi
 462 ])
 463 coreutils_DUMMY_1
 464
 465 AC_SYS_POSIX_TERMIOS()
 466 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 467
 468 if test $ac_cv_sys_posix_termios = yes; then
 469   gl_ADD_PROG([optional_bin_progs], [stty])
 470
 471   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 472   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 473   [AC_EGREP_CPP([yes], [#include <termios.h>
 474 #ifdef IUCLC
 475 yes
 476 #endif], su_cv_sys_termios_needs_xopen_source=no,
 477    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 478 #include <termios.h>
 479 #ifdef IUCLC
 480 yes
 481 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 482    su_cv_sys_termios_needs_xopen_source=no))])
 483   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 484   test $su_cv_sys_termios_needs_xopen_source = yes &&
 485     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 486
 487   AC_MSG_CHECKING([c_line in struct termios])
 488   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 489   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 490                                       #define _XOPEN_SOURCE
 491                                      #endif
 492                                      #include <sys/types.h>
 493                                      #include <termios.h>
 494                                      struct termios t;
 495                                      int s = sizeof t.c_line;]])],
 496     [su_cv_sys_c_line_in_termios=yes],
 497     [su_cv_sys_c_line_in_termios=no])])
 498   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 499   test $su_cv_sys_c_line_in_termios = yes \
 500     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 501 fi
 502
 503 # FIXME: note that this macro appears above, too.
 504 # I'm leaving it here for now.  This whole thing needs to be modernized...
 505 gl_WINSIZE_IN_PTEM
 506
 507 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 508
 509 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 510    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 511   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 512   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 513   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 514 #ifdef WINSIZE_IN_PTEM
 515 # include <sys/stream.h>
 516 # include <sys/ptem.h>
 517 #endif
 518 #include <sys/ioctl.h>
 519 #include <sys/tty.h>
 520 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 521     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 522     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 523   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 524
 525   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 526       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 527                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 528 fi
 529
 530 # Build df only if there's a point to it.
 531 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 532   gl_ADD_PROG([optional_bin_progs], [df])
 533 fi
 534
 535 # Build stdbuf only if supported
 536 ac_save_CFLAGS=$CFLAGS
 537 ac_save_LDFLAGS=$LDFLAGS
 538 cu_save_c_werror_flag=$ac_c_werror_flag
 539 AC_LANG_WERROR
 540 # Detect warnings about ignored "constructor" attributes.
 541 gl_WARN_ADD([-Werror], [CFLAGS])
 542 gl_WARN_ADD([-errwarn], [CFLAGS])
 543 # Put this message here, after gl_WARN_ADD's chatter.
 544 AC_MSG_CHECKING([whether this system supports stdbuf])
 545 CFLAGS="-fPIC $CFLAGS"
 546 LDFLAGS="-shared $LDFLAGS"
 547 AC_CACHE_VAL([utils_cv_stdbuf_supported],[
 548 utils_cv_stdbuf_supported=no
 549 # Note we only LINK here rather than RUN to support cross compilation
 550 AC_LINK_IFELSE(
 551   [AC_LANG_PROGRAM([[
 552     static int stdbuf = 0;
 553
 554     void __attribute__ ((constructor))
 555     stdbuf_init (void)
 556     {
 557       stdbuf = 1;
 558     }]],[[
 559     if (stdbuf != 1)
 560       return 1;]])
 561   ],
 562   [utils_cv_stdbuf_supported=yes])])
 563 AC_MSG_RESULT([$utils_cv_stdbuf_supported])
 564 if test "$utils_cv_stdbuf_supported" = "yes" && test -z "$EXEEXT"; then
 565   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 566 fi
 567 CFLAGS=$ac_save_CFLAGS
 568 LDFLAGS=$ac_save_LDFLAGS
 569 ac_c_werror_flag=$cu_save_c_werror_flag
 570
 571 # Test compiler support for half precision floating point types (for od)
 572 AC_MSG_CHECKING([IEEE 16 bit floating point])
 573 AC_CACHE_VAL([utils_cv_ieee_16_bit_supported],[
 574  AC_RUN_IFELSE(
 575    [AC_LANG_SOURCE([[
 576      int
 577      main (void)
 578      {
 579         volatile _Float16 hf = 1;
 580         float f = hf;  /* Ensure compiler can promote to float.  */
 581         return !(f == 1.0f);
 582      }
 583   ]])
 584   ],[
 585     utils_cv_ieee_16_bit_supported=yes
 586   ],[
 587     utils_cv_ieee_16_bit_supported=no
 588   ],[
 589     utils_cv_ieee_16_bit_supported=no
 590   ])])
 591 AC_MSG_RESULT([$utils_cv_ieee_16_bit_supported])
 592 if test $utils_cv_ieee_16_bit_supported = yes; then
 593   AC_DEFINE([FLOAT16_SUPPORTED], [1], [IEEE 16 bit float supported])
 594 fi
 595
 596 AC_MSG_CHECKING([Brain 16 bit floating point])
 597 AC_CACHE_VAL([utils_cv_brain_16_bit_supported],[
 598  AC_RUN_IFELSE(
 599    [AC_LANG_SOURCE([[
 600      int
 601      main (void)
 602      {
 603         volatile __bf16 hf = 1;
 604         float f = hf;  /* Ensure compiler can promote to float.  */
 605         return !(f == 1.0f);
 606      }
 607   ]])
 608   ],[
 609     utils_cv_brain_16_bit_supported=yes
 610   ],[
 611     utils_cv_brain_16_bit_supported=no
 612   ],[
 613     utils_cv_brain_16_bit_supported=no
 614   ])])
 615 AC_MSG_RESULT([$utils_cv_brain_16_bit_supported])
 616 if test $utils_cv_brain_16_bit_supported = yes; then
 617   AC_DEFINE([BF16_SUPPORTED], [1], [Brain 16 bit float supported])
 618 fi
 619
 620 ac_save_CFLAGS=$CFLAGS
 621 CFLAGS="-mavx -mpclmul $CFLAGS"
 622 AC_MSG_CHECKING([if pclmul intrinsic exists])
 623 AC_CACHE_VAL([utils_cv_pclmul_intrinsic_exists],[
 624 AC_LINK_IFELSE(
 625   [AC_LANG_SOURCE([[
 626     #include <x86intrin.h>
 627
 628     int
 629     main (void)
 630     {
 631       __m128i a, b;
 632       a = _mm_clmulepi64_si128 (a, b, 0x00);
 633       a = _mm_shuffle_epi8 (a, b);
 634       return __builtin_cpu_supports ("pclmul");
 635     }
 636   ]])
 637   ],[
 638     utils_cv_pclmul_intrinsic_exists=yes
 639   ],[
 640     utils_cv_pclmul_intrinsic_exists=no
 641   ])])
 642 AC_MSG_RESULT([$utils_cv_pclmul_intrinsic_exists])
 643 if test $utils_cv_pclmul_intrinsic_exists = yes; then
 644   AC_DEFINE([USE_PCLMUL_CRC32], [1],
 645             [CRC32 calculation by pclmul hardware instruction enabled])
 646 fi
 647 AM_CONDITIONAL([USE_PCLMUL_CRC32],
 648                [test $utils_cv_pclmul_intrinsic_exists = yes])
 649 CFLAGS=$ac_save_CFLAGS
 650
 651 CFLAGS="-mavx2 $CFLAGS"
 652 AC_MSG_CHECKING([for avx2 intrinsics])
 653 AC_CACHE_VAL([utils_cv_avx2_intrinsic_exists],[
 654 AC_LINK_IFELSE(
 655   [AC_LANG_SOURCE([[
 656     #include <x86intrin.h>
 657
 658     int
 659     main (void)
 660     {
 661       __m256i matches = _mm256_setzero_si256 ();
 662       int mask = _mm256_movemask_epi8 (matches);
 663       int lines = __builtin_popcount (mask);
 664       return __builtin_cpu_supports ("avx2");
 665     }
 666   ]])
 667   ],[
 668     utils_cv_avx2_intrinsic_exists=yes
 669   ],[
 670     utils_cv_avx2_intrinsic_exists=no
 671   ])])
 672 AC_MSG_RESULT([$utils_cv_avx2_intrinsic_exists])
 673 if test $utils_cv_avx2_intrinsic_exists = yes; then
 674   AC_DEFINE([USE_AVX2_WC_LINECOUNT], [1], [Counting lines with AVX2 enabled])
 675 fi
 676 AM_CONDITIONAL([USE_AVX2_WC_LINECOUNT],
 677                [test $utils_cv_avx2_intrinsic_exists = yes])
 678
 679 CFLAGS=$ac_save_CFLAGS
 680
 681 ############################################################################
 682
 683 dnl Autogenerated by the 'gen-lists-of-programs.sh' auxiliary script.
 684 dnl Issue proper calls to the macros gl_INCLUDE_EXCLUDE_PROG and
 685 dnl gl_ADD_PROG (updating $optional_bin_progs), and generate the list
 686 dnl of coreutils programs to be built only upon explicit user request,
 687 dnl saving that list in the $no_install_progs_default shell variable.
 688 m4_include([m4/cu-progs.m4])
 689
 690 # Now that we know which programs will actually be built, determine
 691 # which optional helper progs should be compiled.
 692 # Note it adding to pkglibexec_PROGRAMS, $(transform) in src/local.mk
 693 # may need to be updated accordingly.
 694 case " $optional_bin_progs " in
 695   *' stdbuf '*) pkglibexec_PROGRAMS='src/libstdbuf.so';;
 696   *) pkglibexec_PROGRAMS='';;
 697 esac
 698
 699 man1_MANS=`
 700   for p in $optional_bin_progs; do
 701     # Change "ginstall.1" to "install.1".
 702     test $p = ginstall && p=install
 703     # Ignore the "[" program, since writing a portable make rule to
 704     # generate its manpage is not practical.
 705     dnl Use the autoconf-provided quadrigraph to represent "[",
 706     dnl otherwise we will incur in dreadful quoting issues.
 707     test x$p = x'@<:@' && continue
 708     echo "man/$p.1"
 709   done`
 710
 711 # Not installed by "make install", but must be built when creating
 712 # a distribution tarball.
 713 EXTRA_MANS=`for p in $no_install_progs_default $gl_no_install_prog; do
 714               echo man/$p.1
 715             done`
 716
 717 # Replace all the programs by the single binary and symlinks if specified.
 718 single_binary_progs=
 719 single_binary_libs=
 720 single_binary_deps=
 721 single_binary_install_type=
 722 if test "$gl_single_binary" != no; then
 723   man1_MANS="$man1_MANS man/coreutils.1"
 724   # Convert the list to a space separated list
 725   gl_single_binary_exceptions=`echo $gl_single_binary_exceptions | tr ',' ' '`
 726
 727   single_binary_progs=`echo $optional_bin_progs`
 728   optional_bin_progs="coreutils"
 729   for prog in $gl_single_binary_exceptions; do
 730     # Fail if requested to exclude a program than was not part of coreutils.
 731     case " $single_binary_progs " in
 732       *" $prog "*)
 733         gl_REMOVE_PROG([single_binary_progs], [$prog]) ;
 734         gl_ADD_PROG([optional_bin_progs], [$prog]) ;;
 735       *) AC_MSG_ERROR(['$prog' is not being compiled.]) ;;
 736     esac
 737   done
 738
 739   # single_binary_libs holds the list of libs required by the selected
 740   # programs, such as for example -lrt.
 741   single_binary_libs=`
 742     for p in $single_binary_progs; do
 743       # Convert '[' to '_'
 744       test x"$p" = x'@<:@' && p='_'
 745       printf '$(src_libsinglebin_%s_a_ldadd) ' "$p"
 746     done`
 747   # single_binary_deps holds the list of libsinglebin_*.a files that have the
 748   # compiled code of each selected program in a "library" format.
 749   single_binary_deps=`
 750     for p in $single_binary_progs; do
 751       # Convert '[' to '_'
 752       test x"$p" = x'@<:@' && p='_'
 753       printf 'src/libsinglebin_%s.a ' "$p"
 754     done`
 755   single_binary_install_type="$gl_single_binary"
 756 fi
 757 AC_SUBST([single_binary_progs], [$single_binary_progs])
 758 AC_SUBST([single_binary_libs], [$single_binary_libs])
 759 AC_SUBST([single_binary_deps], [$single_binary_deps])
 760 AC_SUBST([single_binary_install_type], [$single_binary_install_type])
 761
 762
 763 # The programs built and installed by "make && make install".
 764 # Since this is AC_SUBST'd, Automake won't be able to perform rewrite
 765 # with $(EXEEXT) appending on it, so we have to do it ourselves -- in
 766 # this case, only for $(bin_PROGRAMS).
 767 bin_PROGRAMS=`
 768   for p in $optional_bin_progs; do echo src/"$p"'$(EXEEXT)'; done`
 769
 770 # Normalize whitespace.
 771 man1_MANS=`echo $man1_MANS`
 772 EXTRA_MANS=`echo $EXTRA_MANS`
 773 bin_PROGRAMS=`echo $bin_PROGRAMS`
 774 pkglibexec_PROGS=`echo $pkglibexec_PROGRAMS`
 775
 776 AC_SUBST([bin_PROGRAMS])        AM_SUBST_NOTMAKE([bin_PROGRAMS])
 777 AC_SUBST([pkglibexec_PROGRAMS]) AM_SUBST_NOTMAKE([pkglibexec_PROGRAMS])
 778 AC_SUBST([man1_MANS])           AM_SUBST_NOTMAKE([man1_MANS])
 779 AC_SUBST([EXTRA_MANS])          AM_SUBST_NOTMAKE([EXTRA_MANS])
 780
 781 AC_SUBST([built_programs], [$optional_bin_progs])
 782
 783 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 784
 785 ############################################################################
 786
 787 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 788 # translatable strings, we must use need-formatstring-macros here.
 789 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 790 AM_GNU_GETTEXT_VERSION([0.19.2])
 791
 792 # For a test of uniq: it uses the $LOCALE_FR envvar.
 793 gt_LOCALE_FR
 794
 795 AC_CONFIG_FILES(
 796   Makefile
 797   po/Makefile.in
 798   gnulib-tests/Makefile
 799   )
 800 AC_OUTPUT