sysdeps/i386/add_n.S

   1 /* Add two limb vectors of the same length > 0 and store sum in a third
   2    limb vector.
   3    Copyright (C) 1992, 1994, 1995, 1997 Free Software Foundation, Inc.
   4    This file is part of the GNU MP Library.
   5
   6    The GNU MP Library is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU Library General Public License as published by
   8    the Free Software Foundation; either version 2 of the License, or (at your
   9    option) any later version.
  10
  11    The GNU MP Library is distributed in the hope that it will be useful, but
  12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  14    License for more details.
  15
  16    You should have received a copy of the GNU Library General Public License
  17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  19    MA 02111-1307, USA. */
  20
  21 /*
  22   INPUT PARAMETERS
  23   res_ptr       (sp + 4)
  24   s1_ptr        (sp + 8)
  25   s2_ptr        (sp + 12)
  26   size          (sp + 16)
  27 */
  28
  29 #include "sysdep.h"
  30 #include "asm-syntax.h"
  31
  32 .text
  33         ALIGN (3)
  34         .globl C_SYMBOL_NAME(__mpn_add_n)
  35         ASM_TYPE_DIRECTIVE(C_SYMBOL_NAME(__mpn_add_n),@function)
  36 C_SYMBOL_NAME(__mpn_add_n:)
  37         pushl %edi
  38         pushl %esi
  39
  40         movl 12(%esp),%edi              /* res_ptr */
  41         movl 16(%esp),%esi              /* s1_ptr */
  42         movl 20(%esp),%edx              /* s2_ptr */
  43         movl 24(%esp),%ecx              /* size */
  44
  45         movl    %ecx,%eax
  46         shrl    $3,%ecx                 /* compute count for unrolled loop */
  47         negl    %eax
  48         andl    $7,%eax                 /* get index where to start loop */
  49         jz      L(oop)                  /* necessary special case for 0 */
  50         incl    %ecx                    /* adjust loop count */
  51         shll    $2,%eax                 /* adjustment for pointers... */
  52         subl    %eax,%edi               /* ... since they are offset ... */
  53         subl    %eax,%esi               /* ... by a constant when we ... */
  54         subl    %eax,%edx               /* ... enter the loop */
  55         shrl    $2,%eax                 /* restore previous value */
  56 #ifdef PIC
  57 /* Calculate start address in loop for PIC.  Due to limitations in some
  58    assemblers, Loop-L0-3 cannot be put into the leal */
  59         call    L(0)
  60 L(0):   leal    (%eax,%eax,8),%eax
  61         addl    (%esp),%eax
  62         addl    $(L(oop)-L(0)-3),%eax
  63         addl    $4,%esp
  64 #else
  65 /* Calculate start address in loop for non-PIC.  */
  66         leal    (L(oop) - 3)(%eax,%eax,8),%eax
  67 #endif
  68         jmp     *%eax                   /* jump into loop */
  69         ALIGN (3)
  70 L(oop): movl    (%esi),%eax
  71         adcl    (%edx),%eax
  72         movl    %eax,(%edi)
  73         movl    4(%esi),%eax
  74         adcl    4(%edx),%eax
  75         movl    %eax,4(%edi)
  76         movl    8(%esi),%eax
  77         adcl    8(%edx),%eax
  78         movl    %eax,8(%edi)
  79         movl    12(%esi),%eax
  80         adcl    12(%edx),%eax
  81         movl    %eax,12(%edi)
  82         movl    16(%esi),%eax
  83         adcl    16(%edx),%eax
  84         movl    %eax,16(%edi)
  85         movl    20(%esi),%eax
  86         adcl    20(%edx),%eax
  87         movl    %eax,20(%edi)
  88         movl    24(%esi),%eax
  89         adcl    24(%edx),%eax
  90         movl    %eax,24(%edi)
  91         movl    28(%esi),%eax
  92         adcl    28(%edx),%eax
  93         movl    %eax,28(%edi)
  94         leal    32(%edi),%edi
  95         leal    32(%esi),%esi
  96         leal    32(%edx),%edx
  97         decl    %ecx
  98         jnz     L(oop)
  99
 100         sbbl    %eax,%eax
 101         negl    %eax
 102
 103         popl %esi
 104         popl %edi
 105         ret
 106
 107         ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(__mpn_add_n))