configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81
  82 dnl Generic infrastructure for drop-in additions to libc.
  83 AC_ARG_ENABLE(add-ons, dnl
  84 [  --enable-add-ons=DIR... configure and build named extra directories],
  85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  86               [add_ons=])
  87 AC_CONFIG_SUBDIRS($add_ons)
  88 add_ons_pfx=
  89 if test x"$add_ons" != x; then
  90   for f in $add_ons; do
  91     add_ons_pfx="$add_ons_pfx $f/"
  92   done
  93 fi
  94
  95 dnl On some platforms we cannot use dynamic loading.  We must provide
  96 dnl static NSS modules.
  97 AC_ARG_ENABLE(static-nss, dnl
  98 [  --enable-static-nss     build static NSS modules [default=no]],
  99               static_nss=$enableval, static_nss=no)
 100 if test x"$static_nss" = xyes; then
 101   AC_DEFINE(DO_STATIC_NSS)
 102 fi
 103
 104 AC_CANONICAL_HOST
 105
 106 # The way shlib-versions is used to generate soversions.mk uses a
 107 # fairly simplistic model for name recognition that can't distinguish
 108 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 109 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 110 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 111 case "$host_os" in
 112 linux*)
 113   ;;
 114 gnu*)
 115   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 116   ;;
 117 esac
 118
 119 # We keep the original values in `$config_*' and never modify them, so we
 120 # can write them unchanged into config.make.  Everything else uses
 121 # $machine, $vendor, and $os, and changes them whenever convenient.
 122 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 123
 124 # Some configurations imply other options.
 125 case "$host_os" in
 126 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 127   # These systems always use GNU tools.
 128   gnu_ld=yes gnu_as=yes ;;
 129 esac
 130 case "$host_os" in
 131 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 132 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 133   ;;
 134 gnu* | linux* | sysv4* | solaris2*)
 135   # These systems (almost) always use the ELF format.
 136   elf=yes
 137   ;;
 138 esac
 139
 140 machine=$config_machine
 141 vendor=$config_vendor
 142 os=$config_os
 143
 144 dnl We need to use [ and ] for other purposes for a while now.
 145 changequote(,)dnl
 146 # Expand the configuration machine name into a subdirectory by architecture
 147 # type and particular chip.
 148 case "$machine" in
 149 a29k | am29000) base_machine=a29k machine=a29k ;;
 150 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 151 arm*)           base_machine=arm machine=arm/$machine ;;
 152 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 153 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 154 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 155 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 156 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 157 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 158 m88???)         base_machine=m88k machine=m88k/$machine ;;
 159 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 160 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 161 mips*)          base_machine=mips machine=mips/$machine ;;
 162 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 163 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 164 sparc64)        base_machine=sparc64 machine=sparc64/$machine ;;
 165 esac
 166 changequote([,])dnl
 167 AC_SUBST(base_machine)
 168
 169 # Compute the list of sysdep directories for this configuration.
 170 # This can take a while to compute.
 171 sysdep_dir=$srcdir/sysdeps
 172 AC_MSG_CHECKING(sysdep dirs)
 173 dnl We need to use [ and ] for other purposes for a while now.
 174 changequote(,)dnl
 175 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 176 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 177
 178 case "$os" in
 179 gnu*)
 180   base_os=mach/hurd ;;
 181 netbsd* | 386bsd* | freebsd* | bsdi*)
 182   base_os=unix/bsd/bsd4.4 ;;
 183 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 184   base_os=unix/bsd ;;
 185 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 186   base_os=unix/sysv ;;
 187 solaris[2-9]*)
 188   base_os=unix/sysv/sysv4 ;;
 189 none)
 190   base_os=standalone ;;
 191 *)
 192   base_os='' ;;
 193 esac
 194
 195 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 196 tail=$os
 197 ostry=$os
 198 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 199   ostry="$ostry /$o"
 200   tail=$o
 201 done
 202 o=`echo $tail | sed 's/[0-9]*$//'`
 203 if test $o != $tail; then
 204   ostry="$ostry /$o"
 205 fi
 206 # For linux-gnu, try linux-gnu, then linux.
 207 o=`echo $tail | sed 's/-.*$//'`
 208 if test $o != $tail; then
 209   ostry="$ostry /$o"
 210 fi
 211
 212 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 213 base=
 214 tail=$base_os
 215 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 216   set $b
 217   base="$base /$1"
 218   tail="$2"
 219 done
 220
 221 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 222 mach=
 223 tail=$machine
 224 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 225   set $m
 226   # Prepend the machine's FPU directory unless --without-fp.
 227   if test "$with_fp" = yes; then
 228     mach="$mach /$1/fpu"
 229   fi
 230   mach="$mach /$1"
 231   tail="$2"
 232 done
 233
 234 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 235 changequote([,])dnl
 236
 237 # Find what sysdep directories exist.
 238 sysnames=
 239 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 240 for d in $add_ons_pfx ''; do
 241   for b in $base ''; do
 242     for m0 in $mach ''; do
 243       for v in /$vendor ''; do
 244         for o in /$ostry ''; do
 245           for m in $mach ''; do
 246             if test "$m0$b$v$o$m"; then
 247               try="${d}sysdeps$m0$b$v$o$m"
 248               test -n "$enable_debug_configure" &&
 249               echo "$0 [DEBUG]: try $try" >&2
 250               case $try in
 251                 /*) dest=$try ;;
 252                 *)  dest=$srcdir/$try ;;
 253               esac
 254               if test -d $dest; then
 255                 sysnames="$sysnames $try"
 256                 { test -n "$o" || test -n "$b"; } && os_used=t
 257                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 258               fi
 259             fi
 260           done
 261         done
 262       done
 263     done
 264   done
 265 done
 266 IFS="$ac_save_ifs"
 267
 268 if test -z "$os_used" && test "$os" != none; then
 269   AC_MSG_ERROR(Operating system $os is not supported.)
 270 fi
 271 if test -z "$machine_used" && test "$machine" != none; then
 272   AC_MSG_ERROR(The $machine is not supported.)
 273 fi
 274
 275 # We have now validated the configuration.
 276
 277
 278 # If using ELF, look for an `elf' subdirectory of each machine directory.
 279 # We prepend these rather than inserting them whereever the machine appears
 280 # because things specified by the machine's ELF ABI should override
 281 # OS-specific things, and should always be the same for any OS on the
 282 # machine (otherwise what's the point of an ABI?).
 283 if test "$elf" = yes; then
 284   elf_dirs=
 285   for d in $add_ons_pfx ''; do
 286     case $d in
 287       /*) xsrcdir= ;;
 288       *)  xsrcdir=$srcdir/ ;;
 289     esac
 290     for m in $mach; do
 291       if test -d $xsrcdir${d}sysdeps$m/elf; then
 292         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 293       fi
 294     done
 295   done
 296   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 297 fi
 298
 299
 300 # Expand the list of system names into a full list of directories
 301 # from each element's parent name and Implies file (if present).
 302 set $sysnames
 303 names=
 304 while test $# -gt 0; do
 305   name=$1
 306   shift
 307
 308   case " $names " in *" $name "*)
 309     # Already in the list.
 310     continue
 311   esac
 312
 313   # Report each name as we discover it, so there is no long pause in output.
 314   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 315
 316   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 317
 318   case $name in
 319     /*) xsrcdir= ;;
 320     *)  xsrcdir=$srcdir/ ;;
 321   esac
 322   test -n "$enable_debug_configure" &&
 323   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 324
 325   if test -f $xsrcdir$name/Implies; then
 326     # Collect more names from the `Implies' file (removing comments).
 327     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 328     implied=
 329     for x in $implied_candidate; do
 330       if test -d $xsrcdir$name_base/$x; then
 331         implied="$implied $name_base/$x";
 332       else
 333         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 334       fi
 335     done
 336   else
 337     implied=
 338   fi
 339
 340   # Add NAME to the list of names.
 341   names="$names $name"
 342
 343   # Find the parent of NAME, using the empty string if it has none.
 344 changequote(,)dnl
 345   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 346 changequote([,])dnl
 347
 348   # Add the names implied by NAME, and NAME's parent (if it has one), to
 349   # the list of names to be processed (the argument list).  We prepend the
 350   # implied names to the list and append the parent.  We want implied
 351   # directories to come before further directories inferred from the
 352   # configuration components; this ensures that for sysv4, unix/common
 353   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 354   # after sysv4).
 355   sysnames="`echo $implied $* $parent`"
 356   test -n "$sysnames" && set $sysnames
 357 done
 358
 359 # Add the default directories.
 360 sysnames="$names sysdeps/generic sysdeps/stub"
 361 AC_SUBST(sysnames)
 362 # The other names were emitted during the scan.
 363 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 364
 365
 366 ### Locate tools.
 367
 368 AC_PROG_INSTALL
 369 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 370   # The makefiles need to use a different form to find it in $srcdir.
 371   INSTALL='$(..)./install-sh -c'
 372 fi
 373 AC_PROG_LN_S
 374 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 375
 376 AC_PROG_CC_LOCAL
 377 AC_CANONICAL_BUILD
 378 if test $host != $build; then
 379   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 380 fi
 381 AC_SUBST(cross_compiling)
 382 AC_PROG_CPP
 383 AC_CHECK_TOOL(AR, ar)
 384 AC_CHECK_TOOL(RANLIB, ranlib, :)
 385
 386 AC_PATH_PROG(BASH, bash, no)
 387 if test "$BASH" != no &&
 388    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 389   libc_cv_have_bash2=yes
 390 else
 391   libc_cv_have_bash2=no
 392 fi
 393 AC_SUBST(libc_cv_have_bash2)
 394
 395 dnl We need a ksh compatible shell for tzselect.
 396 if test "$BASH" = no; then
 397   AC_PATH_PROG(KSH, ksh, no)
 398   if test "$KSH" = no; then
 399     libc_cv_have_ksh=no
 400   else
 401     libc_cv_have_ksh=yes
 402   fi
 403 else
 404   KSH="$BASH"
 405   AC_SUBST(KSH)
 406   libc_cv_have_ksh=yes
 407 fi
 408 AC_SUBST(libc_cv_have_ksh)
 409
 410 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 411 echo '#include <stddef.h>
 412 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 413 if eval "$ac_cpp conftest.c 2>/dev/null" \
 414 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 415   libc_cv_signed_size_t=no
 416 else
 417   libc_cv_signed_size_t=yes
 418 fi
 419 rm -f conftest*])
 420 if test $libc_cv_signed_size_t = yes; then
 421   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 422   cat >> confdefs.h <<\EOF
 423 #undef __SIZE_TYPE__
 424 #define __SIZE_TYPE__ unsigned
 425 EOF
 426 fi
 427
 428 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 429 AC_TRY_COMPILE(dnl
 430 [#define __need_size_t
 431 #define __need_wchar_t
 432 #include <stddef.h>
 433 #define __need_NULL
 434 #include <stddef.h>], [size_t size; wchar_t wchar;
 435 #ifdef offsetof
 436 #error stddef.h ignored __need_*
 437 #endif
 438 if (&size == NULL || &wchar == NULL) abort ();],
 439                libc_cv_friendly_stddef=yes,
 440                libc_cv_friendly_stddef=no)])
 441 if test $libc_cv_friendly_stddef = yes; then
 442   config_vars="$config_vars
 443 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 444 fi
 445
 446 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 447                libc_cv_need_minus_P, [dnl
 448 cat > conftest.S <<EOF
 449 #include "confdefs.h"
 450 /* Nothing whatsoever.  */
 451 EOF
 452 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 453   libc_cv_need_minus_P=no
 454 else
 455   libc_cv_need_minus_P=yes
 456 fi
 457 rm -f conftest*])
 458 if test $libc_cv_need_minus_P = yes; then
 459   config_vars="$config_vars
 460 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 461 fi
 462
 463 AC_CACHE_CHECK(for assembler global-symbol directive,
 464                libc_cv_asm_global_directive, [dnl
 465 libc_cv_asm_global_directive=UNKNOWN
 466 for ac_globl in .globl .global; do
 467   cat > conftest.s <<EOF
 468 .text
 469 ${ac_globl} foo
 470 foo:
 471 EOF
 472   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 473     libc_cv_asm_global_directive=${ac_globl}
 474   fi
 475   rm -f conftest*
 476   test $libc_cv_asm_global_directive != UNKNOWN && break
 477 done])
 478 if test $libc_cv_asm_global_directive = UNKNOWN; then
 479   AC_MSG_ERROR(cannot determine asm global directive)
 480 else
 481   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 482 fi
 483
 484 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 485 cat > conftest.s <<EOF
 486 .text
 487 foo:
 488 .set glibc_conftest_frobozz,foo
 489 $libc_cv_asm_global_directive glibc_conftest_frobozz
 490 EOF
 491 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 492 # (but it doesn't work), so we must do a linking check to be sure.
 493 cat > conftest1.c <<\EOF
 494 extern int glibc_conftest_frobozz;
 495 main () { printf ("%d\n", glibc_conftest_frobozz); }
 496 EOF
 497 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 498             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 499   libc_cv_asm_set_directive=yes
 500 else
 501   libc_cv_asm_set_directive=no
 502 fi
 503 rm -f conftest*])
 504 if test $libc_cv_asm_set_directive = yes; then
 505   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 506 fi
 507
 508 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 509 [cat > conftest.s <<EOF
 510 .text
 511 _sym:
 512 .symver _sym,sym@VERS
 513 EOF
 514 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 515   libc_cv_asm_symver_directive=yes
 516 else
 517   libc_cv_asm_symver_directive=no
 518 fi
 519 rm -f conftest*])
 520 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 521 if test $libc_cv_asm_symver_directive = yes; then
 522   cat > conftest.s <<EOF
 523 .text
 524 _sym:
 525 .symver _sym,sym@VERS
 526 EOF
 527   cat > conftest.map <<EOF
 528 VERS {
 529         global: sym;
 530 };
 531 EOF
 532   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 533     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 534                                         -nostartfiles -nostdlib
 535                                         -Wl,--version-script,conftest.map
 536                        1>&AC_FD_CC]);
 537     then
 538       libc_cv_ld_version_script_option=yes
 539     else
 540       libc_cv_ld_version_script_option=no
 541     fi
 542   else
 543     libc_cv_ld_version_script_option=no
 544   fi
 545 else
 546   libc_cv_ld_version_script_option=no
 547 fi
 548 rm -f conftest*])
 549 if test $libc_cv_asm_symver_directive = yes &&
 550    test $libc_cv_ld_version_script_option = yes; then
 551   VERSIONING=yes
 552   AC_DEFINE(DO_VERSIONING)
 553 else
 554   VERSIONING=no
 555 fi
 556 AC_SUBST(VERSIONING)
 557
 558 if test $elf = yes; then
 559   AC_CACHE_CHECK(for .previous assembler directive,
 560                  libc_cv_asm_previous_directive, [dnl
 561   cat > conftest.s <<EOF
 562 .section foo_section
 563 .previous
 564 EOF
 565   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 566     libc_cv_asm_previous_directive=yes
 567   else
 568     libc_cv_asm_previous_directive=no
 569   fi
 570   rm -f conftest*])
 571   if test $libc_cv_asm_previous_directive = yes; then
 572     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 573   else
 574     AC_CACHE_CHECK(for .popsection assembler directive,
 575                    libc_cv_asm_popsection_directive, [dnl
 576     cat > conftest.s <<EOF
 577 .pushsection foo_section
 578 .popsection
 579 EOF
 580     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 581       libc_cv_asm_popsection_directive=yes
 582     else
 583       libc_cv_asm_popsection_directive=no
 584     fi
 585     rm -f conftest*])
 586     if test $libc_cv_asm_popsection_directive = yes; then
 587       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 588     fi
 589   fi
 590 fi
 591
 592 if test $elf != yes; then
 593   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 594                  [AC_TRY_COMPILE(, [asm (".section .init");
 595                                     asm (".section .fini");
 596                                     asm (".text");],
 597                                  libc_cv_have_initfini=yes,
 598                                  libc_cv_have_initfini=no)])
 599   AC_SUBST(libc_cv_have_initfini)dnl
 600   if test $libc_cv_have_initfini = yes; then
 601     AC_DEFINE(HAVE_INITFINI)
 602   fi
 603 fi
 604
 605 if test $elf = yes; then
 606   libc_cv_asm_underscores=no
 607 else
 608   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 609                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 610                               libc_cv_asm_underscores=yes,
 611                               libc_cv_asm_underscores=no)])
 612 fi
 613 if test $libc_cv_asm_underscores = no; then
 614   AC_DEFINE(NO_UNDERSCORES)
 615 fi
 616
 617 if test $elf = yes; then
 618   libc_cv_weak_symbols=yes
 619   libc_cv_asm_weak_directive=yes
 620   libc_cv_asm_weakext_directive=no
 621 else
 622   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 623                  [dnl
 624 cat > conftest.s <<EOF
 625 .text
 626 ${libc_cv_asm_global_directive} foo
 627 foo:
 628 .weak foo
 629 .weak bar; bar = foo
 630 EOF
 631   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 632     libc_cv_asm_weak_directive=yes
 633   else
 634     libc_cv_asm_weak_directive=no
 635   fi
 636   rm -f conftest*])
 637
 638 if test $libc_cv_asm_weak_directive = no; then
 639   AC_CACHE_CHECK(for assembler .weakext directive,
 640                  libc_cv_asm_weakext_directive,
 641                  [dnl
 642 cat > conftest.s <<EOF
 643 .text
 644 ${libc_cv_asm_global_directive} foo
 645 foo:
 646 .weakext foo
 647 .weakext foo, bar
 648 EOF
 649   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 650     libc_cv_asm_weakext_directive=yes
 651   else
 652     libc_cv_asm_weakext_directive=no
 653   fi
 654   rm -f conftest*])
 655
 656   fi # no .weak
 657 fi # not ELF
 658
 659 if test $libc_cv_asm_weak_directive = yes; then
 660   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 661 elif test $libc_cv_asm_weakext_directive = yes; then
 662   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 663 fi
 664
 665 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 666 cat > conftest.c <<\EOF
 667 _start () {}
 668 int __eh_pc;
 669 __throw () {}
 670 EOF
 671 dnl No \ in command here because it ends up inside ''.
 672 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 673                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 674                             -o conftest conftest.c 1>&AC_FD_CC]); then
 675   libc_cv_ld_no_whole_archive=yes
 676 else
 677   libc_cv_ld_no_whole_archive=no
 678 fi
 679 rm -f conftest*])
 680 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 681
 682 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 683 cat > conftest.c <<\EOF
 684 _start () {}
 685 int __eh_pc;
 686 __throw () {}
 687 EOF
 688 dnl No \ in command here because it ends up inside ''.
 689 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 690                             -nostdlib -nostartfiles -fno-exceptions
 691                             -o conftest conftest.c 1>&AC_FD_CC]); then
 692   libc_cv_gcc_no_exceptions=yes
 693 else
 694   libc_cv_gcc_no_exceptions=no
 695 fi
 696 rm -f conftest*])
 697 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 698
 699 ### End of automated tests.
 700 ### Now run sysdeps configure fragments.
 701
 702 # sysdeps configure fragments may set these with files to be linked below.
 703 libc_link_dests=
 704 libc_link_sources=
 705
 706 # Iterate over all the sysdep directories we will use, running their
 707 # configure fragments, and looking for a uname implementation.
 708 uname=
 709 for dir in $sysnames; do
 710   case $dir in
 711     /*) dest=$dir ;;
 712     *)  dest=$srcdir/$dir ;;
 713   esac
 714   if test -r $dest/configure; then
 715     AC_MSG_RESULT(running configure fragment for $dest)
 716     . $dest/configure
 717   fi
 718 [
 719   if test -z "$uname"; then
 720     if test -r $dest/uname.c ||
 721        test -r $dest/uname.S ||
 722        { test -r $dest/syscalls.list &&
 723          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
 724       uname=$dir
 725     fi
 726   fi
 727 ]dnl
 728 done
 729
 730 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 731
 732 # If we will use the generic uname implementation, we must figure out what
 733 # it will say by examining the system, and write the results in config-name.h.
 734 if test "$uname" = "sysdeps/generic"; then
 735
 736 changequote(,)dnl
 737   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 738 changequote([,])dnl
 739   if test $uname_sysname != $config_os; then
 740     config_release=`echo $config_os | sed s/$uname_sysname//`
 741   fi
 742 dnl
 743 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 744     if test -r /vmunix; then
 745       kernel_id=`strings /vmunix | grep UNIX`
 746     elif test -r /dynix; then
 747       kernel_id=`strings /dynix | grep DYNIX`
 748     else
 749       kernel_id=
 750     fi
 751 ])dnl
 752
 753   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 754 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 755 changequote(,)dnl
 756   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 757 changequote([,])dnl
 758   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 759          != x$config_release; then
 760     # The configuration release is a substring of the kernel release.
 761     libc_cv_uname_release=$kernel_release
 762   elif test x$config_release != x; then
 763     libc_cv_uname_release=$config_release
 764   elif test x$kernel_release != x; then
 765     libc_cv_uname_release=$kernel_release
 766   else
 767     libc_cv_uname_release=unknown
 768   fi])
 769   uname_release="$libc_cv_uname_release"
 770
 771   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 772 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 773 changequote(,)dnl
 774   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 775 changequote([,])dnl
 776   if test -n "$kernel_version"; then
 777     libc_cv_uname_version="$kernel_version"
 778   else
 779     libc_cv_uname_version=unknown
 780   fi])
 781   uname_version="$libc_cv_uname_version"
 782
 783 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 784   config_uname=config-name.h:config-name.in
 785 else
 786   # For non-generic uname, we don't need to create config-name.h at all.
 787   config_uname=
 788 fi
 789
 790 AC_MSG_CHECKING(stdio selection)
 791 AC_SUBST(stdio)
 792 case $stdio in
 793 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 794 default) stdio=stdio ;;
 795 esac
 796 AC_MSG_RESULT($stdio)
 797
 798 AC_SUBST(libc_cv_slibdir)
 799 AC_SUBST(libc_cv_sysconfdir)
 800 AC_SUBST(libc_cv_rootsbindir)
 801
 802 AC_SUBST(has_ldconfig)
 803
 804 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 805 if test $gnu_ld = yes; then
 806   AC_DEFINE(HAVE_GNU_LD)
 807 fi
 808 if test $gnu_as = yes; then
 809   AC_DEFINE(HAVE_GNU_AS)
 810 fi
 811 if test $elf = yes; then
 812   AC_DEFINE(HAVE_ELF)
 813 fi
 814
 815 AC_SUBST(shared)
 816 if test $shared = default; then
 817   if test $gnu_ld = yes; then
 818     shared=$elf
 819   else
 820     # For now we do not assume shared libs are available.  In future more
 821     # tests might become available.
 822     shared=no
 823   fi
 824 fi
 825 AC_SUBST(profile)
 826 AC_SUBST(omitfp)
 827 AC_SUBST(bounded)
 828 AC_SUBST(static_nss)
 829 AC_SUBST(nopic_initfini)
 830
 831 AC_SUBST(DEFINES)
 832
 833 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 834   config_makefile=
 835 else
 836   config_makefile=Makefile
 837 fi
 838
 839 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 840 AC_SUBST(VERSION)
 841
 842 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 843           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])