cmake/gmxGetGmockTupleWorkaround.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # GMock uses tuples extensively, but since it is part of tr1 we cannot
  36 # assume it is present - the Fujitsu compilers on K computer is one
  37 # example of a system where it is not, and this is likely the case for many
  38 # embedded systems too.
  39 #
  40 # In general, we can ask gmock to use its own internal implementation by
  41 # defining GTEST_USE_OWN_TR1_TUPLE=1. This is safe for Gromacs, since we do
  42 # not use tr1/tuple.h elsewhere. However, this workaround itself will not
  43 # compile on MSVC - but this is the only architecture we know where it does
  44 # not work. To make things even worse, on MSVC even the standard tr1/tuple
  45 # implementation is not fully compatible, but we can make it work by setting
  46 # _VARIADIC_MAX=10. This is similar to r675 of googletest, which is still not
  47 # present in GMock 1.7.0. See
  48 # https://code.google.com/p/googletest/source/detail?r=675#, but note
  49 # that its summary does not represent its code correctly.
  50 #
  51 # To make all this work without user intervention, we first check what compiler
  52 # we have, and if it is not MSVC we simply use the internal version. If we are
  53 # using MSVC, we rely on the compiler's version, but set the variable necessary
  54 # to make it compatible.
  55 #
  56 # This function should be called to get the compile definitions
  57 # suitable for making sure we have a tuple implementation that works with gmock.
  58 #
  59 # Returns a string of options in VARIABLE
  60 function(GET_GMOCK_TUPLE_WORKAROUND VARIABLE)
  61     set(${VARIABLE} "")
  62     if(MSVC OR (WIN32 AND CMAKE_CXX_COMPILER_ID MATCHES "Intel"))
  63         if(MSVC_VERSION VERSION_EQUAL 1700)
  64             # Fixes Visual Studio 2012
  65             set(${VARIABLE} "_VARIADIC_MAX=10")
  66         endif()
  67         # For MSVC different from 2012, or Intel on Windows, we reply on tr1/tuple working.
  68     else()
  69         # Use the built-in version on all other compilers.
  70         set(${VARIABLE} "GTEST_USE_OWN_TR1_TUPLE=1")
  71     endif()
  72     set(${VARIABLE} ${${VARIABLE}} PARENT_SCOPE)
  73 endfunction()