CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.3-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "3")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55
  56 ########################################################################
  57 # Fix stupid flags on MSVC
  58 ########################################################################
  59 SET(SHARED_LIBS_DEFAULT ON)
  60 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  61     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  62     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  63     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  64     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  65     SET(SHARED_LIBS_DEFAULT OFF)
  66 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  67
  68 set(GMX_EXTRA_LIBRARIES)
  69
  70
  71
  72 ######################################################################
  73 # compiler tests
  74 # these need ot be done early (before further tests).
  75 #####################################################################
  76
  77 include(CheckCCompilerFlag)
  78 include(CheckCXXCompilerFlag)
  79
  80 include(gmxCFlags)
  81 gmx_c_flags()
  82
  83 ########################################################################
  84 # User input options                                                   #
  85 ########################################################################
  86 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
  87 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  88 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
  89 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  90 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  91 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
  92 mark_as_advanced(GMX_POWERPC_INVSQRT)
  93 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  94 mark_as_advanced(GMX_FAHCORE)
  95 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
  96 set(GMX_ACCELERATION "auto"
  97     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
  98
  99 set(GMX_FFT_LIBRARY "fftw3"
 100     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 101 option(GMX_DISABLE_FFTW_MEASURE
 102        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 103 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 104 set(GMX_QMMM_PROGRAM "none"
 105     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 106 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 107 mark_as_advanced(GMX_BROKEN_CALLOC)
 108 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 109 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 110 mark_as_advanced(GMX_MPI_IN_PLACE)
 111 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 112 mark_as_advanced(GMX_DLOPEN)
 113
 114
 115 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 116 mark_as_advanced(GMX_IA32_ASM)
 117 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 118 mark_as_advanced(GMX_X86_64_ASM)
 119
 120 option(USE_VERSION_H "Generate development version string/information" ON)
 121 mark_as_advanced(USE_VERSION_H)
 122
 123 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 124
 125 if(UNIX AND NOT APPLE)
 126     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 127     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 128 endif()
 129
 130 ########################################################################
 131 # Set up binary and library suffixing
 132 ########################################################################
 133 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 134 set(GMX_LIBS_SUFFIX ""
 135   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 136 if (GMX_DEFAULT_SUFFIX)
 137   set(GMX_BINARY_SUFFIX "")
 138   set(GMX_LIBS_SUFFIX "")
 139   if (GMX_MPI)
 140     set(GMX_BINARY_SUFFIX "_mpi")
 141     set(GMX_LIBS_SUFFIX "_mpi")
 142   endif(GMX_MPI)
 143   if (GMX_DOUBLE)
 144     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 145     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 146   endif(GMX_DOUBLE)
 147   if (GMX_OPENMM)
 148     set (GMX_BINARY_SUFFIX "-gpu")
 149     set (GMX_LIBS_SUFFIX "_gpu")
 150   endif(GMX_OPENMM)
 151   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 152   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 153   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 154 else(GMX_DEFAULT_SUFFIX)
 155   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 156   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 157   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 158 endif(GMX_DEFAULT_SUFFIX)
 159
 160 set(PKG_CFLAGS "")
 161 if(GMX_DOUBLE)
 162     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 163 endif(GMX_DOUBLE)
 164 if(GMX_SOFTWARE_INVSQRT)
 165   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 166 endif(GMX_SOFTWARE_INVSQRT)
 167 if(GMX_POWERPC_INVSQRT)
 168   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 169 endif(GMX_POWERPC_INVSQRT)
 170
 171 ########################################################################
 172 #Process MPI settings
 173 ########################################################################
 174 if(GMX_MPI)
 175         MESSAGE(WARNING "
 176             There are known problems with some MPI implementations:
 177                      OpenMPI version < 1.4.1
 178                      MVAPICH2 version <= 1.4.1                               *")
 179     if(GMX_THREADS)
 180         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 181         set(GMX_THREADS OFF CACHE BOOL
 182             "Thread-based parallelization conflicts with MPI." FORCE)
 183     endif(GMX_THREADS)
 184     find_package(MPI)
 185     if(MPI_FOUND)
 186         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 187         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 188
 189         include_directories(${MPI_INCLUDE_PATH})
 190         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 191         add_definitions( -DMPI ) #for FAHCORE
 192         include(gmxTestMPI_IN_PLACE)
 193         if (GMX_MPI_IN_PLACE)
 194             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 195         endif (GMX_MPI_IN_PLACE)
 196     else(MPI_FOUND)
 197         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 198     endif(MPI_FOUND)
 199     include(gmxTestCatamount)
 200     gmx_test_catamount(GMX_CRAY_XT3)
 201     if(GMX_CRAY_XT3)
 202         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 203         set(GMX_NO_SYSTEM 1)
 204         set(GMX_NO_NICE 1)
 205     endif(GMX_CRAY_XT3)
 206     set(GMX_LIB_MPI 1)
 207     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 208 endif(GMX_MPI)
 209
 210
 211 #######################################################################
 212 # Check for options incompatible with OpenMM build                    #
 213 #######################################################################
 214 if(GMX_OPENMM)
 215     cmake_minimum_required(VERSION 2.6.4)
 216     # we'll use the built-in fft to avoid unnecessary dependencies
 217     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 218     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 219         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 220         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 221                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 222     endif()
 223     if(GMX_MPI)
 224         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 225     endif(GMX_MPI)
 226     if(GMX_THREADS)
 227         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 228         set(GMX_THREADS OFF CACHE BOOL
 229                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 230     endif(GMX_THREADS)
 231     if(GMX_SOFTWARE_INVSQRT)
 232         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 233                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 234     endif(GMX_SOFTWARE_INVSQRT)
 235     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 236     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 237         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 238         set(GMX_ACCELERATION "none" CACHE STRING
 239                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 240     endif()
 241     if(GMX_FAHCORE)
 242         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 243     endif(GMX_FAHCORE)
 244     if(GMX_DOUBLE)
 245         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 246     endif()
 247     # mark as advanced the unused variables
 248     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 249         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 250 else(GMX_OPENMM)
 251      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 252         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 253 endif(GMX_OPENMM)
 254
 255
 256 ########################################################################
 257 # Basic system tests (standard libraries, headers, functions, types)   #
 258 ########################################################################
 259 include(CheckIncludeFiles)
 260 check_include_files(string.h     HAVE_STRING_H)
 261 check_include_files(math.h       HAVE_MATH_H)
 262 check_include_files(limits.h     HAVE_LIMITS_H)
 263 check_include_files(memory.h     HAVE_MEMORY_H)
 264 check_include_files(unistd.h     HAVE_UNISTD_H)
 265 check_include_files(pwd.h        HAVE_PWD_H)
 266 check_include_files(stdint.h     HAVE_STDINT_H)
 267 check_include_files(stdlib.h     HAVE_STDLIB_H)
 268 check_include_files(pthread.h    HAVE_PTHREAD_H)
 269 check_include_files(dirent.h     HAVE_DIRENT_H)
 270 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 271 check_include_files(regex.h      HAVE_REGEX_H)
 272 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 273 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 274 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 275 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 276 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 277 # SSE support
 278 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 279 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 280 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 281 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 282 check_include_files(io.h                 HAVE_IO_H)
 283
 284
 285 include(CheckFunctionExists)
 286 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 287 check_function_exists(strdup            HAVE_STRDUP)
 288 check_function_exists(vprintf           HAVE_VPRINTF)
 289 check_function_exists(memcmp            HAVE_MEMCMP)
 290 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 291 check_function_exists(memalign          HAVE_MEMALIGN)
 292 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 293 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 294 check_function_exists(isnan             HAVE_ISNAN)
 295 check_function_exists(_isnan            HAVE__ISNAN)
 296 check_function_exists(isfinite          HAVE_ISFINITE)
 297 check_function_exists(_isfinite         HAVE__ISFINITE)
 298 check_function_exists(fsync             HAVE_FSYNC)
 299 check_function_exists(_fileno           HAVE__FILENO)
 300 check_function_exists(fileno            HAVE_FILENO)
 301 check_function_exists(_commit           HAVE__COMMIT)
 302
 303 include(CheckLibraryExists)
 304 check_library_exists(m sqrt "" HAVE_LIBM)
 305 check_library_exists(m cbrt "" HAVE_CBRT)
 306
 307
 308 include(CheckTypeSize)
 309
 310 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 311 check_type_size("int"           SIZEOF_INT)
 312 check_type_size("long int"      SIZEOF_LONG_INT)
 313 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 314 check_type_size("off_t"         SIZEOF_OFF_T)
 315 check_type_size("void *"        SIZEOF_VOIDP)
 316
 317 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 318     set(GMX_64_BIT TRUE)
 319 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 320     set(GMX_64_BIT FALSE)
 321 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 322
 323 # Check for some basic types that we *need*, so set these to int if they are not present
 324 check_type_size(uid_t uid_t)
 325 if(NOT uid_t)
 326   set(uid_t int)
 327 else(NOT uid_t)
 328   set(uid_t 0)
 329 endif(NOT uid_t)
 330
 331 check_type_size(gid_t gid_t)
 332 if(NOT gid_t)
 333   set(gid_t 1)
 334 else(NOT gid_t)
 335   set(gid_t 0)
 336 endif(NOT gid_t)
 337
 338 check_type_size(size_t size_t)
 339 if(NOT size_t)
 340   set(size_t int)
 341 else(NOT size_t)
 342   set(size_t 0)
 343 endif(NOT size_t)
 344
 345 check_type_size(off_t off_t)
 346 if(NOT off_t)
 347   set(off_t int)
 348 else(NOT off_t)
 349   set(off_t 0)
 350 endif(NOT off_t)
 351
 352 include(TestBigEndian)
 353 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 354
 355
 356
 357
 358 ########################################################################
 359 # Find external packages                                               #
 360 ########################################################################
 361 if(UNIX AND NOT APPLE)
 362     if(GMX_PREFER_STATIC_LIBS)
 363         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 364         if(BUILD_SHARED_LIBS)
 365             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 366             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 367         endif()
 368     endif()
 369 endif()
 370
 371 find_package(LibXml2)
 372 set(PKG_XML "")
 373 if(LIBXML2_FOUND)
 374     include_directories(${LIBXML2_INCLUDE_DIR})
 375     set(PKG_XML libxml-2.0)
 376     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 377     set(HAVE_LIBXML2 1)
 378 endif(LIBXML2_FOUND)
 379
 380 option(GMX_X11 "Use X window system" OFF)
 381 if (GMX_X11)
 382         find_package(X11)
 383         # X11 includes/libraries are only set in the ngmx subdirectory!
 384         if(X11_FOUND)
 385         set(HAVE_X11 1)
 386         endif(X11_FOUND)
 387 endif(GMX_X11)
 388
 389 if(GMX_THREADS)
 390     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 391     include(ThreadMPI)
 392     set(THREAD_MPI_LIB thread_mpi)
 393     set(GMX_MPI 1)
 394     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 395     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 396         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 397     endif()
 398 endif(GMX_THREADS)
 399
 400 if(GMX_OPENMM)
 401     set(CUDA_BUILD_EMULATION OFF)
 402     find_package(CUDA 3.1 REQUIRED)
 403     add_definitions(-DGMX_OPENMM)
 404     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 405         set(CUDA_VERBOSE_BUILD ON)
 406     endif()
 407     find_package(OpenMM)
 408 endif(GMX_OPENMM)
 409
 410 if(APPLE)
 411    find_library(ACCELERATE_FRAMEWORK Accelerate)
 412    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 413 endif(APPLE)
 414
 415 # only bother with finding git and using version.h if the source is a git repo
 416 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 417     if(USE_VERSION_H)
 418         # We need at least git v1.5.1 be able to parse git's date output. If not
 419         # fund or the version is too small, we can't generate version information.
 420         find_package(Git 1.5.1)
 421         # this should at some point become VERSION_LESS
 422         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 423             message("No compatible git version found, won't be able to generate proper development version information.")
 424             set(USE_VERSION_H OFF)
 425         endif()
 426     endif()
 427 else()
 428     set(USE_VERSION_H OFF)
 429 endif()
 430
 431 if (GMX_DLOPEN)
 432     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 433 endif (GMX_DLOPEN)
 434
 435 ########################################################################
 436 # Generate development version info for cache
 437 ########################################################################
 438 # set(GEN_VERSION_INFO_INTERNAL "ON")
 439 # include(gmxGenerateVersionString)
 440
 441 ########################################################################
 442 # Our own GROMACS tests
 443 ########################################################################
 444
 445 add_definitions( -DHAVE_CONFIG_H )
 446 include_directories(${CMAKE_BINARY_DIR}/src)
 447 include_directories(${CMAKE_SOURCE_DIR}/include)
 448
 449 include(gmxCheckBuildUserTime)
 450 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 451
 452 include(gmxTestFloatFormat)
 453 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 454                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 455                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 456
 457 include(gmxTestLargeFiles)
 458 gmx_test_large_files(GMX_LARGEFILES)
 459 check_function_exists(fseeko     HAVE_FSEEKO)
 460
 461 include(gmxTestSignal)
 462 gmx_test_retsigtype(RETSIGTYPE)
 463 gmx_test_sigusr1(HAVE_SIGUSR1)
 464
 465 include(gmxTestInline)
 466 gmx_test_inline(INLINE_KEYWORD)
 467
 468 include(gmxTestRestrict)
 469 gmx_test_inline(RESTRICT_KEYWORD)
 470
 471 include(gmxTestPipes)
 472 gmx_test_pipes(HAVE_PIPES)
 473
 474 include(gmxTestInlineASM)
 475 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 476 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 477
 478 # turn on SSE if supported with reasonable defaults.
 479 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 480   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 481
 482     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 483
 484     if (GMX_64_BIT)
 485       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 486     else (GMX_64_BIT)
 487       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 488     endif (GMX_64_BIT)
 489
 490     # Determine the assembler/compiler to use
 491   else()
 492     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 493   endif()
 494 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 495
 496 include(gmxTestXDR)
 497 gmx_test_xdr(GMX_SYSTEM_XDR)
 498 if(NOT GMX_SYSTEM_XDR)
 499     set(GMX_INTERNAL_XDR 1)
 500     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 501 endif(NOT GMX_SYSTEM_XDR)
 502
 503 # Process nonbonded accelerated kernels settings
 504 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 505 if(${GMX_ACCELERATION} STREQUAL "NONE")
 506   # nothing to do
 507 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 508
 509     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 510       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 511     else()
 512       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 513     endif()
 514         mark_as_advanced(GMX_ASM_USEASM-NASM)
 515
 516     if (NOT GMX_64_BIT)
 517         # for 32-bit compiles, we might need to turn on sse
 518         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 519         if (XFLAGS_SSE)
 520             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 521         endif (XFLAGS_SSE)
 522         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 523         if (XXFLAGS_SSE)
 524             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 525         endif (XXFLAGS_SSE)
 526     endif (NOT GMX_64_BIT)
 527
 528     if(GMX_IA32_ASM)
 529       if(GMX_DOUBLE)
 530         set(GMX_IA32_SSE2 1)
 531       else()
 532        set(GMX_IA32_SSE 1)
 533       endif()
 534     elseif(GMX_X86_64_ASM)
 535       if(GMX_DOUBLE)
 536        set(GMX_X86_64_SSE2 1)
 537       else()
 538         set(GMX_X86_64_SSE 1)
 539       endif()
 540     endif()
 541
 542 #    if(HAVE_PMMINTRIN_H)
 543 #        set(GMX_SSE3 1)
 544 #    endif(HAVE_PMMINTRIN_H)
 545 #    if(HAVE_SMMINTRIN_H)
 546 #        set(GMX_SSE4_1 1)
 547 #    endif(HAVE_SMMINTRIN_H)
 548
 549 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 550     set(GMX_FORTRAN 1)
 551     #these are switch on by default sometimes
 552     set(GMX_IA32_ASM 0)
 553     set(GMX_GMX_X86_64_ASM 0)
 554 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 555 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 556     message(STATUS "Configuring for BlueGene")
 557     set(GMX_BLUEGENE 1)
 558     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 559         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 560         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 561     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 562     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 563     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 564     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 565     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 566     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 567     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 568     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 569     list(APPEND GMX_EXTRA_LIBRARIES massv)
 570 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 571     set(GMX_POWER6 1)
 572     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 573     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 574 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 575     set(GMX_IA64_ASM 1)
 576     set(DISABLE_WATERWATER_NLIST 1)
 577     set(DISABLE_WATER_NLIST 1)
 578 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 579     check_include_files(altivec.h HAVE_ALTIVEC_H)
 580     if(HAVE_ALTIVEC_H)
 581         set(GMX_PPC_ALTIVEC 1)
 582     endif(HAVE_ALTIVEC_H)
 583 else(${GMX_ACCELERATION} STREQUAL "NONE")
 584     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 585 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 586
 587 if(GMX_FORTRAN OR GMX_POWER6)
 588     if (GMX_THREADS)
 589         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 590     endif(GMX_THREADS)
 591     enable_language(Fortran)
 592     include(FortranCInterface)
 593     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 594     if(extra_under_score)
 595         set(extrasuffix "_")
 596     endif(extra_under_score)
 597     if(prefix)
 598       set(prefix "${prefix} ##")
 599     endif(prefix)
 600
 601     if(isupper)
 602         set(F77_FUNCDEF   "${prefix} NAME ## ${suffix}")
 603         set(F77_FUNCDEF_  "${prefix} NAME ## ${suffix}${extrasuffix}")
 604     else(isupper)
 605         set(F77_FUNCDEF   "${prefix} name ## ${suffix}")
 606         set(F77_FUNCDEF_  "${prefix} name ## ${suffix}${extrasuffix}")
 607     endif(isupper)
 608 else(GMX_FORTRAN OR GMX_POWER6)
 609         set(F77_FUNCDEF   "name ## _")
 610         set(F77_FUNCDEF_  "name ## _")
 611 endif(GMX_FORTRAN OR GMX_POWER6)
 612
 613 # Process QM/MM Settings
 614 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 615 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 616     set(GMX_QMMM_GAUSSIAN 1)
 617 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 618     set(GMX_QMMM_MOPAC 1)
 619 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 620     set(GMX_QMMM_GAMESS 1)
 621 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 622     set(GMX_QMMM_ORCA 1)
 623 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 624     # nothing to do
 625 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 626     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 627 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 628
 629 # Process FFT library settings - if not OpenMM build
 630 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 631 set(PKG_FFT "")
 632 set(PKG_FFT_LIBS "")
 633 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 634 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 635     if(GMX_DOUBLE)
 636         find_package(FFTW3 REQUIRED)
 637                 include_directories(${FFTW3_INCLUDE_DIR})
 638         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 639         set(PKG_FFT "fftw3")
 640     else(GMX_DOUBLE)
 641         find_package(FFTW3F REQUIRED)
 642         include_directories(${FFTW3F_INCLUDE_DIR})
 643         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 644         set(PKG_FFT "fftw3f")
 645     endif(GMX_DOUBLE)
 646
 647     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 648         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 649     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 650
 651     set(GMX_FFT_FFTW3 1)
 652
 653 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 654 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 655     if(GMX_DOUBLE)
 656         find_package(FFTW2 REQUIRED)
 657     else(GMX_DOUBLE)
 658         find_package(FFTW2F REQUIRED)
 659     endif(GMX_DOUBLE)
 660
 661     if(NOT FFTW2_FOUND)
 662            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 663     endif(NOT FFTW2_FOUND)
 664     include_directories(${FFTW2_INCLUDE_DIR})
 665     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 666     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 667
 668     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 669         set(FFTW2_NAME_DFFTW 1)
 670     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 671         set(FFTW2_NAME_SFFTW 1)
 672     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 673         set(FFTW2_NAME_FFTW 1)
 674     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 675
 676     set(GMX_FFT_FFTW2 1)
 677 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 678 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 679     find_package(MKL REQUIRED)
 680     include_directories(${MKL_INCLUDE_DIR})
 681     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 682     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 683
 684     set(GMX_FFT_MKL 1)
 685     set(HAVE_MKL 1)
 686
 687 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 688 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 689 #    set(GMX_FFT_ACML 1)
 690 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 691     MESSAGE(STATUS "Using internal FFT library - fftpack")
 692     set(GMX_FFT_FFTPACK 1)
 693 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 694     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 695 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 696
 697 # MKL has BLAS/LAPACK routines
 698 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 699   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 700   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 701 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 702   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 703   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 704 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 705 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 706 mark_as_advanced(GMX_EXTERNAL_BLAS)
 707
 708 # Math and thread libraries must often come after all others when linking...
 709 if(HAVE_LIBM)
 710     list(APPEND GMX_EXTRA_LIBRARIES m)
 711 endif(HAVE_LIBM)
 712
 713
 714
 715 if(GMX_FAHCORE)
 716   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 717       "Path to swindirect.h")
 718   include_directories(${COREWRAP_INCLUDE_DIR})
 719 endif(GMX_FAHCORE)
 720
 721 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 722 # these are set after everything else
 723 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 724     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 725         FORCE)
 726     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 727         "Flags used by the compiler during all build types" FORCE)
 728     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 729         "Flags used by the compiler during all build types" FORCE)
 730     set(CMAKE_EXE_LINKER_FLAGS
 731         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 732         CACHE STRING "Linker flags" FORCE)
 733 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 734
 735 ########################################################################
 736 # Specify install locations and which subdirectories to process        #
 737 ########################################################################
 738 if ( DEFINED LIB )
 739     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
 740 else()
 741     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 742 endif()
 743 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 744 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 745 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 746 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 747
 748 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 749
 750 ##################################################################
 751 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 752 ##################################################################
 753 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 754     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 755     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 756     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 757     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 758 endif()
 759
 760 add_subdirectory(share)
 761 add_subdirectory(include)
 762 add_subdirectory(man)
 763 add_subdirectory(src)
 764 add_subdirectory(scripts)
 765
 766 #######################
 767 ## uninstall target
 768 #######################
 769     CONFIGURE_FILE(
 770                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 771                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 772                    IMMEDIATE @ONLY)
 773 ###########################
 774 ADD_CUSTOM_TARGET(uninstall
 775                   "${CMAKE_COMMAND}" -P
 776                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 777 ###########################
 778
 779
 780 ########################################################################
 781 # Tests                                                                #
 782 ########################################################################
 783
 784 include(CTest)
 785 mark_as_advanced(BUILD_TESTING)
 786 IF(BUILD_TESTING)
 787         enable_testing()
 788         add_test(TestBuildAll make)
 789         add_subdirectory(tests)
 790 ENDIF()
 791