configure.ac

   1 ##
   2 ## This file is part of the libjaylink project.
   3 ##
   4 ## Copyright (C) 2014-2015 Marc Schink <jaylink-dev@marcschink.de>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([libjaylink], [0.1.0], [jaylink-dev@marcschink.de], [libjaylink],
  23         [http://git.zapb.de/libjaylink.git])
  24 AC_CONFIG_HEADERS([config.h])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CONFIG_AUX_DIR([build-aux])
  27
  28 AC_CANONICAL_HOST
  29
  30 AM_INIT_AUTOMAKE([-Wall -Werror check-news])
  31
  32 # Enable additional compiler warnings via -Wall and -Wextra. Use hidden
  33 # visibility for all non-static symbols by default with -fvisibility=hidden.
  34 JAYLINK_CFLAGS="-Wall -Wextra -Werror -fvisibility=hidden"
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38
  39 # Automake >= 1.12 requires AM_PROG_AR when using options -Wall and -Werror.
  40 # To be compatible with older versions of Automake use AM_PROG_AR if it's
  41 # defined only. This line must occur before LT_INIT.
  42 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  43
  44 # Initialize libtool.
  45 LT_INIT
  46
  47 # Initialize pkg-config.
  48 PKG_PROG_PKG_CONFIG
  49
  50 # Checks for libraries.
  51
  52 # Check for libusb-1.0 which is always needed.
  53 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9])
  54
  55 # Checks for header files.
  56
  57 # Checks for typedefs, structures, and compiler characteristics.
  58 AC_C_BIGENDIAN
  59
  60 # Checks for library functions.
  61
  62 # Disable progress and informational output of libtool.
  63 AC_SUBST([AM_LIBTOOLFLAGS], '--silent')
  64
  65 JAYLINK_SET_PACKAGE_VERSION([JAYLINK_VERSION_PACKAGE], [AC_PACKAGE_VERSION])
  66
  67 # Libtool interface version of libjaylink. This is not the same as the package
  68 # version. For information about the versioning system of libtool, see:
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Libtool-versioning
  70 JAYLINK_SET_LIBRARY_VERSION([JAYLINK_VERSION_LIBRARY], [0:0:0])
  71
  72 AC_ARG_ENABLE([subproject-build], AS_HELP_STRING([--enable-subproject-build],
  73         [enable sub-project build [default=no]]))
  74
  75 AM_CONDITIONAL([SUBPROJECT_BUILD],
  76         [test "x$enable_subproject_build" = "xyes"])
  77
  78 # Libtool interface version is not used for sub-project build as libjaylink is
  79 # built as libtool convenience library.
  80 AS_IF([test "x$enable_subproject_build" != "xyes"],
  81         [JAYLINK_LDFLAGS="-version-info $JAYLINK_VERSION_LIBRARY"])
  82
  83 # Use C99 compatible stdio functions on MinGW instead of the incompatible
  84 # functions provided by Microsoft.
  85 AS_CASE([$host_os], [mingw*],
  86         [AC_DEFINE([__USE_MINGW_ANSI_STDIO], [1],
  87                 [Define to 1 to use C99 compatible stdio functions on MinGW.])])
  88
  89 # Add the Winsock2 library on MinGW for socket and other network-related
  90 # functions.
  91 AS_CASE([$host_os], [mingw*], [JAYLINK_LIBS="$JAYLINK_LIBS -lws2_32"])
  92
  93 AC_SUBST([JAYLINK_CFLAGS])
  94 AC_SUBST([JAYLINK_LDFLAGS])
  95 AC_SUBST([JAYLINK_LIBS])
  96
  97 AC_CONFIG_FILES([Makefile])
  98 AC_CONFIG_FILES([libjaylink/Makefile])
  99 AC_CONFIG_FILES([libjaylink/version.h])
 100 AC_CONFIG_FILES([libjaylink.pc])
 101 AC_CONFIG_FILES([Doxyfile])
 102
 103 AC_OUTPUT
 104
 105 echo
 106 echo "libjaylink configuration summary:"
 107 echo " - Package version ................ $JAYLINK_VERSION_PACKAGE"
 108 echo " - Library version ................ $JAYLINK_VERSION_LIBRARY"
 109 echo " - Installation prefix ............ $prefix"
 110 echo " - Building on .................... $build"
 111 echo " - Building for ................... $host"
 112 echo