arch/sparc/kernel/vmlinux.lds.S

   1 /* ld script to make SparcLinux kernel */
   2
   3 #include <asm-generic/vmlinux.lds.h>
   4
   5 OUTPUT_FORMAT("elf32-sparc", "elf32-sparc", "elf32-sparc")
   6 OUTPUT_ARCH(sparc)
   7 ENTRY(_start)
   8 jiffies = jiffies_64 + 4;
   9 SECTIONS
  10 {
  11   . = 0x10000 + SIZEOF_HEADERS;
  12   .text 0xf0004000 :
  13   {
  14     *(.text)
  15     SCHED_TEXT
  16     LOCK_TEXT
  17     *(.gnu.warning)
  18   } =0
  19   _etext = .;
  20   PROVIDE (etext = .);
  21   RODATA
  22   .data    :
  23   {
  24     *(.data)
  25     CONSTRUCTORS
  26   }
  27   .data1   : { *(.data1) }
  28   _edata  =  .;
  29   PROVIDE (edata = .);
  30   __start___fixup = .;
  31   .fixup   : { *(.fixup) }
  32   __stop___fixup = .;
  33   __start___ex_table = .;
  34   __ex_table : { *(__ex_table) }
  35   __stop___ex_table = .;
  36
  37   . = ALIGN(4096);
  38   __init_begin = .;
  39   _sinittext = .;
  40   .init.text : {
  41         *(.init.text)
  42   }
  43   _einittext = .;
  44   __init_text_end = .;
  45   .init.data : { *(.init.data) }
  46   . = ALIGN(16);
  47   __setup_start = .;
  48   .init.setup : { *(.init.setup) }
  49   __setup_end = .;
  50   __initcall_start = .;
  51   .initcall.init : {
  52         INITCALLS
  53   }
  54   __initcall_end = .;
  55   __con_initcall_start = .;
  56   .con_initcall.init : { *(.con_initcall.init) }
  57   __con_initcall_end = .;
  58   SECURITY_INIT
  59   . = ALIGN(4096);
  60   __initramfs_start = .;
  61   .init.ramfs : { *(.init.ramfs) }
  62   __initramfs_end = .;
  63   . = ALIGN(32);
  64   __per_cpu_start = .;
  65   .data.percpu  : { *(.data.percpu) }
  66   __per_cpu_end = .;
  67   . = ALIGN(4096);
  68   __init_end = .;
  69   . = ALIGN(32);
  70   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  71
  72   __bss_start = .;
  73   .sbss      : { *(.sbss) *(.scommon) }
  74   .bss       :
  75   {
  76    *(.dynbss)
  77    *(.bss)
  78    *(COMMON)
  79   }
  80   _end = . ;
  81   PROVIDE (end = .);
  82   /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
  83
  84   STABS_DEBUG
  85
  86   DWARF_DEBUG
  87 }