extra/crontab/crontab.factor

   1 ! Copyright (C) 2018 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors arrays ascii assocs calendar calendar.english
   5 calendar.private combinators io kernel literals locals math
   6 math.order math.parser math.ranges sequences splitting ;
   7
   8 IN: crontab
   9
  10 :: parse-value ( value quot: ( value -- value' ) seq -- value )
  11     value {
  12         { [ CHAR: , over member? ] [
  13             "," split [ quot seq parse-value ] map concat ] }
  14         { [ dup "*" = ] [ drop seq ] }
  15         { [ CHAR: / over member? ] [
  16             "/" split1 [ quot seq parse-value 0 over length 1 - ] dip
  17             string>number <range> swap nths ] }
  18         { [ CHAR: - over member? ] [
  19             "-" split1 quot bi@ [a,b] ] }
  20         [ quot call 1array ]
  21     } cond ; inline recursive
  22
  23 : parse-day ( str -- n )
  24     dup string>number [ ] [
  25         >lower $[ day-abbreviations3 [ >lower ] map ] index
  26     ] ?if ;
  27
  28 : parse-month ( str -- n )
  29     dup string>number [ ] [
  30         >lower $[ month-abbreviations [ >lower ] map ] index
  31     ] ?if ;
  32
  33 TUPLE: cronentry minutes hours days months days-of-week command ;
  34
  35 CONSTANT: aliases H{
  36     { "@yearly"   "0 0 1 1 *" }
  37     { "@annually" "0 0 1 1 *" }
  38     { "@monthly"  "0 0 1 * *" }
  39     { "@weekly"   "0 0 * * 0" }
  40     { "@daily"    "0 0 * * *" }
  41     { "@midnight" "0 0 * * *" }
  42     { "@hourly"   "0 * * * *" }
  43 }
  44
  45 : parse-cronentry ( entry -- cronentry )
  46     " " split1 [ aliases ?at drop ] dip " " glue
  47     " " split1 " " split1 " " split1 " " split1 " " split1 {
  48         [ [ string>number ] T{ range f 0 60 1 } parse-value ]
  49         [ [ string>number ] T{ range f 0 24 1 } parse-value ]
  50         [ [ string>number ] T{ range f 0 31 1 } parse-value ]
  51         [ [ parse-month ] T{ range f 0 12 1 } parse-value ]
  52         [ [ parse-day ] T{ range f 0 7 1 } parse-value ]
  53         [ ]
  54     } spread cronentry boa ;
  55
  56 :: next-time-after ( cronentry timestamp -- )
  57
  58     timestamp month>> :> month
  59     cronentry months>> [ month >= ] find nip [
  60         dup month = [ drop f ] [ timestamp month<< t ] if
  61     ] [
  62         timestamp cronentry months>> first >>month 1 +year
  63     ] if* [ cronentry timestamp next-time-after ] when
  64
  65     timestamp hour>> :> hour
  66     cronentry hours>> [ hour >= ] find nip [
  67         dup hour = [ drop f ] [
  68             timestamp hour<< 0 timestamp minute<< t
  69         ] if
  70     ] [
  71         timestamp cronentry hours>> first >>hour 1 +day
  72     ] if* [ cronentry timestamp next-time-after ] when
  73
  74     timestamp minute>> :> minute
  75     cronentry minutes>> [ minute >= ] find nip [
  76         dup minute = [ drop f ] [ timestamp minute<< t ] if
  77     ] [
  78         timestamp cronentry minutes>> first >>minute 1 +hour
  79     ] if* [ cronentry timestamp next-time-after ] when
  80
  81     timestamp day-of-week :> weekday
  82     cronentry days-of-week>> [ weekday >= ] find nip [
  83         cronentry days-of-week>> first 7 +
  84     ] unless* weekday -
  85
  86     timestamp day>> :> day
  87     cronentry days>> [ day >= ] find nip [
  88         day -
  89     ] [
  90         timestamp 1 months time+
  91         cronentry days>> first >>day
  92         day-of-year timestamp day-of-year -
  93     ] if*
  94
  95     min [
  96         timestamp swap +day drop
  97         cronentry timestamp next-time-after
  98     ] unless-zero ;
  99
 100 : next-time ( cronentry -- timestamp )
 101     now 0 >>second [ next-time-after ] keep ;
 102
 103 : parse-crontab ( -- entries )
 104     lines [ [ f ] [ parse-cronentry ] if-empty ] map harvest ;