configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Copyright (C) 1992-2019, 2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of DejaGnu.
   6 dnl
   7 dnl DejaGnu is free software; you can redistribute it and/or modify it
   8 dnl under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 3 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl DejaGnu is distributed in the hope that it will be useful, but
  13 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 dnl General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with DejaGnu; if not, write to the Free Software Foundation,
  19 dnl Inc., 51 Franklin Street - Fifth Floor, Boston, MA 02110-1301, USA.
  20
  21 AC_PREREQ(2.50)
  22 AC_INIT([GNU DejaGnu], 1.6.3-git, [bug-dejagnu@gnu.org])
  23 AM_INIT_AUTOMAKE([1.14 subdir-objects])
  24 AM_MAINTAINER_MODE
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_AWK
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_PROG_INSTALL
  31 AC_EXEEXT
  32
  33 if test -z "$AWK"; then
  34   AC_MSG_ERROR([AWK not installed])
  35 fi
  36
  37 dnl Search for expect.
  38 AC_PATH_PROG([EXPECT], [expect])
  39 if test -z $ac_cv_path_EXPECT ; then
  40    AC_MSG_ERROR([unable to locate expect])
  41 fi
  42
  43 dnl Check the Tcl version is >= 8.5.
  44 AC_MSG_CHECKING([Tcl version 8.5 or greater])
  45 AC_CACHE_VAL(ac_cv_dg_tcl_modern,[
  46   ac_cv_dg_tcl_modern=`$EXPECT << EOF
  47 if @<:@ expr \\${tcl_version} >= 8.5 @:>@ then { puts yes } else { puts no }
  48 EOF`
  49 ])
  50 if test x${ac_cv_dg_tcl_modern} = xyes ; then
  51   AC_MSG_RESULT(${ac_cv_dg_tcl_modern})
  52 else
  53   AC_MSG_ERROR([Tcl 8.5 or greater is required])
  54 fi
  55
  56 dnl Provide an empty global site file (/dev/null) as default.
  57 if test x"$DEJAGNU" = x
  58 then
  59   DEJAGNU="/dev/null"
  60 fi
  61 AC_SUBST(DEJAGNU)
  62
  63 # See what branch we're in
  64 # FIXME: this will need to deal with a release branch and
  65 # do something different
  66 BRANCH=$(cd ${srcdir} && git branch | grep '^\*' | cut -d ' ' -f 2)
  67 AC_SUBST(BRANCH)
  68
  69 AC_OUTPUT([Makefile])