arch/s390/kernel/relocate_kernel.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Copyright IBM Corp. 2005
   4  *
   5  * Author(s): Rolf Adelsberger,
   6  *            Heiko Carstens <heiko.carstens@de.ibm.com>
   7  *
   8  */
   9
  10 #include <linux/linkage.h>
  11 #include <asm/page.h>
  12 #include <asm/sigp.h>
  13
  14 /*
  15  * moves the new kernel to its destination...
  16  * %r2 = pointer to first kimage_entry_t
  17  * %r3 = start address - where to jump to after the job is done...
  18  *
  19  * %r5 will be used as temp. storage
  20  * %r6 holds the destination address
  21  * %r7 = PAGE_SIZE
  22  * %r8 holds the source address
  23  * %r9 = PAGE_SIZE
  24  *
  25  * 0xf000 is a page_mask
  26  */
  27
  28         .text
  29 ENTRY(relocate_kernel)
  30                 basr    %r13,0          # base address
  31         .base:
  32                 stctg   %c0,%c15,ctlregs-.base(%r13)
  33                 stmg    %r0,%r15,gprregs-.base(%r13)
  34                 lghi    %r0,3
  35                 sllg    %r0,%r0,31
  36                 stg     %r0,0x1d0(%r0)
  37                 la      %r0,.back_pgm-.base(%r13)
  38                 stg     %r0,0x1d8(%r0)
  39                 la      %r1,load_psw-.base(%r13)
  40                 mvc     0(8,%r0),0(%r1)
  41                 la      %r0,.back-.base(%r13)
  42                 st      %r0,4(%r0)
  43                 oi      4(%r0),0x80
  44                 lghi    %r0,0
  45                 diag    %r0,%r0,0x308
  46         .back:
  47                 lhi     %r1,1           # mode 1 = esame
  48                 sigp    %r1,%r0,SIGP_SET_ARCHITECTURE # switch to esame mode
  49                 sam64                   # switch to 64 bit addressing mode
  50                 basr    %r13,0
  51         .back_base:
  52                 oi      have_diag308-.back_base(%r13),0x01
  53                 lctlg   %c0,%c15,ctlregs-.back_base(%r13)
  54                 lmg     %r0,%r15,gprregs-.back_base(%r13)
  55                 j       .top
  56         .back_pgm:
  57                 lmg     %r0,%r15,gprregs-.base(%r13)
  58         .top:
  59                 lghi    %r7,PAGE_SIZE   # load PAGE_SIZE in r7
  60                 lghi    %r9,PAGE_SIZE   # load PAGE_SIZE in r9
  61                 lg      %r5,0(%r2)      # read another word for indirection page
  62                 aghi    %r2,8           # increment pointer
  63                 tml     %r5,0x1         # is it a destination page?
  64                 je      .indir_check    # NO, goto "indir_check"
  65                 lgr     %r6,%r5         # r6 = r5
  66                 nill    %r6,0xf000      # mask it out and...
  67                 j       .top            # ...next iteration
  68         .indir_check:
  69                 tml     %r5,0x2         # is it a indirection page?
  70                 je      .done_test      # NO, goto "done_test"
  71                 nill    %r5,0xf000      # YES, mask out,
  72                 lgr     %r2,%r5         # move it into the right register,
  73                 j       .top            # and read next...
  74         .done_test:
  75                 tml     %r5,0x4         # is it the done indicator?
  76                 je      .source_test    # NO! Well, then it should be the source indicator...
  77                 j       .done           # ok, lets finish it here...
  78         .source_test:
  79                 tml     %r5,0x8         # it should be a source indicator...
  80                 je      .top            # NO, ignore it...
  81                 lgr     %r8,%r5         # r8 = r5
  82                 nill    %r8,0xf000      # masking
  83         0:      mvcle   %r6,%r8,0x0     # copy PAGE_SIZE bytes from r8 to r6 - pad with 0
  84                 jo      0b
  85                 j       .top
  86         .done:
  87                 sgr     %r0,%r0         # clear register r0
  88                 la      %r4,load_psw-.base(%r13)        # load psw-address into the register
  89                 o       %r3,4(%r4)      # or load address into psw
  90                 st      %r3,4(%r4)
  91                 mvc     0(8,%r0),0(%r4) # copy psw to absolute address 0
  92                 tm      have_diag308-.base(%r13),0x01
  93                 jno     .no_diag308
  94                 diag    %r0,%r0,0x308
  95         .no_diag308:
  96                 sam31                   # 31 bit mode
  97                 sr      %r1,%r1         # erase register r1
  98                 sr      %r2,%r2         # erase register r2
  99                 sigp    %r1,%r2,SIGP_SET_ARCHITECTURE # set cpuid to zero
 100                 lpsw    0               # hopefully start new kernel...
 101
 102                 .align  8
 103         load_psw:
 104                 .long   0x00080000,0x80000000
 105         ctlregs:
 106                 .rept   16
 107                 .quad   0
 108                 .endr
 109         gprregs:
 110                 .rept   16
 111                 .quad   0
 112                 .endr
 113         have_diag308:
 114                 .byte   0
 115                 .align  8
 116         relocate_kernel_end:
 117         .align 8
 118         .globl  relocate_kernel_len
 119         relocate_kernel_len:
 120                 .quad   relocate_kernel_end - relocate_kernel