sysdeps/libm-i387/e_atanhf.S

   1 /* ix87 specific implementation of arctanh function.
   2    Copyright (C) 1996 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(half,@object)
  31 half:   .double 0.5
  32         ASM_SIZE_DIRECTIVE(half)
  33         ASM_TYPE_DIRECTIVE(one,@object)
  34 one:    .double 1.0
  35         ASM_SIZE_DIRECTIVE(one)
  36         ASM_TYPE_DIRECTIVE(limit,@object)
  37 limit:  .double 0.29
  38         ASM_SIZE_DIRECTIVE(limit)
  39         .align ALIGNARG(4)
  40         ASM_TYPE_DIRECTIVE(ln2_2,@object)
  41 ln2_2:  .tfloat 0.3465735902799726547086160
  42         ASM_SIZE_DIRECTIVE(ln2_2)
  43
  44 #ifdef PIC
  45 #define MO(op) op##@GOTOFF(%edx)
  46 #else
  47 #define MO(op) op
  48 #endif
  49
  50         .text
  51 ENTRY(__ieee754_atanhf)
  52         movl    4(%esp), %ecx
  53
  54 #ifdef PIC
  55         call    1f
  56 1:      popl    %edx
  57         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
  58 #endif
  59
  60         andl    $0x80000000, %ecx // ECX == 0 iff X >= 0
  61
  62         fldt    MO(ln2_2)       // 0.5*ln2
  63         xorl    %ecx, 4(%esp)
  64         flds    4(%esp)         // |x| : 0.5*ln2
  65         fcoml   MO(half)        // |x| : 0.5*ln2
  66         fld     %st(0)          // |x| : |x| : 0.5*ln2
  67         fnstsw                  // |x| : |x| : 0.5*ln2
  68         sahf
  69         jae     2f
  70         fadd    %st, %st(1)     // |x| : 2*|x| : 0.5*ln2
  71         fld     %st             // |x| : |x| : 2*|x| : 0.5*ln2
  72         fsubrl  MO(one)         // 1-|x| : |x| : 2*|x| : 0.5*ln2
  73         fxch                    // |x| : 1-|x| : 2*|x| : 0.5*ln2
  74         fmul    %st(2)          // 2*|x|^2 : 1-|x| : 2*|x| : 0.5*ln2
  75         fdivp                   // (2*|x|^2)/(1-|x|) : 2*|x| : 0.5*ln2
  76         faddp                   // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  77         fcoml   MO(limit)       // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  78         fnstsw                  // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  79         sahf
  80         jae     4f
  81         fyl2xp1                 // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
  82         jecxz   3f
  83         fchs                    // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
  84 3:      ret
  85
  86         .align ALIGNARG(4)
  87 4:      faddl   MO(one)         // 1+2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  88         fyl2x                   // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
  89         jecxz   3f
  90         fchs                    // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
  91 3:      ret
  92
  93         .align ALIGNARG(4)
  94 2:      faddl   MO(one)         // 1+|x| : |x| : 0.5*ln2
  95         fxch                    // |x| : 1+|x| : 0.5*ln2
  96         fsubrl  MO(one)         // 1-|x| : 1+|x| : 0.5*ln2
  97         fdivrp                  // (1+|x|)/(1-|x|) : 0.5*ln2
  98         fyl2x                   // 0.5*ln2*ld((1+|x|)/(1-|x|))
  99         jecxz   3f
 100         fchs                    // 0.5*ln2*ld((1+x)/(1-x))
 101 3:      ret
 102 END(__ieee754_atanhf)