| blob | 3fd519ecddca654db5a8b781005c0fe56cc5a746 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [57])
34 m4_define([glib_micro_version], [2])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [https://gitlab.gnome.org/GNOME/glib/issues/new])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 GLIB_TESTS
253 dnl location to install runtime libraries, e.g. ../../lib to install
254 dnl to /lib if libdir is /usr/lib
255 AC_ARG_WITH(runtime-libdir,
256 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
257 [install runtime libraries relative to libdir])],
258 [],
259 [with_runtime_libdir=""])
260 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
261 AC_SUBST(GLIB_RUNTIME_LIBDIR)
262 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
264 dnl Check for a working C++ compiler, but do not bail out, if none is found.
265 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
266 AC_LANG_SAVE
267 AC_LANG_CPLUSPLUS
268 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
269 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
270 AC_LANG_RESTORE
272 AM_PROG_CC_C_O
273 AC_PROG_INSTALL
275 AC_SYS_LARGEFILE
277 PKG_PROG_PKG_CONFIG(0.16)
279 if test "x$enable_debug" = "xyes"; then
280 if test "x$cflags_set" != "x" ; then
281 case " $CFLAGS " in
282 *[[\ \ ]]-g[[\ \ ]]*) ;;
283 *) CFLAGS="$CFLAGS -g" ;;
284 esac
285 fi
286 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
287 else
288 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
290 if test "x$enable_debug" = "xno"; then
291 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
292 fi
293 fi
295 # Ensure MSVC-compatible struct packing convention is used when
296 # compiling for Win32 with gcc.
297 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
298 # gcc2 uses "-fnative-struct".
299 if test x"$glib_native_win32" = xyes; then
300 if test x"$GCC" = xyes; then
301 msnative_struct=''
302 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
303 if test -z "$ac_cv_prog_CC"; then
304 our_gcc="$CC"
305 else
306 our_gcc="$ac_cv_prog_CC"
307 fi
308 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
309 2.)
310 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
311 msnative_struct='-fnative-struct'
312 fi
313 ;;
314 *)
315 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
316 msnative_struct='-mms-bitfields'
317 fi
318 ;;
319 esac
320 if test x"$msnative_struct" = x ; then
321 AC_MSG_RESULT([no way])
322 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
323 else
324 CFLAGS="$CFLAGS $msnative_struct"
325 AC_MSG_RESULT([${msnative_struct}])
326 fi
327 fi
328 fi
329 GLIB_EXTRA_CFLAGS="${msnative_struct}"
330 AC_SUBST(GLIB_EXTRA_CFLAGS)
332 AC_EXEEXT
334 AC_PROG_AWK
336 # option to specify python interpreter to use; this just sets $PYTHON, so that
337 # we will fallback to reading $PYTHON if --with-python is not given, and
338 # python.m4 will get the expected input
339 AC_ARG_WITH(python,
340 AS_HELP_STRING([--with-python=PATH],
341 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
342 [PYTHON="$withval"], [])
343 if test x"$PYTHON" = xyes; then
344 AC_MSG_ERROR([--with-python option requires a path or program argument])
345 fi
346 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
349 dnl ***********************
350 dnl *** Tests for iconv ***
351 dnl ***********************
352 dnl
353 dnl We do this before the gettext checks, to avoid distortion
355 dnl On Windows we use a native implementation
357 AS_IF([ test x"$glib_native_win32" = xyes], [
358 with_libiconv=native
359 ], [
360 AC_ARG_WITH(libiconv,
361 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
362 [use the libiconv library])],,
363 [with_libiconv=maybe])
365 found_iconv=no
366 case $with_libiconv in
367 maybe)
368 # Check in the C library first
369 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
370 # Check if we have GNU libiconv
371 if test $found_iconv = "no"; then
372 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
373 fi
374 # Check if we have a iconv in -liconv, possibly from vendor
375 if test $found_iconv = "no"; then
376 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
377 fi
378 ;;
379 no)
380 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
381 ;;
382 gnu|yes)
383 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
384 ;;
385 native)
386 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
387 ;;
388 esac
390 if test "x$found_iconv" = "xno" ; then
391 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
392 fi
393 ])
395 dnl
396 dnl zlib support
397 dnl
398 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
399 AS_IF([test "x$found_zlib" = "xno"], [
400 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
401 if test "x$found_zlib" = "xno" ; then
402 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
403 fi
404 ZLIB_LIBS='-lz'
405 AC_SUBST(ZLIB_LIBS)
406 ])
408 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
409 AC_SUBST(LIBFFI_CFLAGS)
410 AC_SUBST(LIBFFI_LIBS)
412 dnl
413 dnl gettext support
414 dnl
416 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
417 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
418 GLIB_GNU_GETTEXT
420 if test "$gt_cv_have_gettext" != "yes" ; then
421 AC_MSG_ERROR([
422 *** You must have either have gettext support in your C library, or use the
423 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
424 ])
425 fi
427 LIBS="$INTLLIBS $LIBS"
429 GETTEXT_PACKAGE=glib20
430 AC_SUBST(GETTEXT_PACKAGE)
431 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
432 [Define the gettext package to be used])
434 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
436 dnl
437 dnl Now we are done with gettext checks, figure out ICONV_LIBS
438 dnl
440 AS_IF([test x"$glib_native_win32" != xyes], [
441 if test x$with_libiconv != xno ; then
442 case " $INTLLIBS " in
443 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
444 *) ICONV_LIBS="-liconv" ;;
445 esac
446 fi
447 ])
448 AC_SUBST(ICONV_LIBS)
450 case $with_libiconv in
451 gnu)
452 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
453 ;;
454 native)
455 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
456 ;;
457 esac
459 dnl Initialize libtool
460 LT_PREREQ([2.2])
461 LT_INIT([disable-static win32-dll])
462 dnl when using libtool 2.x create libtool early, because it's used in configure
463 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
466 AS_IF([test "$glib_native_win32" = "yes"], [
467 if test x$enable_static = xyes -a x$enable_shared = xyes; then
468 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
469 fi
470 if test x$enable_static = xyes; then
471 glib_win32_static_compilation=yes
472 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
473 #define GOBJECT_STATIC_COMPILATION 1"
474 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
475 fi
476 ])
477 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
479 # Checks for library functions.
480 AC_FUNC_ALLOCA
481 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
482 AC_CHECK_FUNCS(timegm gmtime_r posix_spawn)
483 AC_FUNC_STRERROR_R()
485 AC_CHECK_SIZEOF(char)
486 AC_CHECK_SIZEOF(short)
487 AC_CHECK_SIZEOF(long)
488 AC_CHECK_SIZEOF(int)
489 AC_CHECK_SIZEOF(void *)
490 AC_CHECK_SIZEOF(long long)
491 AC_CHECK_SIZEOF(__int64)
493 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
494 [AC_TRY_LINK([#include <signal.h>
495 #include <sys/types.h>
496 sig_atomic_t val = 42;],
497 [return val == 42 ? 0 : 1],
498 ac_cv_type_sig_atomic_t=yes,
499 ac_cv_type_sig_atomic_t=no)])
500 if test x$ac_cv_type_sig_atomic_t = xyes; then
501 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
502 [Define if you have the 'sig_atomic_t' type.])
503 fi
505 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
506 :
507 else
508 AC_MSG_ERROR([
509 *** GLib requires a 64 bit type. You might want to consider
510 *** using the GNU C compiler.
511 ])
512 fi
514 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
515 # long long is a 64 bit integer.
516 AC_MSG_CHECKING(for format to printf and scanf a guint64)
517 AC_CACHE_VAL(glib_cv_long_long_format,[
518 for format in ll q I64; do
519 AC_TRY_RUN([#include <stdio.h>
520 int main()
521 {
522 long long b, a = -0x3AFAFAFAFAFAFAFALL;
523 char buffer[1000];
524 sprintf (buffer, "%${format}u", a);
525 sscanf (buffer, "%${format}u", &b);
526 exit (b!=a);
527 }
528 ],
529 [glib_cv_long_long_format=${format}
530 break],
531 [],[:])
532 done])
533 AS_IF([ test -n "$glib_cv_long_long_format"], [
534 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
535 ], [AC_MSG_RESULT(none)])
536 ],[ test x$ac_cv_sizeof___int64 = x8], [
537 # __int64 is a 64 bit integer.
538 AC_MSG_CHECKING(for format to printf and scanf a guint64)
539 # We know this is MSVCRT.DLL, and what the formats are
540 glib_cv_long_long_format=I64
541 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
542 ])
544 AC_C_CONST
546 dnl
547 dnl check in which direction the stack grows
548 dnl
549 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
550 AC_TRY_RUN([
551 volatile int *a = 0, *b = 0;
552 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
553 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
554 ],
555 glib_cv_stack_grows=yes
556 ,
557 glib_cv_stack_grows=no
558 ,)
559 ])
561 # check for flavours of varargs macros
562 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
563 AC_TRY_COMPILE([],[
564 int a(int p1, int p2, int p3);
565 #define call_a(...) a(1,__VA_ARGS__)
566 call_a(2,3);
567 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
568 AC_MSG_RESULT($g_have_iso_c_varargs)
570 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
571 AS_IF([test "$CXX" = ""], [
572 dnl No C++ compiler
573 g_have_iso_cxx_varargs=no
574 else
575 AC_LANG_CPLUSPLUS
576 AC_TRY_COMPILE([],[
577 int a(int p1, int p2, int p3);
578 #define call_a(...) a(1,__VA_ARGS__)
579 call_a(2,3);
580 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
581 AC_LANG_C
582 ])
583 AC_MSG_RESULT($g_have_iso_cxx_varargs)
585 AC_MSG_CHECKING(for GNUC varargs macros)
586 AC_TRY_COMPILE([],[
587 int a(int p1, int p2, int p3);
588 #define call_a(params...) a(1,params)
589 call_a(2,3);
590 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
591 AC_MSG_RESULT($g_have_gnuc_varargs)
593 # check for GNUC visibility support
594 AC_MSG_CHECKING(for GNUC visibility attribute)
595 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
596 void
597 __attribute__ ((visibility ("hidden")))
598 f_hidden (void)
599 {
600 }
601 void
602 __attribute__ ((visibility ("internal")))
603 f_internal (void)
604 {
605 }
606 void
607 __attribute__ ((visibility ("protected")))
608 f_protected (void)
609 {
610 }
611 void
612 __attribute__ ((visibility ("default")))
613 f_default (void)
614 {
615 }
616 int main (void)
617 {
618 f_hidden();
619 f_internal();
620 f_protected();
621 f_default();
622 return 0;
623 }
624 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
625 AC_MSG_RESULT($g_have_gnuc_visibility)
626 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
628 AC_MSG_CHECKING([whether using Sun Studio C compiler])
629 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
630 #else
631 # include "error: this is not Sun Studio."
632 #endif
633 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
634 AC_MSG_RESULT($g_have_sunstudio_visibility)
635 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
637 # check for bytesex stuff
638 AC_C_BIGENDIAN
639 if test x$ac_cv_c_bigendian = xuniversal ; then
640 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
641 fi
644 # check for header files
645 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
646 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
647 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h sys/auxv.h])
648 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
649 AC_CHECK_HEADERS([linux/magic.h])
650 AC_CHECK_HEADERS([termios.h])
652 # Some versions of MSC lack these
653 AC_CHECK_HEADERS([dirent.h sys/time.h])
655 # We don't care about this, but we need to keep including it in
656 # glibconfig.h for backward compatibility
657 AC_CHECK_HEADERS([values.h])
659 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
660 [#if HAVE_SYS_PARAM_H
661 #include <sys/param.h>
662 #endif
663 ])
664 AC_CHECK_FUNCS(sysctlbyname)
666 AC_HEADER_MAJOR
667 AS_IF([test "$ac_cv_header_sys_types_h_makedev" = "yes"],
668 [AC_DEFINE([MAJOR_IN_TYPES], [1], [Define to 1 if `major', `minor', and `makedev' are declared in <sys/types.h>.])])
669 AC_CHECK_HEADERS([xlocale.h])
671 # check for structure fields
672 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
673 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
674 #include <sys/stat.h>
675 #ifdef G_OS_UNIX
676 #include <unistd.h>
677 #endif
678 #ifdef HAVE_SYS_STATFS_H
679 #include <sys/statfs.h>
680 #endif
681 #ifdef HAVE_SYS_PARAM_H
682 #include <sys/param.h>
683 #endif
684 #ifdef HAVE_SYS_MOUNT_H
685 #include <sys/mount.h>
686 #endif])
687 # struct statvfs.f_basetype is available on Solaris but not for Linux.
688 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
689 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
690 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
692 AC_STRUCT_DIRENT_D_TYPE
694 # Checks for libcharset
695 AM_LANGINFO_CODESET
696 gl_GLIBC21
697 AC_ARG_WITH(charsetalias-dir,
698 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
699 [],
700 [with_charsetalias_dir='${libdir}'])
701 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
702 AC_SUBST(GLIB_CHARSETALIAS_DIR)
704 # check additional type sizes
705 AC_CHECK_SIZEOF(size_t)
707 dnl Try to figure out whether gsize should be long or int
708 AC_MSG_CHECKING([for the appropriate definition for size_t])
710 case $ac_cv_sizeof_size_t in
711 $ac_cv_sizeof_short)
712 glib_size_type=short
713 ;;
714 $ac_cv_sizeof_int)
715 glib_size_type=int
716 ;;
717 $ac_cv_sizeof_long)
718 glib_size_type=long
719 ;;
720 $ac_cv_sizeof_long_long)
721 glib_size_type='long long'
722 ;;
723 $ac_cv_sizeof__int64)
724 glib_size_type='__int64'
725 ;;
726 *) AC_MSG_ERROR([No type matching size_t in size])
727 ;;
728 esac
730 dnl If int/long are the same size, we see which one produces
731 dnl warnings when used in the location as size_t. (This matters
732 dnl on AIX with xlc)
733 dnl
734 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
735 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
736 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
737 #if defined(_AIX) && !defined(__GNUC__)
738 #pragma options langlvl=stdc89
739 #endif
740 #include <stddef.h>
741 int main ()
742 {
743 size_t s = 1;
744 unsigned int *size_int = &s;
745 return (int)*size_int;
746 }
747 ]])],glib_size_type=int,
748 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
749 #if defined(_AIX) && !defined(__GNUC__)
750 #pragma options langlvl=stdc89
751 #endif
752 #include <stddef.h>
753 int main ()
754 {
755 size_t s = 1;
756 unsigned long *size_long = &s;
757 return (int)*size_long;
758 }
759 ]])],glib_size_type=long)])
760 ])
762 AC_MSG_RESULT(unsigned $glib_size_type)
764 AC_CHECK_SIZEOF(ssize_t)
766 dnl Try to figure out whether gssize should be long or int
767 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
769 case $ac_cv_sizeof_ssize_t in
770 $ac_cv_sizeof_short)
771 glib_ssize_type=short
772 ;;
773 $ac_cv_sizeof_int)
774 glib_ssize_type=int
775 ;;
776 $ac_cv_sizeof_long)
777 glib_ssize_type=long
778 ;;
779 $ac_cv_sizeof_long_long)
780 glib_ssize_type='long long'
781 ;;
782 $ac_cv_sizeof__int64)
783 glib_ssize_type='__int64'
784 ;;
785 *) AC_MSG_ERROR([No type matching ssize_t in size])
786 ;;
787 esac
789 dnl If int/long are the same size, we see which one produces
790 dnl warnings when used in the location as ssize_t. (This matters
791 dnl on Android where ssize_t is long and size_t is unsigned int)
792 dnl
793 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
794 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
795 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
796 #if defined(_AIX) && !defined(__GNUC__)
797 #pragma options langlvl=stdc89
798 #endif
799 #include <stddef.h>
800 #ifdef HAVE_INTTYPES_H
801 # include <inttypes.h>
802 #endif
803 #ifdef HAVE_STDINT_H
804 # include <stdint.h>
805 #endif
806 #include <sys/types.h>
807 int main ()
808 {
809 ssize_t s = 1;
810 int *size_int = &s;
811 return (int)*size_int;
812 }
813 ]])],glib_ssize_type=int,
814 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
815 #if defined(_AIX) && !defined(__GNUC__)
816 #pragma options langlvl=stdc89
817 #endif
818 #include <stddef.h>
819 #ifdef HAVE_INTTYPES_H
820 # include <inttypes.h>
821 #endif
822 #ifdef HAVE_STDINT_H
823 # include <stdint.h>
824 #endif
825 #include <sys/types.h>
826 int main ()
827 {
828 ssize_t s = 1;
829 long *size_long = &s;
830 return (int)*size_long;
831 }
832 ]])],glib_ssize_type=long)])
833 ])
835 AC_MSG_RESULT($glib_ssize_type)
837 # Check for some functions
838 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
839 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
840 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
841 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
842 AC_CHECK_FUNCS(splice)
843 AC_CHECK_FUNCS(prlimit)
845 # To avoid finding a compatibility unusable statfs, which typically
846 # successfully compiles, but warns to use the newer statvfs interface:
847 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
848 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
850 AC_MSG_CHECKING([whether to use statfs or statvfs])
851 # Some systems have both statfs and statvfs, pick the most "native" for these
852 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
853 [
854 # on solaris and irix, statfs doesn't even have the f_bavail field
855 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
856 [ac_cv_func_statfs=no],
857 # else, at least on linux, statfs is the actual syscall
858 [ac_cv_func_statvfs=no])
859 ])
861 AS_IF([test x$ac_cv_func_statfs = xyes],
862 [
863 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
864 AC_MSG_RESULT([statfs])
865 ],
866 [test x$ac_cv_func_statvfs = xyes],
867 [
868 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
869 AC_MSG_RESULT([statvfs])
870 ],
871 [ AC_MSG_RESULT([neither])])
873 AC_CHECK_HEADERS(crt_externs.h)
874 AC_CHECK_FUNCS(_NSGetEnviron)
876 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
878 # Internet address families
879 if test $glib_native_win32 = yes; then
880 glib_inet_includes=["
881 #include <winsock2.h>
882 "]
883 else
884 glib_inet_includes=["
885 #include <sys/types.h>
886 #include <sys/socket.h>
887 "]
888 fi
890 glib_failed=false
891 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
892 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
893 # winsock defines this even though it doesn't support it
894 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
895 if $glib_failed ; then
896 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
897 fi
899 glib_failed=false
900 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
901 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
902 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
903 if $glib_failed ; then
904 AC_MSG_ERROR([Could not determine values for MSG_* constants])
905 fi
907 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
909 AC_MSG_CHECKING([for SIOCGIFADDR])
910 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
911 [[
912 #include <sys/ioctl.h>
913 #include <net/if.h>
914 ]],
915 [[
916 struct ifreq ifr;
917 ioctl(0, SIOCGIFADDR, &ifr);
918 ]])], [
919 AC_MSG_RESULT(yes)
920 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
921 ], [
922 AC_MSG_RESULT(no)
923 ])
925 # See https://bugzilla.gnome.org/show_bug.cgi?id=740791
926 AS_IF([test $glib_native_android = yes], [
927 AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
928 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
929 [[
930 #include <netinet/in.h>
931 ]],
932 [[
933 struct ip_mreq_source mc_req_src;
934 mc_req_src.imr_interface.s_addr = 0;
935 ]])], [
936 AC_MSG_RESULT(yes)
937 ], [
938 AC_MSG_RESULT(no)
939 AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
940 ])])
942 AS_IF([test $glib_native_win32 = yes], [
943 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
944 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
945 # they aren't present at run-time (on Windows 2000).
946 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
947 AC_SUBST(WSPIAPI_INCLUDE)
948 ], [
949 # Android does not have C_IN in public headers, we define it wherever necessary
950 AS_IF([test $glib_native_android != yes], [
951 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
952 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
953 #include <arpa/nameser.h>],
954 [int qclass = C_IN;])],
955 [AC_MSG_RESULT([no])],
956 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
957 #include <arpa/nameser.h>
958 #include <arpa/nameser_compat.h>],
959 [int qclass = C_IN;])],
960 [AC_MSG_RESULT([yes])
961 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
962 [AC_MSG_ERROR([could not compile test program either way])])])])
963 AC_SUBST(NAMESER_COMPAT_INCLUDE)
965 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
966 NETWORK_LIBS=""
967 AC_MSG_CHECKING([for res_query])
968 AC_TRY_LINK([#include <sys/types.h>
969 #include <netinet/in.h>
970 #include <arpa/nameser.h>
971 #include <resolv.h>
972 ],[
973 res_query("test", 0, 0, (void *)0, 0);
974 ],[AC_MSG_RESULT([yes])],
975 [save_libs="$LIBS"
976 LIBS="-lresolv $LIBS"
977 AC_TRY_LINK([#include <sys/types.h>
978 #include <netinet/in.h>
979 #include <arpa/nameser.h>
980 #include <resolv.h>
981 ],[
982 res_query("test", 0, 0, (void *)0, 0);
983 ],[AC_MSG_RESULT([in -lresolv])
984 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
985 [LIBS="-lbind $save_libs"
986 AC_TRY_LINK([#include <resolv.h>],
987 [res_query("test", 0, 0, (void *)0, 0);],
988 [AC_MSG_RESULT([in -lbind])
989 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
990 [AC_MSG_ERROR(not found)])])
991 LIBS="$save_libs"])
992 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
993 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
994 [AC_MSG_ERROR(Could not find socket())]))
995 save_libs="$LIBS"
996 LIBS="$LIBS $NETWORK_LIBS"
998 AC_MSG_CHECKING([for res_init])
999 AC_TRY_LINK([#include <sys/types.h>
1000 #include <netinet/in.h>
1001 #include <arpa/nameser.h>
1002 #include <resolv.h>
1003 ],[
1004 res_init();
1005 ],[AC_MSG_RESULT([yes])
1006 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1007 ],[AC_MSG_RESULT([no])])
1009 AC_MSG_CHECKING([for res_nclose])
1010 AC_TRY_LINK([#include <sys/types.h>
1011 #include <netinet/in.h>
1012 #include <arpa/nameser.h>
1013 #include <resolv.h>
1014 ],[
1015 struct __res_state res;
1016 res_nclose(&res);
1017 ],[AC_MSG_RESULT([yes])
1018 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1019 ],[AC_MSG_RESULT([no])])
1021 AC_MSG_CHECKING([for res_ndestroy])
1022 AC_TRY_LINK([#include <sys/types.h>
1023 #include <netinet/in.h>
1024 #include <arpa/nameser.h>
1025 #include <resolv.h>
1026 ],[
1027 struct __res_state res;
1028 res_ndestroy(&res);
1029 ],[AC_MSG_RESULT([yes])
1030 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1031 ],[AC_MSG_RESULT([no])])
1033 AC_MSG_CHECKING([for res_ninit])
1034 AC_TRY_LINK([#include <sys/types.h>
1035 #include <netinet/in.h>
1036 #include <arpa/nameser.h>
1037 #include <resolv.h>
1038 ],[
1039 struct __res_state res;
1040 res_ninit(&res);
1041 ],[AC_MSG_RESULT([yes])
1042 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1043 ],[AC_MSG_RESULT([no])])
1045 AC_MSG_CHECKING([for res_nquery])
1046 AC_TRY_LINK([#include <sys/types.h>
1047 #include <netinet/in.h>
1048 #include <arpa/nameser.h>
1049 #include <resolv.h>
1050 ],[
1051 struct __res_state res;
1052 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1053 ],[AC_MSG_RESULT([yes])
1054 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1055 ],[AC_MSG_RESULT([no])])
1056 LIBS="$save_libs"
1057 ])
1058 AC_SUBST(NETWORK_LIBS)
1060 AC_CHECK_HEADER([linux/netlink.h],
1061 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1062 [#include <sys/socket.h>])
1063 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1065 AC_CHECK_TYPE([struct ip_mreqn], [
1066 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1067 [#include <netinet/in.h>])
1069 case $host in
1070 *-*-solaris* )
1071 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1072 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1073 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1074 ;;
1075 esac
1077 dnl
1078 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1079 dnl
1080 AS_IF([test "$ac_cv_func_statfs" = yes], [
1081 AC_MSG_CHECKING([number of arguments to statfs()])
1082 AC_TRY_COMPILE([#include <unistd.h>
1083 #ifdef HAVE_SYS_PARAM_H
1084 #include <sys/param.h>
1085 #endif
1086 #ifdef HAVE_SYS_VFS_H
1087 #include <sys/vfs.h>
1088 #endif
1089 #ifdef HAVE_SYS_MOUNT_H
1090 #include <sys/mount.h>
1091 #endif
1092 #ifdef HAVE_SYS_STATFS_H
1093 #include <sys/statfs.h>
1094 #endif], [struct statfs st;
1095 statfs("/", &st);],[
1096 AC_MSG_RESULT([2])
1097 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1098 AC_TRY_COMPILE([#include <unistd.h>
1099 #ifdef HAVE_SYS_PARAM_H
1100 #include <sys/param.h>
1101 #endif
1102 #ifdef HAVE_SYS_VFS_H
1103 #include <sys/vfs.h>
1104 #endif
1105 #ifdef HAVE_SYS_MOUNT_H
1106 #include <sys/mount.h>
1107 #endif
1108 #ifdef HAVE_SYS_STATFS_H
1109 #include <sys/statfs.h>
1110 #endif], [struct statfs st;
1111 statfs("/", &st, sizeof (st), 0);],[
1112 AC_MSG_RESULT([4])
1113 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1114 AC_MSG_RESULT(unknown)
1115 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1116 ])
1118 dnl
1119 dnl open takes O_DIRECTORY as an option
1120 dnl
1121 AC_MSG_CHECKING([open() option O_DIRECTORY])
1122 AC_TRY_COMPILE([#include <fcntl.h>
1123 #include <sys/types.h>
1124 #include <sys/stat.h>],
1125 [open(0, O_DIRECTORY, 0);],[
1126 AC_MSG_RESULT([yes])
1127 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1128 AC_MSG_RESULT([no])])
1130 #
1131 # Check whether to use an included printf
1132 #
1133 AC_FUNC_VSNPRINTF_C99
1134 AC_FUNC_PRINTF_UNIX98
1136 AC_ARG_ENABLE(included-printf,
1137 [AS_HELP_STRING([--enable-included-printf],
1138 [use included printf [default=auto]])],
1139 enable_included_printf="$enableval")
1141 need_included_printf=no
1142 if test "x$enable_included_printf" = "xyes" ; then
1143 need_included_printf=yes
1144 fi
1145 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1146 need_included_printf=yes
1147 fi
1148 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1149 need_included_printf=yes
1150 fi
1151 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1152 test -z "$glib_cv_long_long_format" ; then
1153 need_included_printf=yes
1154 fi
1156 if test "x$enable_included_printf" = "xno" &&
1157 test "x$need_included_printf" = "xyes" ; then
1158 AC_MSG_ERROR([
1159 *** Your C library's printf doesn't appear to have the features that
1160 *** GLib needs, but you specified --enable-included-printf=no.])
1161 fi
1163 enable_included_printf=$need_included_printf
1165 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1166 AS_IF([test "$enable_included_printf" != "yes"], [
1167 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1168 ], [
1169 if test -z "$glib_cv_long_long_format" ; then
1170 glib_cv_long_long_format="ll"
1171 fi
1172 AC_DEFINE(HAVE_VASPRINTF,1)
1173 ])
1175 # Checks needed for gnulib vasnprintf
1176 bh_C_SIGNED
1177 jm_AC_TYPE_LONG_LONG
1178 gt_TYPE_LONGDOUBLE
1179 gt_TYPE_WCHAR_T
1180 gt_TYPE_WINT_T
1181 AC_TYPE_SIZE_T
1182 AC_CHECK_TYPES(ptrdiff_t)
1183 jm_AC_TYPE_INTMAX_T
1184 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1185 AC_FUNC_SNPRINTF_C99
1187 dnl Check for nl_langinfo and CODESET
1188 AC_LANG_SAVE
1189 AC_LANG_C
1190 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1191 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1192 [char *codeset = nl_langinfo (CODESET);])],
1193 [glib_cv_langinfo_codeset=yes],
1194 [glib_cv_langinfo_codeset=no])])
1195 if test x$glib_cv_langinfo_codeset = xyes; then
1196 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1197 fi
1199 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1200 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1201 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1202 [char *str;
1203 str = nl_langinfo (PM_STR);
1204 str = nl_langinfo (D_T_FMT);
1205 str = nl_langinfo (D_FMT);
1206 str = nl_langinfo (T_FMT);
1207 str = nl_langinfo (T_FMT_AMPM);
1208 str = nl_langinfo (MON_1);
1209 str = nl_langinfo (ABMON_12);
1210 str = nl_langinfo (DAY_1);
1211 str = nl_langinfo (ABDAY_7);])],
1212 [glib_cv_langinfo_time=yes],
1213 [glib_cv_langinfo_time=no])])
1214 if test x$glib_cv_langinfo_time = xyes; then
1215 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1216 fi
1218 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1219 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1220 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1221 [char *str;
1222 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1223 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1224 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1225 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1226 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1227 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1228 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1229 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1230 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1231 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1232 [glib_cv_langinfo_outdigit=yes],
1233 [glib_cv_langinfo_outdigit=no])])
1234 if test x$glib_cv_langinfo_outdigit = xyes; then
1235 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1236 fi
1238 dnl Check for nl_langinfo and ALTMON_n
1239 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1240 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1241 [char *str;
1242 str = nl_langinfo (ALTMON_1);
1243 str = nl_langinfo (ALTMON_2);
1244 str = nl_langinfo (ALTMON_3);
1245 str = nl_langinfo (ALTMON_4);
1246 str = nl_langinfo (ALTMON_5);
1247 str = nl_langinfo (ALTMON_6);
1248 str = nl_langinfo (ALTMON_7);
1249 str = nl_langinfo (ALTMON_8);
1250 str = nl_langinfo (ALTMON_9);
1251 str = nl_langinfo (ALTMON_10);
1252 str = nl_langinfo (ALTMON_11);
1253 str = nl_langinfo (ALTMON_12);])],
1254 [glib_cv_langinfo_altmon=yes],
1255 [glib_cv_langinfo_altmon=no])])
1256 if test x$glib_cv_langinfo_altmon = xyes; then
1257 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1258 fi
1260 dnl Check for nl_langinfo and _NL_ABALTMON_n
1261 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1262 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1263 [char *str;
1264 str = nl_langinfo (_NL_ABALTMON_1);
1265 str = nl_langinfo (_NL_ABALTMON_2);
1266 str = nl_langinfo (_NL_ABALTMON_3);
1267 str = nl_langinfo (_NL_ABALTMON_4);
1268 str = nl_langinfo (_NL_ABALTMON_5);
1269 str = nl_langinfo (_NL_ABALTMON_6);
1270 str = nl_langinfo (_NL_ABALTMON_7);
1271 str = nl_langinfo (_NL_ABALTMON_8);
1272 str = nl_langinfo (_NL_ABALTMON_9);
1273 str = nl_langinfo (_NL_ABALTMON_10);
1274 str = nl_langinfo (_NL_ABALTMON_11);
1275 str = nl_langinfo (_NL_ABALTMON_12);])],
1276 [glib_cv_langinfo_abaltmon=yes],
1277 [glib_cv_langinfo_abaltmon=no])])
1278 if test x$glib_cv_langinfo_abaltmon = xyes; then
1279 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1280 fi
1281 AC_LANG_RESTORE
1284 dnl ****************************************
1285 dnl *** strlcpy/strlcat ***
1286 dnl ****************************************
1287 # Check for strlcpy
1288 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1289 AC_TRY_RUN([#include <stdlib.h>
1290 #include <string.h>
1291 int main() {
1292 char p[10];
1293 (void) strlcpy (p, "hi", 10);
1294 if (strlcat (p, "bye", 0) != 3)
1295 return 1;
1296 return 0;
1297 }], glib_cv_have_strlcpy=yes,
1298 glib_cv_have_strlcpy=no,
1299 glib_cv_have_strlcpy=no)])
1300 if test "$glib_cv_have_strlcpy" = "yes"; then
1301 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1302 fi
1305 dnl **********************
1306 dnl *** va_copy checks ***
1307 dnl **********************
1308 dnl we currently check for all three va_copy possibilities, so we get
1309 dnl all results in config.log for bug reports.
1310 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1311 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1312 #include <stdlib.h>
1313 void f (int i, ...) {
1314 va_list args1, args2;
1315 va_start (args1, i);
1316 va_copy (args2, args1);
1317 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1318 exit (1);
1319 va_end (args1); va_end (args2);
1320 }
1321 int main() {
1322 f (0, 42);
1323 return 0;
1324 }]])],
1325 [glib_cv_va_copy=yes],
1326 [glib_cv_va_copy=no])
1327 ])
1328 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1329 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1330 #include <stdlib.h>
1331 void f (int i, ...) {
1332 va_list args1, args2;
1333 va_start (args1, i);
1334 __va_copy (args2, args1);
1335 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1336 exit (1);
1337 va_end (args1); va_end (args2);
1338 }
1339 int main() {
1340 f (0, 42);
1341 return 0;
1342 }]])],
1343 [glib_cv___va_copy=yes],
1344 [glib_cv___va_copy=no])
1345 ])
1347 if test "x$glib_cv_va_copy" = "xyes"; then
1348 g_va_copy_func=va_copy
1349 else if test "x$glib_cv___va_copy" = "xyes"; then
1350 g_va_copy_func=__va_copy
1351 fi
1352 fi
1354 if test -n "$g_va_copy_func"; then
1355 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1356 fi
1358 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1359 AC_TRY_RUN([#include <stdarg.h>
1360 #include <stdlib.h>
1361 void f (int i, ...) {
1362 va_list args1, args2;
1363 va_start (args1, i);
1364 args2 = args1;
1365 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1366 exit (1);
1367 va_end (args1); va_end (args2);
1368 }
1369 int main() {
1370 f (0, 42);
1371 return 0;
1372 }],
1373 [glib_cv_va_val_copy=yes],
1374 [glib_cv_va_val_copy=no],
1375 [glib_cv_va_val_copy=yes])
1376 ])
1378 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1379 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1380 ])
1382 dnl ***********************
1383 dnl *** g_module checks ***
1384 dnl ***********************
1385 G_MODULE_LIBS=
1386 G_MODULE_LIBS_EXTRA=
1387 G_MODULE_PLUGIN_LIBS=
1388 if test x"$glib_native_win32" = xyes; then
1389 dnl No use for this on Win32
1390 G_MODULE_LDFLAGS=
1391 else
1392 export SED
1393 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1394 fi
1395 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1396 G_MODULE_NEED_USCORE=0
1397 G_MODULE_BROKEN_RTLD_GLOBAL=0
1398 G_MODULE_HAVE_DLERROR=0
1399 dnl *** force native WIN32 shared lib loader
1400 if test -z "$G_MODULE_IMPL"; then
1401 case "$host" in
1402 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1403 esac
1404 fi
1405 dnl *** force native AIX library loader
1406 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1407 if test -z "$G_MODULE_IMPL"; then
1408 case "$host" in
1409 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1410 esac
1411 fi
1412 dnl *** dlopen() and dlsym() in system libraries
1413 AS_IF([ test -z "$G_MODULE_IMPL"], [
1414 AC_CHECK_FUNC(dlopen,
1415 [AC_CHECK_FUNC(dlsym,
1416 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1417 [])
1418 ])
1419 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1420 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1421 AC_CHECK_FUNC(NSLinkModule,
1422 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1423 G_MODULE_NEED_USCORE=1],
1424 [])
1425 ])
1426 dnl *** dlopen() and dlsym() in libdl
1427 AS_IF([ test -z "$G_MODULE_IMPL"], [
1428 AC_CHECK_LIB(dl, dlopen,
1429 [AC_CHECK_LIB(dl, dlsym,
1430 [G_MODULE_LIBS=-ldl
1431 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1432 [])
1433 ])
1434 dnl *** additional checks for G_MODULE_IMPL_DL
1435 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1436 LIBS_orig="$LIBS"
1437 LDFLAGS_orig="$LDFLAGS"
1438 LIBS="$G_MODULE_LIBS $LIBS"
1439 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1440 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1441 echo "void glib_plugin_test(void) { }" > plugin.c
1442 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1443 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1444 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1445 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1446 -shrext ".o" -avoid-version plugin.lo \
1447 -rpath /dont/care >/dev/null 2>&1
1448 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1449 glib_cv_rtldglobal_broken,[
1450 AC_TRY_RUN([
1451 #include <dlfcn.h>
1452 #ifndef RTLD_GLOBAL
1453 # define RTLD_GLOBAL 0
1454 #endif
1455 #ifndef RTLD_LAZY
1456 # define RTLD_LAZY 0
1457 #endif
1458 int glib_plugin_test;
1459 int main () {
1460 void *handle, *global, *local;
1461 global = &glib_plugin_test;
1462 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1463 if (!handle) return 0;
1464 local = dlsym (handle, "glib_plugin_test");
1465 return global == local;
1466 } ],
1467 [glib_cv_rtldglobal_broken=no],
1468 [glib_cv_rtldglobal_broken=yes],
1469 [glib_cv_rtldglobal_broken=no])
1470 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1471 rmdir ${objdir} 2>/dev/null
1472 ])
1473 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1474 G_MODULE_BROKEN_RTLD_GLOBAL=1
1475 else
1476 G_MODULE_BROKEN_RTLD_GLOBAL=0
1477 fi
1478 dnl *** check whether we need preceeding underscores
1479 AC_CACHE_CHECK([for preceeding underscore in symbols],
1480 glib_cv_uscore,[
1481 AC_TRY_RUN([#include <dlfcn.h>
1482 int glib_underscore_test (void) { return 42; }
1483 int main() {
1484 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1485 handle = dlopen ((void*)0, 0);
1486 if (handle) {
1487 f1 = dlsym (handle, "glib_underscore_test");
1488 f2 = dlsym (handle, "_glib_underscore_test");
1489 } return (!f2 || f1);
1490 }],
1491 [glib_cv_uscore=yes],
1492 [glib_cv_uscore=no],
1493 [])
1494 rm -f plugin.c plugin.$ac_objext plugin.lo
1495 ])
1496 GLIB_ASSERT_SET(glib_cv_uscore)
1497 if test "x$glib_cv_uscore" = "xyes"; then
1498 G_MODULE_NEED_USCORE=1
1499 else
1500 G_MODULE_NEED_USCORE=0
1501 fi
1503 AC_CHECK_DECL([RTLD_LAZY],
1504 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1505 [], [[#include <dlfcn.h>]])
1506 AC_CHECK_DECL([RTLD_NOW],
1507 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1508 [], [[#include <dlfcn.h>]])
1509 AC_CHECK_DECL([RTLD_GLOBAL],
1510 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1511 [], [[#include <dlfcn.h>]])
1513 LDFLAGS="$LDFLAGS_orig"
1514 dnl *** check for having dlerror()
1515 AC_CHECK_FUNC(dlerror,
1516 [G_MODULE_HAVE_DLERROR=1],
1517 [G_MODULE_HAVE_DLERROR=0])
1518 LIBS="$LIBS_orig"
1519 ])
1520 dnl *** done, have we got an implementation?
1521 if test -z "$G_MODULE_IMPL"; then
1522 G_MODULE_IMPL=0
1523 G_MODULE_SUPPORTED=false
1524 else
1525 G_MODULE_SUPPORTED=true
1526 fi
1528 AC_MSG_CHECKING(for the suffix of module shared libraries)
1529 export SED
1530 module=yes eval std_shrext=$shrext_cmds
1531 # chop the initial dot
1532 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1533 AC_MSG_RESULT(.$glib_gmodule_suffix)
1534 # any reason it may fail?
1535 if test "x$glib_gmodule_suffix" = x; then
1536 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1537 fi
1539 AC_SUBST(G_MODULE_SUPPORTED)
1540 AC_SUBST(G_MODULE_IMPL)
1541 AC_SUBST(G_MODULE_LIBS)
1542 AC_SUBST(G_MODULE_LIBS_EXTRA)
1543 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1544 AC_SUBST(G_MODULE_LDFLAGS)
1545 AC_SUBST(G_MODULE_HAVE_DLERROR)
1546 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1547 AC_SUBST(G_MODULE_NEED_USCORE)
1548 AC_SUBST(GLIB_DEBUG_FLAGS)
1550 dnl **********************
1551 dnl *** g_spawn checks ***
1552 dnl **********************
1554 AC_MSG_CHECKING(for gspawn implementation)
1555 case "$host" in
1556 *-*-mingw*)
1557 g_spawn_impl=win32
1558 ;;
1559 *)
1560 g_spawn_impl=unix
1561 ;;
1562 esac
1563 AC_MSG_RESULT($g_spawn_impl)
1564 AM_CONDITIONAL(G_SPAWN_WIN32, [test "$g_spawn_impl" = "win32"])
1566 dnl *************************
1567 dnl *** GIOChannel checks ***
1568 dnl *************************
1570 AC_MSG_CHECKING(for GIOChannel implementation)
1571 case "$host" in
1572 *-*-mingw*)
1573 g_io_channel_impl=win32
1574 ;;
1575 *)
1576 g_io_channel_impl=unix
1577 ;;
1578 esac
1579 AC_MSG_RESULT($g_io_channel_impl)
1580 AM_CONDITIONAL(G_IO_CHANNEL_WIN32, [test "$g_io_channel_impl" = "win32"])
1582 dnl *********************************
1583 dnl *** Directory for GIO modules ***
1584 dnl *********************************
1586 AC_ARG_WITH(gio-module-dir,
1587 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1588 [load gio modules from this directory [LIBDIR/gio/modules]])],
1589 [],
1590 [with_gio_module_dir='${libdir}/gio/modules'])
1591 GIO_MODULE_DIR=$with_gio_module_dir
1592 AC_SUBST(GIO_MODULE_DIR)
1594 dnl **********************************
1595 dnl *** Check for libselinux (GIO) ***
1596 dnl **********************************
1597 AC_ARG_ENABLE(selinux,
1598 AS_HELP_STRING([--disable-selinux],
1599 [build without selinux support]))
1600 msg_selinux=no
1601 SELINUX_LIBS=
1602 AS_IF([ test "x$enable_selinux" != "xno"], [
1604 AC_CHECK_LIB(selinux, is_selinux_enabled,
1605 [AC_CHECK_HEADERS(selinux/selinux.h,
1606 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1607 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1608 SELINUX_LIBS="-lselinux"
1609 msg_selinux=yes])
1610 ])
1611 ])
1612 ])
1613 AC_SUBST(SELINUX_LIBS)
1615 dnl *****************************
1616 dnl ** Check for inotify (GIO) **
1617 dnl *****************************
1618 inotify_support=no
1619 AC_CHECK_HEADERS([sys/inotify.h],
1620 [
1621 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1622 ])
1624 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1626 dnl ****************************
1627 dnl ** Check for kqueue (GIO) **
1628 dnl ****************************
1629 kqueue_support=no
1630 AC_CHECK_HEADERS([sys/event.h],
1631 [
1632 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1633 ])
1635 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1637 dnl ****************************
1638 dnl *** Checks for FAM (GIO) ***
1639 dnl ****************************
1641 should_disable_fam=no
1643 AC_ARG_ENABLE(fam,
1644 AS_HELP_STRING([--disable-fam],
1645 [don't use fam for file system monitoring]),
1646 [
1647 if test "x$enable_fam" = "xno"; then
1648 should_disable_fam=yes
1649 fi
1650 ]
1651 )
1652 fam_support=no
1653 FAM_LIBS=
1654 if test "x$should_disable_fam" = "xno"; then
1655 AC_CHECK_LIB(fam, FAMOpen,
1656 [AC_CHECK_HEADERS(fam.h,
1657 [AC_CHECK_LIB(fam, FAMNoExists,
1658 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1659 FAM_LIBS="-lfam"]
1660 fam_support=yes,
1661 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1662 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1663 AC_SUBST(FAM_LIBS)
1664 fi
1665 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1668 dnl *****************************
1669 dnl *** Check for xattr (GIO) ***
1670 dnl *****************************
1671 AC_ARG_ENABLE(xattr,
1672 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1673 msg_xattr=no
1674 XATTR_LIBS=
1675 AS_IF([ test "x$enable_xattr" != "xno"], [
1677 dnl either glibc or libattr can provide xattr support
1679 dnl for both of them, we check for getxattr being in
1680 dnl the library and a valid xattr header.
1682 dnl try glibc
1683 AC_CHECK_LIB(c, getxattr,
1684 [AC_CHECK_HEADERS(sys/xattr.h,
1685 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1686 msg_xattr=yes])
1687 ])
1689 AS_IF([ test "x$msg_xattr" != "xyes"], [
1690 dnl failure. try libattr
1691 AC_CHECK_LIB(attr, getxattr,
1692 [AC_CHECK_HEADERS(attr/xattr.h,
1693 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1694 XATTR_LIBS="-lattr"
1695 msg_xattr=yes])
1696 ])
1697 ])
1699 AS_IF([ test "x$msg_xattr" = "xyes"], [
1700 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1701 AC_TRY_COMPILE([
1702 #include <stdio.h>
1703 #ifdef HAVE_SYS_TYPES_H
1704 #include <sys/types.h>
1705 #endif
1706 #ifdef HAVE_SYS_XATTR_H
1707 #include <sys/xattr.h>
1708 #elif HAVE_ATTR_XATTR_H
1709 #include <attr/xattr.h>
1710 #endif
1711 ],
1712 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1713 [
1714 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1715 AC_MSG_RESULT([yes])
1716 ],
1717 [AC_MSG_RESULT([no])]
1718 )
1719 ])
1720 ])
1721 AC_SUBST(XATTR_LIBS)
1723 dnl ************************
1724 dnl *** check for libelf ***
1725 dnl ************************
1726 AC_ARG_ENABLE(libelf,
1727 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1728 AS_IF([ test "x$enable_libelf" != "xno"],[
1729 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1730 AS_IF([ test $have_libelf = maybe ], [
1731 glib_save_LIBS=$LIBS
1732 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1733 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1734 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1735 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1736 LIBS=$glib_save_LIBS
1738 if test $have_libelf != no; then
1739 LIBELF_LIBS=-lelf
1740 have_libelf=yes
1741 fi
1742 ])
1743 ])
1745 if test x$have_libelf = xyes; then
1746 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1747 fi
1749 dnl ************************
1750 dnl *** check for libmount ***
1751 dnl ************************
1753 dnl The fallback code doesn't really implement the same behaviors - e.g.
1754 dnl so on linux we want to require libmount unless specifically disabled
1755 dnl
1756 enable_libmount_default=${glib_os_linux:-no}
1757 AC_ARG_ENABLE(libmount,
1758 [AS_HELP_STRING([--enable-libmount],
1759 [build with libmount support [default for Linux]])],,
1760 [enable_libmount=$enable_libmount_default])
1761 AS_IF([ test "x$enable_libmount" = "xyes"],[
1762 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1763 if test $have_libmount = no ; then
1764 AC_MSG_ERROR([*** Could not find libmount])
1765 fi
1766 ])
1768 if test x$have_libmount = xyes; then
1769 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1770 fi
1771 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1773 dnl ****************************************
1774 dnl *** platform dependent source checks ***
1775 dnl ****************************************
1777 AC_MSG_CHECKING([whether to compile timeloop])
1778 case "$host" in
1779 *-*-cygwin*|*-*-mingw*|*-*-minix)
1780 enable_timeloop=no
1781 ;;
1782 *)
1783 enable_timeloop=yes
1784 ;;
1785 esac
1786 AC_MSG_RESULT($enable_timeloop)
1787 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1789 AC_MSG_CHECKING([if building for some Win32 platform])
1790 case "$host" in
1791 *-*-mingw*|*-*-cygwin*)
1792 platform_win32=yes
1793 ;;
1794 *)
1795 platform_win32=no
1796 ;;
1797 esac
1798 AC_MSG_RESULT($platform_win32)
1799 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1801 dnl ***********************
1802 dnl *** g_thread checks ***
1803 dnl ***********************
1805 AC_ARG_WITH(threads,
1806 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1807 [specify a thread implementation to use])],
1808 [],
1809 [with_threads=yes])
1811 dnl error and warning message
1812 dnl *************************
1814 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1816 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1817 platform (normally it's "_REENTRANT"). I'll not use any flag on
1818 compilation now, but then your programs might not work.
1819 Please provide information on how it is done on your system."
1821 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1822 "
1824 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1825 provide information on your thread implementation."
1827 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1828 functions will not be MT-safe during their first call because
1829 there is no working 'getpwuid_r' on your system."
1831 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1832 because there is no 'localtime_r' on your system."
1834 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1835 linking threaded applications. As GLib cannot do that
1836 automatically, you will get an linkg error everytime you are
1837 not using the right compiler. In that case you have to relink
1838 with the right compiler. Ususally just '_r' is appended
1839 to the compiler name."
1841 dnl determination of thread implementation
1842 dnl ***************************************
1844 AC_MSG_CHECKING(for thread implementation)
1846 have_threads=no
1847 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1848 AS_IF([ test "x$have_threads" = xno], [
1849 AC_TRY_COMPILE([#include <pthread.h>],
1850 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1851 have_threads=posix)
1852 ])
1853 # Tru64Unix requires -pthread to find pthread.h. See #103020
1854 if test "x$have_threads" = xno; then
1855 glib_save_CPPFLAGS="$CPPFLAGS"
1856 CPPFLAGS="$CPPFLAGS -pthread"
1857 AC_TRY_COMPILE([#include <pthread.h>],
1858 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1859 have_threads=posix)
1860 CPPFLAGS="$glib_save_CPPFLAGS"
1861 fi
1862 ])
1863 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1864 case $host in
1865 *-*-mingw*)
1866 have_threads=win32
1867 ;;
1868 esac
1869 fi
1871 if test "x$have_threads" = xno; then
1872 AC_MSG_RESULT(none available)
1873 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1874 else
1875 AC_MSG_RESULT($have_threads)
1876 fi
1879 dnl determination of G_THREAD_CFLAGS
1880 dnl ********************************
1882 G_THREAD_LIBS=
1883 G_THREAD_LIBS_EXTRA=
1884 G_THREAD_CFLAGS=
1886 dnl
1887 dnl Test program for basic POSIX threads functionality
1888 dnl
1889 m4_define([glib_thread_test],[
1890 #include <pthread.h>
1891 int check_me = 0;
1892 void* func(void* data) {check_me = 42; return &check_me;}
1893 int main()
1894 { pthread_t t;
1895 void *ret;
1896 pthread_create (&t, $1, func, 0);
1897 pthread_join (t, &ret);
1898 return (check_me != 42 || ret != &check_me);
1899 }])
1901 AS_IF([ test x"$have_threads" = xposix], [
1902 # First we test for posix, whether -pthread or -pthreads do the trick as
1903 # both CPPFLAG and LIBS.
1904 # One of them does for most gcc versions and some other platforms/compilers
1905 # too and could be considered as the canonical way to go.
1906 case $host in
1907 *-*-cygwin*|*-*-darwin*)
1908 # skip cygwin and darwin -pthread or -pthreads test
1909 ;;
1910 *-solaris*)
1911 # These compiler/linker flags work with both Sun Studio and gcc
1912 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1913 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1914 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1915 G_THREAD_LIBS="-lpthread -lthread"
1916 ;;
1917 *)
1918 for flag in pthread pthreads mt; do
1919 glib_save_CFLAGS="$CFLAGS"
1920 CFLAGS="$CFLAGS -$flag"
1921 AC_TRY_RUN(glib_thread_test(0),
1922 glib_flag_works=yes,
1923 glib_flag_works=no,
1924 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1925 glib_flag_works=yes,
1926 glib_flag_works=no)])
1927 CFLAGS="$glib_save_CFLAGS"
1928 if test $glib_flag_works = yes ; then
1929 G_THREAD_CFLAGS=-$flag
1930 G_THREAD_LIBS=-$flag
1931 break;
1932 fi
1933 done
1934 ;;
1935 esac
1936 ])
1938 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1940 # The canonical -pthread[s] does not work. Try something different.
1942 case $host in
1943 *-aix*)
1944 if test x"$GCC" = xyes; then
1945 # GCC 3.0 and above needs -pthread.
1946 # Should be coverd by the case above.
1947 # GCC 2.x and below needs -mthreads
1948 G_THREAD_CFLAGS="-mthreads"
1949 G_THREAD_LIBS=$G_THREAD_CFLAGS
1950 else
1951 # We are probably using the aix compiler. Normaly a
1952 # program would have to be compiled with the _r variant
1953 # of the corresponding compiler, but we as GLib cannot
1954 # do that: but the good news is that for compiling the
1955 # only difference is the added -D_THREAD_SAFE compile
1956 # option. This is according to the "C for AIX User's
1957 # Guide".
1958 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1959 fi
1960 ;;
1961 *-sysv5uw7*) # UnixWare 7
1962 # We are not using gcc with -pthread. Catched above.
1963 G_THREAD_CFLAGS="-Kthread"
1964 G_THREAD_LIBS=$G_THREAD_CFLAGS
1965 ;;
1966 *-mingw*)
1967 # No flag needed when using MSVCRT.DLL
1968 G_THREAD_CFLAGS=""
1969 ;;
1970 *)
1971 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1972 ;;
1973 esac
1974 ])
1976 # if we are not finding the localtime_r function, then we probably are
1977 # not using the proper multithread flag
1979 glib_save_CPPFLAGS="$CPPFLAGS"
1980 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1982 # First we test, whether localtime_r is declared in time.h
1983 # directly. Then we test whether a macro localtime_r exists, in
1984 # which case localtime_r in the test program is replaced and thus
1985 # if we still find localtime_r in the output, it is not defined as
1986 # a macro.
1988 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1989 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1990 localtime_r(a,b)],
1991 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1993 CPPFLAGS="$glib_save_CPPFLAGS"
1995 AC_MSG_CHECKING(thread related cflags)
1996 AC_MSG_RESULT($G_THREAD_CFLAGS)
1997 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1999 dnl determination of G_THREAD_LIBS
2000 dnl ******************************
2002 AS_IF([test x$have_threads = xposix], [
2003 glib_save_CPPFLAGS="$CPPFLAGS"
2004 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2005 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2006 case $host in
2007 *-aix*)
2008 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2009 # probably using the aix compiler.
2010 AC_MSG_WARN($AIX_COMPILE_INFO)
2011 ;;
2012 *)
2013 G_THREAD_LIBS=error
2014 glib_save_LIBS="$LIBS"
2015 for thread_lib in "" pthread pthread32 pthreads thread; do
2016 if test x"$thread_lib" = x; then
2017 add_thread_lib=""
2018 IN=""
2019 else
2020 add_thread_lib="-l$thread_lib"
2021 IN=" in -l$thread_lib"
2022 fi
2023 if test x"$have_threads" = xposix; then
2024 defattr=0
2025 else
2026 defattr=pthread_attr_default
2027 fi
2029 LIBS="$add_thread_lib $glib_save_LIBS"
2031 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2032 AC_TRY_RUN(glib_thread_test($defattr),
2033 glib_result=yes,
2034 glib_result=no,
2035 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2036 glib_result=yes,
2037 glib_result=no)])
2038 AC_MSG_RESULT($glib_result)
2040 if test "$glib_result" = "yes" ; then
2041 G_THREAD_LIBS="$add_thread_lib"
2042 break
2043 fi
2044 done
2045 if test "x$G_THREAD_LIBS" = xerror; then
2046 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2047 fi
2048 LIBS="$glib_save_LIBS"
2049 ;;
2050 esac
2051 ])
2053 g_threads_impl="POSIX"
2054 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2055 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2056 CPPFLAGS="$glib_save_CPPFLAGS"
2057 ], [test x$have_threads = xwin32], [
2058 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2059 g_threads_impl="WIN32"
2060 ], [
2061 g_threads_impl="NONE"
2062 G_THREAD_LIBS=error
2063 ])
2064 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2065 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2067 if test "x$G_THREAD_LIBS" = xerror; then
2068 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2069 fi
2071 AC_MSG_CHECKING(thread related libraries)
2072 AC_MSG_RESULT($G_THREAD_LIBS)
2074 dnl check for mt safe function variants and some posix functions
2075 dnl ************************************************************
2077 glib_save_LIBS="$LIBS"
2078 # we are not doing the following for now, as this might require glib
2079 # to always be linked with the thread libs on some platforms.
2080 # LIBS="$LIBS $G_THREAD_LIBS"
2081 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2083 LIBS="$G_THREAD_LIBS $LIBS"
2084 AS_IF([ test x"$have_threads" = xposix], [
2085 glib_save_CPPFLAGS="$CPPFLAGS"
2086 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2087 # This is not AC_CHECK_FUNC to also work with function
2088 # name mangling in header files.
2089 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2090 AC_LINK_IFELSE(
2091 [AC_LANG_PROGRAM(
2092 [#include <pthread.h>],
2093 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2094 [AC_MSG_RESULT(yes)
2095 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2096 [Have function pthread_attr_setstacksize])],
2097 [AC_MSG_RESULT(no)])
2098 AC_MSG_CHECKING(for pthread_condattr_setclock)
2099 AC_LINK_IFELSE(
2100 [AC_LANG_PROGRAM(
2101 [#include <pthread.h>],
2102 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2103 [AC_MSG_RESULT(yes)
2104 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2105 [Have function pthread_condattr_setclock])],
2106 [AC_MSG_RESULT(no)])
2107 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2108 AC_LINK_IFELSE(
2109 [AC_LANG_PROGRAM(
2110 [#include <pthread.h>],
2111 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2112 [AC_MSG_RESULT(yes)
2113 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2114 [Have function pthread_cond_timedwait_relative_np])],
2115 [AC_MSG_RESULT(no)])
2116 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2117 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2118 AC_LINK_IFELSE(
2119 [AC_LANG_PROGRAM(
2120 [#include <pthread.h>],
2121 [pthread_setname_np("example")])],
2122 [AC_MSG_RESULT(yes)
2123 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2124 [Have function pthread_setname_np(const char*)])],
2125 [AC_MSG_RESULT(no)])
2126 dnl Sets thread names on Solaris 11.3 & higher
2127 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2128 AC_LINK_IFELSE(
2129 [AC_LANG_PROGRAM(
2130 [#include <pthread.h>],
2131 [pthread_setname_np(pthread_self(), "example")])],
2132 [AC_MSG_RESULT(yes)
2133 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2134 [Have function pthread_setname_np(pthread_t, const char*)])],
2135 [AC_MSG_RESULT(no)])
2136 AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2137 AC_LINK_IFELSE(
2138 [AC_LANG_PROGRAM(
2139 [#include <pthread.h>],
2140 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2141 [AC_MSG_RESULT(yes)
2142 AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2143 [Have function pthread_getname_np(pthread_t, name, len)])],
2144 [AC_MSG_RESULT(no)])
2145 CPPFLAGS="$glib_save_CPPFLAGS"
2146 ])
2148 LIBS="$glib_save_LIBS"
2150 # now spit out all the warnings.
2151 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2152 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2153 fi
2154 if test "$ac_cv_func_localtime_r" != "yes"; then
2155 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2156 fi
2158 #
2159 # Hack to deal with:
2160 #
2161 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2162 # building shared libraries with linux.
2163 # b) FreeBSD doesn't do this either.
2164 #
2165 case $host in
2166 *android*)
2167 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2168 ;;
2169 *-*-freebsd*|*-*-linux*)
2170 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2171 ;;
2172 *)
2173 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2174 ;;
2175 esac
2177 AC_SUBST(G_THREAD_CFLAGS)
2178 AC_SUBST(G_THREAD_LIBS)
2179 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2180 AC_SUBST(G_THREAD_LIBS_EXTRA)
2182 AC_CHECK_FUNCS(clock_gettime, [], [
2183 AC_CHECK_LIB(rt, clock_gettime, [
2184 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2185 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2186 ])
2187 ])
2190 dnl ************************
2191 dnl *** g_atomic_* tests ***
2192 dnl ************************
2194 dnl We need to decide at configure time if GLib will use real atomic
2195 dnl operations ("lock free") or emulated ones with a mutex. This is
2196 dnl because we must put this information in glibconfig.h so we know if
2197 dnl it is safe or not to inline using compiler intrinsics directly from
2198 dnl the header.
2199 dnl
2200 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2201 dnl user is interested in knowing if they can use the atomic ops across
2202 dnl processes.
2203 dnl
2204 dnl We can currently support the atomic ops natively when building GLib
2205 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2206 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2207 dnl we are using GCC (and not mingw*).
2208 dnl
2209 dnl Note that the atomic ops are only available with GCC on x86 when
2210 dnl using -march=i486 or higher. If we detect that the atomic ops are
2211 dnl not available but would be available given the right flags, we want
2212 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2213 dnl that then to silently fall back on emulated atomic ops just because
2214 dnl the user had the wrong build environment.
2216 dnl We may add other compilers here in the future...
2218 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2219 case $host in
2220 *-*-mingw*)
2221 glib_cv_g_atomic_lock_free=yes
2222 ;;
2223 *)
2224 AC_TRY_LINK([],
2225 [volatile int atomic = 2;\
2226 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2227 [glib_cv_g_atomic_lock_free=yes],
2228 [glib_cv_g_atomic_lock_free=no])
2229 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2230 SAVE_CFLAGS="${CFLAGS}"
2231 CFLAGS="-march=i486"
2232 AC_TRY_LINK([],
2233 [volatile int atomic = 2;\
2234 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2235 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2236 [])
2237 CFLAGS="${SAVE_CFLAGS}"
2238 fi
2239 ;;
2240 esac])
2243 case $host in
2244 *-*-mingw*)
2245 ;;
2246 *)
2247 # Some compilers support atomic operations but do not define
2248 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2249 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2250 AC_TRY_LINK([],
2251 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2252 [],
2253 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2254 fi
2255 ;;
2256 esac
2258 dnl We need a more robust approach here...
2259 case $host_cpu in
2260 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2261 glib_memory_barrier_needed=no
2262 ;;
2263 sparc*|alpha*|powerpc*|ia64)
2264 glib_memory_barrier_needed=yes
2265 ;;
2266 *)
2267 glib_memory_barrier_needed=yes
2268 ;;
2269 esac
2271 dnl ************************
2272 dnl ** Check for futex(2) **
2273 dnl ************************
2274 AC_CACHE_CHECK(for futex(2) system call,
2275 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2276 #include <linux/futex.h>
2277 #include <sys/syscall.h>
2278 #include <unistd.h>
2279 ],[
2280 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2281 ])],glib_cv_futex=yes,glib_cv_futex=no))
2282 if test x"$glib_cv_futex" = xyes; then
2283 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2284 fi
2286 AC_CACHE_CHECK(for eventfd(2) system call,
2287 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2288 #include <sys/eventfd.h>
2289 #include <unistd.h>
2290 ],[
2291 eventfd (0, EFD_CLOEXEC);
2292 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2293 if test x"$glib_cv_eventfd" = x"yes"; then
2294 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2295 fi
2296 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2298 dnl ****************************************
2299 dnl *** GLib POLL* compatibility defines ***
2300 dnl ****************************************
2302 glib_poll_includes=["
2303 #include <sys/types.h>
2304 #include <poll.h>
2305 "]
2307 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2308 test $ac_cv_func_poll = yes ], [
2309 glib_failed=false
2310 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2311 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2312 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2313 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2314 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2315 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2316 if $glib_failed ; then
2317 AC_MSG_ERROR([Could not determine values for POLL* constants])
2318 fi
2319 ], [
2320 glib_cv_value_POLLIN=1
2321 glib_cv_value_POLLOUT=4
2322 glib_cv_value_POLLPRI=2
2323 glib_cv_value_POLLERR=8
2324 glib_cv_value_POLLHUP=16
2325 glib_cv_value_POLLNVAL=32
2326 ])
2328 AC_MSG_CHECKING([for broken poll])
2329 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2330 #include <stdlib.h>
2331 #include <fcntl.h>
2332 #include <poll.h>
2333 int main(void) {
2334 struct pollfd fds[1];
2335 int fd;
2336 fd = open("/dev/null", 1);
2337 fds[0].fd = fd;
2338 fds[0].events = POLLIN;
2339 fds[0].revents = 0;
2340 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2341 exit(1); /* Does not work for devices -- fail */
2342 }
2343 exit(0);
2344 }]])],
2345 [broken_poll=no],
2346 [broken_poll=yes
2347 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2348 [broken_poll="no (cross compiling)"])
2349 AC_MSG_RESULT($broken_poll)
2351 dnl *********************
2352 dnl *** GRegex checks ***
2353 dnl *********************
2355 PCRE_REQUIRED_VERSION=8.31
2357 # Check if we should use the internal or the system-supplied pcre
2358 AC_ARG_WITH(pcre,
2359 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2360 [whether to use system PCRE [default=system]])],
2361 [],
2362 [with_pcre=system])
2364 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2366 AS_IF([ test "x$with_pcre" = xsystem], [
2367 PKG_CHECK_MODULES(PCRE,
2368 libpcre >= $PCRE_REQUIRED_VERSION)
2369 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2370 glib_save_CFLAGS="$CFLAGS"
2371 glib_save_LIBS="$LIBS"
2372 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2373 AC_TRY_RUN([#include <pcre.h>
2374 int main () {
2375 int support;
2376 pcre_config (PCRE_CONFIG_UTF8, &support);
2377 if (!support)
2378 return 1;
2379 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2380 if (!support)
2381 return 1;
2382 return 0;
2383 }],
2384 glib_cv_pcre_has_unicode=yes,
2385 glib_cv_pcre_has_unicode=no,
2386 glib_cv_pcre_has_unicode=yes)
2387 CFLAGS="$glib_save_CFLAGS"
2388 LIBS="$glib_save_LIBS"
2389 ])
2390 if test "$glib_cv_pcre_has_unicode" = "no"; then
2391 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2392 fi
2393 AC_SUBST(PCRE_CFLAGS)
2394 AC_SUBST(PCRE_LIBS)
2395 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2396 PCRE_REQUIRES=libpcre
2397 AC_SUBST(PCRE_REQUIRES)
2398 ], [
2399 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2400 AS_IF([ test x"$GCC" = xyes], [
2401 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2402 save_CFLAGS="$CFLAGS"
2403 CFLAGS="$CFLAGS -Wno-pointer-sign"
2404 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2405 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2406 CFLAGS="$save_CFLAGS"
2407 ])
2408 ])
2409 AC_SUBST(PCRE_WARN_CFLAGS)
2411 dnl **********************
2412 dnl *** Win32 API libs ***
2413 dnl **********************
2415 case $host in
2416 *-*-cygwin*)
2417 G_LIBS_EXTRA="-luser32 -lkernel32"
2418 ;;
2419 *-*-mingw*)
2420 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2421 ;;
2422 *)
2423 G_LIBS_EXTRA=""
2424 ;;
2425 esac
2426 AC_SUBST(G_LIBS_EXTRA)
2428 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2429 dnl since we need it for g_iconv()
2431 AC_MSG_CHECKING([for EILSEQ])
2432 AC_TRY_COMPILE([
2433 #include <errno.h>
2434 ],
2435 [
2436 int error = EILSEQ;
2437 ], have_eilseq=yes, have_eilseq=no);
2438 AC_MSG_RESULT($have_eilseq)
2440 dnl Add a conditional we can use when cross-compiling, so we avoid running
2441 dnl binaries
2442 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2444 dnl **************************
2445 dnl *** Checks for gtk-doc ***
2446 dnl **************************
2447 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2448 # it on it's own line.
2449 m4_ifdef([GTK_DOC_CHECK], [
2450 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2451 ],[
2452 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2453 ])
2455 AC_ARG_ENABLE(man,
2456 [AS_HELP_STRING([--enable-man],
2457 [generate man pages [default=auto]])],,
2458 enable_man=maybe)
2460 AS_IF([test "$enable_man" != no], [
2461 AC_PATH_PROG([XSLTPROC], [xsltproc])
2462 AS_IF([test -z "$XSLTPROC"], [
2463 AS_IF([test "$enable_man" = yes], [
2464 AC_MSG_ERROR([xsltproc is required for --enable-man])
2465 ])
2466 enable_man=no
2467 ])
2468 ])
2470 AS_IF([ test "$enable_man" != no ], [
2471 dnl check for DocBook DTD in the local catalog
2472 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2473 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2474 AS_IF([test "$have_docbook_dtd" != yes], [
2475 AS_IF([test "$enable_man" = yes ], [
2476 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2477 ])
2478 enable_man=no
2479 ])
2480 ])
2482 AS_IF([test "$enable_man" != no], [
2483 dnl check for DocBook XSL stylesheets in the local catalog
2484 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2485 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2486 AS_IF([ test "$have_docbook_style" != yes ], [
2487 AS_IF([ test "$enable_man" = yes ], [
2488 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2489 ])
2490 enable_man=no
2491 ])
2492 ])
2494 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2496 AC_MSG_CHECKING([whether to generate man pages])
2497 AS_IF([ test "$enable_man" != no ], [
2498 AC_MSG_RESULT([yes])
2499 ], [
2500 AC_MSG_RESULT([no])
2501 ])
2503 dnl
2504 dnl Tracing
2505 dnl
2507 AC_ARG_ENABLE([dtrace],
2508 [AS_HELP_STRING([--enable-dtrace],
2509 [include tracing support for dtrace])])
2510 have_dtrace=no
2511 AC_MSG_CHECKING([whether to include dtrace tracing support])
2512 AS_IF([ test "x$enable_dtrace" != xno], [
2513 if test x$glib_have_carbon = xyes; then
2514 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2515 else
2516 AC_MSG_RESULT([yes])
2517 AC_CHECK_PROGS(DTRACE, dtrace)
2518 if test -z "$DTRACE"; then
2519 if test "x$enable_dtrace" = xyes; then
2520 AC_MSG_ERROR([dtrace not found])
2521 fi
2522 else
2523 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2524 [if test "x$enable_dtrace" = xyes; then
2525 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2526 fi])
2527 fi
2528 fi
2529 ], [
2530 AC_MSG_RESULT([no])
2531 ])
2532 if test "x$have_dtrace" = xyes; then
2533 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2534 fi
2535 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2537 AC_MSG_CHECKING([whether to include systemtap tracing support])
2538 AC_ARG_ENABLE([systemtap],
2539 [AS_HELP_STRING([--enable-systemtap],
2540 [include tracing support for systemtap])])
2541 have_systemtap=no
2542 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2543 have_systemtap=yes
2544 fi
2545 AC_MSG_RESULT(${have_systemtap})
2547 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2549 AC_ARG_WITH([tapset-install-dir],
2550 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2551 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2552 [if test "x${withval}" = x; then
2553 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2554 else
2555 ABS_TAPSET_DIR="${withval}"
2556 fi],
2557 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2558 AC_SUBST(ABS_TAPSET_DIR)
2560 dnl ************************************
2561 dnl *** Enable lcov coverage reports ***
2562 dnl ************************************
2564 AC_ARG_ENABLE(coverage,
2565 AS_HELP_STRING([--enable-coverage],
2566 [enable coverage testing with gcov]),
2567 [use_gcov=$enableval], [use_gcov=no])
2569 AS_IF([ test "x$use_gcov" = "xyes"], [
2570 dnl we need gcc:
2571 if test "$GCC" != "yes"; then
2572 AC_MSG_ERROR([GCC is required for --enable-coverage])
2573 fi
2575 dnl Check if ccache is being used
2576 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2577 case `$SHTOOL path $CC` in
2578 *ccache*[)] gcc_ccache=yes;;
2579 *[)] gcc_ccache=no;;
2580 esac
2582 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2583 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2584 fi
2586 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2587 AC_CHECK_PROG(LTP, lcov, lcov)
2588 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2590 AS_IF([ test "$LTP" ], [
2591 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2592 glib_cv_ltp_version=invalid
2593 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2594 for ltp_check_version in $ltp_version_list; do
2595 if test "$ltp_version" = "$ltp_check_version"; then
2596 glib_cv_ltp_version="$ltp_check_version (ok)"
2597 fi
2598 done
2599 ])
2600 ], [
2601 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2602 AC_MSG_ERROR([$ltp_msg])
2603 ])
2605 case $glib_cv_ltp_version in
2606 ""|invalid[)]
2607 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2608 AC_MSG_ERROR([$ltp_msg])
2609 LTP="exit 0;"
2610 ;;
2611 esac
2613 if test -z "$LTP_GENHTML"; then
2614 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2615 fi
2617 dnl Remove all optimization flags from CFLAGS
2618 changequote({,})
2619 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2620 changequote([,])
2622 dnl Add the special gcc flags
2623 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2624 LDFLAGS="$LDFLAGS -lgcov"
2625 ])
2627 dnl *******************************
2628 dnl *** Disable strict aliasing ***
2629 dnl *******************************
2630 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2631 AS_IF([test "${GCC}" = "yes"],[
2632 CFLAGS="$CFLAGS -fno-strict-aliasing"
2633 ])
2635 dnl ******************************
2636 dnl *** output the whole stuff ***
2637 dnl ******************************
2639 dnl this section will only be run if config.status is invoked with no
2640 dnl arguments, or with "glib/glibconfig.h" as an argument.
2641 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2642 [
2643 outfile=glib/glibconfig.h-tmp
2644 cat > $outfile <<\_______EOF
2645 /* glibconfig.h
2646 *
2647 * This is a generated file. Please modify 'configure.ac'
2648 */
2650 #ifndef __GLIBCONFIG_H__
2651 #define __GLIBCONFIG_H__
2653 #include <glib/gmacros.h>
2655 _______EOF
2657 echo '#include <limits.h>' >> $outfile
2658 echo '#include <float.h>' >> $outfile
2659 if test x$glib_values_h = xyes; then
2660 echo '#include <values.h>' >> $outfile
2661 fi
2662 if test "$glib_header_alloca_h" = "yes"; then
2663 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2664 fi
2665 if test x$glib_included_printf != xyes; then
2666 echo "
2667 /* Specifies that GLib's g_print*() functions wrap the
2668 * system printf functions. This is useful to know, for example,
2669 * when using glibc's register_printf_function().
2670 */" >> $outfile
2671 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2672 fi
2674 cat >> $outfile <<_______EOF
2676 G_BEGIN_DECLS
2678 #define G_MINFLOAT FLT_MIN
2679 #define G_MAXFLOAT FLT_MAX
2680 #define G_MINDOUBLE DBL_MIN
2681 #define G_MAXDOUBLE DBL_MAX
2682 #define G_MINSHORT SHRT_MIN
2683 #define G_MAXSHORT SHRT_MAX
2684 #define G_MAXUSHORT USHRT_MAX
2685 #define G_MININT INT_MIN
2686 #define G_MAXINT INT_MAX
2687 #define G_MAXUINT UINT_MAX
2688 #define G_MINLONG LONG_MIN
2689 #define G_MAXLONG LONG_MAX
2690 #define G_MAXULONG ULONG_MAX
2692 _______EOF
2695 ### this should always be true in a modern C/C++ compiler
2696 ### and is statically asserted by glib-init.c
2697 cat >>$outfile <<_______EOF
2698 typedef signed char gint8;
2699 typedef unsigned char guint8;
2700 _______EOF
2703 if test -n "$gint16"; then
2704 cat >>$outfile <<_______EOF
2705 typedef signed $gint16 gint16;
2706 typedef unsigned $gint16 guint16;
2707 #define G_GINT16_MODIFIER $gint16_modifier
2708 #define G_GINT16_FORMAT $gint16_format
2709 #define G_GUINT16_FORMAT $guint16_format
2710 _______EOF
2711 fi
2714 if test -n "$gint32"; then
2715 cat >>$outfile <<_______EOF
2716 typedef signed $gint32 gint32;
2717 typedef unsigned $gint32 guint32;
2718 #define G_GINT32_MODIFIER $gint32_modifier
2719 #define G_GINT32_FORMAT $gint32_format
2720 #define G_GUINT32_FORMAT $guint32_format
2721 _______EOF
2722 fi
2724 cat >>$outfile <<_______EOF
2725 #define G_HAVE_GINT64 1 /* deprecated, always true */
2727 ${glib_extension}typedef signed $gint64 gint64;
2728 ${glib_extension}typedef unsigned $gint64 guint64;
2730 #define G_GINT64_CONSTANT(val) $gint64_constant
2731 #define G_GUINT64_CONSTANT(val) $guint64_constant
2732 _______EOF
2734 if test x$gint64_format != x ; then
2735 cat >>$outfile <<_______EOF
2736 #define G_GINT64_MODIFIER $gint64_modifier
2737 #define G_GINT64_FORMAT $gint64_format
2738 #define G_GUINT64_FORMAT $guint64_format
2739 _______EOF
2740 else
2741 cat >>$outfile <<_______EOF
2742 #undef G_GINT64_MODIFIER
2743 #undef G_GINT64_FORMAT
2744 #undef G_GUINT64_FORMAT
2745 _______EOF
2746 fi
2748 cat >>$outfile <<_______EOF
2750 #define GLIB_SIZEOF_VOID_P $glib_void_p
2751 #define GLIB_SIZEOF_LONG $glib_long
2752 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2753 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2755 _______EOF
2757 cat >>$outfile <<_______EOF
2758 typedef signed $glib_ssize_type_define gssize;
2759 typedef unsigned $glib_size_type_define gsize;
2760 #define G_GSIZE_MODIFIER $gsize_modifier
2761 #define G_GSSIZE_MODIFIER $gssize_modifier
2762 #define G_GSIZE_FORMAT $gsize_format
2763 #define G_GSSIZE_FORMAT $gssize_format
2765 #define G_MAXSIZE G_MAXU$glib_msize_type
2766 #define G_MINSSIZE G_MIN$glib_mssize_type
2767 #define G_MAXSSIZE G_MAX$glib_mssize_type
2769 typedef gint64 goffset;
2770 #define G_MINOFFSET G_MININT64
2771 #define G_MAXOFFSET G_MAXINT64
2773 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2774 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2775 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2777 #define G_POLLFD_FORMAT $g_pollfd_format
2779 _______EOF
2781 if test -z "$glib_unknown_void_p"; then
2782 cat >>$outfile <<_______EOF
2784 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2785 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2787 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2788 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2790 typedef signed $glib_intptr_type_define gintptr;
2791 typedef unsigned $glib_intptr_type_define guintptr;
2793 #define G_GINTPTR_MODIFIER $gintptr_modifier
2794 #define G_GINTPTR_FORMAT $gintptr_format
2795 #define G_GUINTPTR_FORMAT $guintptr_format
2796 _______EOF
2797 else
2798 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2799 fi
2803 cat >>$outfile <<_______EOF
2804 #ifndef G_DISABLE_DEPRECATED
2805 #define g_ATEXIT(proc) (atexit (proc))
2806 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2807 #endif
2808 $glib_defines
2809 $glib_os
2810 $glib_static_compilation
2812 $glib_vacopy
2814 _______EOF
2816 if test x$g_have_iso_c_varargs = xyes ; then
2817 cat >>$outfile <<_______EOF
2818 #ifndef __cplusplus
2819 # define G_HAVE_ISO_VARARGS 1
2820 #endif
2821 _______EOF
2822 fi
2823 if test x$g_have_iso_cxx_varargs = xyes ; then
2824 cat >>$outfile <<_______EOF
2825 #ifdef __cplusplus
2826 # define G_HAVE_ISO_VARARGS 1
2827 #endif
2828 _______EOF
2829 fi
2830 if test x$g_have_gnuc_varargs = xyes ; then
2831 cat >>$outfile <<_______EOF
2833 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2834 * is passed ISO vararg support is turned off, and there is no work
2835 * around to turn it on, so we unconditionally turn it off.
2836 */
2837 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2838 # undef G_HAVE_ISO_VARARGS
2839 #endif
2841 #define G_HAVE_GNUC_VARARGS 1
2842 _______EOF
2843 fi
2845 case x$g_stack_grows in
2846 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2847 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2848 esac
2851 echo >>$outfile
2852 if test x$g_have_eilseq = xno; then
2853 cat >>$outfile <<_______EOF
2854 #ifndef EILSEQ
2855 /* On some pre-C99 systems, EILSEQ is not defined.
2856 * The correspondence between this and the corresponding definition
2857 * in libiconv is essential.
2858 */
2859 # define EILSEQ ENOENT
2860 #endif
2861 _______EOF
2863 fi
2865 if test x$g_have_gnuc_visibility = xyes; then
2866 cat >>$outfile <<_______EOF
2867 #define G_HAVE_GNUC_VISIBILITY 1
2868 _______EOF
2869 fi
2870 cat >>$outfile <<_______EOF
2871 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2872 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2873 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2874 #define G_GNUC_INTERNAL __hidden
2875 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2876 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2877 #else
2878 #define G_GNUC_INTERNAL
2879 #endif
2880 _______EOF
2882 echo >>$outfile
2883 cat >>$outfile <<_______EOF
2884 #define G_THREADS_ENABLED
2885 #define G_THREADS_IMPL_$g_threads_impl_def
2886 _______EOF
2888 if test x"$g_memory_barrier_needed" != xno; then
2889 echo >>$outfile
2890 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2891 fi
2892 if test x"$g_atomic_lock_free" = xyes; then
2893 echo >>$outfile
2894 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2895 fi
2896 echo >>$outfile
2897 g_bit_sizes="16 32 64"
2898 for bits in $g_bit_sizes; do
2899 cat >>$outfile <<_______EOF
2900 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2901 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2902 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2903 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2904 _______EOF
2905 done
2907 cat >>$outfile <<_______EOF
2908 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2909 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2910 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2911 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2912 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2913 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2914 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2915 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2916 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2917 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2918 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2919 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2920 #define G_BYTE_ORDER $g_byte_order
2922 #define GLIB_SYSDEF_POLLIN =$g_pollin
2923 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2924 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2925 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2926 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2927 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2929 #define G_MODULE_SUFFIX "$g_module_suffix"
2931 typedef $g_pid_type GPid;
2932 #define G_PID_FORMAT $g_pid_format
2934 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2935 #define GLIB_SYSDEF_AF_INET $g_af_inet
2936 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2938 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2939 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2940 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2942 #define G_DIR_SEPARATOR '$g_dir_separator'
2943 #define G_DIR_SEPARATOR_S "$g_dir_separator"
2944 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
2945 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
2947 G_END_DECLS
2949 #endif /* __GLIBCONFIG_H__ */
2950 _______EOF
2953 if cmp -s $outfile glib/glibconfig.h; then
2954 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2955 rm -f $outfile
2956 else
2957 mv $outfile glib/glibconfig.h
2958 fi
2959 ],[
2961 # Note that if two cases are the same, case goes with the first one.
2962 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2963 # on variable expansion in case labels. Look at the generated config.status
2964 # for a hint.
2966 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2967 glib_header_alloca_h="$ac_cv_working_alloca_h"
2968 else
2969 glib_header_alloca_h="$ac_cv_header_alloca_h"
2970 fi
2972 if test x$enable_included_printf = xyes ; then
2973 glib_included_printf=yes
2974 fi
2976 case 2 in
2977 $ac_cv_sizeof_short)
2978 gint16=short
2979 gint16_modifier='"h"'
2980 gint16_format='"hi"'
2981 guint16_format='"hu"'
2982 ;;
2983 $ac_cv_sizeof_int)
2984 gint16=int
2985 gint16_modifier='""'
2986 gint16_format='"i"'
2987 guint16_format='"u"'
2988 ;;
2989 esac
2990 case 4 in
2991 $ac_cv_sizeof_short)
2992 gint32=short
2993 gint32_modifier='"h"'
2994 gint32_format='"hi"'
2995 guint32_format='"hu"'
2996 ;;
2997 $ac_cv_sizeof_int)
2998 gint32=int
2999 gint32_modifier='""'
3000 gint32_format='"i"'
3001 guint32_format='"u"'
3002 ;;
3003 $ac_cv_sizeof_long)
3004 gint32=long
3005 gint32_modifier='"l"'
3006 gint32_format='"li"'
3007 guint32_format='"lu"'
3008 ;;
3009 esac
3010 case 8 in
3011 $ac_cv_sizeof_int)
3012 gint64=int
3013 gint64_modifier='""'
3014 gint64_format='"i"'
3015 guint64_format='"u"'
3016 glib_extension=
3017 gint64_constant='(val)'
3018 guint64_constant='(val)'
3019 ;;
3020 $ac_cv_sizeof_long)
3021 gint64=long
3022 gint64_modifier='"l"'
3023 gint64_format='"li"'
3024 guint64_format='"lu"'
3025 glib_extension=
3026 gint64_constant='(val##L)'
3027 guint64_constant='(val##UL)'
3028 ;;
3029 $ac_cv_sizeof_long_long)
3030 gint64='long long'
3031 if test -n "$glib_cv_long_long_format"; then
3032 gint64_modifier='"'$glib_cv_long_long_format'"'
3033 gint64_format='"'$glib_cv_long_long_format'i"'
3034 guint64_format='"'$glib_cv_long_long_format'u"'
3035 fi
3036 glib_extension='G_GNUC_EXTENSION '
3037 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3038 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3039 ;;
3040 $ac_cv_sizeof___int64)
3041 gint64='__int64'
3042 if test -n "$glib_cv_long_long_format"; then
3043 gint64_modifier='"'$glib_cv_long_long_format'"'
3044 gint64_format='"'$glib_cv_long_long_format'i"'
3045 guint64_format='"'$glib_cv_long_long_format'u"'
3046 fi
3047 glib_extension=
3048 gint64_constant='(val##i64)'
3049 guint64_constant='(val##ui64)'
3050 ;;
3051 esac
3052 glib_size_t=$ac_cv_sizeof_size_t
3053 glib_ssize_t=$ac_cv_sizeof_ssize_t
3054 glib_size_type_define="$glib_size_type"
3055 glib_ssize_type_define="$glib_ssize_type"
3056 glib_void_p=$ac_cv_sizeof_void_p
3057 glib_long=$ac_cv_sizeof_long
3059 case "$glib_size_type" in
3060 short)
3061 gsize_modifier='"h"'
3062 gsize_format='"hu"'
3063 glib_msize_type='SHRT'
3064 ;;
3065 int)
3066 gsize_modifier='""'
3067 gsize_format='"u"'
3068 glib_msize_type='INT'
3069 ;;
3070 long)
3071 gsize_modifier='"l"'
3072 gsize_format='"lu"'
3073 glib_msize_type='LONG'
3074 ;;
3075 "long long"|__int64)
3076 gsize_modifier='"I64"'
3077 gsize_format='"I64u"'
3078 glib_msize_type='INT64'
3079 ;;
3080 esac
3082 case "$glib_ssize_type" in
3083 short)
3084 gssize_modifier='"h"'
3085 gssize_format='"hi"'
3086 glib_mssize_type='SHRT'
3087 ;;
3088 int)
3089 gssize_modifier='""'
3090 gssize_format='"i"'
3091 glib_mssize_type='INT'
3092 ;;
3093 long)
3094 gssize_modifier='"l"'
3095 gssize_format='"li"'
3096 glib_mssize_type='LONG'
3097 ;;
3098 "long long"|__int64)
3099 gssize_modifier='"I64"'
3100 gssize_format='"I64i"'
3101 glib_mssize_type='INT64'
3102 ;;
3103 esac
3105 gintbits=`expr $ac_cv_sizeof_int \* 8`
3106 glongbits=`expr $ac_cv_sizeof_long \* 8`
3107 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3108 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3110 case $ac_cv_sizeof_void_p in
3111 $ac_cv_sizeof_int)
3112 glib_intptr_type_define=int
3113 gintptr_modifier='""'
3114 gintptr_format='"i"'
3115 guintptr_format='"u"'
3116 glib_gpi_cast='(gint)'
3117 glib_gpui_cast='(guint)'
3118 ;;
3119 $ac_cv_sizeof_long)
3120 glib_intptr_type_define=long
3121 gintptr_modifier='"l"'
3122 gintptr_format='"li"'
3123 guintptr_format='"lu"'
3124 glib_gpi_cast='(glong)'
3125 glib_gpui_cast='(gulong)'
3126 ;;
3127 $ac_cv_sizeof_long_long)
3128 glib_intptr_type_define='long long'
3129 gintptr_modifier='"I64"'
3130 gintptr_format='"I64i"'
3131 guintptr_format='"I64u"'
3132 glib_gpi_cast='(gint64)'
3133 glib_gpui_cast='(guint64)'
3134 ;;
3135 $ac_cv_sizeof___int64)
3136 glib_intptr_type_define=__int64
3137 gintptr_modifier='"I64"'
3138 gintptr_format='"I64i"'
3139 guintptr_format='"I64u"'
3140 glib_gpi_cast='(gint64)'
3141 glib_gpui_cast='(guint64)'
3142 ;;
3143 *)
3144 glib_unknown_void_p=yes
3145 ;;
3146 esac
3149 glib_defines="
3150 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3151 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3152 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3153 "
3155 case xyes in
3156 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3157 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3158 *) glib_vacopy=''
3159 esac
3161 if test x$glib_cv_va_val_copy = xno; then
3162 glib_vacopy="\$glib_vacopy
3163 #define G_VA_COPY_AS_ARRAY 1"
3164 fi
3166 g_have_gnuc_varargs=$g_have_gnuc_varargs
3167 g_have_iso_c_varargs=$g_have_iso_c_varargs
3168 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3170 g_have_gnuc_visibility=$g_have_gnuc_visibility
3171 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3173 if test x$ac_cv_c_bigendian = xyes; then
3174 g_byte_order=G_BIG_ENDIAN
3175 g_bs_native=BE
3176 g_bs_alien=LE
3177 else
3178 g_byte_order=G_LITTLE_ENDIAN
3179 g_bs_native=LE
3180 g_bs_alien=BE
3181 fi
3183 g_pollin=$glib_cv_value_POLLIN
3184 g_pollout=$glib_cv_value_POLLOUT
3185 g_pollpri=$glib_cv_value_POLLPRI
3186 g_pollhup=$glib_cv_value_POLLHUP
3187 g_pollerr=$glib_cv_value_POLLERR
3188 g_pollnval=$glib_cv_value_POLLNVAL
3190 # If a family is not found on the system, define that family to
3191 # a negative value, picking a different one for each undefined
3192 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3193 # This is needed because glib-mkenums doesn't handle optional
3194 # values in enums, and thus we have to have all existing values
3195 # defined in the enum.
3196 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3197 g_af_unix=$glib_cv_value_AF_UNIX
3198 else
3199 g_af_unix=-1
3200 fi
3201 g_af_inet=$glib_cv_value_AF_INET
3202 g_af_inet6=$glib_cv_value_AF_INET6
3204 g_msg_peek=$glib_cv_value_MSG_PEEK
3205 g_msg_oob=$glib_cv_value_MSG_OOB
3206 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3208 g_stack_grows=$glib_cv_stack_grows
3210 g_have_eilseq=$have_eilseq
3212 g_threads_impl_def=$g_threads_impl
3214 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3215 g_memory_barrier_needed="$glib_memory_barrier_needed"
3216 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3218 g_module_suffix="$glib_gmodule_suffix"
3219 g_dir_separator="$glib_dir_separator"
3220 g_searchpath_separator="$glib_searchpath_separator"
3222 g_pid_type="$glib_pid_type"
3223 g_pid_format="\"$glib_pid_format\""
3224 g_pollfd_format="\"$glib_pollfd_format\""
3226 case $host in
3227 *-*-cygwin*)
3228 glib_os="#define G_OS_UNIX
3229 #define G_PLATFORM_WIN32
3230 #define G_WITH_CYGWIN"
3231 ;;
3232 *-*-mingw*)
3233 glib_os="#define G_OS_WIN32
3234 #define G_PLATFORM_WIN32"
3235 ;;
3236 *)
3237 glib_os="#define G_OS_UNIX"
3238 ;;
3239 esac
3240 glib_static_compilation=""
3241 if test x$glib_win32_static_compilation = xyes; then
3242 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3243 #define GOBJECT_STATIC_COMPILATION 1"
3244 fi
3245 ])
3247 # Redo enough to get guint32 and guint64 for the alignment checks below
3248 case 4 in
3249 $ac_cv_sizeof_short)
3250 gint32=short
3251 ;;
3252 $ac_cv_sizeof_int)
3253 gint32=int
3254 ;;
3255 $ac_cv_sizeof_long)
3256 gint32=long
3257 ;;
3258 esac
3259 case 8 in
3260 $ac_cv_sizeof_int)
3261 gint64=int
3262 ;;
3263 $ac_cv_sizeof_long)
3264 gint64=long
3265 ;;
3266 $ac_cv_sizeof_long_long)
3267 gint64='long long'
3268 ;;
3269 $ac_cv_sizeof___int64)
3270 gint64='__int64'
3271 ;;
3272 esac
3274 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3275 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3276 typedef unsigned $gint32 guint32;])
3277 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3278 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3279 typedef unsigned $gint64 guint64;])
3280 AC_CHECK_TYPE([unsigned long])
3281 AC_CHECK_ALIGNOF([unsigned long])
3283 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3284 #
3285 # 1.2.14 required for dbus_message_set_serial
3286 PKG_CHECK_MODULES(DBUS1,
3287 dbus-1 >= 1.2.14,
3288 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3289 have_dbus1=no)
3290 AC_SUBST(DBUS1_CFLAGS)
3291 AC_SUBST(DBUS1_LIBS)
3292 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3294 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3295 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3297 # Check whether MSVC toolset is explicitly set
3298 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3299 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3301 dnl
3302 dnl Check for -Bsymbolic-functions linker flag used to avoid
3303 dnl intra-library PLT jumps, if available.
3304 dnl
3306 AC_ARG_ENABLE(Bsymbolic,
3307 [AS_HELP_STRING([--disable-Bsymbolic],
3308 [avoid linking with -Bsymbolic])],,
3309 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3310 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3311 LDFLAGS=-Wl,-Bsymbolic-functions
3312 LIBS=
3313 AC_TRY_LINK([], [return 0],
3314 AC_MSG_RESULT(yes)
3315 enable_Bsymbolic=yes,
3316 AC_MSG_RESULT(no)
3317 enable_Bsymbolic=no)
3318 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3320 if test "x${enable_Bsymbolic}" = "xyes"; then
3321 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3322 fi
3324 dnl
3325 dnl Check for -z,nodelete linker flag: the type system assumes that
3326 dnl libgobject stays loaded for the lifetime of the process.
3327 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3328 dnl we also try to check for the --fatal-warnings linker flag if
3329 dnl auto-detecting.
3330 dnl
3332 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3333 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3334 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3335 LDFLAGS=-Wl,--fatal-warnings
3336 LIBS=
3337 AC_TRY_LINK([], [return 0],
3338 AC_MSG_RESULT(yes)
3339 [ldflags_fatal=-Wl,--fatal-warnings],
3340 AC_MSG_RESULT(no)
3341 ldflags_fatal=)
3343 AC_MSG_CHECKING([for -z,nodelete linker flag])
3344 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3345 AC_TRY_LINK([], [return 0],
3346 AC_MSG_RESULT(yes)
3347 enable_znodelete=yes,
3348 AC_MSG_RESULT(no)
3349 enable_znodelete=no)
3350 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3352 if test "x${enable_znodelete}" = "xyes"; then
3353 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3354 fi
3356 AC_SUBST(GLIB_LINK_FLAGS)
3358 dnl
3359 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3360 dnl visibility attributes for symbol export control
3361 dnl
3362 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3363 case "$host" in
3364 *-*-mingw*)
3365 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3366 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3367 [defines how to decorate public symbols while building])
3368 CFLAGS="${CFLAGS} -fvisibility=hidden"
3369 ;;
3370 *)
3371 dnl on other compilers, check if we can do -fvisibility=hidden
3372 SAVED_CFLAGS="${CFLAGS}"
3373 CFLAGS="-fvisibility=hidden"
3374 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3375 AC_TRY_COMPILE([], [return 0],
3376 AC_MSG_RESULT(yes)
3377 enable_fvisibility_hidden=yes,
3378 AC_MSG_RESULT(no)
3379 enable_fvisibility_hidden=no)
3380 CFLAGS="${SAVED_CFLAGS}"
3382 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3383 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3384 [defines how to decorate public symbols while building])
3385 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3386 ])
3387 ;;
3388 esac
3389 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3391 dnl Compiler flags; macro originates from systemd
3392 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3393 AC_ARG_ENABLE(compile-warnings,
3394 [AS_HELP_STRING([--disable-compile-warnings],
3395 [Don't use builtin compiler warnings])],,
3396 enable_compile_warnings=yes)
3397 AS_IF([test "x$enable_compile_warnings" != xno], [
3398 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3399 -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3400 -Wno-bad-function-cast \
3401 -Werror=declaration-after-statement \
3402 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3403 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3404 -Werror=format=2 -Werror=missing-include-dirs])
3405 ])
3406 AC_SUBST(GLIB_WARN_CFLAGS)
3408 #
3409 # Define variables corresponding to the correct include paths to use for
3410 # in-tree building.
3411 #
3413 # for config.h:
3414 config_h_INCLUDES='-I$(top_builddir)'
3415 AC_SUBST(config_h_INCLUDES)
3417 # glib:
3418 # config.h
3419 # $(top_builddir)/glib: for glibconfig.h
3420 # $(top_srcdir)/glib: for glib.h
3421 # $(top_srcdir): for everything
3422 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3423 AC_SUBST(glib_INCLUDES)
3425 # gobject:
3426 # same as glib
3427 gobject_INCLUDES='$(glib_INCLUDES)'
3428 AC_SUBST(gobject_INCLUDES)
3430 # gmodule:
3431 # glib includes
3432 # $(top_srcdir)/gmodule: for gmodule.h
3433 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3434 AC_SUBST(gmodule_INCLUDES)
3436 # gio:
3437 # same as gmodule
3438 gio_INCLUDES='$(gmodule_INCLUDES)'
3439 AC_SUBST(gio_INCLUDES)
3442 AC_CONFIG_FILES([
3443 glib-2.0.pc
3444 gmodule-2.0.pc
3445 gmodule-export-2.0.pc
3446 gmodule-no-export-2.0.pc
3447 gthread-2.0.pc
3448 gobject-2.0.pc
3449 gio-2.0.pc
3450 gio-unix-2.0.pc
3451 gio-windows-2.0.pc
3452 glib-gettextize
3453 Makefile
3454 build/Makefile
3455 build/win32/Makefile
3456 build/win32/dirent/Makefile
3457 glib/Makefile
3458 glib/libcharset/Makefile
3459 glib/gnulib/Makefile
3460 glib/pcre/Makefile
3461 glib/update-pcre/Makefile
3462 glib/tests/Makefile
3463 gmodule/Makefile
3464 gmodule/gmoduleconf.h
3465 gobject/Makefile
3466 gobject/glib-genmarshal
3467 gobject/glib-mkenums
3468 gobject/tests/Makefile
3469 gthread/Makefile
3470 gio/Makefile
3471 gio/gdbus-2.0/codegen/Makefile
3472 gio/gdbus-2.0/codegen/config.py
3473 gio/gnetworking.h
3474 gio/xdgmime/Makefile
3475 gio/inotify/Makefile
3476 gio/kqueue/Makefile
3477 gio/fam/Makefile
3478 gio/win32/Makefile
3479 gio/tests/Makefile
3480 gio/tests/gdbus-object-manager-example/Makefile
3481 gio/tests/services/Makefile
3482 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3483 gio/tests/modules/Makefile
3484 po/Makefile.in
3485 docs/Makefile
3486 docs/reference/Makefile
3487 docs/reference/glib/Makefile
3488 docs/reference/glib/version.xml
3489 docs/reference/gobject/Makefile
3490 docs/reference/gobject/version.xml
3491 docs/reference/gio/Makefile
3492 docs/reference/gio/version.xml
3493 tests/Makefile
3494 tests/gobject/Makefile
3495 tests/refcount/Makefile
3496 m4macros/Makefile
3497 subprojects/Makefile
3498 ])
3500 # We need this command because the configure script will not preserve
3501 # the same attributes of the template files
3502 AC_CONFIG_COMMANDS([chmod-scripts],
3503 [chmod 0755 glib-gettextize
3504 chmod 0755 gobject/glib-genmarshal
3505 chmod 0755 gobject/glib-mkenums])
3507 # we want to invoke this macro solely so that the config.status script
3508 # and automake generated makefiles know about these generated files.
3509 # They are only needed to distcheck the package
3510 if false; then
3511 AC_CONFIG_FILES([
3512 INSTALL
3513 glib/glib.rc
3514 gmodule/gmodule.rc
3515 gobject/gobject.rc
3516 gthread/gthread.rc
3517 gio/gio.rc
3518 ])
3519 fi
3521 AC_OUTPUT