board/eric/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   .resetvec 0xFFFFFFFC :
  31   {
  32     *(.resetvec)
  33   } = 0xffff
  34
  35   /* Read-only sections, merged into text segment: */
  36   . = + SIZEOF_HEADERS;
  37   .interp : { *(.interp) }
  38   .hash          : { *(.hash)           }
  39   .dynsym        : { *(.dynsym)         }
  40   .dynstr        : { *(.dynstr)         }
  41   .rel.text      : { *(.rel.text)               }
  42   .rela.text     : { *(.rela.text)      }
  43   .rel.data      : { *(.rel.data)               }
  44   .rela.data     : { *(.rela.data)      }
  45   .rel.rodata    : { *(.rel.rodata)     }
  46   .rela.rodata   : { *(.rela.rodata)    }
  47   .rel.got       : { *(.rel.got)                }
  48   .rela.got      : { *(.rela.got)               }
  49   .rel.ctors     : { *(.rel.ctors)      }
  50   .rela.ctors    : { *(.rela.ctors)     }
  51   .rel.dtors     : { *(.rel.dtors)      }
  52   .rela.dtors    : { *(.rela.dtors)     }
  53   .rel.bss       : { *(.rel.bss)                }
  54   .rela.bss      : { *(.rela.bss)               }
  55   .rel.plt       : { *(.rel.plt)                }
  56   .rela.plt      : { *(.rela.plt)               }
  57   .init          : { *(.init)   }
  58   .plt : { *(.plt) }
  59   .text      :
  60   {
  61     /* WARNING - the following is hand-optimized to fit within  */
  62     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  63
  64     cpu/ppc4xx/start.o  (.text)
  65     board/eric/init.o   (.text)
  66     cpu/ppc4xx/kgdb.o   (.text)
  67     cpu/ppc4xx/traps.o  (.text)
  68     cpu/ppc4xx/interrupts.o     (.text)
  69     cpu/ppc4xx/serial.o (.text)
  70     cpu/ppc4xx/cpu_init.o       (.text)
  71     cpu/ppc4xx/speed.o  (.text)
  72     cpu/ppc4xx/4xx_enet.o       (.text)
  73     common/dlmalloc.o   (.text)
  74     lib_generic/crc32.o         (.text)
  75     lib_ppc/extable.o   (.text)
  76     lib_generic/zlib.o          (.text)
  77
  78 /*    . = env_offset;*/
  79     common/environment.o(.text)
  80
  81     *(.text)
  82     *(.fixup)
  83     *(.got1)
  84   }
  85   _etext = .;
  86   PROVIDE (etext = .);
  87   .rodata    :
  88   {
  89     *(.rodata)
  90     *(.rodata1)
  91     *(.rodata.str1.4)
  92     *(.eh_frame)
  93   }
  94   .fini      : { *(.fini)    } =0
  95   .ctors     : { *(.ctors)   }
  96   .dtors     : { *(.dtors)   }
  97
  98   /* Read-write section, merged into data segment: */
  99   . = (. + 0x00FF) & 0xFFFFFF00;
 100   _erotext = .;
 101   PROVIDE (erotext = .);
 102   .reloc   :
 103   {
 104     *(.got)
 105     _GOT2_TABLE_ = .;
 106     *(.got2)
 107     _FIXUP_TABLE_ = .;
 108     *(.fixup)
 109   }
 110   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 111   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 112
 113   .data    :
 114   {
 115     *(.data)
 116     *(.data1)
 117     *(.sdata)
 118     *(.sdata2)
 119     *(.dynamic)
 120     CONSTRUCTORS
 121   }
 122   _edata  =  .;
 123   PROVIDE (edata = .);
 124
 125   . = .;
 126   __u_boot_cmd_start = .;
 127   .u_boot_cmd : { *(.u_boot_cmd) }
 128   __u_boot_cmd_end = .;
 129
 130
 131   . = .;
 132   __start___ex_table = .;
 133   __ex_table : { *(__ex_table) }
 134   __stop___ex_table = .;
 135
 136   . = ALIGN(256);
 137   __init_begin = .;
 138   .text.init : { *(.text.init) }
 139   .data.init : { *(.data.init) }
 140   . = ALIGN(256);
 141   __init_end = .;
 142
 143   __bss_start = .;
 144   .bss       :
 145   {
 146    *(.sbss) *(.scommon)
 147    *(.dynbss)
 148    *(.bss)
 149    *(COMMON)
 150   }
 151   _end = . ;
 152   PROVIDE (end = .);
 153 }