arch/parisc/lib/fixup.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  *  Copyright (C) 2004  Randolph Chung <tausq@debian.org>
   5  *
   6  *    This program is free software; you can redistribute it and/or modify
   7  *    it under the terms of the GNU General Public License as published by
   8  *    the Free Software Foundation; either version 2, or (at your option)
   9  *    any later version.
  10  *
  11  *    This program is distributed in the hope that it will be useful,
  12  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *    GNU General Public License for more details.
  15  *
  16  *    You should have received a copy of the GNU General Public License
  17  *    along with this program; if not, write to the Free Software
  18  *    Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19  *
  20  * Fixup routines for kernel exception handling.
  21  */
  22 #include <asm/asm-offsets.h>
  23 #include <asm/assembly.h>
  24 #include <asm/errno.h>
  25 #include <linux/linkage.h>
  26
  27 #ifdef CONFIG_SMP
  28         .macro  get_fault_ip t1 t2
  29         addil LT%__per_cpu_offset,%r27
  30         LDREG RT%__per_cpu_offset(%r1),\t1
  31         /* t2 = smp_processor_id() */
  32         mfctl 30,\t2
  33         ldw TI_CPU(\t2),\t2
  34 #ifdef CONFIG_64BIT
  35         extrd,u \t2,63,32,\t2
  36 #endif
  37         /* t2 = &__per_cpu_offset[smp_processor_id()]; */
  38         LDREGX \t2(\t1),\t2
  39         addil LT%exception_data,%r27
  40         LDREG RT%exception_data(%r1),\t1
  41         /* t1 = this_cpu_ptr(&exception_data) */
  42         add,l \t1,\t2,\t1
  43         /* t1 = t1->fault_ip */
  44         LDREG EXCDATA_IP(\t1), \t1
  45         .endm
  46 #else
  47         .macro  get_fault_ip t1 t2
  48         /* t1 = this_cpu_ptr(&exception_data) */
  49         addil LT%exception_data,%r27
  50         LDREG RT%exception_data(%r1),\t2
  51         /* t1 = t2->fault_ip */
  52         LDREG EXCDATA_IP(\t2), \t1
  53         .endm
  54 #endif
  55
  56         .level LEVEL
  57
  58         .text
  59         .section .fixup, "ax"
  60
  61         /* get_user() fixups, store -EFAULT in r8, and 0 in r9 */
  62 ENTRY(fixup_get_user_skip_1)
  63         get_fault_ip %r1,%r8
  64         ldo 4(%r1), %r1
  65         ldi -EFAULT, %r8
  66         bv %r0(%r1)
  67         copy %r0, %r9
  68 ENDPROC(fixup_get_user_skip_1)
  69
  70 ENTRY(fixup_get_user_skip_2)
  71         get_fault_ip %r1,%r8
  72         ldo 8(%r1), %r1
  73         ldi -EFAULT, %r8
  74         bv %r0(%r1)
  75         copy %r0, %r9
  76 ENDPROC(fixup_get_user_skip_2)
  77
  78         /* put_user() fixups, store -EFAULT in r8 */
  79 ENTRY(fixup_put_user_skip_1)
  80         get_fault_ip %r1,%r8
  81         ldo 4(%r1), %r1
  82         bv %r0(%r1)
  83         ldi -EFAULT, %r8
  84 ENDPROC(fixup_put_user_skip_1)
  85
  86 ENTRY(fixup_put_user_skip_2)
  87         get_fault_ip %r1,%r8
  88         ldo 8(%r1), %r1
  89         bv %r0(%r1)
  90         ldi -EFAULT, %r8
  91 ENDPROC(fixup_put_user_skip_2)
  92