CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsitencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 ########################################################################
 132 # User input options                                                   #
 133 ########################################################################
 134 include(gmxOptionUtilities)
 135
 136 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 137
 138 if(GMX_TARGET_FUJITSU_SPARC64)
 139     # Fujitsu only has SIMD in double precision, so this will be faster
 140     set(GMX_DOUBLE_DEFAULT ON)
 141 else()
 142     set(GMX_DOUBLE_DEFAULT OFF)
 143 endif()
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 145 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 146 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 147
 148 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 149 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 150 gmx_dependent_option(
 151     GMX_MPI_IN_PLACE
 152     "Enable MPI_IN_PLACE for MPIs that have it defined"
 153     ON
 154     GMX_MPI)
 155 mark_as_advanced(GMX_MPI_IN_PLACE)
 156 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 157 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 158 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 159 mark_as_advanced(GMX_FAHCORE)
 160
 161 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 162 mark_as_advanced(GMX_COOL_QUOTES)
 163 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 164
 165 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 166 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 167 if(MSVC)
 168     set(REQUIRED_CUDA_VERSION 4.1)
 169 else()
 170     set(REQUIRED_CUDA_VERSION 4.0)
 171 endif()
 172 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 173 include(gmxManageGPU)
 174
 175 if(GMX_CPU_ACCELERATION)
 176     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 177     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 178     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 179     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 180 endif()
 181
 182 if(NOT GMX_TARGET_MIC)
 183     include(gmxDetectSimd)
 184     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 185 else()
 186     set(GMX_SUGGESTED_SIMD "None")
 187 endif()
 188
 189 gmx_option_multichoice(
 190     GMX_SIMD
 191     "SIMD instruction set for CPU kernels and compiler optimization"
 192     "${GMX_SUGGESTED_SIMD}"
 193     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 194
 195 gmx_option_multichoice(
 196     GMX_FFT_LIBRARY
 197     "FFT library"
 198     "fftw3"
 199     fftw3 mkl "fftpack[built-in]")
 200 gmx_dependent_option(
 201     GMX_BUILD_OWN_FFTW
 202     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 203     OFF
 204     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 205 gmx_dependent_option(
 206     GMX_DISABLE_FFTW_MEASURE
 207     "Do not optimize FFTW setups (not needed with SSE)"
 208     OFF
 209     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 210 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 211 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 212
 213 gmx_option_multichoice(
 214     GMX_QMMM_PROGRAM
 215     "QM package for QM/MM"
 216     None
 217     none gaussian mopac gamess orca)
 218
 219 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 220 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 221
 222 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 223
 224 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 225 mark_as_advanced(GMX_BROKEN_CALLOC)
 226 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 227 mark_as_advanced(GMX_LOAD_PLUGINS)
 228
 229 option(GMX_GPU  "Enable GPU acceleration" ON)
 230 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 231
 232 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 233
 234 if(UNIX)
 235     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 236 endif()
 237 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 238
 239 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 240 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 241
 242 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 243 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 244
 245 option(GMX_BUILD_FOR_COVERAGE
 246        "Tune build for better code coverage metrics (e.g., disable asserts)"
 247        OFF)
 248 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 249
 250 option(GMX_DEVELOPER_BUILD
 251     "Enable Developer convenience features: always build unit-tests"
 252     OFF)
 253 mark_as_advanced(GMX_DEVELOPER_BUILD)
 254
 255 ######################################################################
 256 # Detect OpenMP support
 257 ######################################################################
 258 # The OpenMP detection _must_ come before tests for other CFLAGS.
 259 include(gmxManageOpenMP)
 260
 261
 262
 263 ######################################################################
 264 # Compiler tests
 265 # These need to be done early (before further tests).
 266 #####################################################################
 267
 268 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 269 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 270 # invalid options with the Intel Compilers, and we have added a line
 271 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 272 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 273 # a semicolon. Since this is also used as a separator in lists inside CMake,
 274 # that string ends up being split into two separate patterns, and the last
 275 # part is just a single word that also matches other messages. We solved this
 276 # by replacing the semicolon with a period that matches any character.
 277 #
 278 # These files should be removed from the source tree when a CMake version that
 279 # includes the features in question becomes required for building GROMACS.
 280 include(CheckCCompilerFlag)
 281 include(CheckCXXCompilerFlag)
 282
 283 include(gmxCFlags)
 284 gmx_c_flags()
 285
 286 # This variable should be used for additional compiler flags which are not
 287 # generated in gmxCFlags nor are SIMD or MPI related.
 288 set(EXTRA_C_FLAGS "")
 289 set(EXTRA_CXX_FLAGS "")
 290
 291 # Run through a number of tests for buggy compilers and other issues
 292 include(gmxTestCompilerProblems)
 293 gmx_test_compiler_problems()
 294 # GMX_SIMD will not be set automatically until the second
 295 # pass (which is not strictly guaranteed to occur), so putting this
 296 # check here among logically-related tests is inefficient, but the
 297 # potential loss is likely zero.
 298 if(GMX_SIMD STREQUAL "AVX_256"
 299         AND CMAKE_COMPILER_IS_GNUCC
 300         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 301             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 302     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 303     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 304 endif()
 305
 306
 307 if(GMX_DOUBLE)
 308     add_definitions(-DGMX_DOUBLE)
 309     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 310     if(GMX_RELAXED_DOUBLE_PRECISION)
 311         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 312     endif()
 313 endif()
 314 if(GMX_SOFTWARE_INVSQRT)
 315     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 316 endif()
 317
 318 if(WIN32)
 319     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 320     add_definitions(-DGMX_HAVE_WINSOCK)
 321 endif()
 322
 323
 324
 325 ########################################################################
 326 # Basic system tests (standard libraries, headers, functions, types)   #
 327 ########################################################################
 328 include(CheckIncludeFiles)
 329 include(CheckIncludeFileCXX)
 330 check_include_files(unistd.h     HAVE_UNISTD_H)
 331 check_include_files(pwd.h        HAVE_PWD_H)
 332 check_include_files(dirent.h     HAVE_DIRENT_H)
 333 check_include_files(time.h       HAVE_TIME_H)
 334 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 335 check_include_files(io.h         HAVE_IO_H)
 336 check_include_files(sched.h      HAVE_SCHED_H)
 337
 338 check_include_files(regex.h      HAVE_POSIX_REGEX)
 339 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 340 # TODO: It could be nice to inform the user if no regex support is found,
 341 # as selections won't be fully functional.
 342
 343 include(CheckFunctionExists)
 344 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 345 check_function_exists(memalign          HAVE_MEMALIGN)
 346 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 347 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 348 check_function_exists(fsync             HAVE_FSYNC)
 349 check_function_exists(_fileno           HAVE__FILENO)
 350 check_function_exists(fileno            HAVE_FILENO)
 351 check_function_exists(_commit           HAVE__COMMIT)
 352 check_function_exists(sigaction         HAVE_SIGACTION)
 353 check_function_exists(sysconf           HAVE_SYSCONF)
 354 check_function_exists(rsqrt             HAVE_RSQRT)
 355 check_function_exists(rsqrtf            HAVE_RSQRTF)
 356 check_function_exists(sqrtf             HAVE_SQRTF)
 357 check_function_exists(nice              HAVE_NICE)
 358
 359 include(CheckLibraryExists)
 360 check_library_exists(m sqrt "" HAVE_LIBM)
 361 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 362
 363 include(TestSchedAffinity)
 364 test_sched_affinity(HAVE_SCHED_AFFINITY)
 365
 366 include(TestBigEndian)
 367 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 368
 369 set(GMX_USE_NICE 0)
 370 if (HAVE_UNISTD_H AND HAVE_NICE)
 371     set(GMX_USE_NICE 1)
 372 endif()
 373
 374 # Management of GROMACS options for specific toolchains should go
 375 # here. Because the initial settings for some of the main options have
 376 # already happened, but things like library detection and MPI compiler
 377 # feature detection have not, the docstrings for any over-rides of
 378 # GROMACS defaults or user settings will make sense. Also, any
 379 # toolchain-related reasons for choosing whether to detect various
 380 # things can be sorted out now, before the detection takes place.
 381 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 382     include(gmxManageBlueGene)
 383 endif()
 384
 385 if(GMX_TARGET_FUJITSU_SPARC64)
 386     include(gmxManageFujitsuSparc64)
 387 endif()
 388
 389 ########################################################################
 390 #Process MPI settings
 391 ########################################################################
 392 include(gmxManageMPI)
 393
 394
 395 ########################################################################
 396 #Process shared/static library settings
 397 ########################################################################
 398 include(gmxManageSharedLibraries)
 399
 400
 401 ########################################################################
 402 # Find external packages                                               #
 403 ########################################################################
 404
 405 # Unconditionally find the package, as it is also required for unit
 406 # tests. This exports LIBXML2_FOUND, which we should not use because
 407 # it does not tell us that linking will succeed. Instead, we test that
 408 # next.
 409 if(DEFINED LIBXML2_LIBRARIES)
 410   set(LibXml2_FIND_QUIETLY TRUE)
 411 endif()
 412 find_package(LibXml2)
 413 include(gmxTestLibXml2)
 414 gmx_test_libxml2(HAVE_LIBXML2)
 415 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 416 set(PKG_XML "")
 417 mark_as_advanced(GMX_XML)
 418 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 419 #if(GMX_XML AND NOT HAVE_LIBXML2)
 420 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 421 #endif()
 422 #if(GMX_XML)
 423 #    include_directories(${LIBXML2_INCLUDE_DIR})
 424 #    set(PKG_XML libxml-2.0)
 425 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 426 #endif()
 427
 428 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 429 mark_as_advanced(GMX_EXTRAE)
 430
 431 if (GMX_EXTRAE)
 432   find_package(EXTRAE)
 433   if(EXTRAE_FOUND)
 434     include_directories(${EXTRAE_INCLUDE_DIR})
 435     set(HAVE_EXTRAE 1)
 436   else()
 437     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 438   endif()
 439 endif()
 440
 441 option(GMX_X11 "Use X window system" OFF)
 442 if (GMX_X11)
 443     find_package(X11)
 444     # X11 includes/libraries are only set in the ngmx subdirectory!
 445     if(NOT X11_FOUND)
 446         message(FATAL_ERROR
 447                 "X11 include files and/or libraries were not found. "
 448                 "Set GMX_X11=OFF to compile without X11 support. "
 449                 "gmx view will not be available.")
 450     endif()
 451     include_directories(${X11_INCLUDE_DIR})
 452 endif()
 453
 454 include(ThreadMPI)
 455 # Enable core threading facilities
 456 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 457 # Enable tMPI C++ support
 458 tmpi_enable_cxx()
 459 if(GMX_THREAD_MPI)
 460     # enable MPI functions
 461     tmpi_enable()
 462     set(GMX_MPI 1)
 463     set(MPI_IN_PLACE_EXISTS 1)
 464 endif()
 465 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 466 if (TMPI_ATOMICS_DISABLED)
 467    add_definitions(-DTMPI_ATOMICS_DISABLED)
 468 endif()
 469
 470 if(GMX_GPU)
 471     # now that we have detected the dependencies, do the second configure pass
 472     gmx_gpu_setup()
 473 endif()
 474
 475 if(CYGWIN)
 476     set(GMX_CYGWIN 1)
 477 endif()
 478
 479 if(WIN32)
 480     set(GMX_NATIVE_WINDOWS 1)
 481     # This makes windows.h not declare min/max as macros that would break
 482     # C++ code using std::min/std::max.
 483     add_definitions(-DNOMINMAX)
 484 endif()
 485
 486 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 487 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 488 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 489     find_package(Boost 1.44.0)
 490     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 491         set(Boost_FOUND FALSE)
 492     endif()
 493     # Print the notification only on first run, when determining the default
 494     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 495         message("Boost >= 1.44 not found. Using minimal internal version. "
 496                 "This may cause trouble if you plan on compiling/linking other "
 497                 "software that uses Boost against Gromacs.")
 498     endif()
 499 endif()
 500 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 501        ${Boost_FOUND})
 502 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 503     message(FATAL_ERROR
 504         "Boost >= 1.44 not found. "
 505         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 506         "version of Boost included with Gromacs.")
 507 endif()
 508
 509 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 510     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 511 endif()
 512 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 513 mark_as_advanced(GMX_BUILD_UNITTESTS)
 514 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 515 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 516     message(FATAL_ERROR
 517         "Cannot build unit tests without libxml2. "
 518         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 519 endif()
 520
 521 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 522     # TNG wants zlib if it is available
 523     find_package(ZLIB QUIET)
 524     include(gmxTestZLib)
 525     gmx_test_zlib(HAVE_ZLIB)
 526 endif()
 527
 528 ########################################################################
 529 # Our own GROMACS tests
 530 ########################################################################
 531
 532 add_definitions( -DHAVE_CONFIG_H )
 533 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 534 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 535 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 536 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 537
 538 include(gmxTestInlineASM)
 539 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 540
 541 include(gmxSetBuildInformation)
 542 gmx_set_build_information()
 543 # Turn on RDTSCP if:
 544 # - the build system's CPU supports it
 545 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 546 #   at this point means that the user set it).
 547 # Note: it's better to not use the later set value of GMX_SIMD because
 548 # it reflects the system's capability of both compiling and running AVX code.
 549 # TODO: After merge with 5.0 one could implement a cache variable dependency
 550 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 551 # after the first cmake pass.
 552 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 553     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 554 else()
 555     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 556 endif()
 557 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 558 mark_as_advanced(GMX_USE_RDTSCP)
 559 if(GMX_USE_RDTSCP)
 560     set(HAVE_RDTSCP 1)
 561 endif()
 562
 563 include(gmxTestFloatFormat)
 564 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 565                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 566                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 567
 568 include(gmxTestLargeFiles)
 569 gmx_test_large_files(GMX_LARGEFILES)
 570
 571 include(gmxTestSignal)
 572 gmx_test_sigusr1(HAVE_SIGUSR1)
 573
 574 include(gmxTestPipes)
 575 gmx_test_pipes(HAVE_PIPES)
 576
 577 include(gmxTestIsfinite)
 578 gmx_test_isfinite(HAVE_ISFINITE)
 579 gmx_test__isfinite(HAVE__ISFINITE)
 580 gmx_test__finite(HAVE__FINITE)
 581
 582 include(gmxTestCXX11)
 583 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 584 include(CMakeDependentOption)
 585 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 586 # entirely to keep the compilation environment uniform.
 587 cmake_dependent_option(GMX_CXX11
 588     "Use C++11 features"
 589     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 590 mark_as_advanced(GMX_CXX11)
 591 if(GMX_CXX11)
 592     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 593 endif()
 594
 595
 596 include(gmxTestXDR)
 597 gmx_test_xdr(GMX_SYSTEM_XDR)
 598 if(NOT GMX_SYSTEM_XDR)
 599     set(GMX_INTERNAL_XDR 1)
 600 endif()
 601
 602
 603 ##################################################
 604 # Process SIMD instruction settings
 605 ##################################################
 606 # This checks what flags to add in order to
 607 # support the SIMD instructions we need, and sets
 608 # correct defines for the SIMD instructions supported.
 609 include(gmxTestSimd)
 610 gmx_test_simd()
 611
 612
 613 # Process QM/MM Settings
 614 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 615     set(GMX_QMMM_GAUSSIAN 1)
 616 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 617     set(GMX_QMMM_MOPAC 1)
 618 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 619     set(GMX_QMMM_GAMESS 1)
 620 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 621     set(GMX_QMMM_ORCA 1)
 622 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 623     # nothing to do
 624 else()
 625     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 626 endif()
 627
 628
 629 ##################################################
 630 # Process FFT library settings
 631 ##################################################
 632 include(gmxManageFFTLibraries)
 633
 634
 635 include(gmxManageLinearAlgebraLibraries)
 636
 637 # Whether GROMACS will really try to compile support for VMD plugins
 638 set(GMX_USE_PLUGINS OFF)
 639
 640 if(GMX_LOAD_PLUGINS)
 641   if(NOT WIN32)
 642     # Native Windows does not have, nor need dlopen
 643     include(gmxTestdlopen)
 644     gmx_test_dlopen(HAVE_DLOPEN)
 645   endif()
 646
 647   # so, should we use plug-ins?
 648   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 649     if(NOT VMD_QUIETLY)
 650       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 651     endif()
 652     if(NOT GMX_VMD_PLUGIN_PATH)
 653       find_package(VMD)
 654     endif()
 655     set(GMX_USE_PLUGINS ON)
 656     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 657     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 658   else()
 659     set(PKG_DL_LIBS)
 660   endif()
 661 endif()
 662 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 663
 664 # Link real-time library for POSIX timers. The check for clock_gettime
 665 # confirms the linkability of rt.
 666 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 667     list(APPEND GMX_EXTRA_LIBRARIES rt)
 668 endif()
 669
 670 # Math and thread libraries must often come after all others when linking...
 671 if(HAVE_LIBM)
 672     list(APPEND GMX_EXTRA_LIBRARIES m)
 673 endif()
 674
 675 option(GMX_NACL "Configure for Native Client builds" OFF)
 676 if (GMX_NACL)
 677   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 678   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 679   # TODO: Is this still necessary with the check for its presence?
 680   set(GMX_USE_NICE 0)
 681   set(GMX_NO_RENAME 1)
 682 endif()
 683 mark_as_advanced(GMX_NACL)
 684
 685 if(GMX_FAHCORE)
 686   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 687       "Path to swindirect.h")
 688   include_directories(${COREWRAP_INCLUDE_DIR})
 689 endif()
 690
 691 # Value of AUTO tries to generate things, but will only produce warnings if
 692 # that fails.
 693 set(build_help_default AUTO)
 694 if (SOURCE_IS_SOURCE_DISTRIBUTION)
 695     set(build_help_default OFF)
 696 endif()
 697 gmx_option_trivalue(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" ${build_help_default})
 698 mark_as_advanced(GMX_BUILD_HELP)
 699 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 700     message(FATAL_ERROR
 701         "Rebuilding HTML and man pages or shell completions is not supported "
 702         "for in-source builds from a source distribution. "
 703         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 704 endif()
 705
 706 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 707 # these are set after everything else
 708 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 709     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 710     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 711     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 712     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 713 else()
 714     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 715     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 716     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 717     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 718     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 719     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 720     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 721     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 722     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 723 endif()
 724
 725 if(NOT GMX_OPENMP)
 726     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 727     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 728     unset(OpenMP_C_FLAGS CACHE)
 729     unset(OpenMP_CXX_FLAGS CACHE)
 730 else()
 731     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 732     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 733 endif()
 734
 735 ########################################################################
 736 # Specify install locations
 737 ########################################################################
 738 # Use GNUInstallDirs to set paths on multiarch systems.
 739 include(GNUInstallDirs)
 740
 741 # Customization for the installation tree paths.
 742 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 743     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 744 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 745     "Data installation directory under share/ (default: gromacs)")
 746 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 747
 748 # These variables are used internally to provide a central location for
 749 # customizing the install locations.
 750 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 751 set(BIN_INSTALL_DIR       bin)
 752 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 753 set(MAN_INSTALL_DIR       share/man)
 754 # If the nesting level wrt. the installation root is changed,
 755 # gromacs-config.cmake.cmakein needs to be adapted.
 756 set(CMAKE_INSTALL_DIR     share/cmake)
 757 # TODO: Make GMXRC adapt if this is changed
 758 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 759 set(INCL_INSTALL_DIR      include)
 760
 761 # These variables get written into config.h for use in finding the data
 762 # directories.
 763 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 764 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 765
 766 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 767
 768 # Binary and library suffix options
 769 include(gmxManageSuffixes)
 770
 771 ################################################################
 772 # Shared library load path settings
 773 ################################################################
 774 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 775 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 776 # was added.
 777 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 778    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 779     # The build folder always has bin/ and lib/; if we are also going to
 780     # install to lib/, then the installation RPATH works also in the build
 781     # tree.  This makes installation slightly faster (no need to rewrite the
 782     # RPATHs), and makes the binaries in the build tree relocatable.
 783     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 784         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 785     endif()
 786     # Set the RPATH as relative to the executable location to make the
 787     # binaries relocatable.
 788     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 789         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 790     else()
 791         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 792     endif()
 793     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 794     set(CMAKE_MACOSX_RPATH 1)
 795 else()
 796     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 797     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 798         # Set the RPATH options manually.
 799         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 800         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 801     else()
 802         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 803         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 804     endif()
 805 endif()
 806
 807 #COPYING file: Only necessary for binary distributions.
 808 #Simpler to always install.
 809 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 810
 811 if(GMX_EXTERNAL_BOOST)
 812     include_directories(${Boost_INCLUDE_DIRS})
 813     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 814 else()
 815     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 816     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 817     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 818     # typeid not supported for minimal internal version
 819     # (would add significant amount of code)
 820     add_definitions(-DBOOST_NO_TYPEID)
 821     if (NOT GMX_BUILD_MDRUN_ONLY)
 822         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 823                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 824                 COMPONENT development)
 825     endif()
 826 endif()
 827
 828 if (GMX_BUILD_FOR_COVERAGE)
 829     # Code heavy with asserts makes conditional coverage close to useless metric,
 830     # as by design most of the false branches are impossible to trigger in
 831     # correctly functioning code.  And the benefit of testing those that could
 832     # be triggered by using an API against its specification isn't usually
 833     # worth the effort.
 834     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 835 endif()
 836
 837 if (BUILD_TESTING)
 838     # "tests" target builds all the separate test binaries.
 839     add_custom_target(tests)
 840     # "run-ctest" is an internal target that actually runs the tests.
 841     # This is necessary to be able to add separate targets that execute as part
 842     # of 'make check', but are ensured to be executed after the actual tests.
 843     add_custom_target(run-ctest
 844                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 845                       COMMENT "Running all tests"
 846                       VERBATIM)
 847     add_dependencies(run-ctest tests)
 848     # "check" target builds and runs all tests.
 849     add_custom_target(check DEPENDS run-ctest)
 850 endif()
 851
 852 if (NOT GMX_BUILD_MDRUN_ONLY)
 853     add_subdirectory(docs)
 854     add_subdirectory(share)
 855     add_subdirectory(scripts)
 856 endif()
 857 add_subdirectory(src)
 858
 859 if (BUILD_TESTING)
 860     add_subdirectory(tests)
 861 endif()
 862
 863 gmx_cpack_write_config()
 864
 865 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 866 # Don't bother the user after the first configure pass.
 867 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 868     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 869 endif()
 870 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 871
 872 #######################
 873 ## uninstall target
 874 #######################
 875 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 876                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 877                   IMMEDIATE @ONLY)
 878 ###########################
 879 ADD_CUSTOM_TARGET(uninstall
 880                   "${CMAKE_COMMAND}" -P
 881                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 882 ###########################
 883 set_directory_properties(PROPERTIES
 884             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")