create a graph-includes.report file to hold deps not found

[deps.git] / graph-includes

#!/usr/bin/env perl

# graph-includes - create a graphviz graph of source-files
# dependencies, with an emphasis on getting usable graphs even for
# large projects

# (c) 2005 Yann Dirson <ydirson@altern.org>
# Distributed under version 2 of the GNU GPL.

use warnings;
use strict;

use Getopt::Long;
use graphincludes::params;

package foo;
our $a=0;
package main;
$a=1;
#FIXME: also set arrow head
our $paperparams='-Gnodesep=0.1 -Granksep=0.1 -Nfontsize=5 -Efontsize=5';
our %paper = (
              a4     => '11.6,8.2',
              a3     => '16.5,11.6',
              letter => '11,8.5',
             );

our $showalldeps=0;
our $class='default';
our (@colors);
our ($outfile, $prefixstrip, $paper);

our $usage = <<EOF;
Usage: $0 [options] src/*.[ch]
Options:
    --class {default|uniqueincludes|<your-own-class>}
                           Select "class" of source code
    -I <directory>         Adds a directory to the path where to look for include files
    --prefixstrip <prefix> Strip <prefix> (eg. "src/") from filenames in the graph
    --group <min>-<max>    Draw file groups of levels <min> through <max> (default: 1 1)
    --color <n>:<label>=<color>[,<label>=<color>...]
                           Use specified colors to show members of level-<n> group labelled <label>
    --alldeps              Do not apply transitive reduction to the graph

    --showdropped          Show in special color edges dropped during transitive reduction
    --focus <node-label>   Like -showdropped but only for edges starting from given node

    --output <outfile>.<fmt>
                           Format to output file, using <fmt> as target format

    --verbose              Show progress
    --verbose              Show details of ignored include directives
    --debug                Loads of debuging output

    --help                 This help text
EOF

our @colspecs;

GetOptions ('alldeps' => \$showalldeps,
            'showdropped' => \$graphincludes::params::showdropped,

            'focus=s' => \@graphincludes::params::focus,
            'class=s' => \$class,

            'I=s'     => \@graphincludes::params::inclpath,

            'group=s' => sub {
              my (undef, $range) = @_;
              ($graphincludes::params::minshow, $graphincludes::params::maxshow) = split /-/, $range;
            },
            'color=s@' => sub {
              my (undef, $colspec) = @_;
              my @temp = split /:/, $colspec;
              push @colspecs, [$temp[1], $temp[2]];
            },
            'output=s' => \$outfile,
            'paper=s'  => \$paper,

            'prefixstrip=s' => \$prefixstrip,

            'verbose+' => \$graphincludes::params::verbose,
            'debug' => \$graphincludes::params::debug,
            'help' => sub { print $usage; exit 0; },

           ) or die "Could not parse command-line: $!";

# deal with non-default output formats

our $dotflags = '';
our $outputformat;

if (defined $paper) {
  die "Unkown paper size \`$paper'" unless defined $paper{$paper};
  # paper output format is postscript on stdout unless otherwise specified
  $outputformat = 'ps';
  $dotflags .= " $paperparams -Gpage=" . $paper{$paper};
}

if (defined $outfile) {
  $dotflags .= " -o $outfile";

  $outfile =~ m/.*\.([^.]+)$/ or die "cannot guess output format";
  $outputformat = $1;
}

$dotflags .= " -T$outputformat" if defined $outputformat;

if ($dotflags ne '') {
  print STDERR "Running through \`dot $dotflags'\n" if $graphincludes::params::verbose;
  open STDOUT, "| dot $dotflags";
}

# create a project with specified files
our $classmodule = "graphincludes::project::" . $class;
eval "require $classmodule" or die "cannot locate $classmodule in " . join ':', @INC;
our $project = ($classmodule)->new(prefixstrip => $prefixstrip,
                                   files       => \@ARGV);
$project->init();

@colors = $project->defaultcolors();
foreach my $colspec (@colspecs) {
  foreach my $coldef (split /,/, $colspec->[2]) {
    my @coldef = split /=/, $coldef;
    $colors[$colspec->[1]]->{$coldef[0]} = $coldef[1];
  }
}

# maybe get rid of shortcut deps (transitive reduction)
$project->reduce() unless ($showalldeps);


# print graph

print "strict digraph dependencies {\nrankdir=LR;\n";

sub sprintnode {
  my ($file, $min, $max) = @_;
  my $node = $project->filelabel($file,$max);
  if (!defined $node and $max > $min) {
    return sprintnode($file, $min, $max-1);
  } elsif ($min == $max) {
    my $fill='';
    $fill=",style=filled,fillcolor=" . $colors[2]->{$project->filelabel($file,2)}
      if defined $colors[2] and defined $project->filelabel($file,2) and
        defined $colors[2]->{$project->filelabel($file,2)};
    return $project->{NODEIDS}->{$node} . " [label=\"$node\"" . $fill . "];";
  } else {
    return "subgraph \"cluster $node\" {" . sprintnode($file, $min, $max-1) . '}';
  }
}

foreach my $file (@{$project->{FILES}}) {
  print sprintnode($file, $graphincludes::params::minshow, $graphincludes::params::maxshow), "\n";
}

foreach my $file (keys %{$project->{DEPS}}) {
  foreach my $dest (@{$project->{DEPS}->{$file}}) {
    print "$file -> $dest";
    my $special = $project->special_edge($file, $dest);
    print " [$special]" if defined $special;
    print ";\n";
  }
}

print "}\n";


# print report

our $report = 'graph-includes.report';
$report = $outfile . $report if defined $outfile;
open REPORT, ">$report" or die "cannot open $report for writing: $!";
print REPORT "    Graph-includes report\n";
print REPORT "    =====================\n\n";

print REPORT "Declared dependencies not found:\n";
print REPORT "--------------------------------\n\n";
for my $dep (sort keys %{$project->{REPORT}}) {
  print REPORT " $dep\n";
  for my $src (@{$project->{REPORT}->{$dep}}) {
    print REPORT "  from $src\n";
  }
}
close REPORT;

# wait for dot if needed
if ($dotflags ne '') {
  close STDOUT;
  wait;
}