core/configure.ac

   1 ################################################################################
   2 # autoconf file for generating the splashutils' configure file.
   3 #
   4 # Copyright (c) 2006-2007, Michal Januszewski <spock@gentoo.org>
   5 # Copyright (c) 2007, Paul Bender <pebender@gmail.com>
   6 #
   7 # This file is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 ################################################################################
  17
  18 AC_INIT([splashutils], [1.5.4.4])
  19
  20 AC_SUBST([libfbsplash_version], [1:0:0])
  21 AC_SUBST([libfbsplashrender_version], [1:0:0])
  22
  23 AM_INIT_AUTOMAKE([1.10 -Wno-portability])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_PREREQ(2.59)
  27 AC_PROG_CC
  28 AC_PROG_INSTALL
  29 AC_PROG_LIBTOOL
  30 AC_PROG_MKDIR_P
  31 AC_PROG_LN_S
  32 AC_PROG_SED
  33
  34 AS_IF(
  35   [test "x${BUILD_CC}" = "x" && test "x${build_alias}" != "x"],
  36   [AC_CHECK_PROG([BUILD_CC], [${build_alias}-gcc], [${build_alias}-gcc])]
  37 )
  38 AS_IF(
  39   [test "x${BUILD_CC}" = "x"],
  40   [AC_CHECK_PROG([BUILD_CC], [gcc], [gcc])]
  41 )
  42 AS_IF(
  43   [test "x${BUILD_CC}" = "x"],
  44   [AC_CHECK_PROG([BUILD_CC], [cc], [cc])]
  45 )
  46 AS_IF(
  47   [test "x${BUILD_CC}" = "x"],
  48   [BUILD_CC="\$(CC)"]
  49 )
  50
  51 AC_PREFIX_DEFAULT([/usr])
  52
  53 AC_ARG_ENABLE([debug],
  54   AS_HELP_STRING([--enable-debug], [do not strip files]),
  55   [
  56     AS_CASE(["${enableval}"],
  57       [yes], [config_debug="yes"],
  58       [no],  [config_debug="no"],
  59              [AC_MSG_ERROR([bad value '${enableval}' for --enable-debug])]
  60     )
  61   ],
  62   [config_debug="no"]
  63 )
  64 AM_CONDITIONAL([CONFIG_DEBUG], [test "x${config_debug}" = "xyes"])
  65
  66 AC_ARG_ENABLE([klibc-shared],
  67   AS_HELP_STRING([--enable-klibc-shared], [link to shared klibc]),
  68   [
  69     AS_CASE(["${enableval}"],
  70         [yes], [config_klibc_shared="yes"],
  71         [no],  [config_klibc_shared="no"],
  72                [AC_MSG_ERROR([bad value '${enableval}' for --enable-klibc-shared])]
  73     )
  74   ],
  75   [config_klibc_shared="no"]
  76 )
  77 AM_CONDITIONAL([CONFIG_KLIBC_SHARED], [test "x${config_klibc_shared}" = "xyes"])
  78
  79 AC_ARG_ENABLE([static-binaries],
  80   AC_HELP_STRING([--disable-static-binaries], [do not build any statically linked binaries]),
  81   [
  82     AS_CASE(["${enableval}"],
  83       [yes], [config_static_binaries="yes"],
  84       [no],  [config_static_binaries="no"],
  85              [AC_MSG_ERROR([bad value '${enableval}' for --disable-static-binaries])]
  86     )
  87   ],
  88   [config_static_binaries="yes"]
  89 )
  90 AM_CONDITIONAL([CONFIG_STATIC_BINARIES], [test "x${config_static_binaries}" = "xyes"])
  91 AS_IF(
  92   [test "x${config_static_binaries}" = "xyes"],
  93   [AC_DEFINE([CONFIG_STATIC_BINARIES], [1], [Define to 1 to disable building of statically linked binaries.])]
  94 )
  95
  96 AC_ARG_ENABLE([deprecated],
  97   AC_HELP_STRING([--enable-deprecated], [include support for deprecated features]),
  98   [
  99     AS_CASE(["${enableval}"],
 100       [yes], [config_deprecated="yes"],
 101       [no],  [config_deprecated="no"],
 102              [AC_MSG_ERROR([bad value '${enableval}' for --enable-deprecated])]
 103     )
 104   ],
 105   [config_deprecated="no"]
 106 )
 107 AM_CONDITIONAL([CONFIG_DEPRECATED], [test "x${config_deprecated}" = "xyes"])
 108 AS_IF(
 109   [test "x${config_deprecated}" = "xyes"],
 110   [AC_DEFINE([CONFIG_DEPRECATED], [1], [Define to 1 to include support for deprecated features.])]
 111 )
 112
 113 AC_ARG_ENABLE([fbcondecor],
 114   AC_HELP_STRING([--disable-fbcondecor], [exclude support for fbcondecor]),
 115   [
 116     AS_CASE(["${enableval}"],
 117        [yes], [config_fbcondecor="yes"],
 118        [no],  [config_fbcondecor="no"],
 119               [AC_MSG_ERROR([bad value '${enableval}' for --enable-fbcondecor])]
 120     )
 121   ],
 122   [config_fbcondecor="yes"]
 123 )
 124 AM_CONDITIONAL([CONFIG_FBCON_DECOR], [test "x${config_fbcondecor}" = "xyes"])
 125 AS_IF(
 126   [test "x${config_fbcondecor}" = "xyes"],
 127   [AC_DEFINE([CONFIG_FBCON_DECOR], [1], [Define to 1 to include support for fbcondecor (previously called fbsplash).])]
 128 )
 129
 130 AC_ARG_ENABLE([helper],
 131   AC_HELP_STRING([--disable-helper], [do not build kernel helper]),
 132   [
 133     AS_CASE(["${enableval}"],
 134       [yes], [config_helper="yes"],
 135       [no],  [config_helper="no"],
 136              [AC_MSG_ERROR([bad value '${enableval}' for --enable-helper])]
 137     )
 138   ],
 139   [config_helper="yes"]
 140 )
 141 AM_CONDITIONAL([CONFIG_HELPER], [test "x${config_helper}" = "xyes"])
 142 AS_IF(
 143   [test "x${config_helper}" = "xyes"],
 144   [AC_DEFINE([CONFIG_HELPER], [1], [Define to 1 to build kernel helper.])]
 145 )
 146
 147 AC_ARG_ENABLE([misc],
 148   AC_HELP_STRING([--enable-misc], [build misc programs]),
 149   [
 150     AS_CASE(["${enableval}"],
 151       [yes], [config_misc="yes"],
 152       [no],  [config_misc="no"],
 153              [AC_MSG_ERROR([bad value '${enableval}' for --enable-misc])]
 154     )
 155   ],
 156   [config_misc="no"]
 157 )
 158 AM_CONDITIONAL([CONFIG_MISC], [test "x${config_misc}" = "xyes"])
 159 AS_IF(
 160   [test "x${config_misc}" = "xyes"],
 161   [AC_DEFINE([CONFIG_MISC], [1], [Define to 1 to build misc programs.])]
 162 )
 163
 164 AC_ARG_WITH([gpm],
 165   AC_HELP_STRING([--without-gpm], [exclude support for GPM]),
 166   [
 167     AS_CASE(["${withval}"],
 168       [yes], [config_gpm="yes"],
 169       [no],  [config_gpm="no"],
 170              [AC_MSG_ERROR([bad value '${withval}' for --with-gpm])]
 171     )
 172   ],
 173   [config_gpm="yes"]
 174 )
 175 AM_CONDITIONAL([CONFIG_GPM], [test "x${config_gpm}" = "xyes"])
 176 AS_IF(
 177   [test "x${config_gpm}" = "xyes"],
 178   [AC_DEFINE([CONFIG_GPM], [1], [Define to 1 to include support for GPM.])]
 179 )
 180
 181 AC_ARG_WITH([mng],
 182   AC_HELP_STRING([--with-mng], [include  support for MNG animations]),
 183   [
 184     AS_CASE(["${withval}"],
 185       [yes], [config_mng="yes"],
 186       [no],  [config_mng="no"],
 187              [AC_MSG_ERROR([bad value '${withval}' for --with-mng])]
 188     )
 189   ],
 190   [config_mng="no"]
 191 )
 192 AM_CONDITIONAL([CONFIG_MNG], [test "x${config_mng}" = "xyes"])
 193 AS_IF(
 194   [test "x${config_mng}" = "xyes"],
 195   [AC_DEFINE([CONFIG_MNG], [1], [Define to 1 to include support for MNG animations.])]
 196 )
 197
 198 AC_ARG_WITH([png],
 199   AC_HELP_STRING([--without-png], [exclude support for PNG images]),
 200   [
 201     AS_CASE(["${withval}"],
 202       [yes], [config_png="yes"],
 203       [no],  [config_png="no"],
 204              [AC_MSG_ERROR([bad value '${withval}' for --with-png])]
 205     )
 206   ],
 207   [config_png="yes"]
 208 )
 209 AM_CONDITIONAL([CONFIG_PNG], [test "x${config_png}" = "xyes"])
 210 AS_IF(
 211   [test "x${config_png}" = "xyes"],
 212   [AC_DEFINE([CONFIG_PNG], [1], [Define to 1 to include support for PNG images.])]
 213 )
 214
 215 AC_ARG_WITH([ttf],
 216   AC_HELP_STRING([--without-ttf], [exclude support for truetype fonts]),
 217   [
 218     AS_CASE(["${withval}"],
 219       [yes], [config_ttf="yes"],
 220       [no],  [config_ttf="no"],
 221              [AC_MSG_ERROR([bad value ${withval} for --with-ttf])]
 222     )
 223   ],
 224   [config_ttf="yes"]
 225 )
 226 AM_CONDITIONAL([CONFIG_TTF], [test "x${config_ttf}" = "xyes"])
 227 AS_IF(
 228   [test "x${config_ttf}" = "xyes"],
 229   [AC_DEFINE([CONFIG_TTF], [1], [Define to 1 to include support for truetype fonts.])]
 230 )
 231
 232 AC_ARG_WITH([ttf-kernel],
 233   AC_HELP_STRING([--without-ttf-kernel], [exclude support for truetype fonts in kernel helper]),
 234   [
 235     AS_CASE(["${withval}"],
 236       [yes], [config_ttf_kernel="yes"],
 237       [no],  [config_ttf_kernel="no"],
 238              [AC_MSG_ERROR([bad value ${withval} for --with-ttf-kernel])]
 239     )
 240   ],
 241   [config_ttf_kernel="yes"]
 242 )
 243 AM_CONDITIONAL([CONFIG_TTF_KERNEL], [test "x${config_ttf_kernel}" = "xyes"])
 244 AS_IF(
 245   [test "x${config_ttf_kernel}" = "xyes"],
 246   [AC_DEFINE([CONFIG_TTF_KERNEL], [1], [Define to 1 to include support for truetype fonts in kernel helper.])]
 247 )
 248
 249 AC_ARG_WITH([klibc-compiler],
 250   AS_HELP_STRING([--with-klibc-compiler], [compiler to use when building against klibc @<:@auto@:>@]),
 251   [KLCC="${withval}"],
 252   [
 253     AS_IF(
 254       [test "x${host_alias}" != "x${build_alias}"],
 255       [AC_CHECK_PROG([KLCC], [${host_alias}-klcc], [${host_alias}-klcc])],
 256       [AC_CHECK_PROG([KLCC], [klcc], [klcc])]
 257     )
 258     AS_IF(
 259       [test "x${KLCC}" = "x"],
 260       [AC_MSG_WARN([could not determine compiler to use when building against klibc.])]
 261     )
 262   ]
 263 )
 264 AC_SUBST([KLCC])
 265
 266 AC_ARG_WITH([freetype2-src],
 267   AS_HELP_STRING([--with-freetype2-src=DIR], [freetype2 source to use when linking with klibc]),
 268   [
 269         AS_IF(
 270           [test "`echo ${withval} | sed -e 's,^/.*,,'`" = "${withval}"],
 271           [LIBFREETYPE2_SOURCE="\$(abs_top_srcdir)/${withval}"],
 272           [LIBFREETYPE2_SOURCE="${withval}"]
 273         )
 274   ],
 275   [LIBFREETYPE2_SOURCE="\$(abs_top_srcdir)/\$(LIBFREETYPE2_SOURCE_INTERNAL)"]
 276 )
 277 AC_SUBST([LIBFREETYPE2_SOURCE])
 278
 279 AC_ARG_WITH([jpeg-src],
 280   AS_HELP_STRING([--with-jpeg-src=DIR], [jpeglib source to use when linking with klibc]),
 281   [
 282         AS_IF(
 283           [test "`echo ${withval} | sed -e 's,^/.*,,'`" = "${withval}"],
 284           [LIBJPEG_SOURCE="\$(abs_top_srcdir)/${withval}"],
 285           [LIBJPEG_SOURCE="${withval}"]
 286         )
 287   ],
 288   [LIBJPEG_SOURCE="\$(abs_top_srcdir)/\$(LIBJPEG_SOURCE_INTERNAL)"]
 289 )
 290 AC_SUBST([LIBJPEG_SOURCE])
 291
 292 AC_ARG_WITH([lpng-src],
 293   AS_HELP_STRING([--with-lpng-src=DIR], [libpng source to use when linking with klibc]),
 294   [
 295         AS_IF(
 296           [test "`echo ${withval} | sed -e 's,^/.*,,'`" = "${withval}"],
 297           [LIBPNG_SOURCE="\$(abs_top_srcdir)/${withval}"],
 298           [LIBPNG_SOURCE="${withval}"]
 299         )
 300   ],
 301   [LIBPNG_SOURCE="\$(abs_top_srcdir)/\$(LIBPNG_SOURCE_INTERNAL)"]
 302 )
 303 AC_SUBST([LIBPNG_SOURCE])
 304
 305 AC_ARG_WITH([zlib-src],
 306   AS_HELP_STRING([--with-zlib-src=DIR], [zlib source to use when linking with klibc]),
 307   [
 308         AS_IF(
 309           [test "`echo ${withval} | sed -e 's,^/.*,,'`" = "${withval}"],
 310           [LIBZ_SOURCE="\$(abs_top_srcdir)/${withval}"],
 311           [LIBZ_SOURCE="${withval}"]
 312         )
 313   ],
 314   [LIBZ_SOURCE="\$(abs_top_srcdir)/\$(LIBZ_SOURCE_INTERNAL)"]
 315 )
 316 AC_SUBST([LIBZ_SOURCE])
 317
 318 AC_ARG_WITH([essential-prefix],
 319   AS_HELP_STRING([--with-essential-prefix=ESPREFIX], [install essential files in ESPREFIX @<:@/@:>@]),
 320   [essential_prefix="$(echo ${withval} | sed -e 's#/$##')"],
 321   [essential_prefix="/"]
 322 )
 323 AC_SUBST([essential_prefix])
 324
 325 AC_ARG_WITH([essential-bindir],
 326   AS_HELP_STRING([--with-essential-bindir=DIR], [essential user apps directory @<:@ESPREFIX/bin@:>@]),
 327   [eexecbindir="${withval}"],
 328   [eexecbindir="\$(essential_prefix)/bin"]
 329 )
 330 AC_SUBST([eexecbindir])
 331
 332 AC_ARG_WITH([essential-sbindir],
 333   AS_HELP_STRING([--with-eseential-sbindir=DIR], [essential admin apps directory @<:@ESPREFIX/sbin@:>@]),
 334   [eexecsbindir="${withval}"],
 335   [eexecsbindir="\$(essential_prefix)/sbin"]
 336 )
 337 AC_SUBST([eexecsbindir])
 338
 339 AC_ARG_WITH([essential-libdir],
 340   AS_HELP_STRING([--with-essential-libdir=DIR], [essential libraries directory @<:@ESPREFIX/lib@:>@]),
 341   [eexeclibdir="${withval}"],
 342   [eexeclibdir="\$(essential_prefix)/lib"]
 343 )
 344 AC_SUBST([eexeclibdir])
 345
 346 AC_ARG_WITH([themedir],
 347   AS_HELP_STRING([--with-themedir=DIR], [splash theme directory @<:@ESPREFIX/etc/splash@:>@]),
 348   [themedir="${withval}"],
 349   [themedir="\$(essential_prefix)/etc/splash"]
 350 )
 351 AC_SUBST([themedir])
 352
 353 AC_ARG_WITH([klibc],
 354   AC_HELP_STRING([--without-klibc], [link the kernel helper against glibc instead of klibc]),
 355   [
 356     AS_CASE(["${withval}"],
 357       [yes], [config_klibc="yes"],
 358       [no],  [config_klibc="no"],
 359              [AC_MSG_ERROR([bad value ${withval} for --with-klibc])]
 360     )
 361   ],
 362   [config_klibc="yes"]
 363 )
 364 AM_CONDITIONAL([CONFIG_KLIBC], [test "x${config_klibc}" = "xyes"])
 365 AS_IF(
 366   [test "x${config_klibc}" = "xyes"],
 367   [AC_DEFINE([CONFIG_KLIBC], [1], [use klibc])]
 368 )
 369
 370 M_CFLFAGS=
 371 M_LIBS=
 372 AC_CHECK_HEADER(
 373   [math.h],
 374   [M_CFLAGS="${M_CFLAGS}"],
 375   [AC_MSG_ERROR(['math.h' header file not found.])]
 376 )
 377 AC_CHECK_LIB(
 378   [m], [ceilf],
 379   [M_LIBS="${M_LIBS} -lm"],
 380   [AC_MSG_ERROR(['libm' library not found.])]
 381 )
 382 AC_SUBST([M_CFLAGS])
 383 AC_SUBST([M_LIBS])
 384
 385 RT_CFLFAGS=
 386 RT_LIBS=
 387 AC_CHECK_HEADER(
 388   [time.h],
 389   [RT_CFLAGS="${RT_CFLAGS}"],
 390   [AC_MSG_ERROR(['time.h' header file was not found.])]
 391 )
 392 AC_CHECK_LIB([rt], [clock_gettime],
 393   [RT_LIBS="${RT_LIBS} -lrt"],
 394   [AC_MSG_ERROR(['librt' library was not found.])]
 395 )
 396 AC_SUBST([RT_CFLAGS])
 397 AC_SUBST([RT_LIBS])
 398
 399 PTHREAD_CFLFAGS=
 400 PTHREAD_LIBS=
 401 AC_CHECK_HEADER([pthread.h],
 402   [PTHREAD_CFLAGS="${PTHREAD_CFLAGS}"],
 403   [AC_MSG_ERROR(['pthread.h' header file was not found.])]
 404 )
 405 AC_CHECK_LIB([pthread], [pthread_create],
 406   [PTHREAD_LIBS="${PTHREAD_LIBS} -lpthread"],
 407   [AC_MSG_ERROR(['libpthread' library file was not found.])]
 408 )
 409 AC_SUBST([PTHREAD_CFLAGS])
 410 AC_SUBST([PTHREAD_LIBS])
 411
 412 PTHREAD_STATIC_CFLFAGS=
 413 PTHREAD_STATIC_LIBS=
 414 AC_CHECK_HEADER(
 415   [pthread.h],
 416   [PTHREAD_STATIC_CFLFAGS="${PTHREAD_STATIC_CFLFAGS}"],
 417   [AC_MSG_ERROR(['pthread.h' header file was not found.])]
 418 )
 419 AC_CHECK_LIB([pthread], [xxpthread_create],
 420   [PTHREAD_STATIC_LIBS="${PTHREAD_STATIC_LIBS} -lpthread"],
 421   [
 422     AC_CHECK_LIB([pthread], [pthread_create],
 423       [PTHREAD_STATIC_LIBS="${PTHREAD_STATIC_LIBS} -L\$(DESTDIR)\$(libdir)/nptl -lpthread"],
 424       [
 425         AC_CHECK_LIB([pthread], [pthread_create],
 426           [PTHREAD_STATIC_LIBS="${PTHREAD_STATIC_LIBS} -L\$(DESTDIR)\$(elibdir)/nptl -lpthread"],
 427           [AC_MSG_ERROR([the required 'libpthread' static library file not found.])],
 428           [-static -L${DESTDIR}${elibdir}/nptl]
 429         )
 430       ],
 431       [-static -L${DESTDIR}${libdir}/nptl]
 432     )
 433   ],
 434   [-static]
 435 )
 436 AC_SUBST([PTHREAD_STATIC_CFLAGS])
 437 AC_SUBST([PTHREAD_STATIC_LIBS])
 438
 439 AC_ARG_VAR([JPEG_CFLAGS], [C compiler flags for JPEG library, overriding autodetection])
 440 AC_ARG_VAR([JPEG_LIBS], [linker flags for JPEG library, overriding autodetection])
 441 AS_IF(
 442   [test "x${JPEG_CFLAGS}" = "x"],
 443   [
 444     AC_CHECK_HEADER([jpeglib.h],
 445       [JPEG_CFLAGS="${JPEG_CFLAGS}"],
 446       [AC_MSG_ERROR(['jpeglib.h' header file not found.])]
 447     )
 448   ]
 449 )
 450 AS_IF(
 451   [test "x${JPEG_CFLAGS}" = "no"],
 452   [JPEG_CFLAGS=""]
 453 )
 454 AS_IF(
 455   [test "x${JPEG_LIBS}" = "x"],
 456   [
 457     AC_CHECK_LIB([jpeg], [jpeg_set_defaults],
 458       [JPEG_LIBS="${JPEG_LIBS} -ljpeg"],
 459       [AC_MSG_ERROR([the required 'libjpeg' library file was not found.])]
 460     )
 461   ]
 462 )
 463 AS_IF(
 464   [test "x${JPEG_LIBS}" = "no"],
 465   [JPEG_LIBS=""]
 466 )
 467 AC_SUBST([JPEG_CFLAGS])
 468 AC_SUBST([JPEG_LIBS])
 469
 470 # As needed, check GPM files and set GPM compiler flags.
 471 AC_ARG_VAR([GPM_CFLAGS], [C compiler flags for GPM library, overriding autodetection])
 472 AC_ARG_VAR([GPM_LIBS],   [linker flags for GPM library, overriding autodetection])
 473 AS_IF(
 474   [test "x${config_gpm}" = "xyes"],
 475   [
 476     AS_IF(
 477       [test "x${GPM_CFLAGS}" = "x"],
 478       [
 479         AC_CHECK_HEADER(
 480           [gpm.h],
 481           [GPM_CFLAGS="${GPM_CFLAGS}"],
 482           [AC_MSG_ERROR(['gpm.h' header file was not found.])]
 483         )
 484       ]
 485     )
 486     AS_IF(
 487       [test "x${GPM_CFLAGS}" = "no"],
 488       [GPM_CFLAGS=""]
 489     )
 490     AS_IF(
 491       [test "x${GPM_LIBS}" = "x"],
 492       [
 493         AC_CHECK_LIB(
 494           [gpm], [Gpm_Open],
 495           [GPM_LIBS="${GPM_LIBS} -lgpm"],
 496           [AC_MSG_ERROR(['libgpm' library file was not found.])]
 497         )
 498       ]
 499     )
 500     AS_IF(
 501       [test "x${GPM_LIBS}" = "no"],
 502       [GPM_LIBS=""]
 503     )
 504   ]
 505 )
 506 AC_SUBST([GPM_CFLAGS])
 507 AC_SUBST([GPM_LIBS])
 508
 509 AC_ARG_VAR([MNG_CFLAGS], [C compiler flags for MNG library, overriding autodetection])
 510 AC_ARG_VAR([MNG_LIBS],   [linker flags for MNG library, overriding autodetection])
 511 AS_IF(
 512   [test "x${config_mng}" = "xyes"],
 513   [
 514     AS_IF(
 515       [test "x${MNG_CFLAGS}" = "x"],
 516       [
 517         AC_CHECK_HEADER(
 518           [libmng.h],
 519           [
 520             MNG_CFLAGS="${MNG_CFLAGS}"
 521             MNG_CFLAGS="${MNG_CFLAGS} ${JPEG_CFLAGS}"
 522             MNG_CFLAGS="${MNG_CFLAGS} ${RT_CFLAGS}"
 523           ],
 524           [AC_MSG_ERROR(['libmng.h' header file was not found.])]
 525         )
 526       ]
 527     )
 528     AS_IF(
 529       [test "x${MNG_CFLAGS}" = "xno"],
 530       [MNG_CFLAGS=""]
 531     )
 532     AS_IF(
 533       [test "x${MNG_LIBS}" = "x"],
 534       [
 535         AC_CHECK_LIB(
 536           [mng], [mng_initialize],
 537           [
 538             MNG_LIBS="${MNG_LIBS} -lmng"
 539             MNG_LIBS="${MNG_LIBS} ${JPEG_LIBS}"
 540             AC_CHECK_LIB([z],    [zlibVersion],    [MNG_LIBS="${MNG_LIBS} -lz"   ])
 541             AC_CHECK_LIB([lcms], [cmsCloseProfile],[MNG_LIBS="${MNG_LIBS} -llcms"])
 542           ],
 543           [AC_MSG_ERROR(['libmng' library file was not found.])]
 544         )
 545       ]
 546     )
 547     AS_IF(
 548       [test "x${MNG_LIBS}" = "xno"],
 549       [MNG_LIBS=""]
 550     )
 551   ]
 552 )
 553 AC_SUBST([MNG_CFLAGS])
 554 AC_SUBST([MNG_LIBS])
 555
 556 AC_ARG_VAR([PNG_CFLAGS], [C compiler flags for PNG library, overriding autodetection])
 557 AC_ARG_VAR([PNG_LIBS],   [linker flags for PNG library, overriding autodetection])
 558
 559 AS_IF(
 560   [test "x${config_png}" = "xyes"],
 561   [
 562     AS_IF(
 563       [test "x${LIBPNG_CONFIG}" = "x"],
 564       [AC_PATH_PROG(LIBPNG_CONFIG, libpng-config)]
 565     )
 566     AS_IF(
 567       [test "x${LIBPNG_CONFIG}" = "xno"],
 568       [LIBPNG_CONFIG=""]
 569     )
 570     AS_IF(
 571       [test "x${PNG_CFLAGS}" = "x"],
 572       [
 573         AS_IF(
 574           [test "x$LIBPNG_CONFIG" != "x"],
 575           [PNG_CFLAGS=$(${LIBPNG_CONFIG} --static --cflags)],
 576           [
 577             AC_CHECK_HEADER([png.h],
 578               [PNG_CFLAGS="${PNG_CFLAGS}"],
 579               [AC_MSG_ERROR(['png.h' header file not found.])]
 580             )
 581           ]
 582         )
 583       ]
 584     )
 585     AS_IF(
 586       [test "x${PNG_CFLAGS}" = "xno"],
 587       [PNG_CFLAGS=""]
 588     )
 589     AS_IF(
 590       [test "x${PNG_LIBS}" = "x"],
 591       [
 592         AS_IF(
 593           [test "x$LIBPNG_CONFIG" != "x"],
 594           [PNG_LIBS=$(${LIBPNG_CONFIG} --static --libs)],
 595           [
 596             AC_CHECK_LIB([png], [png_access_version_number],
 597               [
 598                 PNG_LIBS="${PNG_LIBS} -lpng"
 599                 AC_CHECK_LIB([z], [zlibVersion],
 600                   [PNG_LIBS="${PNG_LIBS} -lz"]
 601                 )
 602                 PNG_LIBS="${PNG_LIBS} ${M_LIBS}"
 603               ],
 604               [AC_MSG_ERROR(['libpng' library file not found.])]
 605             )
 606           ]
 607         )
 608       ]
 609     )
 610     AS_IF(
 611       [test "x${PNG_LIBS}" = "xno"],
 612       [PNG_LIBS=""]
 613     )
 614   ]
 615 )
 616 AC_SUBST([PNG_CFLAGS])
 617 AC_SUBST([PNG_LIBS])
 618
 619 AS_IF(
 620   [test "x${config_ttf}" = "xyes"],
 621   [
 622     PKG_CHECK_MODULES(
 623       [FREETYPE2],
 624       [freetype2],
 625       ,
 626       [AC_MSG_ERROR([freetype was not found.])]
 627     )
 628   ]
 629 )
 630
 631 AH_TOP([#ifndef __SPLASH_CONFIG_H
 632 #define __SPLASH_CONFIG_H])
 633 AH_BOTTOM([#endif /* SPLASH_CONFIG_H */])
 634
 635 AC_CONFIG_HEADERS([config.h])
 636 AC_CONFIG_FILES([Makefile src/Makefile libs/Makefile misc/Makefile src/test/Makefile docs/Makefile scripts/Makefile])
 637
 638 AC_OUTPUT