sysdeps/i386/lshift.S

   1 /* i80386 __mpn_lshift --
   2    Copyright (C) 1992, 1994, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU MP Library.
   4
   5    The GNU MP Library is free software; you can redistribute it and/or modify
   6    it under the terms of the GNU Library General Public License as published by
   7    the Free Software Foundation; either version 2 of the License, or (at your
   8    option) any later version.
   9
  10    The GNU MP Library is distributed in the hope that it will be useful, but
  11    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  12    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  13    License for more details.
  14
  15    You should have received a copy of the GNU Library General Public License
  16    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  17    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  18    MA 02111-1307, USA. */
  19
  20 /*
  21   INPUT PARAMETERS
  22   res_ptr       (sp + 4)
  23   s_ptr         (sp + 8)
  24   size          (sp + 12)
  25   cnt           (sp + 16)
  26 */
  27
  28 #include "sysdep.h"
  29 #include "asm-syntax.h"
  30
  31 .text
  32         ALIGN (3)
  33         .globl C_SYMBOL_NAME(__mpn_lshift)
  34 C_SYMBOL_NAME(__mpn_lshift:)
  35         pushl   %edi
  36         pushl   %esi
  37         pushl   %ebx
  38
  39         movl    16(%esp),%edi           /* res_ptr */
  40         movl    20(%esp),%esi           /* s_ptr */
  41         movl    24(%esp),%edx           /* size */
  42         movl    28(%esp),%ecx           /* cnt */
  43
  44         subl    $4,%esi                 /* adjust s_ptr */
  45
  46         movl    (%esi,%edx,4),%ebx      /* read most significant limb */
  47         xorl    %eax,%eax
  48         shldl   %cl,%ebx,%eax           /* compute carry limb */
  49         decl    %edx
  50         jz      L(end)
  51         pushl   %eax                    /* push carry limb onto stack */
  52         testb   $1,%edx
  53         jnz     L(1)                    /* enter loop in the middle */
  54         movl    %ebx,%eax
  55
  56         ALIGN (3)
  57 L(oop): movl    (%esi,%edx,4),%ebx      /* load next lower limb */
  58         shldl   %cl,%ebx,%eax           /* compute result limb */
  59         movl    %eax,(%edi,%edx,4)      /* store it */
  60         decl    %edx
  61 L(1):   movl    (%esi,%edx,4),%eax
  62         shldl   %cl,%eax,%ebx
  63         movl    %ebx,(%edi,%edx,4)
  64         decl    %edx
  65         jnz     L(oop)
  66
  67         shll    %cl,%eax                /* compute least significant limb */
  68         movl    %eax,(%edi)             /* store it */
  69
  70         popl    %eax                    /* pop carry limb */
  71
  72         popl    %ebx
  73         popl    %esi
  74         popl    %edi
  75         ret
  76
  77 L(end): shll    %cl,%ebx                /* compute least significant limb */
  78         movl    %ebx,(%edi)             /* store it */
  79
  80         popl    %ebx
  81         popl    %esi
  82         popl    %edi
  83         ret