meson.build

   1 project('liba', 'c', 'cpp',
   2         default_options: [
   3             'c_std=c11',
   4             'cpp_std=c++11',
   5             'b_ndebug=if-release',
   6             'buildtype=debugoptimized',
   7         ],
   8         license: 'MPL-2.0',
   9         version: '0.1.14')
  10
  11 a_have_h = configuration_data()
  12 a_have_h.set('version', meson.version())
  13 a_have_h.set('A_VERSION', meson.project_version())
  14 a_have_h.set('A_VERSION_MAJOR', meson.project_version().split('.')[0])
  15 a_have_h.set('A_VERSION_MINOR', meson.project_version().split('.')[1])
  16 a_have_h.set('A_VERSION_PATCH', meson.project_version().split('.')[2])
  17 a_have_h.set('A_SIZE_FLOAT', get_option('float'))
  18 if target_machine.endian() == 'little'
  19     a_have_h.set('A_BYTE_ORDER', 1234)
  20 elif target_machine.endian() == 'big'
  21     a_have_h.set('A_BYTE_ORDER', 4321)
  22 endif
  23
  24 compiler = meson.get_compiler('c')
  25 a_have_h.set('A_SIZE_POINTER', compiler.sizeof('void *'))
  26
  27 math = ['expm1', 'log1p', 'hypot', 'atan2',
  28         'csqrt', 'cpow', 'cexp', 'clog',
  29         'csin', 'ccos', 'ctan',
  30         'csinh', 'ccosh', 'ctanh',
  31         'casin', 'cacos', 'catan',
  32         'casinh', 'cacosh', 'catanh']
  33
  34 foreach func: math
  35     float = get_option('float').to_int()
  36     have = 'A_HAVE_' + func.to_upper()
  37     if  float == 4
  38         func = func + 'f'
  39     elif float > 8
  40         func = func + 'l'
  41     endif
  42     if compiler.has_function(func)
  43         a_have_h.set(have, '1')
  44     endif
  45 endforeach
  46
  47 configure_file(
  48     input: 'include/a.meson.h.in',
  49     output: 'a.meson.h',
  50     configuration: a_have_h,
  51 )
  52
  53 c_args = []
  54 sources = [
  55     'include/a/a.h',
  56     'include/a/avl.h',
  57     'include/a/buf.h',
  58     'include/a/complex.h',
  59     'include/a/crc.h',
  60     'include/a/fuzzy.h',
  61     'include/a/hpf.h',
  62     'include/a/list.h',
  63     'include/a/lpf.h',
  64     'include/a/math.h',
  65     'include/a/mf.h',
  66     'include/a/notefreqs.h',
  67     'include/a/pid.h',
  68     'include/a/pid_fuzzy.h',
  69     'include/a/pid_neuro.h',
  70     'include/a/poly.h',
  71     'include/a/que.h',
  72     'include/a/rbt.h',
  73     'include/a/regress_linear.h',
  74     'include/a/slist.h',
  75     'include/a/str.h',
  76     'include/a/tf.h',
  77     'include/a/trajbell.h',
  78     'include/a/trajpoly3.h',
  79     'include/a/trajpoly5.h',
  80     'include/a/trajpoly7.h',
  81     'include/a/trajtrap.h',
  82     'include/a/utf.h',
  83     'include/a/vec.h',
  84     'include/a/version.h',
  85     'src/a.c',
  86     'src/avl.c',
  87     'src/buf.c',
  88     'src/complex.c',
  89     'src/crc.c',
  90     'src/fuzzy.c',
  91     'src/math.c',
  92     'src/mf.c',
  93     'src/pid.c',
  94     'src/pid_fuzzy.c',
  95     'src/pid_neuro.c',
  96     'src/poly.c',
  97     'src/que.c',
  98     'src/rbt.c',
  99     'src/regress_linear.c',
 100     'src/str.c',
 101     'src/tf.c',
 102     'src/trajbell.c',
 103     'src/trajpoly3.c',
 104     'src/trajpoly5.c',
 105     'src/trajpoly7.c',
 106     'src/trajtrap.c',
 107     'src/utf.c',
 108     'src/vec.c',
 109     'src/version.c',
 110 ]
 111
 112 a_include = include_directories('include')
 113 a_meson_h = meson.current_build_dir() / 'a.meson.h'
 114 a_h = meson.current_source_dir() / 'include' / 'a' / 'a.h'
 115
 116 python = import('python').find_installation()
 117 res = run_command(python, '-c', '''import os, sys
 118 dir = os.path.dirname('@1@')
 119 src = os.path.basename('@0@')
 120 dst = os.path.basename('@1@')
 121 cur = "#if defined(A_HAVE_H)"
 122 new = '#include "' + dst + '"\n' + cur
 123 with open('@0@', "r") as f:
 124     txt = f.read()
 125 res = txt.replace(cur, new)
 126 if res != txt:
 127     new = os.path.join(dir, src)
 128     with open(new, "wb") as f:
 129         f.write(res.encode())
 130 dir = os.path.dirname('@0@')
 131 res = os.path.relpath('@1@', dir)
 132 sys.stdout.write(res.replace("\\", "/"))
 133 '''.format(a_h, a_meson_h), capture: true, check: true
 134 )
 135 if res.returncode() == 0
 136     c_args += ['-DA_EXPORTS', '-DA_HAVE_H="' + res.stdout() + '"']
 137 endif
 138
 139 a = both_libraries('a', sources, c_args: c_args, cpp_args: c_args,
 140     dependencies: compiler.find_library('m', required: false),
 141     implicit_include_directories: false,
 142     include_directories: a_include,
 143     install: true,
 144     link_args: get_option('math'),
 145     name_prefix: 'lib',
 146     pic: true,
 147     version: meson.project_version(),
 148 )
 149
 150 install_headers(a_meson_h, subdir: 'a')
 151 install_headers(meson.current_build_dir() / 'a.h', subdir: 'a')
 152 install_subdir('include/a', exclude_files: ['a.h'],
 153     install_dir: get_option('includedir'),
 154 )
 155
 156 if get_option('rust')
 157     rust_args = []
 158     add_languages('rust')
 159     if get_option('float').to_int() == 4
 160         rust_args += ['--cfg', 'feature="float"']
 161     endif
 162     static_library('liba', 'src/lib.rs',
 163         rust_args: rust_args,
 164         install: true,
 165         link_with: a.get_static_lib(),
 166     )
 167 endif
 168
 169 subdir('java')
 170 subdir('lua')
 171 subdir('python')
 172 subdir('quickjs')