JSON/Converter.pm

   1 package JSON::Converter;
   2
   3 use vars qw($AUTOCONVERT $VERSION);
   4 use Carp;
   5
   6 $VERSION     = 0.9902;
   7
   8 $AUTOCONVERT = 1;
   9
  10 sub new { bless {AUTOCONVERT=>$AUTOCONVERT}, shift; }
  11
  12 sub objToJson {
  13         my $self = shift;
  14         my $obj  = shift;
  15
  16         $self->{_stack_myself} = [];
  17
  18         local $AUTOCONVERT = $self->{AUTOCONVERT};
  19
  20         if(ref($obj) eq 'HASH'){
  21                 return $self->hashToJson($obj);
  22         }
  23         elsif(ref($obj) eq 'ARRAY'){
  24                 return $self->arrayToJson($obj);
  25         }
  26         elsif(!ref($obj)){
  27                 return $self->valueToJson($obj);
  28         }
  29         else{
  30                 return;
  31         }
  32 }
  33
  34 sub hashToJson {
  35         my $self = shift;
  36         my $obj  = shift;
  37         my ($k,$v);
  38         my %res;
  39
  40         if(grep { $_ == $obj } @{ $self->{_stack_myself} }){
  41                 die "circular ref!";
  42         }
  43
  44         push @{ $self->{_stack_myself} },$obj;
  45
  46         for my $k (keys %$obj){
  47                 my $v = $obj->{$k};
  48                 if(ref($v) eq "HASH"){
  49                         $res{$k} = $self->hashToJson($v);
  50                 }
  51                 elsif(ref($v) eq "ARRAY"){
  52                         $res{$k} = $self->arrayToJson($v);
  53                 }
  54                 else{
  55                         $res{$k} = $self->valueToJson($v);
  56                 }
  57         }
  58
  59         pop @{ $self->{_stack_myself} };
  60
  61         return '{' . join(',',map { _stringfy($_) . ':' .$res{$_} } sort keys %res) . '}';
  62 }
  63
  64
  65 sub arrayToJson {
  66         my $self = shift;
  67         my $obj  = shift;
  68         my @res;
  69
  70         if(grep { $_ == $obj } @{ $self->{_stack_myself} }){
  71                 die "circular ref!";
  72         }
  73
  74         push @{ $self->{_stack_myself} },$obj;
  75
  76         for my $v (@$obj){
  77                 if(ref($v) eq "HASH"){
  78                         push @res,$self->hashToJson($v);
  79                 }
  80                 elsif(ref($v) eq "ARRAY"){
  81                         push @res,$self->arrayToJson($v);
  82                 }
  83                 else{
  84                         push @res,$self->valueToJson($v);
  85                 }
  86         }
  87
  88         pop @{ $self->{_stack_myself} };
  89
  90         return '[' . join(',',@res) . ']';
  91 }
  92
  93
  94 sub valueToJson {
  95         my $self  = shift;
  96         my $value = shift;
  97
  98         return 'null' if(!defined $value);
  99
 100         if($AUTOCONVERT and !ref($value)){
 101                 return $value  if($value =~ /^-?(?:0|[1-9][\d]*)(?:\.[\d]+)?$/);
 102                 return 'true'  if($value =~ /^true$/i);
 103                 return 'false' if($value =~ /^false$/i);
 104         }
 105
 106         return  _stringfy($value) unless(ref($value));
 107
 108         if( $value->isa('JASON::NotSring') ){
 109                 die "Invalid value";
 110         }
 111
 112         return defined $value->{value} ? $value->{value} : 'null';
 113 }
 114
 115
 116 sub _stringfy {
 117         my $arg = shift;
 118         my $l   = length $arg;
 119         my $s   = '"';
 120         my $i = 0;
 121
 122         while($i < $l){
 123                 my $c = substr($arg,$i++,1);
 124                 if($c ge ' '){
 125                         $c =~ s{(["\\/])}{\\$1};
 126                         $s .= $c;
 127                 }
 128                 elsif($c =~ tr/\n\r\t\f\b/nrtfb/){
 129                         $s .= '\\' . $c;
 130                 }
 131                 else{
 132                         $s .= '\\u00' . unpack('H2',$c);
 133                 }
 134         }
 135         $s =~ s/\]\]>/]]\\u003E/gos;
 136
 137         return $s . '"';
 138 }
 139
 140
 141 1;
 142
 143
 144 =head1 METHODs
 145
 146 =over
 147
 148 =item parse
 149
 150 alias of C<objToJson>.
 151
 152 =item objToJson
 153
 154 convert a passed perl data structure into JSON object.
 155 can't parse blessed object.
 156
 157 =item hashToJson
 158
 159 convert a passed hash into JSON object.
 160
 161 =item arrayToJson
 162
 163 convert a passed array into JSON array.
 164
 165 =item valueToJson
 166
 167 convert a passed data into a string of JSON.
 168
 169 =back
 170
 171 =head1 COPYRIGHT
 172
 173 makamaka [at] donzoko.net
 174
 175 This library is free software; you can redistribute it
 176 and/or modify it under the same terms as Perl itself.
 177
 178 =head1 SEE ALSO
 179
 180 L<http://www.crockford.com/JSON/index.html>
 181
 182 =cut