sysdeps/x86_64/strlen.S

   1 /* strlen(str) -- determine the length of the string STR.
   2    Copyright (C) 2009 Free Software Foundation, Inc.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22
  23
  24         .text
  25 ENTRY(strlen)
  26         movq    %rdi, %rcx
  27         movq    %rdi, %r8
  28         andq    $~15, %rdi
  29         pxor    %xmm1, %xmm1
  30         orl     $0xffffffff, %esi
  31         movdqa  (%rdi), %xmm0
  32         subq    %rdi, %rcx
  33         leaq    16(%rdi), %rdi
  34         pcmpeqb %xmm1, %xmm0
  35         shl     %cl, %esi
  36         pmovmskb %xmm0, %edx
  37         xorl    %eax, %eax
  38         negq    %r8
  39         andl    %esi, %edx
  40         jnz     1f
  41
  42 2:      movdqa  (%rdi), %xmm0
  43         leaq    16(%rdi), %rdi
  44         pcmpeqb %xmm1, %xmm0
  45         pmovmskb %xmm0, %edx
  46         testl   %edx, %edx
  47         jz      2b
  48
  49 1:      leaq    -16(%rdi,%r8), %rdi
  50         bsfl    %edx, %eax
  51         addq    %rdi, %rax
  52         ret
  53 END(strlen)
  54 libc_hidden_builtin_def (strlen)