configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   3 # 2009, 2010 Free Software Foundation, Inc.
   4 #
   5 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   6 #
   7 # This file is part of GnuTLS.
   8 #
   9 # This program is free software; you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  22 # USA
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT([GnuTLS], [2.12.2], [bug-gnutls@gnu.org])
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AC_CONFIG_MACRO_DIR([m4])
  28
  29 AM_INIT_AUTOMAKE([1.10 no-dist-gzip dist-bzip2 -Wall -Werror -Wno-override])
  30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  31 AM_CONFIG_HEADER(config.h)
  32
  33 AC_MSG_RESULT([***
  34 *** Checking for compilation programs...
  35 ])
  36
  37 dnl Checks for programs.
  38 AC_PROG_CC
  39 AC_PROG_LN_S
  40 GTK_DOC_CHECK(1.1)
  41 AC_PATH_PROG([GAA], [gaa])
  42 if test "x$GAA" = "x"; then
  43    AC_MSG_WARN([[***
  44 *** GAA was not found.  It is only needed if you wish to modify
  45 *** the source code or command-line description files.  In this case,
  46 *** you may want to get it from http://gaa.sourceforge.net/ and
  47 *** read doc/README.gaa.
  48 ***]])
  49 fi
  50
  51 gl_EARLY
  52 AC_C_INLINE
  53
  54 # For the C++ code
  55 AC_PROG_CXX
  56 AC_ARG_ENABLE(cxx,
  57   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  58     use_cxx=$enableval, use_cxx=yes)
  59 if test "$use_cxx" != "no"; then
  60   AC_LANG_PUSH(C++)
  61   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  62   AC_LANG_POP(C++)
  63 fi
  64 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  65 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  66
  67 LIBGNUTLS_HOOKS
  68 LIBGNUTLS_EXTRA_HOOKS
  69
  70 AC_HEADER_STDC
  71 AC_DEFINE([HAVE_STRINGS_H], 1, [Hard-code for src/cfg/.])
  72 AC_DEFINE([HAVE_FLOAT_H], 1, [Hard-code for src/cfg/.])
  73 AC_DEFINE([HAVE_LIMITS_H], 1, [Hard-code for src/cfg/.])
  74 AC_DEFINE([HAVE_MATH_H], 1, [Hard-code for src/cfg/.])
  75 AC_DEFINE([HAVE_CTYPE_H], 1, [Hard-code for src/cfg/.])
  76 AC_DEFINE([HAVE_ERRNO_H], 1, [Hard-code for src/cfg/.])
  77
  78 # No fork on MinGW, disable some self-tests until we fix them.
  79 AC_CHECK_FUNCS(fork,,)
  80 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
  81
  82 AC_CHECK_TYPES(uint,,, [
  83 # include <sys/types.h>
  84 ])
  85
  86 # For Guile bindings.
  87 opt_guile_bindings=yes
  88 AC_MSG_CHECKING([whether building Guile bindings])
  89 AC_ARG_ENABLE(guile,
  90         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
  91 opt_guile_bindings=$enableval)
  92 AC_MSG_RESULT($opt_guile_bindings)
  93
  94 AC_ARG_WITH([--with-guile-site-dir],
  95   [AS_HELP_STRING([--with-guile-site-dir],
  96      [use the given directory as the Guile site (use with care)])])
  97
  98 if test "$opt_guile_bindings" = "yes"; then
  99    AC_MSG_RESULT([***
 100 *** Detecting GNU Guile...
 101 ])
 102
 103    AC_PATH_PROG([guile_snarf], [guile-snarf])
 104    if test "x$guile_snarf" = "x"; then
 105       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 106       opt_guile_bindings=no
 107    else
 108       GUILE_PROGS
 109       GUILE_FLAGS
 110
 111       save_CFLAGS="$CFLAGS"
 112       save_LIBS="$LIBS"
 113       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 114       LIBS="$LIBS $GUILE_LDFLAGS"
 115       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 116       AC_LINK_IFELSE(AC_LANG_CALL([], [scm_from_locale_string]),
 117         [], [opt_guile_bindings=no])
 118       CFLAGS="$save_CFLAGS"
 119       LIBS="$save_LIBS"
 120
 121       if test "$opt_guile_bindings" = "yes"; then
 122         AC_MSG_RESULT([yes])
 123         case "x$with_guile_site_dir" in
 124              xno)
 125                 # Use the default $(GUILE_SITE).
 126                 GUILE_SITE_DIR
 127                 ;;
 128              x|xyes)
 129                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 130                 # hack is used to allow `distcheck' to work (see
 131                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 132                 GUILE_SITE="\$(datadir)/guile/site"
 133                 AC_SUBST(GUILE_SITE)
 134                 ;;
 135              *)
 136                 # Use the user-specified directory as $(GUILE_SITE).
 137                 GUILE_SITE="$with_guile_site_dir"
 138                 AC_SUBST(GUILE_SITE)
 139                 ;;
 140         esac
 141         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 142         _gcc_cflags_save="$CFLAGS"
 143         CFLAGS="${CFLAGS} -fgnu89-inline"
 144         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 145                           gnu89_inline=yes, gnu89_inline=no)
 146         AC_MSG_RESULT($gnu89_inline)
 147         CFLAGS="$_gcc_cflags_save"
 148
 149         # Optional Guile functions.
 150         save_CFLAGS="$CFLAGS"
 151         save_LIBS="$LIBS"
 152         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 153         LIBS="$LIBS $GUILE_LDFLAGS"
 154         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 155         CFLAGS="$save_CFLAGS"
 156         LIBS="$save_LIBS"
 157       else
 158         AC_MSG_RESULT([no])
 159         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 160         opt_guile_bindings=no
 161       fi
 162    fi
 163 fi
 164 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 165 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 166 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 167
 168 dnl Check for libcfg+
 169
 170 SAVED_LIBS=$LIBS
 171 AC_ARG_WITH(included-libcfg,
 172         AS_HELP_STRING([--with-included-libcfg],
 173                 [use the included libcfg+ (certtool only)]),
 174         libcfg_enabled=$withval,
 175         libcfg_enabled=no
 176 dnl We search for libcfg+ which is used by certtool
 177 dnl
 178         AC_CHECK_LIB(cfg+, cfg_get_context,:,
 179                      libcfg_enabled=yes
 180                      AC_MSG_WARN([[
 181 ***
 182 *** Libcfg+ was not found. Will use the included one.]])))
 183
 184 AM_CONDITIONAL(HAVE_LIBCFG, test "$libcfg_enabled" = "no")
 185 LIBS=$SAVED_LIBS
 186
 187 AC_MSG_CHECKING([whether to use the included libcfg])
 188 AC_MSG_RESULT($libcfg_enabled)
 189
 190 AC_LIBTOOL_WIN32_DLL
 191 AC_PROG_LIBTOOL
 192
 193 gl_INIT
 194
 195 AC_ARG_ENABLE([gcc-warnings],
 196   [AS_HELP_STRING([--enable-gcc-warnings],
 197                   [turn on lots of GCC warnings (for developers)])],
 198   [case $enableval in
 199      yes|no) ;;
 200      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 201    esac
 202    gl_gcc_warnings=$enableval],
 203   [gl_gcc_warnings=no]
 204 )
 205
 206 if test "$gl_gcc_warnings" = yes; then
 207   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 208   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 209
 210   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 211   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 212   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 213   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 214   nw="$nw -Wlogical-op"             # Too many false positives
 215   nw="$nw -Wold-style-definition"   #
 216   nw="$nw -Wpadded"                 # Our structs are not padded
 217   nw="$nw -Wunreachable-code"       # Too many false positives
 218   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 219   nw="$nw -Wcast-qual"              # Too many warnings for now
 220   nw="$nw -Waggregate-return"       # Too many warnings for now
 221   nw="$nw -Wshadow"                 # Too many warnings for now
 222   nw="$nw -Wswitch-default"         # Too many warnings for now
 223   nw="$nw -Wswitch-enum"            # Too many warnings for now
 224   nw="$nw -Wconversion"             # Too many warnings for now
 225   nw="$nw -Wsign-conversion"        # Too many warnings for now
 226   nw="$nw -Wformat-y2k"             # Too many warnings for now
 227   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 228   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 229   nw="$nw -Wunsafe-loop-optimizations"
 230   nw="$nw -Wstrict-overflow"
 231   nw="$nw -Wmissing-noreturn"
 232
 233   gl_MANYWARN_ALL_GCC([ws])
 234   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 235   for w in $ws; do
 236     gl_WARN_ADD([$w])
 237   done
 238
 239   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 240   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 241   gl_WARN_ADD([-Wno-pointer-sign])     # Too many warnings for now
 242   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 243   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 244   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 245   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 246   gl_WARN_ADD([-fdiagnostics-show-option])
 247 fi
 248
 249 # Export things for */configure.ac.
 250 export WERROR_CFLAGS
 251 export WSTACK_CFLAGS
 252 export WARN_CFLAGS
 253 export use_cxx
 254
 255 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 256
 257 AC_CONFIG_SUBDIRS([lib])
 258 AC_CONFIG_SUBDIRS([libextra])
 259
 260 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 261 AC_CONFIG_FILES([
 262   Makefile
 263   doc/Makefile
 264   doc/credentials/Makefile
 265   doc/credentials/openpgp/Makefile
 266   doc/credentials/srp/Makefile
 267   doc/credentials/x509/Makefile
 268   doc/cyclo/Makefile
 269   doc/doxygen/Doxyfile
 270   doc/examples/Makefile
 271   doc/manpages/Makefile
 272   doc/reference/Makefile
 273   doc/scripts/Makefile
 274   gl/Makefile
 275   gl/tests/Makefile
 276   guile/Makefile
 277   guile/modules/Makefile
 278   guile/src/Makefile
 279   guile/tests/Makefile
 280   src/Makefile
 281   src/cfg/Makefile
 282   src/cfg/platon/Makefile
 283   src/cfg/platon/str/Makefile
 284   tests/Makefile
 285   tests/key-id/Makefile
 286   tests/dsa/Makefile
 287   tests/openpgp-certs/Makefile
 288   tests/safe-renegotiation/Makefile
 289   tests/pathlen/Makefile
 290   tests/pkcs1-padding/Makefile
 291   tests/pkcs12-decode/Makefile
 292   tests/pkcs8-decode/Makefile
 293   tests/rsa-md5-collision/Makefile
 294   tests/sha2/Makefile
 295   tests/userid/Makefile
 296   tests/suite/Makefile
 297 ])
 298
 299 AC_OUTPUT
 300
 301 AC_MSG_NOTICE([summary of build options:
 302
 303   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 304   Host type:        ${host}
 305   Install prefix:   ${prefix}
 306   Compiler:         ${CC}
 307   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 308   Library types:    Shared=${enable_shared}, Static=${enable_static}
 309   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 310   Guile wrappers:   $opt_guile_bindings
 311   C++ library:      $use_cxx
 312   OpenSSL library:  $enable_openssl
 313   /dev/crypto:      $enable_cryptodev
 314   Crypto library:   $cryptolib
 315 ])