cmake/gmxTestLibXml2.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Define macro to check if linking to libxml2 actually works,
  36 # because the find_package macro is content if one exists.  This can
  37 # fail in cross-compilation environments, and we want to know about
  38 # libxml2 so the test binaries are built only when they will work.
  39 #
  40 #  GMX_TEST_LIBXML2(VARIABLE)
  41 #
  42 #  VARIABLE will be set to true if libxml2 support is present
  43
  44 include(CheckLibraryExists)
  45 include(CheckIncludeFiles)
  46 include(gmxOptionUtilities)
  47 function(GMX_TEST_LIBXML2 VARIABLE)
  48     if(LIBXML2_FOUND)
  49         gmx_check_if_changed(_do_libxml2_recompile LIBXML2_INCLUDE_DIR LIBXML2_LIBRARIES)
  50         if(_do_libxml2_recompile)
  51             unset(LIBXML2_LINKS_OK CACHE)
  52         endif()
  53         check_library_exists("${LIBXML2_LIBRARIES}" "xmlTextWriterEndAttribute" "" LIBXML2_LINKS_OK)
  54         if(LIBXML2_LINKS_OK)
  55             #check that xml headers can be included
  56             set(CMAKE_REQUIRED_INCLUDES "${LIBXML2_INCLUDE_DIR}")
  57             check_include_files("libxml/parser.h" LIBXML2_INCL_OK)
  58             if(NOT LIBXML2_INCL_OK)
  59                 #xml headers depend on iconv.h. Test whether adding its path fixes the problem
  60                 find_path(ICONV_INCLUDE_DIR iconv.h)
  61                 if(ICONV_INCLUDE_DIR)
  62                     set(CMAKE_REQUIRED_INCLUDES "${LIBXML2_INCLUDE_DIR};${ICONV_INCLUDE_DIR}")
  63                     unset(LIBXML2_INCL_OK CACHE)
  64                     check_include_files("libxml/parser.h" LIBXML2_INCL_OK)
  65                     set(LIBXML2_INCLUDE_DIR "${LIBXML2_INCLUDE_DIR};${ICONV_INCLUDE_DIR}" CACHE PATH "Libxml2 include path" FORCE)
  66                 endif()
  67             endif()
  68             set(${VARIABLE} ${LIBXML2_INCL_OK} PARENT_SCOPE)
  69         else()
  70             set(${VARIABLE} OFF PARENT_SCOPE)
  71         endif()
  72     else()
  73         set(${VARIABLE} OFF PARENT_SCOPE)
  74     endif()
  75 endfunction()
  76
  77
  78