configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.1.2], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.11.3 no-dist-gzip dist-xz dist-lzip -Wall -Werror -Wno-override])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AC_MSG_RESULT([***
  33 *** Checking for compilation programs...
  34 ])
  35
  36 dnl Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_AS
  39 AC_PROG_CXX
  40 gl_EARLY
  41
  42 # For includes/gnutls/gnutls.h.in.
  43 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  44 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  45 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  46 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  47
  48 touch suppressions.valgrind
  49 dnl C and C++ capabilities
  50 AC_C_INLINE
  51 AC_HEADER_STDC
  52
  53 # For the C++ code
  54 AC_ARG_ENABLE(cxx,
  55   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  56     use_cxx=$enableval, use_cxx=yes)
  57 if test "$use_cxx" != "no"; then
  58   AC_LANG_PUSH(C++)
  59   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  60   AC_LANG_POP(C++)
  61 fi
  62 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  63 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  64
  65 dnl Detect windows build
  66 case "$host" in
  67   *mingw32* | *mingw64*)
  68     have_win=yes
  69   ;;
  70   *darwin*)
  71     have_macosx=yes
  72   ;;
  73   *)
  74     have_elf=yes
  75   ;;
  76 esac
  77
  78 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  79 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
  80 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
  81
  82 dnl Hardware Acceleration
  83 AC_ARG_ENABLE(hardware-acceleration,
  84   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  85     use_accel=$enableval, use_accel=yes)
  86 hw_accel=none
  87
  88
  89 if test "$use_accel" != "no"; then
  90 case $host_cpu in
  91   i?86 | x86_64 | amd64)
  92 dnl    GCC_FLAG_ADD([-maes -mpclmul],[X86])
  93 dnl    if test "x$X86" = "xyes";then
  94       AC_CHECK_HEADERS(cpuid.h)
  95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
  96         hw_accel="x86-64"
  97       else
  98         hw_accel="x86"
  99       fi
 100 dnl    fi
 101   ;;
 102   *)
 103   ;;
 104 esac
 105
 106 fi
 107
 108 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 109 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 110 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
 111 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 112 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 113
 114 dnl Try the hooks.m4
 115 LIBGNUTLS_HOOKS
 116 LIBGNUTLS_EXTRA_HOOKS
 117
 118 GTK_DOC_CHECK(1.1)
 119 AM_GNU_GETTEXT([external])
 120 AM_GNU_GETTEXT_VERSION([0.18])
 121
 122 AC_C_BIGENDIAN
 123
 124
 125
 126 dnl No fork on MinGW, disable some self-tests until we fix them.
 127 AC_CHECK_FUNCS([fork getrusage getpwuid_r daemon],,)
 128 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 129 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 130
 131 dnl Check for p11-kit
 132 AC_ARG_WITH(p11-kit,
 133         AS_HELP_STRING([--without-p11-kit],
 134                 [Build without p11-kit and PKCS#11 support]))
 135 if test "$with_p11_kit" != "no"; then
 136         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
 137         if test "$with_p11_kit" != "no";then
 138                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 139                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 140                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 141                 else
 142                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 143                 fi
 144         else
 145                 with_p11_kit=no
 146                 AC_MSG_WARN([[
 147 ***
 148 *** p11-kit was not found. PKCS #11 support will be disabled.
 149 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 150 *** ]])
 151         fi
 152 fi
 153
 154 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 155
 156 AC_ARG_WITH(tpm,
 157         AS_HELP_STRING([--without-tpm],
 158                 [Build without TPM (trousers) support]))
 159 if test "$with_tpm" != "no"; then
 160     LIBS="$oldlibs -ltspi"
 161     AC_MSG_CHECKING([for tss library])
 162     AC_LINK_IFELSE([AC_LANG_PROGRAM([
 163                    #include <trousers/tss.h>
 164                    #include <trousers/trousers.h>],[
 165                    int err = Tspi_Context_Create((void *)0);
 166                    Trspi_Error_String(err);])],
 167                   [AC_MSG_RESULT(yes)
 168                    AC_SUBST([TSS_LIBS], [-ltspi])
 169                    AC_SUBST([TSS_CFLAGS], [])
 170                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
 171                    with_tpm=yes],
 172                   [AC_MSG_RESULT(no)
 173                    AC_MSG_WARN([[
 174 ***
 175 *** trousers was not found. TPM support will be disabled.
 176 *** ]])
 177                   with_tpm=no])
 178     LIBS="$oldlibs"
 179 fi
 180
 181 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
 182
 183 enable_local_libopts=yes
 184 dnl PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
 185
 186 NEED_LIBOPTS_DIR=true
 187 LIBOPTS_CHECK([src/libopts])
 188
 189 AC_CHECK_TYPE(ssize_t,
 190   [
 191     DEFINE_SSIZE_T="#include <sys/types.h>"
 192     AC_SUBST(DEFINE_SSIZE_T)
 193   ], [
 194     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 195     DEFINE_SSIZE_T="typedef int ssize_t;"
 196     AC_SUBST(DEFINE_SSIZE_T)
 197   ], [
 198     #include <sys/types.h>
 199   ])
 200
 201 # For minitasn1.
 202 AC_CHECK_SIZEOF(unsigned long int, 4)
 203 AC_CHECK_SIZEOF(unsigned int, 4)
 204
 205 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 206                                  [disable zlib compression support]),
 207             ac_zlib=$withval, ac_zlib=yes)
 208 AC_MSG_CHECKING([whether to include zlib compression support])
 209 if test x$ac_zlib != xno; then
 210  AC_MSG_RESULT(yes)
 211  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 212  if test x$ac_cv_libz != xyes; then
 213    AC_MSG_WARN(
 214 ***
 215 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 216  fi
 217 else
 218  AC_MSG_RESULT(no)
 219 fi
 220
 221 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 222
 223 if test x$ac_zlib != xno; then
 224   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 225     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 226       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 227     else
 228       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
 229     fi
 230   else
 231     GNUTLS_ZLIB_LIBS_PRIVATE="$LTLIBZ"
 232   fi
 233 fi
 234 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 235 AC_SUBST(GNUTLS_ZLIB_LIBS_PRIVATE)
 236
 237
 238
 239 gl_INIT
 240
 241 dnl GCC warnings to enable
 242
 243 AC_ARG_ENABLE([gcc-warnings],
 244   [AS_HELP_STRING([--enable-gcc-warnings],
 245                   [turn on lots of GCC warnings (for developers)])],
 246   [case $enableval in
 247      yes|no) ;;
 248      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 249    esac
 250    gl_gcc_warnings=$enableval],
 251   [gl_gcc_warnings=no]
 252 )
 253
 254 if test "$gl_gcc_warnings" = yes; then
 255   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 256   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 257
 258   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 259   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 260   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 261   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 262   nw="$nw -Wlogical-op"             # Too many false positives
 263   nw="$nw -Wold-style-definition"   #
 264   nw="$nw -Wpadded"                 # Our structs are not padded
 265   nw="$nw -Wunreachable-code"       # Too many false positives
 266   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 267   nw="$nw -Wcast-qual"              # Too many warnings for now
 268   nw="$nw -Waggregate-return"       # Too many warnings for now
 269   nw="$nw -Wshadow"                 # Too many warnings for now
 270   nw="$nw -Wswitch-default"         # Too many warnings for now
 271   nw="$nw -Wswitch-enum"            # Too many warnings for now
 272   nw="$nw -Wconversion"             # Too many warnings for now
 273   nw="$nw -Wsign-conversion"        # Too many warnings for now
 274   nw="$nw -Wformat-y2k"             # Too many warnings for now
 275   nw="$nw -Woverlength-strings"     # We use some in tests/
 276   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 277   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 278   nw="$nw -Wunsafe-loop-optimizations"
 279   nw="$nw -Wstrict-overflow"
 280   nw="$nw -Wmissing-noreturn"
 281   nw="$nw -Winline"                 # Too compiler dependent
 282   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
 283   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
 284   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
 285   nw="$nw -Wstack-protector"        # Some functions cannot be protected
 286   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
 287
 288   gl_MANYWARN_ALL_GCC([ws])
 289   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 290   for w in $ws; do
 291     gl_WARN_ADD([$w])
 292   done
 293
 294   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 295   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
 296   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
 297   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 298   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 299   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 300   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 301   gl_WARN_ADD([-fdiagnostics-show-option])
 302 fi
 303
 304 AC_SUBST([WERROR_CFLAGS])
 305 AC_SUBST([WSTACK_CFLAGS])
 306 AC_SUBST([WARN_CFLAGS])
 307
 308 dnl Programs for compilation or development
 309 AC_PROG_LN_S
 310 AC_LIBTOOL_WIN32_DLL
 311 AC_PROG_LIBTOOL
 312
 313 AC_ARG_WITH([default-trust-store-pkcs11],
 314   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
 315     [use the given pkcs11 uri as default trust store])])
 316
 317 if test "x$with_default_trust_store_pkcs11" != x; then
 318   if test "x$with_p11_kit" = xno; then
 319     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
 320   fi
 321   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
 322     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
 323 fi
 324
 325 AC_ARG_WITH([default-trust-store-file],
 326   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
 327     [use the given file default trust store])])
 328
 329 AC_ARG_WITH([default-crl-file],
 330   [AS_HELP_STRING([--with-default-crl-file=FILE],
 331     [use the given CRL file as default])])
 332
 333 if test "x$with_default_trust_store_pkcs11" = x -a "x$with_default_trust_store_file" = x; then
 334   # auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
 335   for i in \
 336     /etc/ssl/certs/ca-certificates.crt \
 337     /etc/pki/tls/cert.pem \
 338     /usr/local/share/certs/ca-root-nss.crt \
 339     /etc/ssl/cert.pem
 340     do
 341     if test -e $i; then
 342       with_default_trust_store_file="$i"
 343       break
 344     fi
 345   done
 346 fi
 347
 348 if test "x$with_default_trust_store_file" != x; then
 349   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
 350     ["$with_default_trust_store_file"], [use the given file default trust store])
 351 fi
 352
 353 if test "x$with_default_crl_file" != x; then
 354   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
 355     ["$with_default_crl_file"], [use the given CRL file])
 356 fi
 357
 358 dnl Guile bindings.
 359 opt_guile_bindings=yes
 360 AC_MSG_CHECKING([whether building Guile bindings])
 361 AC_ARG_ENABLE(guile,
 362         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 363 opt_guile_bindings=$enableval)
 364 AC_MSG_RESULT($opt_guile_bindings)
 365
 366 AC_ARG_WITH([--with-guile-site-dir],
 367   [AS_HELP_STRING([--with-guile-site-dir],
 368      [use the given directory as the Guile site (use with care)])])
 369
 370 if test "$opt_guile_bindings" = "yes"; then
 371    AC_MSG_RESULT([***
 372 *** Detecting GNU Guile...
 373 ])
 374
 375    AC_PATH_PROG([guile_snarf], [guile-snarf])
 376    if test "x$guile_snarf" = "x"; then
 377       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 378       opt_guile_bindings=no
 379    else
 380       GUILE_PROGS
 381       GUILE_FLAGS
 382
 383       save_CFLAGS="$CFLAGS"
 384       save_LIBS="$LIBS"
 385       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 386       LIBS="$LIBS $GUILE_LDFLAGS"
 387       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 388       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
 389         [], [opt_guile_bindings=no])
 390       CFLAGS="$save_CFLAGS"
 391       LIBS="$save_LIBS"
 392
 393       if test "$opt_guile_bindings" = "yes"; then
 394         AC_MSG_RESULT([yes])
 395         case "x$with_guile_site_dir" in
 396              xno)
 397                 # Use the default $(GUILE_SITE).
 398                 GUILE_SITE_DIR
 399                 ;;
 400              x|xyes)
 401                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 402                 # hack is used to allow `distcheck' to work (see
 403                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 404                 GUILE_SITE="\$(datadir)/guile/site"
 405                 AC_SUBST(GUILE_SITE)
 406                 ;;
 407              *)
 408                 # Use the user-specified directory as $(GUILE_SITE).
 409                 GUILE_SITE="$with_guile_site_dir"
 410                 AC_SUBST(GUILE_SITE)
 411                 ;;
 412         esac
 413         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 414         _gcc_cflags_save="$CFLAGS"
 415         CFLAGS="${CFLAGS} -fgnu89-inline"
 416         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 417                           gnu89_inline=yes, gnu89_inline=no)
 418         AC_MSG_RESULT($gnu89_inline)
 419         CFLAGS="$_gcc_cflags_save"
 420
 421         # Optional Guile functions.
 422         save_CFLAGS="$CFLAGS"
 423         save_LIBS="$LIBS"
 424         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 425         LIBS="$LIBS $GUILE_LDFLAGS"
 426         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 427         CFLAGS="$save_CFLAGS"
 428         LIBS="$save_LIBS"
 429
 430         # The place where guile-gnutls.la will go.
 431         AC_MSG_CHECKING([the Guile effective version])
 432         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
 433         AC_MSG_RESULT([$guile_effective_version])
 434         guileextensiondir="$libdir/guile/$guile_effective_version"
 435         AC_SUBST([guileextensiondir])
 436       else
 437         AC_MSG_RESULT([no])
 438         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 439         opt_guile_bindings=no
 440       fi
 441    fi
 442 fi
 443 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 444
 445 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 446 LIBGNUTLS_CFLAGS="-I${includedir}"
 447 AC_SUBST(LIBGNUTLS_LIBS)
 448 AC_SUBST(LIBGNUTLS_CFLAGS)
 449
 450
 451 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 452 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 453
 454 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
 455 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
 456 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
 457
 458 dnl Crywrap dependencies
 459    AC_MSG_RESULT([***
 460 *** Checking dependencies for crywrap...
 461 ])
 462
 463 crywrap=no
 464
 465 if test "$have_win" != "yes"; then
 466
 467 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 468
 469 dnl **********************
 470 dnl * Typedefs & co
 471 dnl **********************
 472 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 473 [AC_LANG_PROGRAM([#include <sys/types.h>
 474 #include <signal.h>
 475 ],
 476                  [return *(signal (0, 0)) (0) == 1;])],
 477                    [ac_cv_type_signal=int],
 478                    [ac_cv_type_signal=void])])
 479 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 480                     (`int' or `void').])
 481
 482 AC_FUNC_SELECT_ARGTYPES
 483 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 484                 putenv regcomp scandir select socket strcasecmp strchr \
 485                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 486
 487 AC_ARG_ENABLE(crywrap,
 488         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
 489
 490  libidn=no
 491
 492  if test "x$enable_crywrap" != "xno" ; then
 493         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 494  fi
 495
 496  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no";then
 497   crywrap=yes
 498  fi
 499
 500 fi
 501
 502 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
 503 rm -f suppressions.valgrind
 504 dnl end of crywrap requirements
 505
 506 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 507 AC_CONFIG_FILES([
 508   Makefile
 509   doc/Makefile
 510   doc/credentials/Makefile
 511   doc/credentials/openpgp/Makefile
 512   doc/credentials/srp/Makefile
 513   doc/credentials/x509/Makefile
 514   doc/cyclo/Makefile
 515   doc/doxygen/Doxyfile
 516   doc/examples/Makefile
 517   doc/latex/Makefile
 518   doc/manpages/Makefile
 519   doc/reference/Makefile
 520   doc/reference/version.xml
 521   doc/scripts/Makefile
 522   extra/Makefile
 523   extra/includes/Makefile
 524   gl/Makefile
 525   gl/tests/Makefile
 526   guile/Makefile
 527   guile/modules/Makefile
 528   guile/src/Makefile
 529   guile/tests/Makefile
 530   lib/Makefile
 531   lib/accelerated/Makefile
 532   lib/accelerated/x86/Makefile
 533   lib/algorithms/Makefile
 534   lib/auth/Makefile
 535   lib/ext/Makefile
 536   lib/extras/Makefile
 537   lib/gnutls.pc
 538   lib/includes/Makefile
 539   lib/includes/gnutls/gnutls.h
 540   lib/minitasn1/Makefile
 541   lib/nettle/Makefile
 542   lib/opencdk/Makefile
 543   lib/openpgp/Makefile
 544   lib/x509/Makefile
 545   po/Makefile.in
 546   src/Makefile
 547   src/crywrap/Makefile
 548   tests/Makefile
 549   tests/cert-tests/Makefile
 550   tests/dsa/Makefile
 551   tests/dtls/Makefile
 552   tests/srp/Makefile
 553   tests/ecdsa/Makefile
 554   tests/key-id/Makefile
 555   tests/openpgp-certs/Makefile
 556   tests/pkcs1-padding/Makefile
 557   tests/pkcs12-decode/Makefile
 558   tests/pkcs8-decode/Makefile
 559   tests/rsa-md5-collision/Makefile
 560   tests/safe-renegotiation/Makefile
 561   tests/scripts/Makefile
 562   tests/sha2/Makefile
 563   tests/slow/Makefile
 564   tests/suite/Makefile
 565   tests/userid/Makefile
 566 ])
 567
 568 AC_OUTPUT
 569
 570 AC_MSG_NOTICE([summary of build options:
 571
 572   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 573   Host type:        ${host}
 574   Install prefix:   ${prefix}
 575   Compiler:         ${CC}
 576   CFlags:           ${CFLAGS}
 577   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 578   Library types:    Shared=${enable_shared}, Static=${enable_static}
 579   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 580 ])
 581
 582 AC_MSG_NOTICE([Optional features:
 583 (note that included applications might not compile properly
 584 if features are disabled)
 585
 586   OCSP support:     $ac_enable_ocsp
 587   OpenPGP support:  $ac_enable_openpgp
 588   SRP support:      $ac_enable_srp
 589   PSK support:      $ac_enable_psk
 590   Anon auth support:$ac_enable_anon
 591
 592   Trust store pkcs: $with_default_trust_store_pkcs11
 593   Trust store file: $with_default_trust_store_file
 594   CRL file: $with_default_crl_file
 595 ])
 596
 597 AC_MSG_NOTICE([Optional applications:
 598
 599   crywrap app:      $libidn
 600   local libopts:    $enable_local_libopts
 601 ])
 602
 603 AC_MSG_NOTICE([Optional libraries:
 604
 605   Guile wrappers:   $opt_guile_bindings
 606   C++ library:      $use_cxx
 607   OpenSSL compat:   $enable_openssl
 608 ])
 609
 610 AC_MSG_NOTICE([Hardware acceleration/support:
 611
 612   /dev/crypto:      $enable_cryptodev
 613   Hardware accel:   $hw_accel
 614   PKCS#11 support:  $with_p11_kit
 615   TPM support:      $with_tpm
 616 ])