cmake/FindSphinx.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 find_program(SPHINX_EXECUTABLE NAMES sphinx-build
  36     HINTS
  37     $ENV{SPHINX_DIR}
  38     PATH_SUFFIXES bin
  39     DOC "Sphinx documentation generator"
  40 )
  41 mark_as_advanced(SPHINX_EXECUTABLE)
  42
  43 # Detect Sphinx version
  44 if (SPHINX_EXECUTABLE AND NOT DEFINED SPHINX_EXECUTABLE_VERSION)
  45     execute_process(
  46         COMMAND ${SPHINX_EXECUTABLE} --version
  47         OUTPUT_VARIABLE SPHINX_VERSION_OUTPUT_VARIABLE
  48         RESULT_VARIABLE SPHINX_VERSION_RESULT_VARIABLE
  49         ERROR_QUIET
  50         OUTPUT_STRIP_TRAILING_WHITESPACE
  51         )
  52     string(REGEX REPLACE "Sphinx \\([^)]*\\) ([^ ]+)" "\\1" SPHINX_EXECUTABLE_VERSION "${SPHINX_VERSION_OUTPUT_VARIABLE}")
  53     set(SPHINX_EXECUTABLE_VERSION "${SPHINX_EXECUTABLE_VERSION}" CACHE INTERNAL "Version of ${SPHINX_EXECUTABLE}")
  54 endif()
  55
  56 set(_find_deps_options)
  57 if (Sphinx_FIND_QUIETLY)
  58     set(_find_deps_options QUIET)
  59 endif()
  60 include(FindPythonModule)
  61 find_python_module(pygments ${_find_deps_options})
  62 if (PYTHONMODULE_PYGMENTS)
  63     set(Sphinx_pygments_FOUND 1)
  64 endif()
  65
  66 include(FindPackageHandleStandardArgs)
  67
  68 find_package_handle_standard_args(Sphinx
  69     REQUIRED_VARS SPHINX_EXECUTABLE
  70     VERSION_VAR SPHINX_EXECUTABLE_VERSION
  71     HANDLE_COMPONENTS
  72     )