cmake/gmxBuildTypeTSAN.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Custom build type "TSAN", to be used for compiling GROMACS
  36 # with clang 3.4 or gcc 4.8 (currently pre-release) with ThreadSanitizer
  37 # (aka "TSan") turned on, so that the tests can be run to detect data races.
  38 #
  39 # The main advantage of the clang version is that there can be a
  40 # suppressions file that acts at compile time, though there is no use of
  41 # that yet. The main advantage of the gcc version is that it can be used
  42 # with a OpenMP (if gomp is compiled with --disable-linux-futex).
  43 #
  44 # Unfortunately, out of the box Thread-MPI provokes several false
  45 # positives. One example is that tMPI_Event_t contains an atomic int
  46 # field "sync" that is initialized before thread spawn. During a
  47 # collective, this is atomically updated by the source thread, and the
  48 # update is observed by sink threads in tMPI_Event_wait, which do a
  49 # yield wait when no change has occured. This means the read can
  50 # happen before the write (by design, whether or not the read is
  51 # atomic), but the surrounding logic prevents action until the write
  52 # has happened. There is no way for the sink thread(s) to avoid
  53 # reading until the write has happened - that is the point of the
  54 # implementation.
  55 #
  56 # This ought to be able to be suppressed, but my attempts to apply
  57 # suppressions on individual functions don't suppress reporting of the
  58 # race event. Applying the suppression to the whole thread-MPI library
  59 # might work, but seems to defeat the point. We want to be able to
  60 # detect mis-use of the primitives provided by thread-MPI.
  61 #
  62 # This means there needs to be a way for this build type to trigger
  63 # the use of the generic mutex-based fallback implementation within
  64 # thread-MPI.
  65 #
  66 # Later, if a blacklist is needed, use something like
  67 # "-fsanitize-blacklist=${CMAKE_SOURCE_DIR}/cmake/thread-sanitizer.supp"
  68 # TODO find a better home for this and other suppression files
  69 set(_flags "-O1 -g -fsanitize=thread")
  70
  71 foreach(_language C CXX)
  72
  73     string(REPLACE "X" "+" _human_readable_language ${_language})
  74
  75     if (CMAKE_${_language}_COMPILER_ID MATCHES "GNU")
  76         set(CMAKE_${_language}_FLAGS_TSAN "${_flags} -pie -fPIE" CACHE STRING "${_human_readable_language} flags for thread sanitizer")
  77     else()
  78         set(CMAKE_${_language}_FLAGS_TSAN ${_flags} CACHE STRING "${_human_readable_language} flags for thread sanitizer")
  79     endif()
  80     mark_as_advanced(CMAKE_${_language}_FLAGS_TSAN)
  81     string(TOUPPER "${CMAKE_BUILD_TYPE}" _cmake_build_type)
  82     if (_cmake_build_type STREQUAL TSAN)
  83         set(TMPI_ATOMICS_DISABLED 1)
  84         set(TMPI_ATOMICS 0)
  85         if (NOT((CMAKE_${_language}_COMPILER_ID MATCHES "Clang" AND
  86                     CMAKE_${_language}_COMPILER_VERSION VERSION_GREATER 3.2.999)
  87              OR (CMAKE_${_language}_COMPILER_ID MATCHES "GNU" AND
  88                     CMAKE_${_language}_COMPILER_VERSION VERSION_GREATER 4.7.999)))
  89             message(FATAL_ERROR "The ThreadSanitizer build is only available with clang ${_human_readable_language} >=3.3 and gnu ${_human_readable_language} >=4.8.")
  90         endif()
  91     endif()
  92
  93 endforeach()