gio/fam/meson.build

   1 if not get_option('fam')
   2   subdir_done()
   3 endif
   4
   5 fam_dep = cc.find_library('fam')
   6 fam_c_args = ['-DG_DISABLE_DEPRECATED'] + gio_c_args
   7 if cc.has_function('FAMNoExists', dependencies : fam_dep)
   8   fam_c_args += '-DHAVE_FAM_NO_EXISTS=1'
   9 endif
  10
  11 deps = [
  12   fam_dep,
  13   libglib_dep,
  14   libgobject_dep,
  15   libgio_dep,
  16 ]
  17
  18 symbol_map = join_paths(meson.current_source_dir(), 'gfamfilemonitor.map')
  19 fam_ldflags = cc.get_supported_link_arguments([
  20   '-Wl,--version-script,' + symbol_map,
  21   '-Wl,-no-undefined',
  22 ])
  23
  24 module = shared_module('giofam', 'gfamfilemonitor.c',
  25   include_directories : [gmoduleinc],
  26   dependencies : deps,
  27   c_args : fam_c_args,
  28   link_args : fam_ldflags,
  29   link_depends : symbol_map,
  30   install_dir : glib_giomodulesdir,
  31   install : true,
  32 )
  33
  34 if not meson.is_cross_build()
  35   meson.add_install_script('../gio-querymodules-wrapper.py', gio_querymodules.full_path(), glib_giomodulesdir)
  36 endif