sysdeps/rs6000/rshift.s

   1 # IBM POWER __mpn_rshift --
   2
   3 # Copyright (C) 1992, 1994 Free Software Foundation, Inc.
   4
   5 # This file is part of the GNU MP Library.
   6
   7 # The GNU MP Library is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU Library General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.
  11
  12 # The GNU MP Library is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  15 # License for more details.
  16
  17 # You should have received a copy of the GNU Library General Public License
  18 # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 # MA 02111-1307, USA.
  21
  22
  23 # INPUT PARAMETERS
  24 # res_ptr       r3
  25 # s_ptr         r4
  26 # size          r5
  27 # cnt           r6
  28
  29         .toc
  30         .extern __mpn_rshift[DS]
  31         .extern .__mpn_rshift
  32 .csect [PR]
  33         .align 2
  34         .globl __mpn_rshift
  35         .globl .__mpn_rshift
  36         .csect __mpn_rshift[DS]
  37 __mpn_rshift:
  38         .long .__mpn_rshift, TOC[tc0], 0
  39         .csect [PR]
  40 .__mpn_rshift:
  41         sfi     8,6,32
  42         mtctr   5               # put limb count in CTR loop register
  43         l       0,0(4)          # read least significant limb
  44         ai      9,3,-4          # adjust res_ptr since it's offset in the stu:s
  45         sle     3,0,8           # compute carry limb, and init MQ register
  46         bdz     Lend2           # if just one limb, skip loop
  47         lu      0,4(4)          # read 2:nd least significant limb
  48         sleq    7,0,8           # compute least significant limb of result
  49         bdz     Lend            # if just two limb, skip loop
  50 Loop:   lu      0,4(4)          # load next higher limb
  51         stu     7,4(9)          # store previous result during read latency
  52         sleq    7,0,8           # compute result limb
  53         bdn     Loop            # loop back until CTR is zero
  54 Lend:   stu     7,4(9)          # store 2:nd most significant limb
  55 Lend2:  sre     7,0,6           # compute most significant limb
  56         st      7,4(9)          # store it"                             \
  57         br