cmake/gmxTestLargeFiles.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2012,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Define macro to check large file support
  36 #
  37 #  GMX_TEST_LARGE_FILES(VARIABLE)
  38 #
  39 #  VARIABLE will be set to true if off_t is 64 bits, and fseeko/ftello present.
  40 #  This macro will also set defines necessary enable large file support, for instance
  41 #  _LARGE_FILES
  42 #  _LARGEFILE_SOURCE
  43 #  _FILE_OFFSET_BITS 64
  44 #
  45 #  However, it is YOUR job to make sure these defines are set in a cmakedefine so they
  46 #  end up in a config.h file that is included in your source if necessary!
  47
  48 include(CheckTypeSize)
  49
  50 MACRO(GMX_TEST_LARGE_FILES VARIABLE)
  51     IF(NOT DEFINED ${VARIABLE})
  52
  53         # On most platforms it is probably overkill to first test the flags for 64-bit off_t,
  54         # and then separately fseeko. However, in the future we might have 128-bit filesystems
  55         # (ZFS), so it might be dangerous to indiscriminately set e.g. _FILE_OFFSET_BITS=64.
  56
  57         MESSAGE(STATUS "Checking for 64-bit off_t")
  58
  59         # First check without any special flags
  60         TRY_COMPILE(FILE64_OK "${CMAKE_BINARY_DIR}"
  61                     "${CMAKE_SOURCE_DIR}/cmake/TestFileOffsetBits.c")
  62         if(FILE64_OK)
  63             MESSAGE(STATUS "Checking for 64-bit off_t - present")
  64         endif()
  65
  66         if(NOT FILE64_OK)
  67             # Test with _FILE_OFFSET_BITS=64
  68             TRY_COMPILE(FILE64_OK "${CMAKE_BINARY_DIR}"
  69                         "${CMAKE_SOURCE_DIR}/cmake/TestFileOffsetBits.c"
  70                         COMPILE_DEFINITIONS "-D_FILE_OFFSET_BITS=64" )
  71             if(FILE64_OK)
  72                 MESSAGE(STATUS "Checking for 64-bit off_t - present with _FILE_OFFSET_BITS=64")
  73                 set(_FILE_OFFSET_BITS 64 CACHE INTERNAL "64-bit off_t requires _FILE_OFFSET_BITS=64")
  74             endif()
  75         endif()
  76
  77         if(NOT FILE64_OK)
  78             # Test with _LARGE_FILES
  79             TRY_COMPILE(FILE64_OK "${CMAKE_BINARY_DIR}"
  80                         "${CMAKE_SOURCE_DIR}/cmake/TestFileOffsetBits.c"
  81                         COMPILE_DEFINITIONS "-D_LARGE_FILES" )
  82             if(FILE64_OK)
  83                 MESSAGE(STATUS "Checking for 64-bit off_t - present with _LARGE_FILES")
  84                 set(_LARGE_FILES 1 CACHE INTERNAL "64-bit off_t requires _LARGE_FILES")
  85             endif()
  86         endif()
  87
  88         if(NOT FILE64_OK)
  89             # Test with _LARGEFILE_SOURCE
  90             TRY_COMPILE(FILE64_OK "${CMAKE_BINARY_DIR}"
  91                         "${CMAKE_SOURCE_DIR}/cmake/TestFileOffsetBits.c"
  92                         COMPILE_DEFINITIONS "-D_LARGEFILE_SOURCE" )
  93             if(FILE64_OK)
  94                 MESSAGE(STATUS "Checking for 64-bit off_t - present with _LARGEFILE_SOURCE")
  95                 set(_LARGEFILE_SOURCE 1 CACHE INTERNAL "64-bit off_t requires _LARGEFILE_SOURCE")
  96             endif()
  97         endif()
  98
  99         if(NOT FILE64_OK)
 100             MESSAGE(STATUS "Checking for 64-bit off_t - not present")
 101         else()
 102             # 64-bit off_t found. Now check that ftello/fseeko is available.
 103
 104             # Set the flags we might have determined to be required above
 105             configure_file("${CMAKE_SOURCE_DIR}/cmake/TestLargeFiles.c.cmakein"
 106                            "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/TestLargeFiles.c")
 107
 108             MESSAGE(STATUS "Checking for fseeko/ftello")
 109             # Test if ftello/fseeko are available
 110             TRY_COMPILE(FSEEKO_COMPILE_OK "${CMAKE_BINARY_DIR}"
 111                         "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/TestLargeFiles.c")
 112             if(FSEEKO_COMPILE_OK)
 113                 MESSAGE(STATUS "Checking for fseeko/ftello - present")
 114             endif()
 115
 116             if(NOT FSEEKO_COMPILE_OK)
 117                 # glibc 2.2 neds _LARGEFILE_SOURCE for fseeko (but not 64-bit off_t...)
 118                 TRY_COMPILE(FSEEKO_COMPILE_OK "${CMAKE_BINARY_DIR}"
 119                             "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/TestLargeFiles.c"
 120                             COMPILE_DEFINITIONS "-D_LARGEFILE_SOURCE" )
 121                 if(FSEEKO_COMPILE_OK)
 122                     MESSAGE(STATUS "Checking for fseeko/ftello - present with _LARGEFILE_SOURCE")
 123                     set(_LARGEFILE_SOURCE 1 CACHE INTERNAL "64-bit fseeko requires _LARGEFILE_SOURCE")
 124                 else()
 125                     set(FILE64_OK 0)
 126                     message(STATUS "64-bit off_t present but fseeko/ftello not found!")
 127                 endif()
 128             endif()
 129         endif()
 130
 131         if(NOT FILE64_OK)
 132             # now check for Windows stuff
 133             TRY_COMPILE(FILE64_OK "${CMAKE_BINARY_DIR}"
 134                         "${CMAKE_SOURCE_DIR}/cmake/TestWindowsFSeek.c")
 135             if(FILE64_OK)
 136                 MESSAGE(STATUS "Checking for 64-bit off_t - present with _fseeki64")
 137                 set(HAVE__FSEEKI64 1 CACHE INTERNAL "64-bit off_t requires _fseeki64")
 138             endif()
 139         endif()
 140
 141         if(FSEEKO_COMPILE_OK)
 142             SET(${VARIABLE} 1 CACHE INTERNAL "Result of test for large file support" FORCE)
 143             set(HAVE_FSEEKO 1 CACHE INTERNAL "64bit fseeko is available" FORCE)
 144         elseif(HAVE__FSEEKI64)
 145             SET(${VARIABLE} 1 CACHE INTERNAL "Result of test for large file support" FORCE)
 146             SET(HAVE__FSEEKI64 1 CACHE INTERNAL "Windows 64-bit fseek" FORCE)
 147         else()
 148             check_type_size("long int"      SIZEOF_LONG_INT)
 149             if(SIZEOF_LONG_INT EQUAL 8) #standard fseek is OK for 64bit
 150                 SET(${VARIABLE} 1 CACHE INTERNAL "Result of test for large file support" FORCE)
 151             else()
 152                 MESSAGE(FATAL_ERROR "Checking for 64bit file support failed.")
 153             endif()
 154         endif()
 155
 156     ENDIF()
 157 ENDMACRO(GMX_TEST_LARGE_FILES VARIABLE)
 158
 159
 160